EllipticK

EllipticK[m]

第1種完全楕円積分を与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
EllipticKは，第2種不完全楕円積分で与えられる．
EllipticK[m]は，複素 m 平面上，〜の範囲で不連続な分枝切断線を持つ．
特別な引数の場合，EllipticKは，自動的に厳密値を計算する．
EllipticKは任意の数値精度で評価できる．
EllipticKは自動的にリストに縫い込まれる．
EllipticKはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開くすべて閉じる

例 (5)

数値的に評価する：

Wolfram Language code: EllipticK[0.5]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[EllipticK[x], {x, -1, 1}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[EllipticK[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[EllipticK[x], {x, 0, 5}]

Infinityにおける級数展開：

Wolfram Language code: Series[EllipticK[x], {x, ∞, 2}]//Normal

スコープ (38)

数値評価 (5)

高精度で評価する：

Wolfram Language code: N[EllipticK[8 / 10], 50]

出力精度は入力精度に従う：

Wolfram Language code: EllipticK[0.999999999999999990000000000000000]

複素引数について数値的に評価する：

Wolfram Language code: EllipticK[2.5 + I]

EllipticKを高精度で効率よく評価する：

Wolfram Language code: EllipticK[0.4`500]//Timing

Wolfram Language code: EllipticK[0.4`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: EllipticK[Interval[{0.4, 0.5}]]

Wolfram Language code: EllipticK[CenteredInterval[4, 1 / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: EllipticK[ Around[1 / 2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: EllipticK[{{-1, 0}, {1 / 2, -1}}]//FunctionExpand

MatrixFunctionを使って行列のEllipticK関数を計算することもできる：

Wolfram Language code: MatrixFunction[EllipticK, {{-1, 0}, {1 / 2, -1}}]//FunctionExpand

特定の値 (5)

簡単な厳密値は自動的に生成される：

Wolfram Language code: {EllipticK[0], EllipticK[1]}

FunctionExpandを適用した後でのGammaについてのいくつかの厳密値：

Wolfram Language code: {EllipticK[-1], EllipticK[1 / 2]}//FunctionExpand

分枝切断線における方向を持った極限値を求める：

Wolfram Language code: Limit[EllipticK[2 + ε I], ε -> 0, Direction -> 1]

Wolfram Language code: Limit[EllipticK[2 + ε I], ε -> 0, Direction -> -1]

無限大における値：

Wolfram Language code: EllipticK[Infinity]

方程式の根を求める：

Wolfram Language code:

f[m_] := EllipticK[m] - 2;
xzero = Solve[f[m] == 0 && 0.5 < m < 1, m][[1, 1, 2]]//Quiet

Wolfram Language code: Plot[f[m], {m, -1, 1}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可視化 (2)

EllipticKをプロットする：

Wolfram Language code: Plot[{EllipticK[m]}, {m, -2, 1}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[EllipticK[z]], {z, -5 - 5I, 5 + 5I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[EllipticK[z]], {z, -5 - 5I, 5 + 5I}, IconizedObject[«PlotOptions»]]

関数の特性 (9)

EllipticKは，1未満のすべての実数値について定義される：

Wolfram Language code: FunctionDomain[EllipticK[m], m]

EllipticKはすべての正の実数値を取る：

Wolfram Language code: FunctionRange[EllipticK[m], m, y]//Quiet

EllipticKは解析関数ではない：

Wolfram Language code: FunctionAnalytic[EllipticK[m], m]

特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[EllipticK[m], m]//Quiet

Wolfram Language code: FunctionDiscontinuities[EllipticK[m], m]//Quiet

EllipticKは有理型関数ではない：

Wolfram Language code: FunctionMeromorphic[EllipticK[m], m]

EllipticKはその定義域上で非減少である：

Wolfram Language code: FunctionMonotonicity[{EllipticK[m], m < 1}, m]

EllipticKは単射である：

Wolfram Language code: FunctionInjective[EllipticK[m], m]

Wolfram Language code: Plot[{EllipticK[m], 2}, {m, -2, 2}]

EllipticKは全射ではない：

Wolfram Language code: FunctionSurjective[EllipticK[m], m]

Wolfram Language code: Plot[{EllipticK[m], -2}, {m, -2, 2}]

EllipticKはその定義域上で非負である：

Wolfram Language code: FunctionSign[{EllipticK[m], m < 1}, m]

EllipticKはその定義域上で凸である：

Wolfram Language code: FunctionConvexity[{EllipticK[m], m < 1}, m]

微分 (3)

一次導関数：

Wolfram Language code: D[EllipticK[m], m]

高次導関数：

Wolfram Language code: Table[D[EllipticK[m], {m, n}], {n, 1, 3}]//FullSimplify

Wolfram Language code: Plot[Evaluate[%], {m, -1, 1}, PlotLegends -> Table[Inactive[D][EllipticK[m], {m, k}], {k, Length[%]}]]

次導関数の式：

Wolfram Language code: D[EllipticK[m], {m, n}]

積分 (3)

EllipticKの不定積分：

Wolfram Language code: Integrate[EllipticK[m], m]

分枝切断線上の区間上の定積分：

Wolfram Language code: Integrate[EllipticK[m], {m, 1, 2}]

その他の積分例：

Wolfram Language code: Integrate[z^αEllipticK[z], z]

Wolfram Language code: Integrate[(z EllipticK[z^2]/(1 - z^2)^3 / 2), z]

級数展開 (3)

EllipticKのテイラー(Taylor)展開：

Wolfram Language code: Series[EllipticK[m], {m, 0, 3}]

の周りのEllipticKの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[EllipticK[m], {m, 0, n}], {n, 1, 3}];
Plot[{EllipticK[m], terms}, {m, -2, 2}]

分岐点における級数展開：

Wolfram Language code: Series[EllipticK[x], {x, 1, 1}]

EllipticKはベキ級数に適用できる：

Wolfram Language code: EllipticK[Exp[x] - 1 + O[x] ^ 4]

積分変換 (3)

LaplaceTransformを使ってラプラス(Laplace)変換を計算する：

Wolfram Language code: LaplaceTransform[EllipticK[-t], t, s]

MellinTransform：

Wolfram Language code: MellinTransform[EllipticK[-t], t, s ]

HankelTransform：

Wolfram Language code: HankelTransform[EllipticK[-r], r, s ]

関数表現 (5)

他の楕円積分との関係：

Wolfram Language code: EllipticPi[0, m]

Wolfram Language code: EllipticF[(π/2), m]

LegendrePとの関係：

Wolfram Language code: (π/2)LegendreP[-(1/2), 1 - 2 m]//FullSimplify

MeijerGReduceを使ってMeijerGについて表現する：

Wolfram Language code: MeijerGReduce[EllipticK[x], x]

Wolfram Language code: Activate[%]

EllipticKはDifferentialRootとして表現できる：

Wolfram Language code: DifferentialRootReduce[EllipticK[m], m]

TraditionalFormによる表示：

Wolfram Language code: EllipticK[m]//TraditionalForm

アプリケーション (7)

振子周期の小さい角の近似：

Wolfram Language code: Series[4Sqrt[(d/g)]EllipticK[Sin[(α/2)]^2], {α, 0, 2}]

周期と初期の角度の比をプロットする：

Wolfram Language code: Plot[EllipticK[Sin[(α/2)] ^ 2], {α, 0, Pi}, AxesOrigin -> {0, EllipticK[0]}]

円柱座標における円電流フローによるベクトルポテンシャル：

Wolfram Language code:

A = -2(((r + R)^2 + z^2) EllipticE[(4 r R/(r + R)^2 + z^2)] - (r^2 + R^2 + z^2) EllipticK[(4 r R/(r + R)^2 + z^2)]) / (r R Sqrt[(r + R)^2 + z^2]);

磁場の要素：

Wolfram Language code: Bz = D[r A, r] / r//FullSimplify

Wolfram Language code: Br = -D[A, z]//FullSimplify

磁場の強度をプロットする：

Wolfram Language code: Plot3D[Sqrt[Br^2 + Bz^2] /. R -> 1, {r, 0.001, 3 / 2}, {z, -1, 1}]

単位抵抗の無限大三次元格子における原点と点の間の抵抗：

Wolfram Language code: ρ[n_] := (1/π^2)NIntegrate[EllipticK[((2/3 - Cos[x]))^2](2 - Cos[n x]/3 - Cos[x]), {x, 0, Pi}]

Wolfram Language code: DiscretePlot[ρ[n], {n, 50}, PlotRange -> All]

イジングモデルのOnsager解のエネルギー：

Wolfram Language code:

ℰ = With[{β = (1/Subscript[k, B]T)}, -2 n J Tanh[2 β J] - n J (Sinh[2 β J]^2 - 1/Sinh[2β J]Cosh[2β J])((2/π)EllipticK[(2 (Sinh[2β J]/Cosh[2β J]^2))^2] - 1)];

比熱のプロット：

Wolfram Language code: Plot[Evaluate[D[ℰ, T] /. {n -> 1, J -> 1, Subscript[k, B] -> 1}], {T, 0.1, 4}, AxesOrigin -> {0, 0}]

臨界温度を求める：

Wolfram Language code: Select[Solve[1 / D[ℰ, T] == 0, T], (Subscript[k, B]T / J /. #) > 0&]//Quiet

特異値を計算する：

Wolfram Language code: FindRoot[Re[(EllipticK[1 - z^2]/EllipticK[z^2])] == Sqrt[2], {z, 1 / 2}, WorkingPrecision -> 50]

Wolfram Language code: (z /. %) - (Sqrt[2] - 1)

一対の対角に電圧が印加された長方形の導電シート内の電流の流れ：

Wolfram Language code:

flow[m_] = (NevilleThetaD[x, m] NevilleThetaD[y, 1 - m] NevilleThetaS[x, m] NevilleThetaS[y, 1 - m]) / (NevilleThetaC[x, m] NevilleThetaC[y, 1 - m] NevilleThetaN[x, m] NevilleThetaN[y, 1 - m]);

EllipticKで境界を定義して流線をプロットする：

Wolfram Language code:

With[{m = 0.4}, ContourPlot[flow[m], {x, 0, EllipticK[m]}, {y, 0, EllipticK[1 - m]}, ContourShading -> False, MaxRecursion -> 1, Contours -> {0.02, 0.13, 0.3, 0.54, 0.9, 1.46, 2.53, 5.17, 28.4}]]

アナログ信号用のローパス楕円フィルタを構築する：

Wolfram Language code: 𝒩 = 5;ωPass = 4.8;ℊPass = 0.92;ℊStop = 0.08;

フィルタリプルパラメータと陪楕円関数パラメータを計算する：

Wolfram Language code:

ϵp = Sqrt[ℊPass^-2 - 1];ϵs = Sqrt[ℊStop^-2 - 1];
m1 = (ϵp / ϵs)^2;
K1 = EllipticK[m1];
K1p = EllipticK[1 - m1];

パス周波数とストップ周波数の比を求めるために楕円次数方程式を使用する：

Wolfram Language code:

us = Range[1, 2⌊(𝒩/2)⌋ - 1, 2] / 𝒩;
m = 1 - (1 - m1) ^ 𝒩 Apply[Times, JacobiSN[us K1p, 1 - m1] ^ 8]

タイプするストップ周波数と楕円パラメータを計算する：

Wolfram Language code:

K = EllipticK[m];Kp = EllipticK[1 - m];
ωStop = ωPass / Sqrt[m]

リプル位置および伝達関数の極と零点を計算する：

Wolfram Language code:

ζs = JacobiCD[us K, m];
zeros = I ωStop / ζs;

伝達関数の極を計算する：

Wolfram Language code:

Subscript[ν, 0] = (1/𝒩 K1)InverseJacobiSC[(1/ϵp), 1 - m1];
poles = ωPass I JacobiCD[(us - I Subscript[ν, 0])K, m];

伝達関数を組み立てる：

Wolfram Language code:

H[ω_] = Piecewise[{{ℊPass, Mod[𝒩, 2] == 0}, {(1/1 + I ω / ωPass JacobiCS[Subscript[ν, 0] K, 1 - m]), Mod[𝒩, 2] == 1}}] Apply[Times, ((1 - I ω / zeros)(1 - I ω / Conjugate[zeros])/(1 - I ω / poles)(1 - I ω / Conjugate[poles]))];

Wolfram Language code:

Plot[Abs[H[ω]], {ω, 0, 8}, PlotRange -> All, Epilog -> {Pink, Dashed, Line[{{0, ℊPass}, {ωPass, ℊPass}, {ωPass, ℊStop}}], Line[{{ωStop, ℊPass}, {ωStop, ℊStop}, {10, ℊStop}}]}]

EllipticFilterModelの結果と比較する：

Wolfram Language code: tf = EllipticFilterModel[{"Lowpass", {ωPass, ωStop}, -20Log10[{ℊPass, ℊStop}]}];

Wolfram Language code: Plot[Abs[tf[I ω]], {ω, 0, 8}]

特性と関係 (4)

これは，EllipticK関数の分枝切断線を示している：

Wolfram Language code: Plot3D[Im[EllipticK[x + I y]], {x, -2, 2}, {y, -2, 2}]

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[EllipticK[z]^2 - 5 EllipticK[z + 2] + z == 6, {z, 10}]

微分方程式を解く：

Wolfram Language code: DSolve[z (1 - z) w''[z] + (1 - 2 z) w'[z] - w[z] / 4 == 0, w[z], z]//Simplify

EllipticKはさまざまな数学関数の特別な場合である：

Wolfram Language code:

{LegendreP[-(1/2), 1 - 2 z], AppellF1[(1/2), (1/2), (1/2), (3/2), 1, z ], EllipticF[(π/2), z], EllipticPi[0, (π/2), z], MeijerG[{{(1/2), (1/2)}, {}}, {{0}, {0}}, -z]}

考えられる問題 (3)

機械精度の評価は分枝切断線付近で数値的に不正確な答を与えることがある：

Wolfram Language code: EllipticK[ 2 - I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])] // N

Wolfram Language code: EllipticK[2 - I ((Pi + 1) ^ 2 - Pi ^ 2 - 2Pi - 1 - Exp[-Pi ^ 4])] //N[#, 100]& // N

定義積分は追加的な条件の下でのみ収束する：

Wolfram Language code: Integrate[1 / Sqrt[1 - m Sin[t] ^ 2], {t, 0, Pi / 2}]

異なる結果を与える異なる引数の慣習も存在する：

Wolfram Language code: Integrate[1 / Sqrt[1 - k ^ 2 Sin[t] ^ 2], {t, 0, Pi / 2}, Assumptions -> k ^ 2 < 1]

おもしろい例題 (2)

三次元立方格子内のランダム歩行者が原点に戻る確率：

Wolfram Language code: p = 1 - (π^2/72)(6 + 2 Sqrt[3] + Sqrt[6]) EllipticK[35 + 24 Sqrt[2] - 20 Sqrt[3] - 14 Sqrt[6]]^-2 //N

1000回のモデル歩行を実行し，原点に戻る回数を数える：

Wolfram Language code:

maxSteps = 500;
BlockRandom[SeedRandom[2021];
	start = {0, 0, 0};Count[Table[walkerPosition = start;steps = 0;While[steps == 0 || (steps < maxSteps && walkerPosition =!= start), steps++;walkerPosition = walkerPosition + {{1, 0, 0}, {-1, 0, 0}, {0, 1, 0}, {0, -1, 0}, {0, 0, 1}, {0, 0, -1}}[[RandomInteger[{1, 6}]]]];steps, {1000}], _ ? (# < maxSteps&)]]

における期待される回数と比較する：

Wolfram Language code:

With[{countDist = BinomialDistribution[1000, p]}, Around[Mean[countDist], 2StandardDeviation[countDist]]
	]

のリーマン(Riemann)面：

Wolfram Language code:

Show[Plot3D[Evaluate[Table[Im[EllipticK[x + I y] - j 2 I EllipticK[1 - (x + I y)]], {j, -2, 2}]], {x, -9, 9}, {y, ##}, ClippingStyle -> None, PlotStyle -> Opacity[0.6], Mesh -> False, BoxRatios -> {1, 1, 1}, MaxRecursion -> 5, PlotRange -> {All, All, {-9, 9}}]&@@@{{-9, -10 ^ -6}, {10 ^ -6, 9}}]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

EllipticK

詳細

例題

例 (5)

スコープ (38)

数値評価 (5)

特定の値 (5)

可視化 (2)

関数の特性 (9)

微分 (3)

積分 (3)

級数展開 (3)

積分変換 (3)

関数表現 (5)

アプリケーション (7)

特性と関係 (4)

考えられる問題 (3)

おもしろい例題 (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

EllipticK

詳細

例題

例 (5)

スコープ (38)

数値評価 (5)

特定の値 (5)

可視化 (2)

関数の特性 (9)

微分 (3)

積分 (3)

級数展開 (3)

積分変換 (3)

関数表現 (5)

アプリケーション (7)

特性と関係 (4)

考えられる問題 (3)

おもしろい例題 (2)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX