Wolfram 语言与系统参考资料中心

Norm

Norm[expr]

给出一个数字、向量或矩阵的模（范数）.

Norm[expr,p]

给出 ‐范数.

范例

打开所有单元关闭所有单元

基本范例 (3)

二维向量的范数：

Wolfram Language code: Norm[{3, 4}]

三维向量的范数：

Wolfram Language code: Norm[{x, y, z}]

复数的模（范数）：

Wolfram Language code: Norm[-2 + I]

范围 (16)

向量 (7)

符号向量的范数：

Wolfram Language code: Norm[{1, 2 + x, y}]

化简，假设各项为实数：

Wolfram Language code: Simplify[%, {x, y}∈Reals]

复值向量的范数：

Wolfram Language code: Norm[{1 + I, 2 - 3I, 4}]

有限 -范数：

Wolfram Language code: Norm[{x, y, z}, p]

-范数：

Wolfram Language code: Norm[{-10, 0, 5}, Infinity]

使用非整数计算范数：

Wolfram Language code: Norm[{1, 2, 3}, 1.5]

v 是一个整数向量：

Wolfram Language code: v = {1, 0, 1, 0, 0, 1, 0, 0, 0, 1, 0, 0, 0, 0, 1};

使用精确算术来计算范数：

Wolfram Language code: Norm[v]

使用近似的机器数值计算：

Wolfram Language code: Norm[N[v]]

使用 35 位数值精度运算：

Wolfram Language code: Norm[N[v, 35]]

结构化向量的范数：

Wolfram Language code: Norm[QuantityArray[{3, 4, 5 }, "Meters"]]

维度为 20 的稀疏向量的 -范数：

Wolfram Language code: Norm[SparseArray[{1 -> 5, 10 -> 500}, {20}], ∞]

矩阵 (6)

矩阵的范数，等于最大的奇异值：

Wolfram Language code: Norm[{{2, 1.5}, {3, 5}}]

Wolfram Language code: SingularValueList[{{2, 1.5}, {3, 5}}]

实参数的符号矩阵范数：

Wolfram Language code: Refine[Norm[{{1, x}, {3, 4}}], x∈Reals]

当范数在没有实数假设的情况下计算时，结果会复杂得多：

Wolfram Language code: LeafCount /@ {%, Norm[{{1, x}, {3, 4}}]}

矩阵的 -范数是该矩阵各列的 -范数的最大值：

Wolfram Language code:

Norm[(|   |   |   |
| - | - | - |
| a | b | c |
| d | e | f |
| g | h | i |), 1]

矩阵的 -范数是该矩阵各行的 -范数的最大值：

Wolfram Language code:

Norm[(|   |   |   |
| - | - | - |
| a | b | c |
| d | e | f |
| g | h | i |), Infinity]

矩阵的 Frobenius 范数：

Wolfram Language code:

Norm[(|   |   |
| - | - |
| a | b |
| c | d |), "Frobenius"]

结构化矩阵的范数：

Wolfram Language code: id = IdentityMatrix[10 ^ 5]

Wolfram Language code: Norm[id]

单位矩阵的三种诱导范数是相同的：

Wolfram Language code: Norm[id] == Norm[id, 1] == Norm[id, ∞]

Frobenius 范数是不同的，其值等于维数的平方根：

Wolfram Language code: Norm[id, "Frobenius"]

以 SparseArray 对象表示的三对角矩阵的谱范数：

Wolfram Language code: s = SparseArray[{{i_, i_} -> -2, {i_, j_} /; Abs[i - j] == 1 -> 1}, {50, 50}]

Wolfram Language code: Norm[s]

格式化 (3)

输入 norm 以创建模板，然后输入一个向量以计算其范数：

Wolfram Language code: {1, 2, 3}

输入 norm2 以插入模板；按下在各位置间切换：

Wolfram Language code: Norm[{1, 2, 3}, 1]

输出格式：

Wolfram Language code: Norm[v]

Wolfram Language code: Norm[v, 2]

Frobenius 范数有专门的格式：

Wolfram Language code: Norm[x, "Frobenius"]

应用 (3)

在单位面积里，估计从原点到随机点的平均距离：

Wolfram Language code: pts = RandomReal[1, {10 ^ 3, 2}];

Wolfram Language code: ListPlot[pts]

Wolfram Language code: Mean[Map[Norm, pts]]

与渐近线的结果相比较：

Wolfram Language code: NIntegrate[Sqrt[x ^ 2 + y ^ 2], {x, 0, 1}, {y, 0, 1}]

用一个已知的解，求解一个病态线性系统：

Wolfram Language code:

m = N[HilbertMatrix[20]];
b = m.Range[20];
x = LinearSolve[m, b]

得到余范数：

Wolfram Language code: Norm[m.x - b]

得到实际误差的范数：

Wolfram Language code: Norm[x - Range[20]]

使用个空间点和时间步长求函数的近似解：

Wolfram Language code:

f0[x_]  :=   Exp[-(10( x - 1 / 2)) ^ 2];
α = 0.1;
heat[n_, k_] := Module[{u, m, dt = 1 / k}, 
	m = SparseArray[{{i_, i_} -> -2.dt n ^ 2, {i_, j_} /; Abs[i - j] == 1 -> 1.dt n ^ 2}, {n - 1, n - 1}, 0.];
	minv = LinearSolve[SparseArray[{i_, i_} -> 1., {n - 1, n - 1}] - α m];
	xgrid = N[Range[n - 1] / n];
	u  = f0[xgrid];
	Do[u = minv[u], {k}] ;
	u]

找到两个带有固定的的解，第二个有两倍的时间步长：

