Wolfram言語＆システムドキュメントセンター

MaxValue

MaxValue[f,x]

x についての f の最大値を与える．

MaxValue[f,{x,y,…}]

x, y, …についての f の最大値を与える．

MaxValue[{f,cons},{x,y,…}]

制約条件 cons の下での f の最大値を与える．

MaxValue[…,x∈rdom]

x が領域 rdom 内にあるように制限する．

MaxValue[…,…,dom]

変数を領域 dom（一般にRealsまたはIntegers）に制限する．

MaxValue

MaxValue[f,x]

x についての f の最大値を与える．

MaxValue[f,{x,y,…}]

x, y, …についての f の最大値を与える．

MaxValue[{f,cons},{x,y,…}]

制約条件 cons の下での f の最大値を与える．

MaxValue[…,x∈rdom]

x が領域 rdom 内にあるように制限する．

MaxValue[…,…,dom]

変数を領域 dom（一般にRealsまたはIntegers）に制限する．

詳細とオプション

MaxValueは上限（シュープレマム）としても知られている．
MaxValueは与えられた制約条件に従って f の最大値を求める．
MaxValueは，通常，制約条件下で可能な最大値を求めるために使われる．分野によっては，最適な戦略，最良適合，最適な構成等と呼ばれることがある．
Maximizeは{f_max,{x->x_max,y->y_max,…}}の形式のリストを返す．

f および cons が線形あるいは多項式の場合，MaxValueは常に大域的な上限を求める．
制約条件 cons は以下の任意の論理結合でよい．

	lhs==rhs	等式
	lhs>rhs, lhs≥rhs, lhs<rhs, lhs≤rhs	不等式 (LessEqual,…)
	lhsrhs, lhsrhs, lhsrhs, lhsrhs	ベクトル不等式 (VectorLessEqual,…)
	Exists[…], ForAll[…]	量化条件
	{x,y,…}∈rdom	領域指定

MaxValue[{f,cons},x∈rdom]は，事実上，MaxValue[{f,cons∧x∈rdom},x]に等しい．
x∈rdom については，Indexed[x,i]を使って別の座標に言及することができる．
次は，使用可能な領域 rdom である．

	Reals	実数スカラー変数
	Integers	整数スカラー変数
	Vectors[n,dom]	のベクトル変数
	Matrices[{m,n},dom]	の行列変数
	ℛ	幾何領域に制限されたベクトル変数

デフォルトで，すべての変数が実数であるとみなされる．
MaxValueは入力が厳密値の場合は厳密値を返す．入力が近似値の場合は自動的にNMaxValueを呼び出す．
MaxValueは次の形式を返す．

	f_max	有限最大値
	-∞	実行不可能，つまり，制約条件集合が空
	∞	非有界，つまり，f の値は任意に大きくできる

MaxValueは f の値の最小上界を与える．これは，x, y, …のいずれの値についても達成できない可能性がある．
N[MaxValue[…]]は，記号的には解けない最適化問題についてはNMaxValueを呼び出す．

例題

すべて開くすべて閉じる

例 (5)

一変数関数の最大値を求める：

Wolfram Language code: MaxValue[-2x ^ 2 - 3x + 5, x]

多変数関数の最大値を求める：

Wolfram Language code: MaxValue[1 - (x y - 3) ^ 2, {x, y}]

制約条件のもとでの関数の最大値を求める：

Wolfram Language code: MaxValue[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

最大値をパラメータの関数として求める：

Wolfram Language code: MaxValue[a x ^ 2 + b x + c, x]

幾何学領域上で関数の最大値を求める：

Wolfram Language code: MaxValue[x + y, {x, y}∈Disk[]]

Wolfram Language code: Plot3D[{x + y, %}, {x, y}∈Disk[], PlotStyle -> Opacity[0.7]]

スコープ (36)

基本的な用法 (7)

制約条件のない実数上でを最大にする：

Wolfram Language code: MaxValue[Sin[x] + Cos[x], x]

制約条件に従ってを最大にする：

Wolfram Language code: MaxValue[{x + 2y, x ^ 2 + 2y ^ 2 ≤ 3 && x + y == 2 && x ≥ 1}, {x, y}]

制約条件は任意の論理結合を含むことがある：

Wolfram Language code: MaxValue[{x y, x ^ 2 + y ^ 2 ≤ 1 || (x + 1) ^ 2 + (y - 1) ^ 2 ≤ 2}, {x, y}]

非有界の問題：

Wolfram Language code: MaxValue[{x + y, x ≤ y ^ 2}, {x, y}]

実行不可能な問題：

Wolfram Language code: MaxValue[{x + y, x ^ 2 + y ^ 2 < 0}, {x, y}]

上限値には達しないかもしれない：

Wolfram Language code: MaxValue[-Exp[x], x]

Wolfram Language code: Plot[-Exp[x], {x, -3, 3}]

ベクトル変数とベクトル不等式を使う：

Wolfram Language code: MaxValue[{{-1, -1}.v, {{1, 2}, {1, 0}}.v{3, -1}}, v]

一変数の問題 (7)

制約条件なしの一変数多項式の最大化：

Wolfram Language code: MaxValue[-x ^ 4 + 2x ^ 3 + 5x - 7, x]

制約条件付きの一変数多項式の最大化：

Wolfram Language code: MaxValue[{-3x ^ 2 - x + 9, 2x ^ 3 + 5x - 7 ≥ 0}, x]

指数対数関数：

Wolfram Language code: MaxValue[-E ^ (2E ^ x) + Log[x ^ 2 + 1] + 20x, x]

有界の条件上での解析関数：

Wolfram Language code: MaxValue[{AiryAi[x + Sin[x]] + Cos[x ^ 2], -5 ≤ x ≤ 5}, x]

Wolfram Language code: Plot[{AiryAi[x + Sin[x]] + Cos[x ^ 2], %}, {x, -5, 5}]

Wolfram Language code: MaxValue[{BesselJ[2, x] / Gamma[x + 1] + (x + 1) ^ Sin[x], 0 ≤ x ≤ 10}, x]

Wolfram Language code: Plot[{BesselJ[2, x] / Gamma[x + 1] + (x + 1) ^ Sin[x], %}, {x, 0, 10}]

周期関数：

Wolfram Language code: MaxValue[{Sin[x], -1 / 2 ≤ Cos[x] ≤ 1 / 2}, x]

三角関数と通約可能な周期の組合せ：

Wolfram Language code: MaxValue[Sin[E ^ (x / 3) - 3 x] + 2 Cos[2 E ^ (x / 3) - 6 x + 1] ^ 2, x]

周期関数と通約可能な周期の組合せ：

Wolfram Language code: MaxValue[Sin[Sqrt[3] x] - Exp[Cos[3 x] + 2], x]

Wolfram Language code: Plot[{Sin[Sqrt[3] x] - Exp[Cos[3 x] + 2], %}, {x, -50, 50}]

区分関数：

Wolfram Language code: MaxValue[{Floor[x + UnitStep[x - 1]] - x, Ceiling[Abs[x]] < 5}, x]

関数の特性情報を使って可解の制約条件がない問題：

Wolfram Language code: MaxValue[SinhIntegral[DawsonF[x]], x]

Wolfram Language code: MaxValue[BesselJ[7 / 4, x ^ 2 + x + 1], x]

多変数の問題 (9)

多変数線形制約条件付き最大化：

Wolfram Language code: MaxValue[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]

線形分数制約条件付き最大化：

Wolfram Language code: MaxValue[{(2x + y - z) / (5x - 7y + 3), 0 ≤ x + y + z ≤ 1 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]

制約条件なしの多項式の最大化：

Wolfram Language code: MaxValue[x ^ 2 - 2y - 1 - (x ^ 2 - 2y) ^ 2, {x, y}]

制約条件付き多項式の最適化は常に解くことができる：

Wolfram Language code: MaxValue[{x y - 1, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

最大値には達しないことがあるかもしれない：

Wolfram Language code: MaxValue[{1 - x ^ 2, x y ≥ 1}, {x, y}]

目的関数は有界ではないかもしれない：

Wolfram Language code: MaxValue[{x, x y ≤ 1}, {x, y}]

制約条件を満足する点は存在しないかもしれない：

Wolfram Language code: MaxValue[{x, x ^ 2 + y ^ 2 < 0}, {x, y}]

定量化された多項式制約：

Wolfram Language code:

MaxValue[{-(x + 7)^2 - (y - 8)^2, Subscript[∀, z]Subscript[∃, w]3 z^2 w + (x + y) z^4 - 1 == (x^3 - x y + y^2 - 1) w^2}, {x, y}]

代数的最大化：

Wolfram Language code: MaxValue[{-x - Sqrt[x + y] , x Sqrt[y] ≥ 1}, {x, y}]

有界超越関数の最大化：

Wolfram Language code: MaxValue[{E ^ x + Log[y], x Log[y] == 2 && -10 ≤ x ≤ 10 && 1 / 10 ≤ y ≤ 10}, {x, y}]

区分関数の最大化：

Wolfram Language code: MaxValue[{-Max[x - y, Abs[y]], Min[x - 2, x - y ^ 2] ≥ Abs[x y - 1]}, {x, y}]

凸最大化：

Wolfram Language code: MaxValue[v.{1, -1}, {VectorGreaterEqual[{{{1, 0}, {0, 1}, {-1, -2}}.v, {0, 0, -2}}, "ExponentialCone"]}, v]

が半正定でとなるように凹目的関数を最大にする：

Wolfram Language code:

MaxValue[{Log[x + y], (⁠|       |       |
| ----- | ----- |
| x + y | 1     |
| 1     | x - y |⁠)Underscript[, {"SemidefiniteCone", 2}]0 && 1 ≤ x ≤ 10 && -1 ≤ y ≤ 1}, {x, y}]

関数と最大値を領域上にプロットする：

Wolfram Language code: Plot3D[{Log[x + y], %}, {x, 1, 10}, {y, -1, 1}, ...]

パラメトリック問題 (4)

パラメトリック線形最適化：

Wolfram Language code:

MaxValue[{8x + 7y, -6 x - 4 y ≤ 8 - 5 a - 7 b && 7 x + 5 y ≤ a + 4 b && -x + y ≤ 6 + 4a - 5 b && -4 x + 7 y ≤ -1 - 2 a - 7 b && 5 y ≤ 6 - 9 b}, {x, y}]

最大値はパラメータの連続関数である：

Wolfram Language code: Plot3D[%, {a, -3, 3}, {b, 0, 3}]

パラメトリック二次最適化：

Wolfram Language code: MaxValue[{-(x - 1) ^ 2 - (2y - 1) ^ 2, x + 2y ≤ a + b && 2x - y ≤ a - b + 1 && x - 2y ≤ 2a - b + 1}, {x, y}]

最大値はパラメータの連続関数である：

Wolfram Language code: Plot3D[%, {a, -5, 5}, {b, -5, 5}]

制約条件なしのパラメトリック多項式最大化：

Wolfram Language code: MaxValue[-x ^ 4 + a x ^ 2 + b, x]

制約条件付きのパラメトリック多項式最大化：

Wolfram Language code: MaxValue[{-x ^ 2 - y ^ 2, x ^ 3 + y ^ 2 == a}, {x, y}]

整数上の最適化 (3)

一変数問題：

Wolfram Language code: MaxValue[{x ^ 3 Log[x] - E ^ x, x > 0}, x, Integers]

Wolfram Language code: MaxValue[Sin[2x] + Cos[3x], x, Integers]

Wolfram Language code: Show[{ListPlot[Table[Sin[2x] + Cos[3 x], {x, 0, 10000}]], Graphics[{Red, Line[{{0, %}, {10000, %}}]}]}]

整数線形計画法：

Wolfram Language code: MaxValue[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}, Integers]

整数上における多項式の最大化：

Wolfram Language code: MaxValue[{-x ^ 2 - x y + 1, x y ≥ 1}, {x, y}, Integers]

領域上の最適化 (6)

幾何学領域上で関数の最大値を求める：

Wolfram Language code: ℛ = Cylinder[{{1, 2, 3}, {3, 2, 1}}, 1];

Wolfram Language code: MaxValue[z, {x, y, z}∈ℛ]

これをプロットする：

Wolfram Language code: Graphics3D[{Opacity[0.5], {Green, ℛ}, {Red, InfinitePlane[{{0, 0, %}, {1, 0, %}, {0, 1, %}}]}}]

2領域中の点の最大距離を求める：

Wolfram Language code:

Subscript[ℛ, 1] = Disk[];
Subscript[ℛ, 2] = Line[{{-(1/2), -(1/2)}, {-(1/2), (1/2)}, {(1/2), (1/2)}, {(1/2), -(1/2)}, {-(1/2), -(1/2)}}];

Wolfram Language code: MaxValue[(x - u)^2 + (y - v)^2, {{x, y}∈Subscript[ℛ, 1], {u, v}∈Subscript[ℛ, 2]}]

三角形と楕円が交差するの最大値を求める：

Wolfram Language code:

Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Subscript[ℛ, 2] = Circle[{(1/3), (1/3)}, {2 r, r}];

Wolfram Language code: MaxValue[{r, {x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2]}, {r, x, y}]

これをプロットする：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]} /. r -> %}]

に指定された3点が含まれるの最大値を求める：

Wolfram Language code: Subscript[ℛ, 3] = Disk[{a, b}, {r, 2 - r}];

Wolfram Language code: MaxValue[{r, ({0, 0} | {1, 0} | {0, 1})∈Subscript[ℛ, 3]}, {a, b, r}]

を使ってが中のベクトルであると指定する：

Wolfram Language code: ℛ = Sphere[];

Wolfram Language code: MaxValue[x.{1, 2, 3}, x∈ℛ]

2領域内の点の最大距離を求める：

Wolfram Language code:

Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Subscript[ℛ, 2] = Disk[{2, 2}, 1];

Wolfram Language code: MaxValue[EuclideanDistance[x, y], {x∈Subscript[ℛ, 1], y∈Subscript[ℛ, 2]}]//RootReduce

オプション (2)

手法 (1)

MaxValueが円筒代数分解を使用するよう指定する：

Wolfram Language code: maxcad = MaxValue[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}, Method -> "CAD"]

ラグランジュ(Lagrange)乗数を用いる：

Wolfram Language code: maxlm = MaxValue[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}, Method -> "LagrangeMultipliers"]

デフォルトメソッドを使用する：

Wolfram Language code: maxdef = MaxValue[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}]

結果はすべて等価である：

Wolfram Language code: RootReduce[maxcad] === RootReduce[maxlm] === RootReduce[maxdef]

WorkingPrecision (1)

厳密な最大値を求めるのには時間がかかる：

Wolfram Language code:

TimeConstrained[MaxValue[{x ^ 2 + y ^ 2 + z ^ 2, x ^ 2 - 3 x y z + 9 z ^ 2 + y ^ 2 == E && x y z ≤ Pi}, {x, y, z}], 60]

WorkingPrecision->200とすると，厳密な最大値を求めることはできるが，結果は正しくないかもしれない：

Wolfram Language code:

MaxValue[{x ^ 2 + y ^ 2 + z ^ 2, x ^ 2 - 3 x y z + 9 z ^ 2 + y ^ 2 == E && x y z ≤ Pi}, {x, y, z}, WorkingPrecision -> 200]//Timing

アプリケーション (13)

基本的なアプリケーション (4)

単位周長の長方形で面積が最大のものを求める：

Wolfram Language code: MaxValue[{x y, 2x + 2y == 1 && x > 0 && y > 0}, {x, y}]

単位周長の三角形で面積が最大のものを求める：

Wolfram Language code:

triangle = a > 0 && b > 0 && c > 0 && a + b > c && a + c > b && b + c > a;
s = 1 / 2(a + b + c);

Wolfram Language code: MaxValue[{Sqrt[s(s - a)(s - b)(s - c)], triangle && a + b + c == 1}, {a, b, c}]

投射物で高さが最大のものを求める：

Wolfram Language code: MaxValue[ {v Sin[α] t - 5 t ^ 2, t ≥ 0 && 0 < Sin[α] ≤ 1 && v > 0}, t]

Wolfram Language code: Refine[%, 0 < Sin[α] ≤ 1 && v > 0]

投射物の最大範囲を求める：

Wolfram Language code:

MaxValue[{v Cos[α] t, v Sin[α] t - 5 t ^ 2 == 0  && t ≥ 0 && v > 0 && 0 ≤ Sin[α] ≤ 1 && 0 ≤ Cos[α] ≤ 1 && Sin[α] ^ 2 + Cos[α] ^ 2 == 1}, {Sin[α], Cos[α], t}]

Wolfram Language code: Refine[%, v > 0]

関数 f[x] の無限ノルムはMaxValue[{Norm[f[x]],x∈},x]で与えられる．ただし， は f[x]についての関心領域である．区間{-3,3}についてのの無限ノルムを求める：

Wolfram Language code:

f = x^2 - x + 1;
𝒟 = Interval[{-3, 3}];

Wolfram Language code: MaxValue[{Norm[{f}], {x}∈𝒟}, x]

プロットする：

