WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DynamicModule[{x,y,…},expr]

expr 中のDynamicオブジェクトの評価すべてにおいて，記号 x, y, … の局所的なインスタンスを同じに保つオブジェクトを表す．DynamicModuleで指定された記号は，デフォルトで，Wolframシステムのセッション間でさえもその値を保持する．

DynamicModule[{x=x0,y=y0,…},expr]

x, y, … の初期値を指定する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
DynamicModuleの変数  
DynamicModuleの状態  
一般化と拡張  
オプション  
BaseStyle  
Deinitialization  
DynamicModuleValues  
Show More Show More
ExcludedContexts  
InheritScope  
Initialization  
IncludedContexts  
SaveDefinitions  
SynchronousInitialization  
UndoTrackedVariables  
UnsavedVariables  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連するワークフロー
履歴
引用書式

DynamicModule

DynamicModule[{x,y,…},expr]

expr 中のDynamicオブジェクトの評価すべてにおいて，記号 x, y, … の局所的なインスタンスを同じに保つオブジェクトを表す．DynamicModuleで指定された記号は，デフォルトで，Wolframシステムのセッション間でさえもその値を保持する．

DynamicModule[{x=x0,y=y0,…},expr]

x, y, … の初期値を指定する．

詳細とオプション

  • DynamicModuleはModuleと同じように，まず expr 中の局所変数に一意的な名前を与える．続いて結果の式を評価し，このバージョンをDynamicModuleで包み込んで返す．
  • ノートブックでは，この返されたバージョンがしばしば出力セル中に表示される．Manipulateからの出力がこの例である．
  • 表示されているDynamicModuleの形式中でDynamicオブジェクトがインタラクティブに変更・編集された結果，局所変数の値が変化した場合，DynamicModuleオブジェクトはこれを反映するように修正される．
  • DynamicModule中の局所変数の値は，Wolframシステムのセッション間で実質的に持続されるように，DynamicModuleを含むノートブックが保存されると，デフォルトで自動的に保存される．
  • DynamicModuleオブジェクトを含むノートブックの一部をコピーすると，コピー中の局所変数は，同じ値から始まりはするが，もとの局所変数とは無関係になる．
  • 次のオプションを使うことができる．
  • BaseStyle {}表示オブジェクトのベーススタイル指定
    Deinitialization NoneDynamicModuleがもはや表示できなくなったときに評価される式
    DynamicModuleValues Automatic動的に更新した変数値のデータ
    ExcludedContexts AutomaticSaveDefinitionsから除外されるコンテキスト
    InheritScope FalseDynamicModule変数を他のDynamicModuleインスタンスに接続
    IncludedContexts AllSaveDefinitionsに考慮されるコンテキスト
    Initialization NoneDynamicModuleが最初に表示されたときに評価される式
    SaveDefinitions Falseexprに関連するすべての定義を保存するかどうか
    SynchronousInitialization True初期化を同期して行うかどうか
    UndoTrackedVariables None変更されるとフロントエンドの取り消しメカニズムで追跡される変数
    UnsavedVariables {}値を保存すべきではない変数
  • DynamicModuleがはじめて評価されると，評価の最中に局所変数の割当てがはじめて行われる．続いてInitializationオプションの設定は，それが何であれ，DynamicModuleの出力が表示されるときにのみ評価される．
  • DynamicModuleオブジェクトが特定のノートブックにはじめて表示されると，局所変数の保存された値が復元され，Initializationオプションが設定されていればそれが評価される．
  • UnsavedVariablesリストに含まれる変数を除き，局所変数のすべての値が保存される．記号の一般的な値はDynamicModuleの第1引数に保存される．その他の値はDynamicModuleValuesオプションの設定の中に保存される．
  • DynamicModuleは属性HoldAllを持つ．
  • DynamicModule構文はどのようにもネストすることができる．必要であれば内側の変数の名前が変更される．
  • DynamicModuleは，語彙スコーピングを実装するスコーピング構文である．

例題

すべて開く すべて閉じる

例  (1)

動的に変更される局所変数を持つSliderを作成する：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x]], Dynamic[x]}]

この出力をコピー，ペーストしてスタンドアロンのオブジェクトを得る：

スコープ  (6)

DynamicModuleの変数  (3)

DynamicModuleを使って変数を局所化し，大域的な変数との衝突を防ぐ：

Wolfram Language code: {Slider[Dynamic[x]], Dynamic[x]}
Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x]], Dynamic[x]}]

局所変数は生成された出力に関して一意的である：

Wolfram Language code: {Slider[Dynamic[x]], Dynamic[x]}
Wolfram Language code: %
Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x]], Dynamic[x]}]
Wolfram Language code: %

Moduleのように，局所変数に初期値を割り当てる：

Wolfram Language code: DynamicModule[{a = 3, b = 2, c = 1}, {a, b, c}.x ^ Range[3]]

関数を局所変数として定義する：

Wolfram Language code: DynamicModule[{f, p}, f[g_] := Graphics[g, ImageSize -> Tiny];{SetterBar[Dynamic[p], {Disk[] -> Disk, Rectangle[] -> Rectangle}], Dynamic[f[p]]}]

DynamicModuleの状態  (3)

DynamicModuleを使って異なるWolframシステムセッション間で表示状態を保存する：

Wolfram Language code: DynamicModule[{x = 1}, Slider[Dynamic[x]]]
Wolfram Language code: InputForm[ToBoxes[%]]

Moduleは現行のWolframシステムセッションに一意的な状態しか与えない：

Wolfram Language code: Module[{x = 1}, Slider[Dynamic[x]]]
Wolfram Language code: InputForm[ToBoxes[%]]

Initializationを使ってコンテンツの表示前に式を評価する：

Wolfram Language code: DynamicModule[{x = .5}, Slider[Dynamic[x]], Initialization :> (SelectionMove[EvaluationNotebook[], All, EvaluationCell];SetOptions[NotebookSelection[], CellFrame -> 1, CellFrameColor -> Hue[x]])]

Initializationは局所変数の割当て後に評価される：

Wolfram Language code: DynamicModule[{a = 2}, Dynamic@a, Initialization :> (a = 1)]

一般化と拡張  (1)

変数にダウン値を割り当てることで任意数の局所変数を定義する：

Wolfram Language code: displayInputFields[numInputFields_] := DynamicModule[{values}, Do[values[i] = i, {i, numInputFields}]; InputField[Dynamic[values[#]]]& /@ Range[numInputFields]]
Wolfram Language code: displayInputFields[5]

オプション  (16)

BaseStyle  (1)

ベーススタイルを設定する：

Wolfram Language code: DynamicModule[{x = "これはテキストです"}, Dynamic[x], BaseStyle -> {FontSize -> 8}]

Deinitialization  (1)

出力が表示されなくなってから式を評価するように指定する：

Wolfram Language code: CreateDialog[DynamicModule[{c}, ColorSlider[Dynamic[c]], Initialization :> (c = Pink), Deinitialization :> (CreateDialog[Graphics[{c, Disk[]}]])]];

DynamicModuleValues  (1)

局所的な記号の関数定義は自動的にDynamicModuleValuesに挿入される：

Wolfram Language code: InputForm[DynamicModule[{c}, c[x_] := {x};c[1]]]

ExcludedContexts  (1)

デフォルトで，システムについて内部的な特定のコンテキストは初期化オプションには保存されない：

Wolfram Language code: x := $TimeZone DynamicModule[{x}, x, SaveDefinitions -> True]//ToBoxes

ExcludedContexts{}を使ってプロテクトされていないすべてのシンボルの定義を保存する：

Wolfram Language code: DynamicModule[{x}, x, ExcludedContexts -> {}, SaveDefinitions -> True]//ToBoxes

InheritScope  (1)

親DynamicModuleから変数を継承するDynamicModuleのあるダイアログボックスを作る：

Wolfram Language code: DynamicModule[{a = 1}, {Dynamic[a], Button["ダイアログ", CreateDialog[DynamicModule[{}, Button["a++", a++], InheritScope -> True]]]}]

Initialization  (4)

デフォルトで，外部定義はカーネルセッション間で失われる：

Wolfram Language code: f[x_] := {x}
Wolfram Language code: DynamicModule[{c}, {Slider[Dynamic[c]], Dynamic[f[c]]}]

Initializationを使ってコンテンツに必要な評価を保存する：

Wolfram Language code: DynamicModule[{c}, {Slider[Dynamic[c]], Dynamic[g[c]]}, Initialization :> (g[x_] := {x})]

局所変数も初期化することができる：

Wolfram Language code: DynamicModule[{c = 0.2, g}, {Slider[Dynamic[c]], Dynamic[g[c]]}, Initialization :> (g[x_] := {x})]

初期化は出力が表示されるときにのみ評価される：

Wolfram Language code: DynamicModule[{}, 1, Initialization :> (x = 2)];DynamicModule[{}, 2, Initialization :> (y = 3)]

最初のDynamicModuleはセミコロンで出力が出ないようにされているので，この割当てが実行されることは全くなかった：

Wolfram Language code: {x, y}

IncludedContexts  (1)

シンボル定義の再帰的包含を"c1`"と"c2`"のコンテキストに限定する：

Wolfram Language code: c1`x := {c1`Private`bar , c2`baz} c1`Private`bar := 1 c2`baz := 3
Wolfram Language code: DynamicModule[{c1`x}, c1`x, IncludedContexts -> {"c1`", "c2`"}, SaveDefinitions -> True]//ToBoxes

SaveDefinitions  (2)

デフォルトで，外部定義はカーネルセッション間で失われる：

Wolfram Language code: f[x_] := x
Wolfram Language code: DynamicModule[{u = 5}, Dynamic[f[u]]]

SaveDefinitionsをTrueに設定すると，外部定義が出力とともに保存されるようになる：

Wolfram Language code: f[x_] := x
Wolfram Language code: DynamicModule[{u = 5}, Dynamic[f[u]], SaveDefinitions -> True]

SynchronousInitialization  (2)

デフォルトで，初期化は出力が表示される前に（同期的に）評価される：

Wolfram Language code: DynamicModule[{c = 0.2, g}, {Slider[Dynamic[c]], Dynamic[g[c]]}, Initialization :> (Pause[2];g[x_] := {x})]

初期化が非同期的に評価されている間の出力表示を強制する：

Wolfram Language code: DynamicModule[{c = 0.2}, {Slider[Dynamic[c]], Dynamic[g[c]]}, Initialization :> (Pause[2];g[x_] := {x}), SynchronousInitialization -> False]

UndoTrackedVariables  (1)

「取消し」メニューコマンドに反応するインターフェースを作る：

Wolfram Language code: DynamicModule[{a = 1}, {Button["increment", a++], Dynamic[a]}, UndoTrackedVariables :> {a}]

UnsavedVariables  (1)

状態が保存されるべきではない記号を指定する：

Wolfram Language code: dm = DynamicModule[{x, y}, Column@{Slider[Dynamic[x]], Slider[Dynamic[y]], Dynamic[{x, y}]}, UnsavedVariables -> {y}];

次を評価して2つのスライダーを動かし，次にCloseをクリックする：

Wolfram Language code: nb = DialogInput[{dm, Button["Close", DialogReturn[NotebookGet[]]]}];

次を評価する．2番目のスライダーが前の状態を記憶していないことに注意のこと：

Wolfram Language code: nb = DialogInput[nb];

アプリケーション  (3)

動的な計算インターフェースを構築する：

Wolfram Language code: DynamicModule[{a = 0, b = 0}, Deploy[Style[Panel[Grid[Transpose[{{Style["数を入力", Red], Style["別の数を入力", Red], "2数の和", "2数の差", "2数の積"}, {InputField[Dynamic[a], Number], InputField[Dynamic[b], Number], InputField[Dynamic[a + b], Enabled -> False], InputField[Dynamic[a - b], Enabled -> False], InputField[Dynamic[a b], Enabled -> False]}}], Alignment -> Right], ImageMargins -> 10], DefaultOptions -> {InputField -> {ContinuousAction -> True, FieldSize -> {{5, 30}, {1, Infinity}}}}]]]

インタラクティブな曲線フィットプロット：

Wolfram Language code: DynamicModule[{pts = {{0, 0}, {1, 1}, {2, 0}, {3, 2}}}, LocatorPane[Dynamic[pts], Dynamic[Plot[InterpolatingPolynomial[pts, x], {x, 0, 3}, PlotRange -> 3]]]]

範囲がの角度スライダー：

Wolfram Language code: angularSlider[Dynamic[angle_]] := DynamicModule[{p = {1, 0}, angleCalc}, LocatorPane[Dynamic[p, (angleCalc@@Normalize /@ {#, p})&], Graphics[{Circle[], Arrowheads[0.15], Arrow[Dynamic[{{0, 0}, p}]]}, ImageSize -> Tiny], Appearance -> None], Initialization :> (angle = 0;angleCalc[newp_, oldp_] := (angle = angle + Abs[ArcCos[newp.oldp]]Sign[Cross[newp].(newp - oldp)];p = {Cos[angle], Sin[angle]}))]

スライダーを動的変数に結び付ける：

Wolfram Language code: {angularSlider[Dynamic[θ]], Dynamic[θ]}

正弦関数関係を示す：

Wolfram Language code: DynamicModule[{θ = 0}, Grid[{{angularSlider[Dynamic[θ]], Plot[Sin[x], {x, -10, 10}, Epilog -> {PointSize[Medium], Dynamic@Point[{θ, Sin[θ]}]}]}, {ParametricPlot[{Cos[y], y}, {y, -10, 10}, AspectRatio -> 2, Epilog -> {PointSize[Medium], Dynamic@Point[{Cos[θ], θ}]}], Dynamic[θ]}}]]

PolarPlotを使って螺線を示す：

Wolfram Language code: DynamicModule[{θ = 0}, Grid[{{angularSlider[Dynamic[θ]], Dynamic@PolarPlot[t, {t, -Pi, θ}, ImageSize -> Tiny]}}]]

特性と関係  (2)

DynamicModuleとModuleは同じように見えるが根本的に異なる：

Wolfram Language code: DynamicModule[{x}, {x, Slider[Dynamic[x]], Dynamic[x]}]
Wolfram Language code: %

この場合，どちらのスライダーも動くが，再度開かれた場合は評価されない限りどちらも動かない：

Wolfram Language code: Module[{x}, {x, Slider[Dynamic[x]], Dynamic[x]}]
Wolfram Language code: %

Manipulateは出力作成でDynamicModuleに依存する：

Wolfram Language code: Manipulate[x, {x, 0, 1}]
Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x]], Dynamic[x]}]

考えられる問題  (2)

デフォルトで，"System`"シンボルの定義は取得されない：

Wolfram Language code: x := Subscript[y, 1] Subscript[y, 1] := 17 Options[DynamicModule[{x}, x, SaveDefinitions -> True]//ToBoxes, Initialization]

ExcludedContexts{}を使ってすべてのコンテキストから定義を取得する：

Wolfram Language code: Options[DynamicModule[{x}, x, SaveDefinitions -> True, ExcludedContexts -> {}]//ToBoxes, Initialization]

自分のシンボルに定義を与えることもできる：

Wolfram Language code: Clear[Subscript] y/:Subscript[y, 1] = 17 Options[DynamicModule[{x}, x, SaveDefinitions -> True]//ToBoxes, Initialization]

外部で宣言されたModule変数を動的モジュールで使うとスコープが衝突する：

Wolfram Language code: Module[{outer = 1}, DynamicModule[{inner = Hold[outer]}, Dynamic[ReleaseHold[inner]]]]

ボックスは，カーネルが終了した後に値がなくなるリークされた一時Moduleシンボルを参照する：

Wolfram Language code: ToBoxes[%, StandardForm]

Withを使って完全に解決されたModuleシンボルを挿入し，ボックスによって参照されないようにする：

Wolfram Language code: Module[{outer = 1}, With[{tmp = outer}, DynamicModule[{inner = Hold[tmp]}, Dynamic[ReleaseHold[tmp]]]]]

ボックスはシンボルを参照しなくなった：

Wolfram Language code: ToBoxes[%, StandardForm]

おもしろい例題  (2)

独立状態のスライダー：

Wolfram Language code: Expand[(DynamicModule[{x}, Slider2D[Dynamic[x]]] + 1) ^ 3]

枠で囲まれたエリアをクリックしてボールが跳ねるのを見る：

Wolfram Language code: Framed@DynamicModule[{contents = {}}, EventHandler[Graphics[{PointSize[0.1], Point[Dynamic[contents = Map[If[#[[1, 2]] ≥ 0, {#[[1]] - #[[2]], #[[2]] + {0, 0.001}}, {{#[[1, 1]], 0}, {1, -0.8}#[[2]]}]&, contents];Map[First, contents]]]}, PlotRange -> {{0, 1}, {0, 1}}, ImageSize -> 80], "MouseDown" :> (AppendTo[contents, {MousePosition["Graphics"], {0, 0}}])]]

動的オブジェクトを入力に使う．別の枠内をクリックして追加のボールを作る：

Wolfram Language code: (% + 1) ^ 3//Expand
Wolfram Research (2007), DynamicModule, Wolfram言語関数， https://reference.wolfram.com/language/ref/DynamicModule.html （2021年に更新）.

テキスト

Wolfram Research (2007), DynamicModule, Wolfram言語関数， https://reference.wolfram.com/language/ref/DynamicModule.html （2021年に更新）.

CMS

Wolfram Language. 2007. "DynamicModule." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/DynamicModule.html.

APA

Wolfram Language. (2007). DynamicModule. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DynamicModule.html

BibTeX

@misc{reference.wolfram_2026_dynamicmodule, author="Wolfram Research", title="{DynamicModule}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/DynamicModule.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dynamicmodule, organization={Wolfram Research}, title={DynamicModule}, year={2021}, url={https://reference.wolfram.com/language/ref/DynamicModule.html}, note=[Accessed: 08-September-2026]}