Wolfram Language code:

u1 = heat[100, 10];
u2 = heat[100, 20];

通过计算差异范数，估计误差：

Wolfram Language code: Norm[u1 - u2]

从反向欧拉方法的一阶收敛外推导出一个较好的解：

Wolfram Language code: u3 = 2 u2 - u1;

Wolfram Language code: ListPlot[Transpose[{xgrid, u3}]]

用 NDSolve 计算更精确的答案：

Wolfram Language code:

sol = First[u /. NDSolve[{D[u[t, x], t] == α D[u[t, x], x, x], u[0, x] == Exp[-(10( x - 1 / 2)) ^ 2], u[t, 0] == u[t, 1] == 0}, u, {t, 0, 1}, {x, 0, 1}]]

比较三个答案的误差：

Wolfram Language code: und = sol[1, xgrid];

Wolfram Language code: {Norm[u1 - und], Norm[u2 - und], Norm[u3 - und]}

属性和关系 (7)

范数始终为非负数：

Wolfram Language code: FullSimplify[Norm[x] >= 0]

v 的范数与 Dot 和乘积的平方根相等：

Wolfram Language code: v = RandomComplex[1 + I, {3}];

Wolfram Language code: Norm[v] == Sqrt[v. Conjugate[v]]

对于向量，默认范数为 2-范数：

Wolfram Language code: With[{v = RandomReal[1, 10]}, Norm[v] === Norm[v, 2]]

矩阵也是如此：

Wolfram Language code: With[{m = RandomReal[1, {19, 19}]}, Norm[m] === Norm[m, 2]]

是的减函数：

Wolfram Language code: v = RandomReal[1, {100}];

Wolfram Language code: LogLinearPlot[Norm[v, p], {p, 1, 100}, PlotRange -> All]

极限值为范数，等于 Max[Abs[v]]：

Wolfram Language code: Underscript[, p -> ∞]Norm[v, p] == Norm[v, ∞] == Max[Abs[v]]

对于所有单位向量 v 来说，矩阵 -范数是 m.v 的 -范数的最大值：

Wolfram Language code: m = RandomReal[9, {3, 3}];

Wolfram Language code: Block[{v = {x, y, z}}, Maximize[{Norm[m.v], Norm[v] == 1}, v]]

Wolfram Language code: Norm[m]

这个与的最大奇异值相等：

Wolfram Language code: SingularValueList[m, 1]

Frobenius 范数与元素向量生成的范数是一样的：

Wolfram Language code: m = RandomReal[1, {9, 10}];

Wolfram Language code: Norm[m, "Frobenius"]

Wolfram Language code: Norm[Flatten[m]]

对于矩阵 m，Norm[m,Infinity] 可以计算为 Max[Total/@Abs/@m]：

Wolfram Language code: With[{m = RandomReal[1, {10, 10}]}, Norm[m, ∞] == Max[Total /@ Abs /@ m]]

这相当于计算每一行的-范数，并取其最大值：

Wolfram Language code: With[{m = RandomReal[1, {10, 10}]}, Norm[m, ∞] == Max[Norm[#, 1]& /@ m]]

Norm[m,1] 可以通过 Max[Total/@Abs/@Transpose[m]] 计算得到：

Wolfram Language code: With[{m = RandomReal[1, {10, 10}]}, Norm[m, 1] == Max[Total /@ Abs /@ Transpose[m]]]

这相当于计算各列的-范数并取最大值：

Wolfram Language code: With[{m = RandomReal[1, {10, 10}]}, Norm[m, 1] == Max[Norm[#, 1]& /@ Transpose[m]]]

可能存在的问题 (2)

计算大型矩阵的 -范数，比较费时：

Wolfram Language code: m = RandomReal[1, {1000, 1000}];

Wolfram Language code: Timing[Norm[m]]

如果你只需要估计，-范数或者 -范数是非常快的：

Wolfram Language code: Timing[{Norm[m, 1], Norm[m, ∞]}]

一般向量的范数包含 Abs：

Wolfram Language code: Norm[{x, y, z}]

使用 Simplify 和 FullSimplify 可以在假设参数为实数的情况下得到更简洁的结果：

Wolfram Language code: Simplify[%, {x, y, z}∈Reals]

巧妙范例 (2)

使用 1、2、3 和范数的单位球：

Wolfram Language code: Table[RegionPlot[Norm[{x, y}, p] ≤ 1, {x, -1.5, 1.5}, {y, -1.5, 1.5}, FrameTicks -> None], {p, {1, 2, 3, Infinity}}]

不同的范数函数：

Wolfram Language code: Table[Plot3D[Norm[{x, y}, p], {x, -1.5, 1.5}, {y, -1.5, 1.5}, Mesh -> None, Ticks -> None], {p, {1, 2, 3, Infinity}}]

Top

	1	诱导 -范数，算子 -范数
	2	谱范数，算子范数
	Infinity	诱导 -范数，算子 -范数
	"Frobenius"	Frobenius 范数或 Hilbert–Schmidt 范数

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Norm

更多信息和选项

范例

基本范例 (3)

范围 (16)

向量 (7)

矩阵 (6)

格式化 (3)

应用 (3)

属性和关系 (7)

可能存在的问题 (2)

巧妙范例 (2)

文本

CMS

APA

BibTeX

BibLaTeX

Norm

更多信息和选项

范例

基本范例 (3)

范围 (16)

向量 (7)

矩阵 (6)

格式化 (3)

应用 (3)

属性和关系 (7)

可能存在的问题 (2)

巧妙范例 (2)

参见

技术笔记

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX