WOLFRAM

Wolfram 语言与系统参考资料中心

DimensionReduce[{example1,example2,…}]

把实例 examplei 投影成低维近似流形.

DimensionReduce[examples,n]

投影到 n 维空间中的近似流形.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
FeatureExtractor  
FeatureTypes  
Method  
PerformanceGoal  
TargetDevice  
应用  
数据集可视化  
参见
相关指南
历史
按以下格式引用：

DimensionReduce

DimensionReduce[{example1,example2,…}]

把实例 examplei 投影成低维近似流形.

DimensionReduce[examples,n]

投影到 n 维空间中的近似流形.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

对向量降维：

Wolfram Language code: vectors = {{1, 2, 3}, {2, 3, 5}, {3, 5, 8}, {4, 5, 8.5}};
Wolfram Language code: DimensionReduce[vectors]

指定目标维度为 1：

Wolfram Language code: DimensionReduce[vectors, 1]

对混合类型数据集降维：

Wolfram Language code: DimensionReduce[{{1.4, "A"}, {1.5, "A"}, {2.3, "B"}, {5.4, "B"}}]

范围  (6)

创建并可视化随机三维向量：

Wolfram Language code: vectors = Join[RandomReal[{0, 3}, {1000, 3}], RandomReal[{2, 5}, {1000, 3}], RandomReal[{4, 7}, {1000, 3}] ];
Wolfram Language code: ListPointPlot3D[vectors]

将此数据集降到二维，并可视化：

Wolfram Language code: ListPlot[DimensionReduce[vectors, 2]]

图像数据集的降维：

Wolfram Language code: DimensionReduce[{[image], [image], [image] , [image], [image], [image]}, 5]

文本数据集的降维：

Wolfram Language code: DimensionReduce[{"the cat is grey", "my cat is fast", "this dog is scary", "the big dog"}]

DateObject 列表的降维：

Wolfram Language code: DimensionReduce[{DateObject[{2014, 5, 5, 9, 53, 6.30158}, "Instant", "Gregorian", -6.], DateObject[{2000, 1, 1, 0, 0, 0.}, "Instant", "Gregorian", -6.], DateObject[{2006, 12}, "Month", "Gregorian", -6.], DateObject[{2007, 8, 23}, "Day", "Gregorian", -6.], DateObject[{2016, 4, 4, 15, 59, 18.2738}, "Instant", "Gregorian", -4.]}]

混合类型数据集的降维：

Wolfram Language code: DimensionReduce[{{"the cat is grey", [image]}, {"my cat is fast", [image]}, {"this dog is scary", [image]}, {"the big dog", [image]}}]

关联列表的降维：

Wolfram Language code: DimensionReduce[{<|"age" -> 32, "height" -> 160, "gender" -> "female"|>, <|"height" -> 183, "age" -> 41, "gender" -> "female"|>, <|"height" -> 123, "age" -> 30, "gender" -> "female"|>, <|"height" -> 175, "age" -> 21, "gender" -> "male"|>, <|"height" -> 150, "age" -> 11, "gender" -> "male"|>, <|"age" -> 52, "height" -> 164, "gender" -> "female"|>}]

选项  (6)

FeatureExtractor  (1)

对由自定义函数和提取方法预处理过的文本降维：

Wolfram Language code: DimensionReduce[{"The cat is grey.", "My cat is fast.", "This dog is scary." , "The big dog."}, FeatureExtractor -> {ToUpperCase, RemoveDiacritics, "SegmentedWords"}]

FeatureTypes  (1)

简单数据集的降维：

Wolfram Language code: DimensionReduce[{{1, "A"}, {2, "A"}, {2, "B"}, {1, "B"}}]

第一个特征被解释为数据型. 使用 FeatureTypes 将第一个特征解释为名义型：

Wolfram Language code: DimensionReduce[{{1, "A"}, {2, "A"}, {2, "B"}, {1, "B"}}, FeatureTypes -> <|1 -> "Nominal"|>]

Method  (2)

使用 t-SNE 方法对费雪鸢尾花卉（Fisher Iris）数据集降维：

Wolfram Language code: iris = ExampleData[{"MachineLearning", "FisherIris"}, "Data"];
Wolfram Language code: features = DimensionReduce[iris[[All, 1]], 2, Method -> "TSNE"];

可视化降维后的数据集：

Wolfram Language code: byspecies = GroupBy[Thread[features -> iris[[All, 2]]], Last -> First]; ListPlot[Values[byspecies], PlotLegends -> Keys[byspecies]]

使用不同的 Perplexity 值进行同一操作：

Wolfram Language code: features = DimensionReduce[iris[[All, 1]], 2, Method -> {"TSNE", "Perplexity" -> 100}];
Wolfram Language code: byspecies = GroupBy[Thread[features -> iris[[All, 2]]], Last -> First]; ListPlot[Values[byspecies], PlotLegends -> Keys[byspecies]]

使用自动编码方法降低一些图像的维度：

Wolfram Language code: flowers = {[image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image]};
Wolfram Language code: reduced = DimensionReduce[flowers, 2, Method -> "Autoencoder"];

可视化已降维的数据集：

Wolfram Language code: ListPlot[MapThread[Labeled[#1, #2]&, {reduced, flowers}]]

PerformanceGoal  (1)

加载 MNIST 数据集：

Wolfram Language code: data = ResourceData[ResourceObject["MNIST"], "TestData"];

采用设置 PerformanceGoal"Quality" 对图像数据进行降维，并测量训练时间：

Wolfram Language code: AbsoluteTiming[quality = DimensionReduce[data[[All, 1]], 2, Method -> "TSNE", PerformanceGoal -> "Quality"];]

使用 PerformanceGoal"Speed" 进行同一操作：

Wolfram Language code: AbsoluteTiming[speed = DimensionReduce[data[[All, 1]], 2, Method -> "TSNE", PerformanceGoal -> "Speed"];]

可视化结果：

Wolfram Language code: groupquality = GroupBy[Thread[quality -> data[[All, 2]]], Last -> First]; ListPlot[Values[groupquality], PlotLegends -> Keys[groupquality]]
Wolfram Language code: groupspeed = GroupBy[Thread[speed -> data[[All, 2]]], Last -> First]; ListPlot[Values[groupspeed], PlotLegends -> Keys[groupspeed]]

TargetDevice  (1)

使用系统默认的 GPU 上完全连接的 "AutoEncoder" 约简向量的维数并查看 AbsoluteTiming：

Wolfram Language code: AbsoluteTiming[DimensionReduce[RandomReal[1, {10000, 10}], Method -> {"AutoEncoder", "NetworkType" -> "FullyConnected"}, TargetDevice -> "GPU"]]

比较之前的时间和使用默认 CPU 计算获取的时间：

Wolfram Language code: AbsoluteTiming[DimensionReduce[RandomReal[1, {10000, 10}], Method -> {"AutoEncoder", "NetworkType" -> "FullyConnected"}]]

应用  (1)

数据集可视化  (1)

从 ExampleData 加载费雪鸢尾花卉数据集：

Wolfram Language code: iris = ExampleData[{"MachineLearning", "FisherIris"}, "Data"];
Wolfram Language code: ExampleData[{"MachineLearning", "FisherIris"}, "LongDescription"]
Wolfram Language code: RandomSample[iris, 5]

对特征降维：

Wolfram Language code: features = DimensionReduce[iris[[All, 1]], 2];

根据属种对范例分组：

Wolfram Language code: byspecies = GroupBy[Thread[features -> iris[[All, 2]]], Last -> First];

可视化降维数据集：

Wolfram Language code: ListPlot[Values[byspecies], PlotLegends -> Keys[byspecies]]
Wolfram Research (2015)，DimensionReduce，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DimensionReduce.html （更新于 2018 年）.

文本

Wolfram Research (2015)，DimensionReduce，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DimensionReduce.html （更新于 2018 年）.

CMS

Wolfram 语言. 2015. "DimensionReduce." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2018. https://reference.wolfram.com/language/ref/DimensionReduce.html.

APA

Wolfram 语言. (2015). DimensionReduce. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DimensionReduce.html 年

BibTeX

@misc{reference.wolfram_2026_dimensionreduce, author="Wolfram Research", title="{DimensionReduce}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/DimensionReduce.html}", note=[Accessed: 05-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dimensionreduce, organization={Wolfram Research}, title={DimensionReduce}, year={2018}, url={https://reference.wolfram.com/language/ref/DimensionReduce.html}, note=[Accessed: 05-September-2026]}