Wolfram 语言与系统参考资料中心

DynamicModule

DynamicModule[{x,y,…},expr]

表示一个对象，可保持 expr 中所有 Dynamic 对象在计算过程中符号 x、y、… 的局部值. 在默认情况下， DynamicModule 中指定的符号甚至在整个 Mathematica 进程中都不会改变其值.

DynamicModule[{x=x₀,y=y₀,…},expr]

为 x、y、… 指定初始值.

范例

打开所有单元关闭所有单元

基本范例 (1)

生成一个带有动态更新的局部变量的 Slider：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x]], Dynamic[x]}]

复制和粘贴以上输出以获得一个独立对象：

范围 (6)

DynamicModule 变量 (3)

利用 DynamicModule 确定变量并防止与其相应的全局变量发生冲突：

Wolfram Language code: {Slider[Dynamic[x]], Dynamic[x]}

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x]], Dynamic[x]}]

局部变量与生成的输出完全不同：

Wolfram Language code: {Slider[Dynamic[x]], Dynamic[x]}

Wolfram Language code: %

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x]], Dynamic[x]}]

Wolfram Language code: %

为局部变量赋初始值，例如 Module：

Wolfram Language code: DynamicModule[{a = 3, b = 2, c = 1}, {a, b, c}.x ^ Range[3]]

定义一个函数作为局部变量：

Wolfram Language code:

DynamicModule[{f, p}, f[g_] := Graphics[g, ImageSize -> Tiny];{SetterBar[Dynamic[p], {Disk[] -> Disk, Rectangle[] -> Rectangle}], Dynamic[f[p]]}]

DynamicModule 状态 (3)

在不同的 Mathematica 进程中，用 DynamicModule 保存显示状态：

Wolfram Language code: DynamicModule[{x = 1}, Slider[Dynamic[x]]]

Wolfram Language code: InputForm[ToBoxes[%]]

Module 仅给出当前 Mathematica 进程的单一状态：

Wolfram Language code: Module[{x = 1}, Slider[Dynamic[x]]]

Wolfram Language code: InputForm[ToBoxes[%]]

在显示内容前，用 Initialization 计算表达式：

Wolfram Language code:

DynamicModule[{x = .5}, Slider[Dynamic[x]], Initialization :> (SelectionMove[EvaluationNotebook[], All, EvaluationCell];SetOptions[NotebookSelection[], CellFrame -> 1, CellFrameColor -> Hue[x]])]

Initialization 的计算是在局部变量赋值后：

Wolfram Language code: DynamicModule[{a = 2}, Dynamic@a, Initialization :> (a = 1)]

推广和延伸 (1)

通过把下值赋给变量，定义任意数目的局部变量：

Wolfram Language code:

displayInputFields[numInputFields_] := DynamicModule[{values}, 
	Do[values[i] = i, {i, numInputFields}];
	InputField[Dynamic[values[#]]]& /@ Range[numInputFields]]

Wolfram Language code: displayInputFields[5]

选项 (16)

BaseStyle (1)

设置基本样式：

Wolfram Language code: DynamicModule[{x = "this is some text"}, Dynamic[x], BaseStyle -> {FontSize -> 8}]

Deinitialization (1)

当输出不再显示时，指定计算的表达式：

Wolfram Language code:

CreateDialog[DynamicModule[{c}, ColorSlider[Dynamic[c]], Initialization :> (c = Pink), Deinitialization :> (CreateDialog[Graphics[{c, Disk[]}]])]];

DynamicModuleValues (1)

局部变量的函数定义自动插入到 DynamicModuleValues：

Wolfram Language code: InputForm[DynamicModule[{c}, c[x_] := {x};c[1]]]

ExcludedContexts (1)

默认情况下，某些系统内部的上下文没有被保存在初始化选项中：

Wolfram Language code:

x := $TimeZone
DynamicModule[{x}, x, SaveDefinitions -> True]//ToBoxes

用 ExcludedContexts{} 保存所有非保护符号的定义：

Wolfram Language code: DynamicModule[{x}, x, ExcludedContexts -> {}, SaveDefinitions -> True]//ToBoxes

InheritScope (1)

用 DynamicModule 创建一个对话框，继承来自父 DynamicModule 的变量：

Wolfram Language code:

DynamicModule[{a = 1}, {Dynamic[a], Button["dialog", CreateDialog[DynamicModule[{}, Button["a++", a++], InheritScope -> True]]]}]

Initialization (4)

在默认情况下，外部定义在核心进程之间丢失：

Wolfram Language code: f[x_] := {x}

Wolfram Language code: DynamicModule[{c}, {Slider[Dynamic[c]], Dynamic[f[c]]}]

用 Initialization 保存内容中所需的计算：

Wolfram Language code: DynamicModule[{c}, {Slider[Dynamic[c]], Dynamic[g[c]]}, Initialization :> (g[x_] := {x})]

局部变量也可以初始化：

Wolfram Language code:

DynamicModule[{c = 0.2, g}, 
	{Slider[Dynamic[c]], Dynamic[g[c]]}, Initialization :> (g[x_] := {x})]

只有当输出显示时，才运行初始化：

Wolfram Language code: DynamicModule[{}, 1, Initialization :> (x = 2)];DynamicModule[{}, 2, Initialization :> (y = 3)]

第一个 DynamicModule 受分号抑制，所以它无法运行赋值：

Wolfram Language code: {x, y}

IncludedContexts (1)

将符号定义的递归包含限制在上下文 "c1`" 和 "c2`" 中：

Wolfram Language code:

c1`x := {c1`Private`bar , c2`baz}
c1`Private`bar := 1
c2`baz := 3

Wolfram Language code: DynamicModule[{c1`x}, c1`x, IncludedContexts -> {"c1`", "c2`"}, SaveDefinitions -> True]//ToBoxes

SaveDefinitions (2)

默认情况下，内核会话之间的外部定义丢失了：

Wolfram Language code: f[x_] := x

Wolfram Language code: DynamicModule[{u = 5}, Dynamic[f[u]]]

通过设置 SaveDefinitions 为 True，外部定义通过输出保存：

Wolfram Language code: f[x_] := x

Wolfram Language code: DynamicModule[{u = 5}, Dynamic[f[u]], SaveDefinitions -> True]

SynchronousInitialization (2)

默认情况下，在显示输出之前进行初始化计算（同步进行）：

Wolfram Language code: DynamicModule[{c = 0.2, g}, {Slider[Dynamic[c]], Dynamic[g[c]]}, Initialization :> (Pause[2];g[x_] := {x})]

使输出在非同步初始化计算时进行显示：

Wolfram Language code:

DynamicModule[{c = 0.2}, {Slider[Dynamic[c]], Dynamic[g[c]]}, Initialization :> (Pause[2];g[x_] := {x}), SynchronousInitialization -> False]

UndoTrackedVariables (1)

创建界面，响应撤消菜单命令：

Wolfram Language code: DynamicModule[{a = 1}, {Button["increment", a++], Dynamic[a]}, UndoTrackedVariables :> {a}]

UnsavedVariables (1)

指定变量状态不被保存：

Wolfram Language code: dm = DynamicModule[{x, y}, Column@{Slider[Dynamic[x]], Slider[Dynamic[y]], Dynamic[{x, y}]}, UnsavedVariables -> {y}];

进行以下计算并且移动两个滑尺，然后按下关闭：

Wolfram Language code: nb = DialogInput[{dm, Button["Close", DialogReturn[NotebookGet[]]]}];

进行以下计算并且注意第二个滑尺不会记忆它以前的状态：

Wolfram Language code: nb = DialogInput[nb];

应用 (3)

构造一个动态计算界面：

Wolfram Language code:

DynamicModule[{a = 0, b = 0}, Deploy[Style[Panel[Grid[Transpose[{{Style["input a number", Red], Style["input another number", Red], "here is their sum", "their difference", "their product"}, {InputField[Dynamic[a], Number], InputField[Dynamic[b], Number], InputField[Dynamic[a + b], Enabled -> False], InputField[Dynamic[a - b], Enabled -> False], InputField[Dynamic[a b], Enabled -> False]}}], Alignment -> Right], ImageMargins -> 10], DefaultOptions -> {InputField -> {ContinuousAction -> True, FieldSize -> {{5, 30}, {1, Infinity}}}}]]]

交互式曲线拟合图：

Wolfram Language code:

DynamicModule[{pts = {{0, 0}, {1, 1}, {2, 0}, {3, 2}}}, LocatorPane[Dynamic[pts], Dynamic[Plot[InterpolatingPolynomial[pts, x], {x, 0, 3}, PlotRange -> 3]]]]

范围为的箭头滑尺：

Wolfram Language code:

angularSlider[Dynamic[angle_]] := DynamicModule[{p = {1, 0}, angleCalc}, LocatorPane[Dynamic[p, (angleCalc@@Normalize /@ {#, p})&], Graphics[{Circle[], Arrowheads[0.15], Arrow[Dynamic[{{0, 0}, p}]]}, ImageSize -> Tiny], Appearance -> None], Initialization :> (angle = 0;angleCalc[newp_, oldp_] := (angle = angle + Abs[ArcCos[newp.oldp]]Sign[Cross[newp].(newp - oldp)];p = {Cos[angle], Sin[angle]}))]

使滑尺与一个动态变量相连：

Wolfram Language code: {angularSlider[Dynamic[θ]], Dynamic[θ]}

证明一种正弦曲线关系：

Wolfram Language code:

DynamicModule[{θ = 0}, Grid[{{angularSlider[Dynamic[θ]], Plot[Sin[x], {x, -10, 10}, Epilog -> {PointSize[Medium], Dynamic@Point[{θ, Sin[θ]}]}]}, {ParametricPlot[{Cos[y], y}, {y, -10, 10}, AspectRatio -> 2, Epilog -> {PointSize[Medium], Dynamic@Point[{Cos[θ], θ}]}], Dynamic[θ]}}]]

用 PolarPlot 证明螺旋曲线：

Wolfram Language code: DynamicModule[{θ = 0}, Grid[{{angularSlider[Dynamic[θ]], Dynamic@PolarPlot[t, {t, -Pi, θ}, ImageSize -> Tiny]}}]]

属性和关系 (2)

DynamicModule 和 Module 尽管表面相似但本质不同：

Wolfram Language code: DynamicModule[{x}, {x, Slider[Dynamic[x]], Dynamic[x]}]

Wolfram Language code: %

在这个范例中两个滑尺都会移动，当重新打开时如果不计算同样不起作用：

Wolfram Language code: Module[{x}, {x, Slider[Dynamic[x]], Dynamic[x]}]

Wolfram Language code: %

Manipulate 依据 DynamicModule 生成输出：

Wolfram Language code: Manipulate[x, {x, 0, 1}]

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x]], Dynamic[x]}]

可能存在的问题 (2)

默认情况下，不会引入附加到 "System`" 符号上的定义：

Wolfram Language code:

x := Subscript[y, 1]
Subscript[y, 1] := 17
Options[DynamicModule[{x}, x, SaveDefinitions -> True]//ToBoxes, Initialization]

用 ExcludedContexts{} 从所有上下文中提取定义：

Wolfram Language code: Options[DynamicModule[{x}, x, SaveDefinitions -> True, ExcludedContexts -> {}]//ToBoxes, Initialization]

或者，将定义附加到自己的符号：

Wolfram Language code:

Clear[Subscript]
y/:Subscript[y, 1] = 17
Options[DynamicModule[{x}, x, SaveDefinitions -> True]//ToBoxes, Initialization]

在动态模块中使用外部声明的 Module 变量会造成范围冲突：

Wolfram Language code: Module[{outer = 1}, DynamicModule[{inner = Hold[outer]}, Dynamic[ReleaseHold[inner]]]]

框符引用了一个泄露的临时 Module 符号，内核退出后，符号将没有值：

Wolfram Language code: ToBoxes[%, StandardForm]

用 With 注入被完全解析的 Module 符号，使其不被框符引用：

Wolfram Language code: Module[{outer = 1}, With[{tmp = outer}, DynamicModule[{inner = Hold[tmp]}, Dynamic[ReleaseHold[tmp]]]]]

框符不再引用符号：

Wolfram Language code: ToBoxes[%, StandardForm]

巧妙范例 (2)

独立状态的滑尺：

Wolfram Language code: Expand[(DynamicModule[{x}, Slider2D[Dynamic[x]]] + 1) ^ 3]

点击框架内区域观察弹球：

Wolfram Language code:

Framed@DynamicModule[{contents = {}}, EventHandler[Graphics[{PointSize[0.1], Point[Dynamic[contents = Map[If[#[[1, 2]] ≥ 0, {#[[1]] - #[[2]], #[[2]] + {0, 0.001}}, {{#[[1, 1]], 0}, {1, -0.8}#[[2]]}]&, contents];Map[First, contents]]]}, PlotRange -> {{0, 1}, {0, 1}}, ImageSize -> 80], "MouseDown" :> (AppendTo[contents, {MousePosition["Graphics"], {0, 0}}])]]

选择输出和扩展；点击不同框架以生成附加的球：

Wolfram Language code: (% + 1) ^ 3//Expand

Top

BaseStyle	{}	所显示的对象的基本样式指定
Deinitialization	None	当 DynamicModule 不能再被显示时计算的表达式
DynamicModuleValues	Automatic	对变量值，动态更新数据
ExcludedContexts	Automatic	SaveDefinitions 中排除的上下文
InheritScope	False	将 DynamicModule 变量与另一个 DynamicModule 实例连接
IncludedContexts	All	SaveDefinitions 中包含的上下文
Initialization	None	DynamicModule 首次被显示时，计算的表达式
SaveDefinitions	False	是否保存所有与 expr 相关的定义
SynchronousInitialization	True	是否同步执行初始化
UndoTrackedVariables	None	当变化时，应由前端的撤消机制来跟踪的变量
UnsavedVariables	None	数值不应被保存的变量

DynamicModule

更多信息和选项

范例

基本范例 (1)

范围 (6)

DynamicModule 变量 (3)

DynamicModule 状态 (3)

推广和延伸 (1)

选项 (16)

BaseStyle (1)

Deinitialization (1)

DynamicModuleValues (1)

ExcludedContexts (1)

InheritScope (1)

Initialization (4)

IncludedContexts (1)

SaveDefinitions (2)

SynchronousInitialization (2)

UndoTrackedVariables (1)

UnsavedVariables (1)

应用 (3)

属性和关系 (2)

可能存在的问题 (2)

巧妙范例 (2)

参见

技术笔记

相关指南

相关的工作流程

历史

文本

CMS

APA

BibTeX

BibLaTeX