WOLFRAM

Wolfram 语言与系统参考资料中心

Disk[{x,y},r]

表示以点为 {x,y} 中心、r 为半径的圆盘.

Disk[{x,y}]

给出半径为 1 的圆盘.

Disk[{x,y},{rx,ry}]

给出一个半轴为 rx 和 ry 的轴对齐椭圆盘.

Disk[{x,y},…,{θ1,θ2}]

给出一个从角 θ1 到 θ2 的扇区.

Disk[{{x1,y1},{x2,y2},…},…]

给出以给定坐标为中心的多个相同的圆盘.

更多信息和选项
Details and Options Details and Options
背景
范例  
基本范例  
范围  
图形  
规范  
样式化  
坐标  
区域  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

Disk

Disk[{x,y},r]

表示以点为 {x,y} 中心、r 为半径的圆盘.

Disk[{x,y}]

给出半径为 1 的圆盘.

Disk[{x,y},{rx,ry}]

给出一个半轴为 rx 和 ry 的轴对齐椭圆盘.

Disk[{x,y},…,{θ1,θ2}]

给出一个从角 θ1 到 θ2 的扇区.

Disk[{{x1,y1},{x2,y2},…},…]

给出以给定坐标为中心的多个相同的圆盘.

更多信息和选项

背景

  • Disk 是一个图形和几何图元，表示一个圆盘、椭圆盘或平面的扇区. 并且，Disk[{x,y},r] 表示中心在 {x,y} 的 中半径为 r 的圆盘，Disk[{x,y},{rx,ry}] 表示 中，轴对齐填充的椭圆，中心为 {x,y}，半轴长为 rx 和 ry，Disk[{x,y},…,{θ1,θ2}] 表示（潜在椭圆）扇区，中心在 {x,y}，范围在正 轴逆时针弧度度量的 θ1 与 θ2 之间. 缩短形式 Disk[{x,y}] 等同于 Disk[{x,y},1]，其中 Disk[] 自动等同于 Disk[{0,0},1].
  • Disk 对象的格式化可以通过把他们放在 Graphics 表达式中进行. 图形中 Disk 对象的外观的修改可通过制定边和面指令 EdgeForm 和 FaceForm，颜色指令，例如 Red，透明指令 Opacity 以及样式选项 Antialiasing 进行.
  • Disk 还可用于执行计算的区域规范. 例如，Integrate[1,{x,y}∈Disk[{0,0},r]] 和 Area[Disk[{0,0},r]] 均返回半径为 的圆盘面积 ，以及，Perimeter[Disk[{x,y},r]] 返回周长 .
  • Disk 也与其他符号相关. Circle 表示圆盘的边界，可使用 RegionBoundary[Disk[{x,y},r]] 计算. Ball 和 Ellipsoid 被认为是圆盘的更高维度的类似. Annulus 给出通过从较大的同心圆盘的内部除去小圆盘而获得的区域. Disk[{x,y},r] 也可以用 Ball[{x,y},r]、ImplicitRegion[(x-u)2+(y-v)2≤r2,{u,v}] 或 ParametricRegion[a{Cos[θ],Sin[θ]}-{x,y},{{θ,0,2π},{a,0,r}}] 表示. 圆盘的预计算属性以及标准位置中的变体可使用 LaminaData["entity","property"] 或 EntityValue[Entity["Lamina","entity"],"property"]，其中，"entity" 是 "CircularSector"、"Disk"、"FilledEllipse"、"FilledHalfEllipse"、"HalfDisk" 等其中之一.

范例

打开所有单元 关闭所有单元

基本范例  (5)

单位圆盘：

Wolfram Language code: Graphics[Disk[]]

扇区：

Wolfram Language code: Graphics[{Orange, Disk[{0, 0}, 1, {Pi / 4, 3Pi / 4}]}]

椭圆盘：

Wolfram Language code: Graphics[{Orange, Disk[{0, 0}, {3, 4}]}]

不同样式的单位圆盘：

Wolfram Language code: {Graphics[{Pink, Disk[]}], Graphics[{EdgeForm[Thick], Pink, Disk[]}], Graphics[{EdgeForm[Dashed], Pink, Disk[]}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, Disk[]}]}

获得圆盘的 Area：

Wolfram Language code: Area[Disk[]]

椭圆的面积：

Wolfram Language code: Area[Disk[{0, 0}, {Subscript[r, 1], Subscript[r, 2]}]]

范围  (23)

图形  (13)

规范  (7)

指定半径：

Wolfram Language code: Graphics[{Red, Disk[{0, 0}, 5], Green, Disk[{0, 0}, 3], Blue, Disk[{0, 0}, 1]}]

指定中心：

Wolfram Language code: Graphics[{Red, Disk[{0, 0}, 1], Green, Disk[{1, 1}, 1], Blue, Disk[{2, 2}, 1]}]

扇区：

Wolfram Language code: Graphics[Disk[{0, 0}, 1, {0, 4Pi / 3}]]
Wolfram Language code: Graphics[Disk[{0, 0}, 1, {4Pi / 3, 2Pi}]]

椭圆盘：

Wolfram Language code: Graphics[Disk[{0, 0}, {3, 2}]]

椭圆扇区：

Wolfram Language code: Graphics[Disk[{0, 0}, {3, 2}, {0, 4Pi / 3}]]

在原点的单位圆盘的简写形式：

Wolfram Language code: Graphics[Disk[], Frame -> True]

多个相同圆盘：

Wolfram Language code: Graphics[Disk[{{1, 1}, {5, 5}, {8, 2}}]]

样式化  (2)

颜色指令指定圆盘面的颜色：

Wolfram Language code: Table[Graphics[{c, Disk[]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm 和 EdgeForm 可用于指定内部和边界的样式：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], Disk[]}]

椭圆盘扇区的边界：

Wolfram Language code: Graphics[{Yellow, EdgeForm[Directive[Thick, Blue]], Disk[{0, 0}, {3, 2}, {0, 4Pi / 3}]}]

坐标  (4)

使用 Scaled 坐标和半径：

Wolfram Language code: Graphics[Disk[Scaled[{.2, .2}], .2], Frame -> True]
Wolfram Language code: Graphics[Disk[{0, 0}, Scaled[.25]], Frame -> True]
Wolfram Language code: Graphics[Disk[{0, 0}, Scaled[{.5, .25}]], Frame -> True]

使用 ImageScaled 坐标和半径：

Wolfram Language code: Graphics[Disk[ImageScaled[{.2, .2}], .2], Frame -> True]
Wolfram Language code: Graphics[Disk[{0, 0}, ImageScaled[{.5, .25}]], Frame -> True]

使用 Offset 坐标：

Wolfram Language code: Graphics[Disk[Offset[{10, 10}, {0, 0}], .5], Frame -> True]

使用 Offset 指定打印机点的半径：

Wolfram Language code: Graphics[Disk[{0, 0}, Offset[{10, 40}]], Frame -> True]

区域  (10)

嵌入维数：

Wolfram Language code: RegionEmbeddingDimension[Disk[{x, y}, r]]

几何尺寸：

Wolfram Language code: RegionDimension[Disk[{x, y}, r]]

点成员检验：

Wolfram Language code: {RegionMember[Disk[], {0, 0}], RegionMember[Disk[], {0, 2}]}

得到点成员的条件：

Wolfram Language code: RegionMember[Disk[{Subscript[x, 0], Subscript[y, 0]}, {Subscript[r, 1], Subscript[r, 2]}], {x, y}]

面积：

Wolfram Language code: ℛ = Disk[];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

质心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

从一个点的距离：

Wolfram Language code: ℛ = Disk[];
Wolfram Language code: {RegionDistance[ℛ, {1, 2}], RegionDistance[ℛ, {0, 0}]}

到单位圆盘上最近点的距离：

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

从一个点的有符号距离：

Wolfram Language code: ℛ = Disk[];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 2}], SignedRegionDistance[ℛ, {0, 0}]}

到单位圆盘的有符号距离：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}, Exclusions -> Norm[{x, y}] == 1]

区域上最近的点：

Wolfram Language code: ℛ = Disk[{1, 2}, {3, 4}];
Wolfram Language code: RegionNearest[ℛ, {5, 6}]

最近的点：

Wolfram Language code: pts = Table[{1, 2} + 5{Cos[k 2 π / 16], Sin[k 2π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

椭圆是有界的：

Wolfram Language code: ℛ = Disk[{0, 0}, {2, 1}];
Wolfram Language code: BoundedRegionQ[ℛ]

得到它的范围：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{Black, ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.1, Yellow], Cuboid@@Transpose[rr]}}]

在一个椭圆上积分：

Wolfram Language code: ℛ = Disk[{Subscript[x, 0], Subscript[y, 0]}, {Subscript[r, 1], Subscript[r, 2]}];
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

在一个椭圆上进行最优化：

Wolfram Language code: ℛ = Disk[];
Wolfram Language code: {MinValue[{x y - x, {x, y}∈ℛ}, {x, y}], ArgMin[{x y - x, {x, y}∈ℛ}, {x, y}]}

求解椭圆上的方程：

Wolfram Language code: ℛ = Disk[{1, 2}, {3, 4}];
Wolfram Language code: Solve[x^2 + y^2 == 7 && x y == 1 && {x, y}∈ℛ, {x, y}]
Wolfram Language code: Show[{Graphics[{{Green, ℛ}, {Blue, Circle[{0, 0}, Sqrt[7]]}}], Plot[1 / x, {x, -3, 5}, PlotRange -> {{-3, 5}, {-3, 6}}], Graphics[{PointSize[Large], Red, Point[{x, y}] /. %}]}, Axes -> True]

应用  (11)

创建虚幻的轮廓：

Wolfram Language code: Graphics[{Disk[{0, 0}, 2, {Pi / 3, 2Pi}], Disk[{6, 0}, 2, {-Pi, 2Pi / 3}], Disk[{3, 5}, 2, {4Pi / 3, -Pi / 3}]}]

使用 Disk 注释三角函数图形：

Wolfram Language code: Plot[Sin[x], {x, 0, 4Pi}, Epilog -> {Opacity[0.5], EdgeForm[Opacity[.7]], Red, Table[Disk[{x, Sin[x]}, Offset[{8, 8}], {0, Mod[x, 2Pi]}], {x, 0, 4Pi, Pi / 2}]}, PlotRangePadding -> .2]

制作一个饼图：

Wolfram Language code: data = Reverse[Sort[RandomReal[1, 5]]];
Wolfram Language code: Module[{t = 0, len = Length[data], sum = Total[data]}, Graphics[Table[{Hue[i / len], EdgeForm[Opacity[.8]], Disk[{0, 0}, 1, {t, t += 2 Pi data[[i]] / sum}]}, {i, len}]]]

圆周面积的阿基米德近似：

Wolfram Language code: Table[Graphics[{EdgeForm[Opacity[.8]], Table[{Hue[i / n, .5], Disk[{i Sin[Pi / n ], ((-1) ^ (i + 1) + 1)Cos[Pi / n] / 2}, 1, Pi{(-1) ^ i / 2 - 1 / n, (-1) ^ i / 2 + 1 / n}]}, {i, n}]}], {n, 4, 12}]

圆盘的方形堆砌：

Wolfram Language code: Graphics[{EdgeForm[Blue], LightYellow, Table[Disk[{i, j}, 1 / 2], {i, 7}, {j, 5}]}]

圆盘的六边形堆砌：

Wolfram Language code: Graphics[{EdgeForm[Blue], LightYellow, Table[Disk[{i + Boole[EvenQ[j]] / 2, Sqrt[3] / 2j}, 1 / 2], {i, 7}, {j, 5}]}]

模拟椭圆齿轮：

Wolfram Language code: Animate[Module[{a = 4, b = 3, f, r}, f = Sqrt[a ^ 2 - b ^ 2];r = b ^ 2 / (a + f Cos[θ]);Graphics[{Lighter[Red], Rotate[Disk[{-f, 0}, {a, b}], θ, {0, 0}], Lighter[Blue], Translate[Rotate[Disk[{-f, 0}, {a, b}], -ArcTan[ 2 f + r Cos[θ], r Sin[θ]], {0, 0}], {2a, 0}], Black, Point[{{0, 0}, {2a, 0}}]}, PlotRange -> {{-2a, 4a}, {-2a, 2a}}, ImageSize -> 250]], {θ, 0, 2Pi}, AnimationRunning -> False]

圆环是具有相同圆心的两个圆盘的 RegionDifference：

Wolfram Language code: d1 = Disk[{0, 0}, 5]; d2 = Disk[{0, 0}, 3]; annulus = RegionDifference[d1, d2]
Wolfram Language code: Region[annulus]

使具有固定周长的椭圆面积最大：

Wolfram Language code: d = Disk[{0, 0}, {Subscript[r, x], Subscript[r, y]}];
Wolfram Language code: NMaximize[{Area[d], ArcLength[RegionBoundary[d]] == 2π && Subscript[r, x] > 0 && Subscript[r, y] > 0}, {Subscript[r, x], Subscript[r, y]}]

正如所预期的那样，最大的这种椭圆是圆盘：

Wolfram Language code: Region[d /. Last[%]]

说明曲率函数的半径：

Wolfram Language code: y[x_] := Sin[x ^ 2]; r[x_] := ((1 + y'[x] ^ 2) ^ (3 / 2)) / y''[x]; d[x_] := Disk[{x, y[x]} + r[x] * Normalize[{-y'[x], 1}], Abs[r[x]]];
Wolfram Language code: Show[{Plot[y[x], {x, -2, 2}], Graphics[{Gray, Opacity[0.5], d[-1.2], d[0], d[1.4], Red, PointSize[Medium], Point[{-1.2, y[-1.2]}], Point[{0, y[0]}], Point[{1.4, y[1.4]}]}]}, AspectRatio -> Automatic]

通过取多个圆盘的 RegionUnion，可近似网状扩张：

Wolfram Language code: mr = BoundaryDiscretizeGraphics[Graphics[Text[""]], _Text]

围绕网格边界创建扩张半径的圆盘：

Wolfram Language code: rad = 0.25; pts = MeshCoordinates[mr]; disks = BoundaryDiscretizeRegion[Disk[#, rad]]& /@ pts;

然后，只需取所有圆盘的并集，加上原来的网格：

Wolfram Language code: RegionUnion[RegionUnion@@disks, mr]

通过去除多个圆盘的 RegionUnion，可近似网格侵蚀：

Wolfram Language code: mr = BoundaryDiscretizeGraphics[Graphics[Text[""]], _Text]

围绕网格边界创建侵蚀半径的圆盘：

Wolfram Language code: rad = 0.1; pts = AnnotationValue[{mr, 1}, MeshCellCentroid]; disks = BoundaryDiscretizeRegion[Disk[#, rad]]& /@ pts;

然后，从原始网格减去圆盘的并集：

Wolfram Language code: RegionDifference[mr, RegionUnion@@disks]

属性和关系  (9)

用 Rotate 来获得所有可能的椭圆盘：

Wolfram Language code: Graphics[{Pink, Rotate[Disk[{0, 0}, {4, 2}], Pi / 6]}, Axes -> True]

圆盘的边界定义一个圆环：

Wolfram Language code: {Graphics[Circle[]], Graphics[{FaceForm[], EdgeForm[Black], Disk[]}]}

圆盘的隐式指定可以使用 RegionPlot 生成：

Wolfram Language code: RegionPlot[x ^ 2 + y ^ 2 < 1, {x, -1, 1}, {y, -1, 1}]

圆盘的参数式指定可以使用 ParametricPlot 生成：

Wolfram Language code: ParametricPlot[{r Cos[θ], r Sin[θ]}, {r, 0, 1}, {θ, 0, 2π}, Mesh -> 15]

Disk 是 Ball 的一个特例：

Wolfram Language code: Subscript[ℛ, 1] = Ball[{x, y}, r]; Subscript[ℛ, 2] = Disk[{x, y}, r];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Disk 是 Ellipsoid 的一个特例：

Wolfram Language code: Subscript[ℛ, 1] = Ellipsoid[{x, y}, {r1, r2}]; Subscript[ℛ, 2] = Disk[{x, y}, {r1, r2}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegion 可以表示任何 Disk：

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{{r Cos[θ], 2r Sin[θ]}, 0 ≤ r ≤ 1 && 0 ≤ θ ≤ 2π}, {r, θ}]; Subscript[ℛ, 2] = Disk[{0, 0}, {1, 2}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegion 可以表示任何 Disk：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}]; Subscript[ℛ, 2] = Disk[{0, 0}, 1];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Disk 对于欧几里德范数是一个范数球：

Wolfram Language code: ℛ = Disk[{0, 0}, 1];
Wolfram Language code: Reduce[{x, y}∈ℛ⧦Norm[{x, y}] ≤ 1, {x, y}, Reals]

可能存在的问题  (2)

使用 Scaled 半径将取决于 PlotRange：

Wolfram Language code: Table[Graphics[Disk[{0, 0}, Scaled[.25]], PlotRange -> {{-n, n}, {-1, 1}}, Frame -> True, FrameTicks -> {{{-1, 1}, None}, {{-n, n}, None}}], {n, {1, 2, 3}}]

使用 ImageScaled 大小将取决于 ImageSize 和 AspectRatio：

Wolfram Language code: Table[Graphics[Disk[ImageScaled[{.5, .5}], ImageScaled[{.25, .25}]], Frame -> True, FrameTicks -> {{{-1, 1}, None}, {{-1, 1}, None}}, ImageSize -> n], {n, {50, 70, 100}}]
Wolfram Language code: Table[Graphics[Disk[ImageScaled[{.5, .5}], ImageScaled[{.25, .25}]], Frame -> True, FrameTicks -> {{{-1, 1}, None}, {{-1, 1}, None}}, ImageSize -> 100, AspectRatio -> n], {n, {1, 1 / 2, 1 / 3}}]

巧妙范例  (4)

随机圆盘集合：

Wolfram Language code: Graphics[Table[{EdgeForm[Black], Hue[RandomReal[]], Disk[RandomReal[4, {2}], RandomReal[1]]}, {40}]]

圆盘簇：

Wolfram Language code: Graphics[Table[{Hue[t / 15, 1, .9, .3], Disk[{Cos[2Pi t / 15], Sin[2Pi t / 15]}]}, {t, 15}]]

数字花瓣：

Wolfram Language code: Graphics[Table[{EdgeForm[Opacity[.6]], Hue[(-11 + q + 10 r) / 72], Disk[(8 - r){Cos[2Pi q / 12], Sin[2Pi q / 12]}, (8 - r) / 3]}, {r, 6}, {q, 12}]]

阴和阳：

Wolfram Language code: Animate[Graphics[{Red, Disk[{0, 0}, 2, {0, Pi}], Blue, Disk[{0, 0}, 2, {Pi, 2Pi}], Red, Disk[{-1, 0}, 1], Blue, Disk[{1, 0}, 1]}, PlotRange -> 2.1, ImageSize -> 150] /. Disk[x__] :> Rotate[Disk[x], d Degree, {0, 0}], {d, 0, 360}, AnimationRunning -> False]
Wolfram Research (1991)，Disk，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Disk.html （更新于 2023 年）.

文本

Wolfram Research (1991)，Disk，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Disk.html （更新于 2023 年）.

CMS

Wolfram 语言. 1991. "Disk." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2023. https://reference.wolfram.com/language/ref/Disk.html.

APA

Wolfram 语言. (1991). Disk. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Disk.html 年

BibTeX

@misc{reference.wolfram_2026_disk, author="Wolfram Research", title="{Disk}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/Disk.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_disk, organization={Wolfram Research}, title={Disk}, year={2023}, url={https://reference.wolfram.com/language/ref/Disk.html}, note=[Accessed: 08-September-2026]}