WOLFRAM

Wolfram 语言与系统参考资料中心

DifferentiatorFilter[data,ωc]

对数据数组应用截止频率为 ωc 的微分滤波器.

DifferentiatorFilter[data,ωc,n]

使用长度为 n 的滤波器核.

DifferentiatorFilter[data,ωc,n,wfun]

对滤波器核应用平滑窗 wfun.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
数据  
参数  
选项  
Padding  
SampleRate  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

DifferentiatorFilter

DifferentiatorFilter[data,ωc]

对数据数组应用截止频率为 ωc 的微分滤波器.

DifferentiatorFilter[data,ωc,n]

使用长度为 n 的滤波器核.

DifferentiatorFilter[data,ωc,n,wfun]

对滤波器核应用平滑窗 wfun.

更多信息和选项

  • DifferentiatorFilter 是一个有限冲击响应 (FIR) 离散时间滤波器，通常用于近似采样数据的导数.
  • data 可以采用以下形式：
  • list任意维数的数值数组
    tseries暂态数据，如 TimeSeries 和 TemporalData
    image任意 Image 或 Image3D 对象
    audioAudio 或 Sound 对象
    videoVideo 对象
  • 当应用于图像和多维数组时，滤波器连续应用于每个维度，从第 1 层开始. 对第 i 维，DifferentiatorFilter[data,{ωc1,ωc2,…}] 使用频率 ωci.
  • 截止频率为 ωc 的滤波降低了导数对信号噪声的敏感性，平滑量取决于截止频率 ωc 的值.
  • 截止频率 ωc 应位于 0 和 之间. ωc 的值越小，平滑度越好.
  • DifferentiatorFilter[data,ωc] 使用适用于截止频率 ωc 和输入 data 的滤波器核长度和平滑窗.
  • 典型的平滑窗 wfun 包括：
  • BlackmanWindow使用 Blackman 窗平滑
    DirichletWindow不使用平滑
    HammingWindow使用 Hamming 窗平滑
    {v1,v2,…}使用值为 vi 的窗
    f通过在 和 之间采样 f 创建窗
  • 可以给出以下选项：
  • Padding "Fixed"要用的填充值
    SampleRate Automatic对输入假定的采样率
  • 默认情况下，对于图像和数据，均有 SampleRate->1. 对于采样率为 r 的采样 sound 对象，使用 SampleRate->r.
  • 当 SampleRate->r 时，截止频率 ωc 应位于 0 和 r× 之间.

范例

打开所有单元 关闭所有单元

基本范例  (2)

对余弦抽样信号进行微分：

Wolfram Language code: dx = 0.1; data = Table[Cos[2x], {x, 0, 2π, dx}]; ListLinePlot[{data, (1/ 2dx) DifferentiatorFilter[data, Pi, 20]}]

对图像求微分：

Wolfram Language code: DifferentiatorFilter[[image], Pi / 2]//ImageAdjust

范围  (10)

数据  (7)

对一维三角序列进行滤波：

Wolfram Language code: data = BoxMatrix[5, {41}]; ListLinePlot[{data, DifferentiatorFilter[data, 1.]}, PlotRange -> All]

对二维脉冲序列进行滤波：

Wolfram Language code: data = Table[UnitBox[(n/7), (m/7)], {n, -7, 7}, {m, -7, 7}]; ListPlot3D[data]
Wolfram Language code: ListPlot3D[DifferentiatorFilter[data, 1.], PlotRange -> All]

对 TimeSeries 进行滤波：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{0., -0.27267267057145633, -0.6672983789995302, -0.5338541947930846, -0.6117404489279314, -0.6755527076595494, -0.02125421294486496, -0.10792797291843935, -0.6138271235477938, -0.3248568606554575, -0.08843449054 ... 2053424, -0.49980440691873723, -0.5388679788215971, -0.4101602764645551}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1]; filtered = DifferentiatorFilter[ts, Quantity[10, "Hertz"]];
Wolfram Language code: ListLinePlot[{ts, 5filtered}, PlotLegends -> {"original", "filtered"}, PlotRange -> All]

方波音频信号的数字微分：

Wolfram Language code: a = AudioGenerator["Square"]
Wolfram Language code: DifferentiatorFilter[a, Quantity[15000, "Hertz"]]

对视频进行滤波：

Wolfram Language code: DifferentiatorFilter[Video["ExampleData/fish.mp4"], 3]

三维图像的微分：

Wolfram Language code: 200DifferentiatorFilter[[image], Pi]

精确滤波：

Wolfram Language code: DifferentiatorFilter[{0, 0, 0, 1, 1, 1, 0, 0, 0}, Pi, 4]

参数  (3)

对于音频信号，数值截止频率会被解释为以弧度每秒为单位：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-iz4x8)"]\);
Wolfram Language code: DifferentiatorFilter[a, 10000 2 Pi] === DifferentiatorFilter[a, Quantity[10000*2*Pi, "Radians"/"Seconds"]] === DifferentiatorFilter[a, Quantity[10000, "Hertz"]]

使用长度为 7 的滤波器对单位阶跃序列进行微分：

Wolfram Language code: DifferentiatorFilter[{0., 0., 0., 0., 1., 1., 1., 1.}, Pi, 6]

使用不同的截止频率：

Wolfram Language code: DifferentiatorFilter[{0., 0., 0., 0., 1., 1., 1., 1.}, Pi / 2, 6]

使用特定窗口函数：

Wolfram Language code: DifferentiatorFilter[{0., 0., 0., 0., 1., 1., 1., 1.}, Pi, 6, BlackmanWindow]

用数值列表指定窗口函数：

Wolfram Language code: DifferentiatorFilter[{0., 0., 0., 0., 1., 1., 1., 1.}, Pi, 6, {1, 1, 1, 1, 1, 1}]

在各维度使用不同的截止频率：

Wolfram Language code: DifferentiatorFilter[[image], {Pi / 3, Pi}, 20]//ImageAdjust

选项  (4)

Padding  (2)

缺省情况下，使用 "Fixed" 填充方法：

Wolfram Language code: DifferentiatorFilter[[image], Pi / 3, 21]//ImageAdjust

用 Padding->None 消除潜在的图像边界伪影：

Wolfram Language code: DifferentiatorFilter[[image], Pi / 3, 21, Padding -> None]//ImageAdjust

不同的填充方法导致边呈现不同的效果：

Wolfram Language code: ramp = Range[21] / 21. + RandomReal[.1, 21]; GraphicsRow@(ListLinePlot[{ramp, DifferentiatorFilter[ramp, Pi, 6, Padding -> #]}, ...]& /@ {"Fixed", "Periodic", 0})

SampleRate  (2)

使用微分半带滤波器，假定归一化采样率为 1：

Wolfram Language code: DifferentiatorFilter[{0, 0, 0, 1, 1, 1, 0, 0, 0}, π / 2., 5]

假定采样率为 3：

Wolfram Language code: DifferentiatorFilter[{0, 0, 0, 1, 1, 1, 0, 0, 0}, 3 π / 2., 5, SampleRate -> 3]

将微分半带滤波器应用于采样率为 的音频信号：

Wolfram Language code: a = AudioGenerator[Sin[11025 2 π #^2]&]; sr = QuantityMagnitude@AudioSampleRate[a]
Wolfram Language code: DifferentiatorFilter[a, sr π / 2., 21]//Periodogram

应用  (2)

使用导数滤波突出显示图像中的边：

Wolfram Language code: DifferentiatorFilter[[image], Pi, 6]//ImageAdjust

将三角波转换为方波：

Wolfram Language code: x = Table[TriangleWave[n / 32], {n, 0, 63}]//N; y = DifferentiatorFilter[x, Pi, 6, Padding -> "Periodic"];
Wolfram Language code: GraphicsRow[{ListPlot[x, Filling -> 0, ImageSize -> Small], ListPlot[y, Filling -> 0, ImageSize -> Small]}]

属性和关系  (7)

使用 LeastSquaresFilterKernel 和 Hamming 窗创建微分滤波器：

Wolfram Language code: n = 5; ω = 1.5; win = Array[HammingWindow, n, {-1 / 2, 1 / 2}]; ker = win LeastSquaresFilterKernel[{"Differentiator", ω}, n]
Wolfram Language code: ListConvolve[ker, {0, 0, 0, 0, 1, 1, 1, 1}, Ceiling[n / 2], 0]

与 DifferentiatorFilter 比较：

Wolfram Language code: DifferentiatorFilter[{0, 0, 0, 0, 1, 1, 1, 1}, ω, n, win, Padding -> 0]

长度为 21 的全带导数滤波器的冲激响应：

Wolfram Language code: h = DifferentiatorFilter[ArrayPad[{1.}, 10], Pi, 21]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

滤波器的幅频响应：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

没有平滑窗口的长度为奇数的全带导数滤波器的幅度谱：

Wolfram Language code: Plot[Evaluate@Abs[ListFourierSequenceTransform[DifferentiatorFilter[ArrayPad[{1.}, 10], Pi, 21, None], ω]], {ω, 0, π}]

长度为偶数的导数滤波器的冲激响应：

Wolfram Language code: h = DifferentiatorFilter[ArrayPad[{1.}, 10], Pi, 20]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

滤波器的幅频响应：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}, PlotRange -> All]

没有平滑窗口的长度为偶数的全带导数滤波器的幅度谱：

Wolfram Language code: Plot[Evaluate@Abs[ListFourierSequenceTransform[DifferentiatorFilter[ArrayPad[{1.}, 10], Pi, 20, None], ω]], {ω, 0, π}]

不同的长度为奇数的微分滤波器的幅值响应：

Wolfram Language code: Manipulate[ ListLinePlot[Abs[Fourier[DifferentiatorFilter[ArrayPad[{1.}, 128], Pi, n], FourierParameters -> {1, -1}]][[ ;; 129]], ...], {{n, 21}, 3, 127, 2}]

长度为奇数的半带导数滤波器的冲激响应：

Wolfram Language code: h = DifferentiatorFilter[ArrayPad[{1.}, 10], Pi / 2, 21]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

滤波器的幅频响应：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

可能存在的问题  (1)

如果设置 PaddingNone，输出的长度将小于输入的长度：

Wolfram Language code: DifferentiatorFilter[{0., 0., 0., 1., 1., 1.}, 1., Padding -> None]
Wolfram Research (2012)，DifferentiatorFilter，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DifferentiatorFilter.html （更新于 2025 年）.

文本

Wolfram Research (2012)，DifferentiatorFilter，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DifferentiatorFilter.html （更新于 2025 年）.

CMS

Wolfram 语言. 2012. "DifferentiatorFilter." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/DifferentiatorFilter.html.

APA

Wolfram 语言. (2012). DifferentiatorFilter. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DifferentiatorFilter.html 年

BibTeX

@misc{reference.wolfram_2026_differentiatorfilter, author="Wolfram Research", title="{DifferentiatorFilter}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/DifferentiatorFilter.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_differentiatorfilter, organization={Wolfram Research}, title={DifferentiatorFilter}, year={2025}, url={https://reference.wolfram.com/language/ref/DifferentiatorFilter.html}, note=[Accessed: 16-September-2026]}