WOLFRAM

Wolfram 语言与系统参考资料中心

Polyhedron[{f1,…,fn}]

表示封闭曲面内的一个填充多面体，其多边形面为 fi.

Polyhedron[{f1,…,fn}{{g1,…,gm},…}]

表示有洞 {g1,…,gm},… 的多面体.

Polyhedron[{poly1,poly2,…}]

表示一组多面体 polyi.

Polyhedron[{p1,…,pn},data]

表示一个多面体，其中 data 中用整数 i 给出的坐标被认为是 pi.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
图形  
规范  
样式  
坐标  
区域  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

Polyhedron

Polyhedron[{f1,…,fn}]

表示封闭曲面内的一个填充多面体，其多边形面为 fi.

Polyhedron[{f1,…,fn}{{g1,…,gm},…}]

表示有洞 {g1,…,gm},… 的多面体.

Polyhedron[{poly1,poly2,…}]

表示一组多面体 polyi.

Polyhedron[{p1,…,pn},data]

表示一个多面体，其中 data 中用整数 i 给出的坐标被认为是 pi.

更多信息和选项

  • Polyhedron 可被用作几何区域及图形基元.
  • Polyhedron[{f1,…,fn}] 是一个体积区域，表示具有多边形面 fi 的封闭曲面内的所有点.
  • 如果来自任何方向上的点的直线穿过边界多边形面奇数次，则点是多面体的元素.
  • Polyhedron[{f1,…,fn}{{g1,…,gm},…}] 指定一个有洞的多面体，其中，洞由外多面体 Polyhedron[{f1,…,fn}] 和一个或几个内多面体 Polyhedron[{g1,…,gm}],… 组成.
  • 如果点 p 在外多面体中而不在任何内多面体中，则是多面体的元素.
  • Polyhedron[{poly1,poly2,…}] 是一组有洞或没有洞的多面体 polyi，几何计算时将其视为 polyi 的并集.
  • Polyhedron[{p1,…,pn},data] 实际上将 data 中作为坐标出现的整数 i 替换为相应的 pi.
  • Polyhedron[{p1,…,pn},{f1,…,fn}]具有点 {po1,…,pok} 的多面体边界面 fi
    Polyhedron[{p1,…,pn},{{f1,…,fk}{{g1,…,gl},…}]具有点 {po1,…,pok} 的外多面体边界面 fi，具有点 {pv1,…,pvl} 的内多面体边界面 gj 等.
    Polyhedron[{p1,…,pn},{{b1,…,bn},{f1,…,fk}{{g1,…,gl},…},…}]几个多面体的集合
  • 作为几何区域，多边形面 fi 可以具有任何嵌入维度，但必须都是简单多边形并具有相同的嵌入维度.
  • 在图形中，多边形面 fi 的点可以是 Scaled 和 Dynamic 表达式.
  • 图形渲染受 FaceForm、EdgeForm、Texture、Specularity、Opacity 和颜色等指令的影响.
  • 可在图形中使用以下选项和设置：
  • VertexColorsAutomatic要插值的顶点颜色
    VertexNormalsAutomatic用于着色的有效顶点法线
    VertexTextureCoordinatesNone用于纹理的坐标

范例

打开所有单元 关闭所有单元

基本范例  (1)

一个多面体：

Wolfram Language code: 𝒫 = Polyhedron[{{0., 0., 0.6}, {-0.3, -0.5, -0.2}, {-0.3, 0.5, -0.2}, {0.6, 0., -0.2}}, {{2, 3, 4}, {3, 2, 1}, {4, 1, 2}, {1, 4, 3}}]

多面体图形：

Wolfram Language code: Graphics3D[𝒫]

体积：

Wolfram Language code: Volume[𝒫]

范围  (11)

图形  (8)

规范  (2)

多面体：

Wolfram Language code: Graphics3D[Polyhedron[{{{1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{0, 1, 0}, {1, 0, 0}, {0, 0, 0}}, {{0, 0, 1}, {0, 0, 0}, {1, 0, 0}}, {{0, 0, 0}, {0, 0, 1}, {0, 1, 0}}}]]

有洞的多面体：

Wolfram Language code: Graphics3D[{Opacity[.5], Polyhedron[{{-Sqrt[1 + 2/Sqrt[5]], 0, Root[1 - 20*#1^2 + 80*#1^4 & , 3, 0]}, {Sqrt[1 + 2/Sqrt[5]], 0, Root[1 - 20*#1^2 + 80*#1^4 & , 2, 0]}, {Root[1 - 20*#1^2 + 80*#1^4 & , 1, 0], (-3 - Sqrt[5])/4, Root[1 - 20*#1^2 + 80*#1^4 & , 3, 0]}, {R ... }, {11, 12, 8, 16, 7}, {12, 6, 20, 4, 8}, {6, 2, 13, 18, 20}, {2, 5, 19, 17, 13}, {4, 20, 18, 10, 15}, {18, 13, 17, 9, 10}, {17, 19, 3, 14, 9}, {3, 7, 16, 1, 14}, {16, 8, 4, 15, 1}, {22, 23, 24}, {23, 22, 21}, {24, 21, 22}, {21, 24, 23}}]}]

样式  (5)

颜色指令指定多面体面的颜色：

Wolfram Language code: Table[Graphics3D[{c, Polyhedron[{{0., 1/Sqrt[2], 0.}, {1/Sqrt[2], 0., 0.}, {0., -(1/Sqrt[2]), 0.}, {-(1/Sqrt[2]), 0., 0.}, {0., 0., 1/Sqrt[2]}, {0., 0., -(1/Sqrt[2])}}, {{5, 2, 1}, {5, 3, 2}, {5, 4, 3}, {4, 5, 1}, {2, 6, 1}, {2, 3, 6}, {4, 6, 3}, {1, 6, 4}}]}], {c, {Red, Green, Blue, Yellow}}]

Texture 可用于指定要在多面体的面上使用的纹理：

Wolfram Language code: Graphics3D[{Texture[[image]], Polyhedron[{{{0, 0, 0}, {0, 1, 0}, {1, 1, 0}, {1, 0, 0}}, {{0, 0, 0}, {1, 0, 0}, {1, 0, 1}, {0, 0, 1}}, {{1, 0, 0}, {1, 1, 0}, {1, 1, 1}, {1, 0, 1}}, {{1, 1, 0}, {0, 1, 0}, {0, 1, 1}, {1, 1, 1}}, {{0, 1, 0}, {0, 0, 0}, {0, 0, 1}, {0, 1, 1}}, {{0, 0, 1}, {1, 0, 1}, {1, 1, 1}, {0, 1, 1}}}, VertexTextureCoordinates -> Table[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, {6}]]}]

Texture 可与不同的 Opacity 一起使用：

Wolfram Language code: Table[Graphics3D[{Opacity[o], Texture[ExampleData[{"TestImage", "House"}]], Polyhedron[{{{0, 0, 0}, {0, 1, 0}, {1, 1, 0}, {1, 0, 0}}, {{0, 0, 0}, {1, 0, 0}, {1, 0, 1}, {0, 0, 1}}, {{1, 0, 0}, {1, 1, 0}, {1, 1, 1}, {1, 0, 1}}, {{1, 1, 0}, {0, 1, 0}, {0, 1, 1}, {1, 1, 1}}, {{0, 1, 0}, {0, 0, 0}, {0, 0, 1}, {0, 1, 1}}, {{0, 0, 1}, {1, 0, 1}, {1, 1, 1}, {0, 1, 1}}}, VertexTextureCoordinates -> Table[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, {6}]]}], {o, {0.25, 0.5, 0.75, 1}}]

Texture 可与不同的 Lighting 一起使用：

Wolfram Language code: Table[Graphics3D[{Texture[ExampleData[{"TestImage", "Sailboat"}]], Polyhedron[{{{0, 0, 0}, {0, 1, 0}, {1, 1, 0}, {1, 0, 0}}, {{0, 0, 0}, {1, 0, 0}, {1, 0, 1}, {0, 0, 1}}, {{1, 0, 0}, {1, 1, 0}, {1, 1, 1}, {1, 0, 1}}, {{1, 1, 0}, {0, 1, 0}, {0, 1, 1}, {1, 1, 1}}, {{0, 1, 0}, {0, 0, 0}, {0, 0, 1}, {0, 1, 1}}, {{0, 0, 1}, {1, 0, 1}, {1, 1, 1}, {0, 1, 1}}}, VertexTextureCoordinates -> Table[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, {6}]]}, Lighting -> {{"Directional", c, {4, -4, 4}}}], {c, {Red, Green, Yellow, White}}]

FaceForm 和 EdgeForm 可用于指定边和面的样式：

Wolfram Language code: Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], Polyhedron[{{0., 1/Sqrt[2], 0.}, {1/Sqrt[2], 0., 0.}, {0., -(1/Sqrt[2]), 0.}, {-(1/Sqrt[2]), 0., 0.}, {0., 0., 1/Sqrt[2]}, {0., 0., -(1/Sqrt[2])}}, {{5, 2, 1}, {5, 3, 2}, {5, 4, 3}, {4, 5, 1}, {2, 6, 1}, {2, 3, 6}, {4, 6, 3}, {1, 6, 4}}]}]

可用 VertexColors 指定顶点的颜色：

Wolfram Language code: Graphics3D[Polyhedron[{{0, 0, Sqrt[2 / 3] - 1 / (2 * Sqrt[6])}, {-1 / (2 * Sqrt[3]), -1 / 2, -1 / (2 * Sqrt[6])}, {-1 / (2 * Sqrt[3]), 1 / 2, -1 / (2 * Sqrt[6])}, {1 / Sqrt[3], 0, -1 / (2 * Sqrt[6])}}, {{2, 3, 4}, {3, 2, 1}, {4, 1, 2}, {1, 4, 3}}, VertexColors -> {Red, Green, Yellow, Blue}]]

可用 VertexNormals 指定三维多边形在顶点处的法线：

Wolfram Language code: n = {1, -1, 1};
Wolfram Language code: Graphics3D[{Yellow, Polyhedron[{{0, 0, Sqrt[2 / 3] - 1 / (2 * Sqrt[6])}, {-1 / (2 * Sqrt[3]), -1 / 2, -1 / (2 * Sqrt[6])}, {-1 / (2 * Sqrt[3]), 1 / 2, -1 / (2 * Sqrt[6])}, {1 / Sqrt[3], 0, -1 / (2 * Sqrt[6])}}, {{2, 3, 4}, {3, 2, 1}, {4, 1, 2}, {1, 4, 3}}, VertexNormals -> {-n, n, n, n}]}]

坐标  (1)

使用 Scaled 坐标：

Wolfram Language code: Graphics3D[Polyhedron[{{Scaled[{0.2, 0., 0.3}], Scaled[{0.2, 0.9, 0.3}], Scaled[{1, 0.5, 0.3}]}, {Scaled[{0.2, 0.9, 0.3}], Scaled[{0.2, 0., 0.3}], Scaled[{0.5, 0.5, 1.}]}, {Scaled[{1, 0.5, 0.3}], Scaled[{0.5, 0.5, 1.}], Scaled[{0.2, 0., 0.3}]}, {Scaled[{0.5, 0.5, 1.}], Scaled[{1, 0.5, 0.3}], Scaled[{0.2, 0.9, 0.3}]}}], Axes -> True]

区域  (3)

嵌入维度：

Wolfram Language code: RegionEmbeddingDimension[Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{2, 3, 4}, {3, 2, 1}, {4, 1, 2}, {1, 4, 3}}]]

几何维度：

Wolfram Language code: RegionDimension[Polyhedron[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{2, 3, 4}, {3, 2, 1}, {4, 1, 2}, {1, 4, 3}}]]

体积：

Wolfram Language code: ℛ = Polyhedron[{{0., 0., 0.6123724356957945}, {-0.2886751345948129, -0.5, -0.20412414523193154}, {-0.2886751345948129, 0.5, -0.20412414523193154}, {0.5773502691896258, 0., -0.20412414523193154}}, {{2, 3, 4}, {3, 2, 1}, {4, 1, 2}, {1, 4, 3}}];
Wolfram Language code: Volume[ℛ]

几何中心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.2], ℛ}, {Red, Point[c]}}]

多面体是有界的：

Wolfram Language code: ℛ = Polyhedron[{{-Sqrt[1 + 2/Sqrt[5]], 0, Root[1 - 20*#1^2 + 80*#1^4 & , 3, 0]}, {Sqrt[1 + 2/Sqrt[5]], 0, Root[1 - 20*#1^2 + 80*#1^4 & , 2, 0]}, {Root[1 - 20*#1^2 + 80*#1^4 & , 1, 0], (-3 - Sqrt[5])/4, Root[1 - 20*#1^2 + 80*#1^4 & , 3, 0]}, {R ... {{15, 10, 9, 14, 1}, {2, 6, 12, 11, 5}, {5, 11, 7, 3, 19}, {11, 12, 8, 16, 7}, {12, 6, 20, 4, 8}, {6, 2, 13, 18, 20}, {2, 5, 19, 17, 13}, {4, 20, 18, 10, 15}, {18, 13, 17, 9, 10}, {17, 19, 3, 14, 9}, {3, 7, 16, 1, 14}, {16, 8, 4, 15, 1}}];
Wolfram Language code: BoundedRegionQ[ℛ]

求它的范围：

Wolfram Language code: r = RegionBounds[ℛ]
Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, Boxed -> False]

可能存在的问题  (1)

退化多面体不是有效的几何区域：

Wolfram Language code: Polyhedron[{{0, 0, 0}, {1, 1, 0}, {0, 1, 0}, {0, 0, 1}}, {{2, 3, 4}, {3, 2, 1}}]
Wolfram Language code: RegionQ[%]
Wolfram Research (2019)，Polyhedron，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Polyhedron.html.

文本

Wolfram Research (2019)，Polyhedron，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Polyhedron.html.

CMS

Wolfram 语言. 2019. "Polyhedron." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Polyhedron.html.

APA

Wolfram 语言. (2019). Polyhedron. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Polyhedron.html 年

BibTeX

@misc{reference.wolfram_2026_polyhedron, author="Wolfram Research", title="{Polyhedron}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Polyhedron.html}", note=[Accessed: 13-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_polyhedron, organization={Wolfram Research}, title={Polyhedron}, year={2019}, url={https://reference.wolfram.com/language/ref/Polyhedron.html}, note=[Accessed: 13-November-2026]}