Wolfram Language code: Plot[{f, -13, 13}, {x, -3, 3}, Filling -> {2 -> {3}}]

についての無限ノルムをRectangle[{-1,-1},{1,1}]上で求める：

Wolfram Language code:

f = x^2 + x y;
𝒟 = Rectangle[{-1, -1}, {1, 1}];

Wolfram Language code: MaxValue[{Norm[{f}], {x, y}∈𝒟}, {x, y}]

プロットする：

Wolfram Language code: Plot3D[{f, -2, 2}, {x, y}∈𝒟, PlotStyle -> {White, Opacity[0.3], Opacity[0.3]}, Mesh -> None]

幾何学的距離 (9)

領域 ℛ 内の点から指定された点 p までの最大距離はMaxValue[EuclideanDistance[p,q],q∈ℛ]で与えられる．単位Disk[]内の点から{1,1}までの最大距離を求める：

Wolfram Language code:

p = {1, 1};
q = {q1, q2};
ℛ = Disk[];

Wolfram Language code: d = MaxValue[EuclideanDistance[p, q], q∈ℛ]//RootReduce

これをプロットする：

Wolfram Language code: Graphics[{{LightBlue, EdgeForm[Gray], ℛ}, {Green, Circle[p, d]}, {Red, Point[p]}}]

標準的な単位シンプレックスSimplex[2]内の点から点{1,3/4}までの最大距離を求める：

Wolfram Language code:

p = {1, 3 / 4};
q = {q1, q2};
ℛ = Simplex[{{0, 0}, {1, 0}, {0, 1}}];

Wolfram Language code: d = MaxValue[EuclideanDistance[p, q], q∈ℛ]

これをプロットする：

Wolfram Language code: Graphics[{{LightBlue, EdgeForm[Gray], ℛ}, {Green, Circle[p, d]}, {Red, Point[p]}}]

標準的な単位球Sphere[]内の点から{1,1,1}までの最大距離を求める：

Wolfram Language code:

p = {1, 1, 1};
q = {q1, q2, q3};
ℛ = Sphere[];

Wolfram Language code: d = MaxValue[EuclideanDistance[p, q], q∈ℛ]//RootReduce

これをプロットする：

Wolfram Language code: Graphics3D[{{Opacity[0.5], ℛ}, {Opacity[0.3], Green, Sphere[p, d]}, {Red, Point[p]}}]

標準的な単位シンプレックスSimplex[3]内の点から点{-1/3,1/3,1/3}までの最大距離を求める：

Wolfram Language code:

p = {-1 / 3, 1 / 3, 1 / 3};
q = {q1, q2, q3};
ℛ = Simplex[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];

Wolfram Language code: d = MaxValue[EuclideanDistance[p, q], q∈ℛ]

これをプロットする：

Wolfram Language code: Graphics3D[{{Opacity[0.5], ℛ}, {Opacity[0.3], Green, Sphere[p, d]}, {Red, Point[p]}}]

領域 ℛ の直径は ℛ 内の2点の最大距離であり，MaxValue[EuclideanDistance[p,q],{p∈ℛ,q∈ℛ}]で計算することができる．Circle[]の直径を求める：

Wolfram Language code: ℛ = Circle[];

Wolfram Language code: MaxValue[EuclideanDistance[p, q], {p∈ℛ, q∈ℛ}]

標準的な単位シンプレックスSimplex[2]の直径を求める：

Wolfram Language code: ℛ = Simplex[{{0, 0}, {1, 0}, {0, 1}}];

Wolfram Language code: MaxValue[EuclideanDistance[p, q], {p∈ℛ, q∈ℛ}]

標準的な単位立方体Cuboid[]の直径を求める：

Wolfram Language code: ℛ = Cuboid[];

Wolfram Language code: MaxValue[EuclideanDistance[p, q], {p∈ℛ, q∈ℛ}]

点 p∈ と q∈ 野最大距離はMaxValue[EuclideanDistance[p,q],{p∈,q∈}]で求めることができる．Disk[{0,0}]内の点とRectangle[{3,3}]内の点の最大距離を求める：

Wolfram Language code: 𝒫 = Disk[{0, 0}]; 𝒬 = Rectangle[{3, 3}];

Wolfram Language code: MaxValue[EuclideanDistance[p, q], {p∈𝒫, q∈𝒬}]

Line[{{0,0,0},{1,1,1}}]内の点とBall[{5,5,0},1]内の点の最大距離を求める：

Wolfram Language code: 𝒫 = Line[{{0, 0, 0}, {1, 1, 1}}]; 𝒬 = Ball[{5, 5, 0}, 1];

Wolfram Language code: MaxValue[EuclideanDistance[p, q], {p∈𝒫, q∈𝒬}]

特性と関係 (4)

Maximizeは最大値と最大となる点の両方を与える：

Wolfram Language code: Maximize[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

MaxValueは目的関数の厳密な最大値を与える：

Wolfram Language code: f = Expand[-Product[(x - i)(x - 100 - i), {i, 5}]];

Wolfram Language code: MaxValue[f, x]

Wolfram Language code: Plot[f, {x, 0, 100}, Epilog -> {Green, Dashing[Medium], Line[{{0, %}, {100, %}}]}]

NMaxValueは最大値を数値的に求めようとするが，求まるのは極大値のことがある：

Wolfram Language code: NMaxValue[f, x]

Wolfram Language code: Plot[f, {x, 0.5, 5.5}, Epilog -> {Red, Dashing[Medium], Line[{{0.5, %}, {5.5, %}}]}]

FindMaxValueは始点によって極大値を求める：

Wolfram Language code: FindMaxValue[f, {x, #}]& /@ {1, 50}

Wolfram Language code:

Plot[f, {x, 0, 100}, Epilog -> {Dashing[Medium], {Red, Line[{{0, %[[1]]}, {100, %[[1]]}}]}, {Green, Line[{{0, %[[2]]}, {100, %[[2]]}}]}}]

MaxValueは線形計画法問題を解くことができる：

Wolfram Language code: MaxValue[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]

LinearProgrammingは行列表記で与えられた同じ問題を解くのに使うことができる：

Wolfram Language code:

c = {2, 3, -1};
m = {{1, 1, 1}, {1, 1, 1}, {1, -1, 1}, {1, -1, 1}, {1, -1, -1}};
b = {{1, 1}, {2, -1}, {1, 1}, {2, -1}, {3, 0}};

Wolfram Language code: c.LinearProgramming[-c, m, b, -Infinity]

RegionBoundsを使って境界ボックスを計算する：

Wolfram Language code:

f = x^4 + 3 x^2 y + 2 x^2 y^2 - y^3 + y^4 ≤ 0;
ℛ = ImplicitRegion@@{f, {x, y}}

Wolfram Language code: RegionBounds[ℛ]

MaxValueおよびMinValueを使って同じ境界を計算する：

Wolfram Language code: {{x1, x2}, {y1, y2}} = {MinValue[#, {x, y}∈ℛ], MaxValue[#, {x, y}∈ℛ]}& /@ {x, y}

Wolfram Language code: Show[{Graphics[{LightBlue, Rectangle[{x1, y1}, {x2, y2}]}], RegionPlot[f, {x, x1 - 1, x2 + 1}, {y, y1 - 1, y2 + 1}]}]

考えられる問題 (1)

MaxValueは入力中のすべての関数が実数値であることを必要とする：

Wolfram Language code: MaxValue[{-x - y, Sqrt[x] - Sqrt[y] == 0}, {x, y}]

方程式は満たすが平方根が実数ではない値は許容されない：

Wolfram Language code: {Sqrt[x] - Sqrt[y] == 0, Sqrt[x], Sqrt[y]} /. {x -> -1, y -> -1}

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

MaxValue

詳細とオプション

例題

例 (5)

スコープ (36)

基本的な用法 (7)

一変数の問題 (7)

多変数の問題 (9)

パラメトリック問題 (4)

整数上の最適化 (3)

領域上の最適化 (6)

オプション (2)

手法 (1)

WorkingPrecision (1)

アプリケーション (13)

基本的なアプリケーション (4)

幾何学的距離 (9)

特性と関係 (4)

考えられる問題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

MaxValue

詳細とオプション

例題

例 (5)

スコープ (36)

基本的な用法 (7)

一変数の問題 (7)

多変数の問題 (9)

パラメトリック問題 (4)

整数上の最適化 (3)

領域上の最適化 (6)

オプション (2)

手法 (1)

WorkingPrecision (1)

アプリケーション (13)

基本的なアプリケーション (4)

幾何学的距離 (9)

特性と関係 (4)

考えられる問題 (1)

関連項目

テクニカルノート

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX