Wolfram 语言与系统参考资料中心

Root

Root[{f,c}]

表示一般方程 f[x]0 在 x=c 附近的精确根.

Root[{{f₁,…,f_n},{c₁,…,c_n}},j]

表示方程组 {f₁[x₁,…,x_n]0,…,f_n[x₁,…,x_n]0} 在 {x₁,…,x_n}={c₁,…,c_n} 附近的精确根的第 j 个坐标.

Root[f,k]

表示多项式方程 f[x]0 的 k 次方根.

Root[{f₁,f₂,…},{k₁,k₂,…}]

表示精确向量 {a₁,a₂,…} 的最后一个坐标，使得 a_i 是多项式方程 f_i[a₁,…,a_i-1,x]0 的 k_i 次方根.

Root

Root[{f,c}]

表示一般方程 f[x]0 在 x=c 附近的精确根.

Root[{{f₁,…,f_n},{c₁,…,c_n}},j]

表示方程组 {f₁[x₁,…,x_n]0,…,f_n[x₁,…,x_n]0} 在 {x₁,…,x_n}={c₁,…,c_n} 附近的精确根的第 j 个坐标.

Root[f,k]

表示多项式方程 f[x]0 的 k 次方根.

Root[{f₁,f₂,…},{k₁,k₂,…}]

表示精确向量 {a₁,a₂,…} 的最后一个坐标，使得 a_i 是多项式方程 f_i[a₁,…,a_i-1,x]0 的 k_i 次方根.

范例

打开所有单元关闭所有单元

基本范例 (4)

五次方程的解：

Wolfram Language code: Solve[x ^ 5 + 2x + 1 == 0, x]

数值：

Wolfram Language code: N[%]

指数-对数方程的实数解：

Wolfram Language code: Reduce[E ^ x - 5x + Log[2 x] + 1 == 0, x, Reals]

方程组的实解：

Wolfram Language code: Solve[x ^ 5 - x == 2 && y ^ 5 - x ^ 2 y == 3, {x, y}, Reals]

超越方程组的解的实例：

Wolfram Language code: FindInstance[Sin[x E ^ y] - x == 1 && Gamma[x - Cos[y]] == Erf[x + y], {x, y}]

范围 (22)

基本用法 (5)

自动生成某些精确值：

Wolfram Language code: Root[# ^ 2 - 3# - 1&, 2]

Wolfram Language code: Root[# ^ 5 - 3#&, 2]

Wolfram Language code: Root[{#1 ^ 2 - 3&, #2 ^ 2 - #1 - 5&}, {1, 2}]

Wolfram Language code: Root[{Sin[#]&, 3.1415926535897932385}]

高精度求解：

Wolfram Language code: N[Root[# ^ 7 - 3# + 1&, 1], 100]

Wolfram Language code: N[Root[{#1 ^ 7 - 3#1 + 1&, #2 ^ 7 - #1 ^ 2#2 - 5&, #3 ^ 7 - #2 ^ 2#3 - #1 + 1&}, {1, 2, 3}], 100]

Wolfram Language code: N[Root[{1 + E ^ #1 + Log[2#1] - 5#1&, 2.071312961691322349521}], 100]

精确比较：

Wolfram Language code: Root[# ^ 6 - 11# + 1&, 1] < Sqrt[2]

将根式转换为 Root 对象：

Wolfram Language code: RootReduce[Sqrt[2] + Sqrt[3]]

将 Root 对象转换为根式：

Wolfram Language code: ToRadicals[%]

禁用 Root 的省略格式：

Wolfram Language code: SetSystemOptions["TypesetOptions" -> {"NumericalApproximationForms" -> False}];

Wolfram Language code: Reduce[x ^ 3 - 2x + 7 == 0, x]

重新启用省略格式：

Wolfram Language code: SetSystemOptions["TypesetOptions" -> {"NumericalApproximationForms" -> True}];

Wolfram Language code: Reduce[x ^ 3 - 2x + 7 == 0, x]

单变量函数的根 (4)

指对数函数的实根：

Wolfram Language code: Reduce[E ^ (2E ^ x) - Log[x ^ 2 + 1] - 20x == 11, x, Reals]

Root 表示涉及一个单变量函数和一个隔离根的近似值：

Wolfram Language code: r = %[[2, 2]]

Wolfram Language code: List@@r

Root 对象是精确的数值表达式：

Wolfram Language code: Log[r] < 1 / 2

Wolfram Language code: N[r, 50]

有界区域内解析函数的根：

Wolfram Language code: Reduce[2Sin[Exp[x]] - Cos[Pi x] == 1 / 3 && Abs[x] < 1, x]

三重根：

Wolfram Language code: Reduce[Cos[3x] - 6x Cos[2x] + (12x ^ 2 + 3)Cos[x] - 4x ^ 3 - 6x == 0 && Abs[x] < 1, x]

Wolfram Language code: List@@%[[2]]

此表示用于次数超过 $MaxRootDegree 的多项式的根：

Wolfram Language code: Reduce[x ^ 1234567 + 5 x + 1 == 0, x, Reals]

Wolfram Language code: r = %[[2]]

Wolfram Language code: List@@r

用于表示根的近似值等于，但根不是：

Wolfram Language code: Block[{$MaxExtraPrecision = Infinity}, N[r + 1 / 5, 20]]

多变量系统的根 (1)

求超越方程组的解的实例：

Wolfram Language code: FindInstance[Exp[x - y] == 2 + Sin[x y] && Tan[x / y] == 5x - y, {x, y}]

根是精确的数值表达式：

Wolfram Language code: r = x /. %[[1]]

Wolfram Language code: N[r, 50]

Root 表示涉及一个多变量系统和一个隔离根的近似：

Wolfram Language code: List@@r

单变量多项式的根 (10)

具有有理系数的单变量多项式的根是代数数：

Wolfram Language code: SolveValues[x ^ 5 - 3x + 7 == 0, x]

Wolfram Language code: Element[%, Algebraics]

多项式自动约化：

Wolfram Language code: r = Root[3# ^ 7 - 3&, 3]

最小多项式总是不可约化且初等的：

Wolfram Language code: First[%]

使用 MinimalPolynomial 提取最小多项式：

Wolfram Language code: MinimalPolynomial[%%, x]

代表代数数的 Root 对象具有三个参数：

Wolfram Language code: r = Root[# ^ 7 - 4# ^ 3 + 9&, 5]

代表代数数的根对象具有三个参数：

Wolfram Language code: List@@r

所用的根隔离方法可能会影响非实根的排序：

Wolfram Language code: Root[# ^ 7 - 4# ^ 3 + 9&, 5, 1]

Wolfram Language code: % ≠ r

1 次和 2 次多项式的根自动化简：

Wolfram Language code: Root[2# + 3&, 1]

Wolfram Language code: Root[7 # ^ 2 + 8 # + 9&, 2]

代数数的代数组合是代数数：

Wolfram Language code: Sqrt[Root[# ^ 3 - 2# - 7&, 1]] + 2Root[# ^ 4 - 5# - 9&, 3] ^ 2

使用 RootReduce 将结果表示为单个 Root 对象：

Wolfram Language code: RootReduce[%]

规范化不是自动完成的，因为最小多项式可以快速增长：

Wolfram Language code: MinimalPolynomial[%, x]

代数数的复数部分：

Wolfram Language code: Re[Root[# ^ 6 - # + 1&, 1]]//RootReduce

Wolfram Language code: Abs[Root[# ^ 6 - # + 1&, 1]]//RootReduce

具有精确数值系数的多项式的 Root 是一个精确数值对象：

Wolfram Language code: Root[# ^ 3 + Pi # + I ^ E&, 1]

Wolfram Language code: Abs[%] < 2

Wolfram Language code: N[%%, 50]

系数涉及符号参数的多项式的根：

Wolfram Language code: SolveValues[x ^ 5 - 2a x + a ^ 2 == 1, x]

绘制实值根：

Wolfram Language code: Plot[%, {a, -5, 5}, WorkingPrecision -> 20]

求关于参数的级数：

Wolfram Language code: Series[First[%%], {a, 0, 10}]

在分支点处求根的 Puiseux 级数：

Wolfram Language code: Series[Root[Function[x, x ^ 3 - x ^ 2 - x + a], 2], {a, 1, 2}]

具有符号系数的二次方的根：

Wolfram Language code: {Root[a # ^ 2 + b # + c&, 1], Root[a # ^ 2 + b # + c&, 2]}

当 a、b、c 和根为实数时，根始终按其值排序：

Wolfram Language code: % /. {{a -> 1, b -> -3, c -> 2}, {a -> -1, b -> 3, c -> -2}}

二次方根的“标准”公式不保证根的顺序：

Wolfram Language code: SolveValues[a x ^ 2 + b x + c == 0, x]

Wolfram Language code: % /. {{a -> 1, b -> -3, c -> 2}, {a -> -1, b -> 3, c -> -2}}

三角多项式系统的根 (2)

三角方程组的实根：

Wolfram Language code: FindInstance[x ^ 5 - x == 2 && y ^ 5 - x ^ 2 y == 3 && z ^ 5 - x ^ 3 y ^ 2 z == 5, {x, y, z}, Reals]

Root 表示涉及三角多项式系统和根索引：

Wolfram Language code: r = z /. %[[1]]

Wolfram Language code: List@@r

Root 对象是一个精确的数值表达式：

Wolfram Language code: r == 163 / 100

Wolfram Language code: N[r, 50]

具有有理系数的多项式系统的根具有代数数坐标：

Wolfram Language code: Element[r, Algebraics]

最小多项式的次数通常是系统多项式的次数的乘积：

Wolfram Language code: MinimalPolynomial[r, x]

此表示用于具有代数数系数的多项式的根：

Wolfram Language code: r = Root[# ^ 5 + Sqrt[2]# + 1&, 1]

Wolfram Language code: List@@r

将根转换为规范的代数数表示：

Wolfram Language code: s = RootReduce[r]

Wolfram Language code: List@@s

选项 (1)

ExactRootIsolation (1)

Root[f,k] 默认使用经过验证的数值方法隔离多项式的复根. 设置 ExactRootIsolationTrue 将使 Root 采用通常慢得多的符号方法.

ExactRootIsolation 的设置受到 Root 对象的第 3 个自变量的影响：

Wolfram Language code:

a = Root[# ^ 40 - 15# ^ 17 - 21# ^ 3 + 11&, 20, ExactRootIsolation -> False];
b = Root[# ^ 40 - 15# ^ 17 - 21# ^ 3 + 11&, 20, ExactRootIsolation -> True];

Wolfram Language code: {a, b}//InputForm

根的首次分离需要数值根：

Wolfram Language code: N[a, 20]//Timing

符号的复数根的分离方法通常较有效一个数值根要慢：

Wolfram Language code: N[b, 20]//Timing

根的分离方法可能会影响非实数根的次序：

Wolfram Language code:

N[{Root[# ^ 20 - 15# ^ 17 - 21# ^ 3 + 11&, 20, ExactRootIsolation -> True], Root[# ^ 20 - 15# ^ 17 - 21# ^ 3 + 11&, 20, ExactRootIsolation -> False]}, 20]

应用 (19)

按照 Root 的封闭形式求解任意次数的多项式方程：

Wolfram Language code: First[Solve[(x + 1) ^ 20 + x - 2 == 0, x]]

求解一个 Hilbert 矩阵的特征方程：

Wolfram Language code: CharacteristicPolynomial[Table[1 / (i + j + 1), {i, 5}, {j, 5}], λ]

Wolfram Language code: Solve[% == 0, λ]//Last

用 Eigenvalues：

Wolfram Language code: Eigenvalues[Table[1 / (i + j + 1), {i, 5}, {j, 5}]]//First

求出参数多项式的最小值：

Wolfram Language code: Minimize[x ^ 4 + 3 x ^ 3 + a x - 1, x]

求出任意次数的常系数微分方程：

Wolfram Language code: DSolve[D[y[t], {t, 5}] + 11 D[y[t], {t, 1}] + y[t] == 0, y[t], t]

求解任意次数的常系数微分方程：

Wolfram Language code: RSolve[y[k + 5] + 11 y[k + 1] + y[k] == 0, y[k], k]

求三角方程组的解：

Wolfram Language code: FindInstance[x ^ 3 - 3x + 1 == 0 && y ^ 3 - x y + 2 == 0 && z ^ 3 - x y z + 3 == 0, {x, y, z}]

以 Root[f,k] 格式表示解：

Wolfram Language code: RootReduce[%]

这里，Root[f,k] 表示法应该包含次数为 1000000 的多项式：

Wolfram Language code: FindInstance[x ^ 100 - 3x + 1 == 0 && y ^ 100 - x y + 2 == 0 && z ^ 100 - x y z + 3 == 0, {x, y, z}]

计算解的近似值：

Wolfram Language code: N[%, 20]

求解一个分段函数：

Wolfram Language code: UnitStep[x ^ 6 + 5x - 1]

Wolfram Language code: PiecewiseExpand[%]

求解单个指数-对数方程和不等式的实数解：

Wolfram Language code: Reduce[E ^ x / x ^ 3 - (x + 1)Log[x] - Log[Log[x]] == 1, x, Reals]

Wolfram Language code: Reduce[x Log[x] - E ^ x > -2, x, Reals]

求解有限区域的初等函数方程：

Wolfram Language code: Reduce[Sin[Cos[x]] - 4x ^ 2 + E ^ x == 1 && -1 < x < 1, x]

Wolfram Language code: Reduce[(x + 1) ^ Sin[x] == Cos[x ^ 2 - Tan[x]] + I / 2 && 0 ≤ Re[x] ≤ 1 && 0 ≤ Im[x] ≤ 1, x]

求解有限区域的解析函数方程：

Wolfram Language code: Reduce[Cos[x] - BesselJ[5, x] == 1 / 2 && 0 ≤ x ≤ 10, x]

Wolfram Language code: Reduce[Gamma[x] - Log[x] == 1 && Abs[x - 2] < 3 / 2, x]

求解高阶稀疏多项式和代数函数的实根：

Wolfram Language code: Reduce[x ^ 1000001 - 5x ^ 2 + 1 == 0, x, Reals]

Wolfram Language code: Reduce[Sqrt[x] - 3 x ^ (1 / 300000) + 5x ^ 2 == 0, x, Reals]

求解单超越优化问题：

Wolfram Language code: Minimize[{E ^ (x E ^ x) + x ^ Log[x], x > 0}, x]

Wolfram Language code: Maximize[{Sin[Cos[x]] - Exp[(x - 1) ^ 2], 0 < x < 2}, x]

带有指数-对数不等条件的分段函数积分：

Wolfram Language code: Integrate[x Boole[E ^ x - x ^ x > 2], {x, 0, Infinity}]

计算六边形熵常数：

Wolfram Language code:

N[Root[-32751691810479015985152 + 97143135277377575190528# ^ 4 - 
	73347491183630103871488 # ^ 6 - 71220809441400405884928 # ^ 8 + 
	107155448150443388043264# ^ 10 - 72405670285649161617408 # ^ 12 + 
    2958015038376958230528# ^ 14 + 7449488310131083100160# ^ 16 + 
	797726698866658379776# ^ 18 + 2505062311720673792#1 ^ 20 + 
	2013290651222784# ^ 22 + 25937424601# ^ 24&, 2] , 20]

求解 Kepler 方程：

Wolfram Language code: Reduce[x - Sin[x] / 2 == 1 && 0 <= x <= 2, x]

计算拉普拉斯限制常数：

Wolfram Language code: Reduce[y E ^ Sqrt[1 + y ^ 2] / (1 + Sqrt[1 + y ^ 2]) == 1, y, Reals]

Wolfram Language code: N[%[[2]], 100]

绘制作为参数函数的一个根：

Wolfram Language code: Plot[Re[Root[# ^ 5 + a # + 1&, 1]], {a, -5, 5}]

求解凸优化问题：

Wolfram Language code: Minimize[{v.{-1, 1}, {{1, 0}, {0, 1}, {-1, -2}}.vUnderscript[, "ExponentialCone"]{0, 0, -2}}, v]

求超越方程和不等式系统的解的实例：

Wolfram Language code: FindInstance[Exp[x + y] + Sin[z] == x z && Log[z ^ 2 - x] == Erf[x - 2y] + 1 && Tan[x ^ y] < z - 2, {x, y, z}, Reals]

属性和关系 (11)

Root 对象代表精确的数：

Wolfram Language code: Root[# ^ 5 - 3# + 4&, 1]

计算任意精度的近似值：

Wolfram Language code: N[%, 50]

Wolfram Language code: SolveValues[Sin[x] - Log[x] / x == 0 && 0 < x < 10, x]

Wolfram Language code: N[Last[%], 50]

使用 MinimalPolynomial 求代数数的最小多项式：

Wolfram Language code: Root[# ^ 5 + # + 1&, 1]

Wolfram Language code: MinimalPolynomial[%, x]

Wolfram Language code: Root[{#1 ^ 3 + 7#1 + 11&, #2 ^ 5 - 3#1 #2 + 5#1 ^ 2 + 1&}, {2, 3}]

Wolfram Language code: MinimalPolynomial[%, x]

使用 ToRadicals 尝试将 Root 对象转换为根式的算术组合：

Wolfram Language code: root = Root[# ^ 3 + # + 11&, 1]

次数不超过 4 的多项式的所有根都可以用根式表示：

Wolfram Language code: ToRadicals[root]

用 RootReduce 规范化代数，包括来自操作：

Wolfram Language code: Root[# ^ 5 + # + 1&, 1] ^ (1 / 3)

Wolfram Language code: RootReduce[%]

Wolfram Language code: Root[# ^ 5 + # + 1&, 1] - Root[# ^ 6 - # + 1&, 1]

Wolfram Language code: RootReduce[%]

从一个三角形系统：

Wolfram Language code: Root[{#1 ^ 3 - 3#1 + 1&, #2 ^ 3 - #1 ^ 2#2 - 5&, #3 ^ 3 - #2 ^ 2#3 - #1 + 1&}, {1, 2, 3}]

Wolfram Language code: RootReduce[%]

在有理数的固定简单扩展中使用 AlgebraicNumber 进行计算：

Wolfram Language code: a = AlgebraicNumber[Root[# ^ 5 - 2# + 7&, 1], {0, 1}]

对 AlgebraicNumber 对象的有理运算生成 AlgebraicNumber 对象：

Wolfram Language code: (5a ^ 3 + 7a + 9) / (15a ^ 4 - 11a + 3)

使用 ToNumberField 把给定的代数数表示为相同简单扩展的元素：

Wolfram Language code: {a, b, c} = {Root[# ^ 3 + 3# - 5&, 1], Root[# ^ 5 + 2# + 7&, 1], Sqrt[5]}

Wolfram Language code: {aa, bb, cc} = ToNumberField[{a, b, c}]

Wolfram Language code: RootReduce[{a, b, c} - {aa, bb, cc}]

在常见的简单扩展或有理数中执行计算：

Wolfram Language code: (aa ^ 2 - bb cc) / (bb ^ 3 - 3aa + cc ^ 2)

RootSum 表示多项式根上函数值的总和：

Wolfram Language code: RootSum[# ^ 5 - 3# + 5&, Sin[#]&]

使用 Normal 使用显式根表示总和：

Wolfram Language code: Normal[%]

对于有理函数，可以在不求根的情况下计算和：

Wolfram Language code: RootSum[# ^ 5 - 3# + 5&, (# ^ 3 - 5# + 12) / (2# ^ 7 - 3# ^ 4 + 6# - 9)&]

化简包含 Root 对象的组合：

Wolfram Language code: Product[Root[2# ^ 5 + 4# + 1&, i], {i, 5}]

Wolfram Language code: FullSimplify[%]

求解 Root 对象中参数的方程：

Wolfram Language code: Solve[Root[# ^ 5 + a # + 2a ^ 2&, 1] == -3, a]

用 ImplicitD 计算方程隐式解的导数：

Wolfram Language code: r = Root[# ^ 5 - x # + 1&, 1]

Wolfram Language code: ImplicitD[r[[1]][y] == 0, y, x]

与直接计算的导数得到的结果比较：

Wolfram Language code: (% /. y -> r) == D[r, x]

计算方程隐式解的级数展开式：

Wolfram Language code: Series[Root[# ^ 5 + a # + 1&, 1], {a, 0, 10}]

Wolfram Language code: % ^ 5 + a % + 1

使用 AsymptoticSolve 求所有根的级数展开式：

Wolfram Language code: AsymptoticSolve[x ^ 5 + a x + 1 == 0, x, {a, 0, 5}]

使用 RootApproximant 生成近似给定数值的 Root 对象：

Wolfram Language code: RootApproximant[Sqrt[2.] + Sqrt[3.]]

Wolfram Language code: RootApproximant[N[Pi, 10]]

可能存在的问题 (5)

在分支点的级数在所有方向上可能不一定有效：

Wolfram Language code: Series[Root[Function[x, x ^ 3 - x ^ 2 - x + a], 2], {a, 1, 2}]

规范化仅对无参数根有效：

Wolfram Language code: RootReduce[Sqrt[Root[# ^ 5 + # + a&, 1] ]]

参数根在复平面上有复杂的分支线：

Wolfram Language code:

ContourPlot[With[{z = x + I y}, Arg[Root[# ^ 5  + (z ^ 2 - 1)# ^ 3 - 1 / z  # ^ 2 + (z - I) ^ 3 - z&, 4] ]], {x, -2, 2}, {y, -2, 2}, Exclusions -> None]

一个非多项式 Root 对象可以代表一组不同的根：

Wolfram Language code: f = Evaluate[Expand[(Sin[#] - 1 - I 10 ^ -100)(Sin[#] - 1 + I 10 ^ -100)]]&;

Wolfram Language code: cluster = Root[{f, N[Pi / 2, 20]}]

带有较高精度的数值计算产生一个近似根：

Wolfram Language code: N[cluster, 100]

对于后续计算，根的选择保持不变：

Wolfram Language code: N[cluster, 200]

对于具有非整数系数的根，可能需要 $MaxExtraPrecision 的较大设置：

Wolfram Language code: Root[Function[x, Evaluate[(Rationalize[Pi, 10 ^ -200] - Pi)x ^ 3 + 2 x - 1]], 1]

Wolfram Language code: Block[{$MaxExtraPrecision = 200}, Root[Function[x, Evaluate[(Rationalize[Pi, 10 ^ -200] - Pi)x ^ 3 + 2 x - 1]], 1]]

巧妙范例 (1)

Pisot 数的一个较高幂是一个近似整数：

Wolfram Language code: FractionalPart[Root[-1 - # + # ^ 3&, 1] ^ 1000]

Wolfram Language code: Block[{$MaxExtraPrecision = Infinity}, N[%, 100]]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Root

更多信息和选项

范例

基本范例 (4)

范围 (22)

基本用法 (5)

单变量函数的根 (4)

多变量系统的根 (1)

单变量多项式的根 (10)

三角多项式系统的根 (2)

选项 (1)

ExactRootIsolation (1)

应用 (19)

属性和关系 (11)

可能存在的问题 (5)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

Root

更多信息和选项

范例

基本范例 (4)

范围 (22)

基本用法 (5)

单变量函数的根 (4)

多变量系统的根 (1)

单变量多项式的根 (10)

三角多项式系统的根 (2)

选项 (1)

ExactRootIsolation (1)

应用 (19)

属性和关系 (11)

可能存在的问题 (5)

巧妙范例 (1)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX