Wolfram 语言与系统参考资料中心

Series

Series[f,{x,x₀,n}]

生成 f 关于点 x=x₀ 的幂级数展开式，最高次数为 (x-x₀)ⁿ，其中 n 是显式整数.

Series[f,xx₀]

生成 f 关于点 x=x₀ 的幂级数展开式的首项.

Series[f,{x,x₀,n_x},{y,y₀,n_y}]

求出连续的先关于 x 然后关于 y 的幂级数展开式.

范例

打开所有单元关闭所有单元

基本范例 (4)

指数函数关于的幂级数：

Wolfram Language code: Series[Exp[x], {x, 0, 10}]

转换为普通表达式：

Wolfram Language code: Normal[%]

任意函数关于的幂级数：

Wolfram Language code: Series[f[x], {x, a, 3}]

Wolfram Language code: Series[Cos[x] / x, {x, 0, 10}]

在级数的一些操作中，仅保留适当项：

Wolfram Language code: 1 / (1 + %) + % ^ 2

求幂级数的首项：

Wolfram Language code: Series[Gamma[Sin[x] - x] ^ 3, x -> 0]

范围 (10)

单元系列 (10)

Series 可以处理分数幂和对数：

Wolfram Language code: Series[Sqrt[Sin[x]], {x, 0, 10}]

Wolfram Language code: Series[x ^ x, {x, 0, 4}]

通常使用符号参数：

Wolfram Language code: Series[(1 + x) ^ n, {x, 0, 4}]

产生负数次幂的 Laurent 级数：

Wolfram Language code: Series[1 / Sin[x] ^ 10, {x, 0, 2}]

按指定的负数幂截取级数：

Wolfram Language code: Series[1 / Sin[x] ^ 10, {x, 0, -5}]

求出特定函数的幂级数：

Wolfram Language code: Series[Gamma[x], {x, 0, 1}]

Wolfram Language code: Series[Zeta[x], {x, 0, 2}]

Wolfram Language code: Series[BesselK[0, x], {x, 0, 2}]

Wolfram Language code: Series[BesselJ[n, x], {x, 0, 4}]

Wolfram Language code: Series[JacobiSN[u, m], {u, 0, 5}]

Wolfram Language code: Series[HermiteH[n, x], {x, 1, 2}]

求出函数在分支点的级数：

Wolfram Language code: Series[ArcSin[x], {x, 1, 1}]

当 x 假设位于分支点的左边，给出一个简单的结果：

Wolfram Language code: Series[ArcSin[x], {x, 1, 1}, Assumptions -> (x < 1)]

分段函数：

Wolfram Language code: Series[Min[x, 1 - x], {x, a, 5}]

在无穷处的幂级数：

Wolfram Language code: Series[Sin[1 / x], {x, Infinity, 10}]

Wolfram Language code: Series[ArcSin[x], {x, Infinity, 5}]

Series 可以给出渐近线级数：

Wolfram Language code: Series[x!, {x, Infinity, 5}]

Wolfram Language code: Series[BesselJ[0, x], {x, Infinity, 5}]

Wolfram Language code: Normal[Series[ProductLog[x], {x, Infinity, 0}]]

方程隐式解的级数展开：

Wolfram Language code: Series[Root[# ^ 5 + a # + 1&, 1], {a, 0, 10}]

不计算的积分的级数展开：

Wolfram Language code: Integrate[Sin[a Sin[x]], {x, 0, a}]

Wolfram Language code: Series[%, {a, 0, 15}]

推广和延伸 (4)

二元幂级数：

Wolfram Language code: Series[Sin[x + y], {x, 0, 3}, {y, 0, 3}]

Series 按元素线性作用于列表：

Wolfram Language code: Series[{Sin[x], Cos[x], Tan[x]}, {x, 0, 5}]

Series 产生 SeriesData 表达式：

Wolfram Language code: InputForm[Series[Sin[x], {x, 0, 5}]]

Series 可以作用于近似数：

Wolfram Language code: Series[Sin[2.5 x], {x, 0, 10}]

选项 (4)

Analytic (1)

缺省下 Series 假设函数是解析的：

Wolfram Language code: Series[f[x]Exp[x], {x, 0, 2}]

Wolfram Language code: Series[f[x] Exp[x], {x, 0, 2}, Analytic -> False]

Assumptions (3)

用 Assumptions 指定应用展开的复平面上的区域：

Wolfram Language code: Series[ArcCos[x], {x, 1, 1}, Assumptions -> (x > 1)]

在没有假设的情况下，会出现一个分段常数因子：

Wolfram Language code: Series[ArcCos[x], {x, 1, 1}]

在 Stokes 区域上获得级数：

Wolfram Language code: Series[AiryAi[x], {x, ComplexInfinity, 0}, Assumptions -> 0 < Arg[x] < Pi / 6]//Simplify

指定参数的假设条件：

Wolfram Language code: Series[AiryAi[a x], {x, Infinity, 0}, Assumptions -> a > 0]

如果没有假设条件，结果会更复杂：

Wolfram Language code: Series[AiryAi[a x], {x, Infinity, 0}]//FullSimplify

应用 (8)

绘制近似于的连续级数：

Wolfram Language code: Plot[Evaluate[Table[Normal[Series[Sin[x], {x, 0, n}]], {n, 20}]], {x, 0, 2Pi}]

求出标准复合问题的级数展开：

Wolfram Language code: Series[(1 + 1 / n) ^ n, {n, Infinity, 5}]

从生成函数中求出 Fibonacci 数：

Wolfram Language code: CoefficientList[Series[1 / (1 - t - t ^ 2), {t, 0, 15}], t]

通过展开生成函数求出 Legendre 多项式：

Wolfram Language code: CoefficientList[Series[1 / Sqrt[1 - 2 t x + t ^ 2], {t, 0, 5}], t]

Wolfram Language code: Table[LegendreP[n, x], {n, 0, 5}]

用 U.S. coins 建立一个生成函数，列举改变的方式：

Wolfram Language code: gf = 1 / Apply[Times, 1 - z ^ {1, 5, 10, 25, 50, 100}]

Wolfram Language code: Series[gf, {z, 0, 10}]

关于 $1 改变方式的数量：

Wolfram Language code: SeriesCoefficient[Series[gf, {z, 0, 100}], 100]

在较长多项式中求出最低项：

Wolfram Language code: Series[(1 + 2x) ^ 1000, {x, 0, 5}]

Wolfram Language code: Normal[%]

用牛顿近似法求出 f[x] 在周围的高次项：

Wolfram Language code: InverseSeries[Series[f[x], {x, a, 3}], x]

Wolfram Language code: Normal[%] /. x -> 0

绘制近似 Exp[x] 的级数的零：

Wolfram Language code: ComplexListPlot[x /. NSolve[Normal[Series[Exp[x], {x, 0, 40}]] == 0, x]]

属性和关系 (10)

Series 通常将项保持到指定次数为止：

Wolfram Language code: Series[(1 + x) ^ 10, {x, 0, 5}]

级数的操作仅对适当的项起作用：

Wolfram Language code: Sqrt[%]

Normal 转换为普通多项式：

Wolfram Language code: Sqrt[Normal[Series[(1 + x) ^ 10, {x, 0, 5}]]]

任何数学函数可以应用到级数中：

Wolfram Language code: Series[Sin[x], {x, 0, 10}]

Wolfram Language code: BesselJ[0, %] ^ %

增加低次项会导致高次项的丢失：

Wolfram Language code: Series[Exp[x], {x, 0, 10}]

Wolfram Language code: % + Series[Sin[x], {x, 0, 5}]

级数的微分：

Wolfram Language code: D[Series[Tan[x], {x, 0, 10}], x]

求解级数系数的方程：

Wolfram Language code: Series[a Sin[x] + b Sin[2 x], {x, 0, 3}] == Series[Sinh[x], {x, 0, 3}]

Wolfram Language code: Solve[%, {a, b}]

求出级数中系数的列表：

Wolfram Language code: Series[Sin[x], {x, 0, 10}]

Wolfram Language code: CoefficientList[%, x]

用 O[x] 强调级数的构建：

Wolfram Language code: Sin[x] + O[x] ^ 10

ComposeSeries 将一个级数作为一个函数，应用到另一个级数中：

Wolfram Language code: ComposeSeries[x + 2x ^ 2 + O[x] ^ 10, Series[Exp[x] - 1, {x, 0, 10}]]

InverseSeries 执行级数的逆操作，求出级数逆函数的级数：

Wolfram Language code: Series[Sin[x], {x, 0, 10}]

Wolfram Language code: InverseSeries[%, x]

Wolfram Language code: Series[ArcSin[x], {x, 0, 10}]

使用 FunctionAnalytic 检验函数是否为解析函数：

Wolfram Language code: f = x Cos[2 ^ Sin[x ^ 2] + 2x];

Wolfram Language code: FunctionAnalytic[f, x]

解析函数可以在其定义域的每个点上表示为泰勒级数：

Wolfram Language code: s = Series[f, {x, 0, 3}]

所得的多项式在 0 附近逼近：

Wolfram Language code: Plot@@{{f, Normal[s]}, {x, -2, 2}}

可能存在的问题 (7)

当存在奇点，Series 将尽可能的因式分解：

Wolfram Language code: Series[Sin[1 / x], {x, 0, 1}]

Wolfram Language code: Series[Sin[1 / x] Sin[x], {x, 0, 10}]

数值量不能直接被级数中展开变量替代：

Wolfram Language code: Series[Exp[x], {x, 0, 10}]

Wolfram Language code: % /. x -> 1

用 Normal 获取可以执行替代的普通表达式：

Wolfram Language code: Normal[Series[Exp[x], {x, 0, 10}]] /. x -> 1

在绘制前，级数必须转换为普通表达式：

Wolfram Language code: Plot[Evaluate[Normal[Series[Sin[x], {x, 0, 10}]]], {x, 0, 2Pi}]

不同展开点的幂级数不能组合：

Wolfram Language code: Series[Exp[x], {x, 1, 3}] + Series[Exp[x], {x, 0, 3}]

不是所有级数可以用有头部 SeriesData 的表达式来表示：

Wolfram Language code: Series[x ^ a Exp[x], {x, 0, 5}]

Wolfram Language code: InputForm[%]

某些函数不能分解成类幂函数的级数：

Wolfram Language code: Series[Zeta[x], {x, Infinity, 10}]

Series 没有改变独立于扩展变量的表达式：

Wolfram Language code: Series[0, {x, 0, 4}]

Wolfram Language code: Series[Sin[y], {x, 0, 4}]

Top

Analytic	True	是否将无法识别的函数视为解析函数
Assumptions	$Assumptions	关于参数的假设
SeriesTermGoal	Automatic	近似式的项数

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Series

更多信息和选项

范例

基本范例 (4)