WOLFRAM

Wolfram 语言与系统参考资料中心

SeriesCoefficient[series,n]

求出由 Series 产生的幂级数中的 n 次项的系数.

SeriesCoefficient[f,{x,x0,n}]

在 f 关于点 处展开式中 的系数.

SeriesCoefficient[f,{x,x0,nx},{y,y0,ny},…]

求出多元级数的系数.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Assumptions  
Method  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

SeriesCoefficient

SeriesCoefficient[series,n]

求出由 Series 产生的幂级数中的 n 次项的系数.

SeriesCoefficient[f,{x,x0,n}]

在 f 关于点 处展开式中 的系数.

SeriesCoefficient[f,{x,x0,nx},{y,y0,ny},…]

求出多元级数的系数.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (4)

求出级数中一个项的系数：

Wolfram Language code: Series[Exp[Sin[x]], {x, 0, 10}]
Wolfram Language code: SeriesCoefficient[%, 8]

在一个级数中，求出一般项的系数：

Wolfram Language code: SeriesCoefficient[Exp[-x], {x, 0, n}]
Wolfram Language code: Table[%, {n, 0, 5}]
Wolfram Language code: Series[Exp[-x], {x, 0, 5}]

在一个多元级数中，求出一项的系数：

Wolfram Language code: Series[Exp[x + y], {x, 0, 3}, {y, 0, 3}]
Wolfram Language code: SeriesCoefficient[%, {3, 3}]

在一个多元级数中，求出一般项的系数：

Wolfram Language code: SeriesCoefficient[Exp[x + y], {x, 0, n}, {y, 0, m}]

范围  (6)

计算级数的系数：

Wolfram Language code: SeriesCoefficient[1 / (x ^ 2 - 3 / 2x + 1), {x, 0, n}]

绘制由此得出的序列：

Wolfram Language code: ListPlot[Table[%, {n, 0, 30}], Filling -> Axis]

有理函数：

Wolfram Language code: SeriesCoefficient[x / (x - 5), {x, 0, n}]
Wolfram Language code: SeriesCoefficient[x ^ 3 / ((-3 + x) (-2 + x) (-1 + x)), {x, 0, n}]

初等函数：

Wolfram Language code: SeriesCoefficient[Exp[x] / (1 - x), {x, 0, n}]
Wolfram Language code: SeriesCoefficient[Cos[Sqrt[x]], {x, 0, n}]
Wolfram Language code: SeriesCoefficient[Log[1 / Sqrt[1 - 5x ^ 2]], {x, 0, n}]

特殊函数：

Wolfram Language code: SeriesCoefficient[PolyLog[-k, x], {x, 0, n}]
Wolfram Language code: SeriesCoefficient[BesselI[3, 2x] / x ^ 7, {x, 0, n}]
Wolfram Language code: SeriesCoefficient[HypergeometricPFQ[{1, 2}, {3, 4, 5}, 6x], {x, 0, n}]

一般情况下，可能需要用 DifferenceRoot 函数来表示答案：

Wolfram Language code: SeriesCoefficient[BesselI[3, (1/2x + 1)], {x, 0, n}, Assumptions -> n ≥ 0]

求出多元函数中的系数：

Wolfram Language code: SeriesCoefficient[Exp[3x + y ^ 2], {x, 0, m}, {y, 0, n}]
Wolfram Language code: SeriesCoefficient[Exp[x + y ^ 2] / (x + 1), {x, 0, m}, {y, 0, n}]
Wolfram Language code: SeriesCoefficient[Sin[x + y ^ 2] / (x + 1), {x, 0, m}, {y, 0, n}]

选项  (3)

Assumptions  (2)

Chebyshev 多项式的扩展系数：

Wolfram Language code: SeriesCoefficient[ChebyshevT[k, x], {x, 0, n}]

使用 Assumptions 得到一个简单结果：

Wolfram Language code: SeriesCoefficient[ChebyshevT[k, x], {x, 0, n}, Assumptions -> k∈ Integers]

没有 Assumptions，产生一般结果：

Wolfram Language code: SeriesCoefficient[Exp[x], {x, 0, n}]

有 Assumptions， 给予在假设下的有效结果：

Wolfram Language code: SeriesCoefficient[Exp[x], {x, 0, n}, Assumptions -> (n ≥ 0)]

Method  (1)

在可能的情况下，产生一个DifferenceRoot 对象：

Wolfram Language code: SeriesCoefficient[Exp[x], {x, 0, n}, Method -> "Holonomic"]

应用  (4)

从生成函数中求出第 11 个Fibonacci 数：

Wolfram Language code: Series[1 / (1 - t - t ^ 2), {t, 0, 10}]
Wolfram Language code: SeriesCoefficient[%, 10]
Wolfram Language code: Fibonacci[11]

从生成函数中求出 Chebyshev 多项式：

Wolfram Language code: Series[1 / (1 - 2 t x + t ^ 2), {t, 0, 4}]
Wolfram Language code: SeriesCoefficient[%, 4]
Wolfram Language code: ChebyshevU[4, x]

求解一个线性差分方程：

Wolfram Language code: GeneratingFunction[y[n + 1] - 5y[n] == 1, n, x]

增加转换的初值方程并求解代数方程：

Wolfram Language code: Solve[% /. y[0] -> 2, GeneratingFunction[y[n], n, x]]

求出 y[n] 的表达式：

Wolfram Language code: SeriesCoefficient[GeneratingFunction[y[n], n, x] /. First[%], {x, 0, n}]

用 RSolve：

Wolfram Language code: RSolve[{y[n + 1] - 5y[n] == 1, y[0] == 2}, y[n], n]

求 1/(1+x) 的幂级数展开式中通项的系数：

Wolfram Language code: s = SeriesCoefficient[1 / (1 + x), {x, 0, n}]

获取 Inactive 形式的幂级数展开：

Wolfram Language code: Inactive[Sum][Refine[s x ^ n, n ≥ 0], {n, 0, Infinity}]

制作不同函数的幂级数展开表格：

Wolfram Language code: flist = {2 / (3 - x), 1 / (x + 10), 3 / (x ^ 2 - x - 2), 1 / (1 + x) ^ 2, 1 / (1 + x) ^ 3, (x ^ 2) / (1 + x) ^ 3, 10 ^ x, (1 - 3 x) ^ (-5), (E ^ x) / x};
Wolfram Language code: Grid[Prepend[{#, Inactive[Sum][Refine[SeriesCoefficient[#1, {x, 0, n}] x ^ n, n ≥ 0], {n, 0, Infinity}]}& /@ flist, {"Function", "Power Series"}], IconizedObject[«Grid options»]]//TraditionalForm

属性和关系  (4)

用 DiscreteAsymptotic 计算渐近近似式：

Wolfram Language code: DiscreteAsymptotic[Inactive[SeriesCoefficient][-(z / (-1 + z + z ^ 2)), {z, 0, n}], n -> ∞]

被截的级数展开的系数：

Wolfram Language code: Table[Coefficient[Series[Log[1 / Sqrt[1 + 5x ^ 2]], {x, 0, 5}], x, n], {n, 0, 4}]

一般系数公式为：

Wolfram Language code: SeriesCoefficient[Log[1 / Sqrt[1 + 5x ^ 2]], {x, 0, n}]

一般公式和截断展开一致：

Wolfram Language code: Table[%, {n, 0, 4}]

CoefficientList 求出级数中的所有系数：

Wolfram Language code: s = Series[1 / (1 - t - t ^ 2), {t, 0, 10}]
Wolfram Language code: Table[SeriesCoefficient[s, i], {i, 0, 10}]
Wolfram Language code: CoefficientList[s, t]

SeriesCoefficient 和 InverseZTransform 密切相关：

Wolfram Language code: SeriesCoefficient[Exp[x ^ 2], {x, 0, n}]
Wolfram Language code: InverseZTransform[Exp[x ^ 2] /. x -> 1 / x, x, n]
Wolfram Language code: Simplify[% - %%, n ≥ 0]

可能存在的问题  (2)

级数系数可以是展开变量的函数：

Wolfram Language code: Series[x ^ x, {x, 0, 5}]
Wolfram Language code: SeriesCoefficient[%, 4]

级数的一般系数可能没有：

Wolfram Language code: SeriesCoefficient[EllipticK[Sin[x ^ 2]], {x, 0, n}]
Wolfram Language code: Series[EllipticK[Sin[x ^ 2]], {x, 0, 12}]
Wolfram Language code: SeriesCoefficient[%, 4]

巧妙范例  (2)

超几何函数的级数系数：

Wolfram Language code: SeriesCoefficient[HypergeometricPFQ[{Subscript[a, 1], Subscript[a, 2]}, {Subscript[b, 1], Subscript[b, 2], Subscript[b, 3]}, x], {x, 0, n}]

创建常见级数系数的集合：

Wolfram Language code: flist = {Exp[x], Sin[x], Cos[x], 1 / (1 + x), Log[1 + x], ArcTan[x]};
Wolfram Language code: Grid[Prepend[{#, SeriesCoefficient[#1, {x, 0, n}]}& /@ flist, {f[x], "Series Coefficient"}], IconizedObject[«Grid options»]]//TraditionalForm
Wolfram Research (1996)，SeriesCoefficient，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SeriesCoefficient.html （更新于 2008 年）.

文本

Wolfram Research (1996)，SeriesCoefficient，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SeriesCoefficient.html （更新于 2008 年）.

CMS

Wolfram 语言. 1996. "SeriesCoefficient." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2008. https://reference.wolfram.com/language/ref/SeriesCoefficient.html.

APA

Wolfram 语言. (1996). SeriesCoefficient. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/SeriesCoefficient.html 年

BibTeX

@misc{reference.wolfram_2026_seriescoefficient, author="Wolfram Research", title="{SeriesCoefficient}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/SeriesCoefficient.html}", note=[Accessed: 29-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_seriescoefficient, organization={Wolfram Research}, title={SeriesCoefficient}, year={2008}, url={https://reference.wolfram.com/language/ref/SeriesCoefficient.html}, note=[Accessed: 29-October-2026]}