WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター
Slider

Slider[x]

x の設定範囲が0から1までのスライダーを表す．

Slider[Dynamic[x]]

設定として x の動的に更新された現在値を取る．x の値はスライダーが動かされるとリセットされる．

Slider[x,{xmin,xmax}]

範囲が xminから xmaxまでのスライダーを表す．

Slider[x,{xmin,xmax,dx}]

刻み幅 dx でジャンプするスライダーを表す．

Slider[x,{{e1,e2,…}}]

等間隔の区間が連続する設定 ei に対応するスライダーを表す．

Slider[x,{{{e1,w1},{e2,w2},…}}]

eiに対して相対的な区間幅 wiを用いる．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Appearance  
AutoAction  
Background  
Show More Show More
BaselinePosition  
ContinuousAction  
Enabled  
Exclusions  
ImageMargins  
ImageSize  
アプリケーション  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連するワークフロー
関連リンク
履歴
引用書式

Slider

Slider[x]

x の設定範囲が0から1までのスライダーを表す．

Slider[Dynamic[x]]

設定として x の動的に更新された現在値を取る．x の値はスライダーが動かされるとリセットされる．

Slider[x,{xmin,xmax}]

範囲が xminから xmaxまでのスライダーを表す．

Slider[x,{xmin,xmax,dx}]

刻み幅 dx でジャンプするスライダーを表す．

Slider[x,{{e1,e2,…}}]

等間隔の区間が連続する設定 ei に対応するスライダーを表す．

Slider[x,{{{e1,w1},{e2,w2},…}}]

eiに対して相対的な区間幅 wiを用いる．

詳細とオプション

  • Slider[…]はインタラクティブに操作できる水平のスライダーをノートブックに表示する．
  • Slider[Dynamic[x]]は，スライダーが動かされると x の値をリセットする．Slider[x]はリセットしない．
  • Slider[n,{nmin,nmax,dn}]は nminと dn が整数のときは整数位置にジャンプする． »
  • Slider[x,{xmin,xmax,dx}]は通常Range[xmin,xmax,dx]が与える位置にジャンプする． »
  • Slider[x]は左から右に進むスライダーを表す．
  • xmax > xminであるSlider[x,{xmax,xmin}]は右から左に進むスライダーを表す． »
  • スライダーの値が与えられた範囲の外側に出るときは，どちらかの端に表示される．
  • Slider[x,{0,1,dx}]はたとえ dx の倍数ではない場合でも，x の位置で表示される．
  • Slider[x,{{e1,e2,…}}]において，eiは数字でなくてもよく，いかなる式でもよい． »
  • 次のオプションを使うことができる．
  • Appearance Automaticスライダーの全体的な外観
    AutoAction Falseマウスが上に置かれたときにスライダーを自動的に動かすかどうか
    BaselinePosition Automatic周囲のテキストと相対的な並べ方
    BaseStyle{}スライダーのベーススタイル指定
    ContinuousAction Trueスライダーが動かされるたびに継続的に更新するかどうか
    Enabled Automaticスライダーを有効にするか，灰色（無効）にするか
    Exclusions {}除外すべき特定の値
    ImageMargins 0表示されたスライダーの画像の周りの余白
    ImageSize Automatic表示されたスライダーの画像全体の大きさ
  • Appearanceの可能な設定値にはTiny，Small，Medium，Large等，および通常"UpArrow"，"DownArrow"等の他の設定が含まれる．
  • Appearance->"Labeled"はスライダーの現行値を編集可能なラベルとして表示する．
  • BaseStyleの設定値は，一般に現行スタイルシートの"Slider"スタイルで与えられるデフォルトスタイルに加えられる．
  • Slider[]はSlider[0.5]に等しい．
  • 結果として表示されるスライダーはキー（Macintoshではキー）を押しながらマウスをドラッグすることで微調整できる．こうするとスライダーはマウス速度の1/20の割合で移動する．キーおよび／またはキーを同時に押しながらマウスをドラッグするとスライダーがさらに細かく操作できる．

例題

すべて開く すべて閉じる

例  (3)

デフォルト範囲がからまででに設定されたスライダー：

Wolfram Language code: Slider[0.8]

その値が動的に更新されるスライダー：

Wolfram Language code: {Slider[Dynamic[x]], Dynamic[x]}

値がからまでの整数値のスライダー：

Wolfram Language code: {Slider[Dynamic[n], {0, 100, 1}], Dynamic[n]}

スコープ  (5)

左から右に動くときに増加するからまでの範囲を使う：

Wolfram Language code: x = 0;{Slider[Dynamic[x], {-1, 1}], Dynamic[x]}

範囲がからまでで右から左に動くときに増加するスライダー：

Wolfram Language code: y = 0;{Slider[Dynamic[y], {1, -1}], Dynamic[y]}

整数の変数値のみを使う：

Wolfram Language code: {Slider[Dynamic[n], {0, 100, 1}], Dynamic[n]}

有理数のステップを使う：

Wolfram Language code: {Slider[Dynamic[x], {0, 1, 1 / 5}], Dynamic[x]}

π をスライダーの増分とする：

Wolfram Language code: {Slider[Dynamic[y], {0, 10Pi, Pi}], Dynamic[y]}

記号的範囲を使う：

Wolfram Language code: {Slider[Dynamic[z], {a, 20a, 2a}], Dynamic[z]}

可能な値のリストを使う：

Wolfram Language code: {Slider[Dynamic[x], {{a, 2, True}}], Dynamic[x]}

それぞれの可能な値に対応する相対幅を変更する：

Wolfram Language code: {Slider[Dynamic[x], {{{a, 10}, {2, 5}, {True, 20}}}], Dynamic[x]}

オプション  (20)

Appearance  (4)

異なるサイズ：

Wolfram Language code: Table[Slider[0.5, Appearance -> a], {a, {Tiny, Small, Medium, Large}}]

ラベルを加える：

Wolfram Language code: Slider[0.5, Appearance -> "Labeled"]

プラットフォームの中には，特別の矢印の外観が使用可能なものがある：

Wolfram Language code: Table[Slider[Appearance -> a], {a, {"UpArrow", "DownArrow"}}]

Round[x]が かかに基づく動的な外観を使う：

Wolfram Language code: {Slider[Dynamic[x], Appearance -> Dynamic[If[Round[x] == 1, "UpArrow", "DownArrow"]]], Dynamic[Round[x]]}

AutoAction  (2)

デフォルトで，スライダーエリア内でクリックされない限り，スライダーの値は変化しない：

Wolfram Language code: {Slider[Dynamic[x]], Dynamic[x]}

AutoActionに設定すると，マウスがスライダーエリアの上を通るとスライダーの値が変化するようになる：

Wolfram Language code: {Slider[Dynamic[x], AutoAction -> True], Dynamic[x]}

Background  (2)

背景色を変更する：

Wolfram Language code: Table[Slider[0.5, Background -> c], {c, {Pink, Green, Gray, Yellow}}]

背景色を動的に変更する：

Wolfram Language code: Slider[Dynamic[x], Background -> Dynamic[Hue[x]]]

BaselinePosition  (2)

周囲のテキストに揃える：

Wolfram Language code: Row[Table[Slider[0.5, ImageSize -> 100, BaselinePosition -> p], {p, {Top, Center, Bottom}}], "xxx"]

ベースラインの位置を動的に変更する：

Wolfram Language code: {"x", Slider[Dynamic[x], {{Top, Center, Bottom}}, BaselinePosition -> Dynamic[x]], "x"}//Row

ContinuousAction  (2)

デフォルトで，変数は継続的に更新される：

Wolfram Language code: {Slider[Dynamic[x]], Dynamic[x]}

ContinuousActionをFalseにすると，スライダーが解放されたときにのみ変数が更新されるようになる：

Wolfram Language code: {Slider[Dynamic[y], ContinuousAction -> False], Dynamic[y]}

Enabled  (2)

デフォルトでSliderは有効になっている：

Wolfram Language code: Slider[0.5]

Enabled->Falseとすると，スライダーは無効だが現行状態で可視となる：

Wolfram Language code: Slider[0.3, Enabled -> False]

Exclusions  (1)

範囲から値を除く：

Wolfram Language code: {Slider[Dynamic[x], {0, 1, 0.2}, Exclusions -> {0.4, 0.8}], Dynamic[x]}

ImageMargins  (1)

ImageMarginsの設定で，スライダーエリアが大きくできる：

Wolfram Language code: Table[Slider[0.5, ImageMargins -> m, Background -> Pink], {m, {0, 5, 10, 20}}]

ImageSize  (4)

設定済の値を用いる：

Wolfram Language code: Column[Table[Slider[0.5, ImageSize -> i], {i, {Tiny, Small, Medium, Large}}]]

あるいは任意の値を用いる：

Wolfram Language code: Column[Table[Slider[0.5, ImageSize -> i], {i, {50, 150, 300, 500}}]]

第2要素を設定することで，スライダーに用意された高さも制御できる：

Wolfram Language code: Slider[0.5, ImageSize -> {Automatic, 50}]

完全にカスタマイズ可能な画像サイズ：

Wolfram Language code: Slider[ImageSize -> {400, 50}]

アプリケーション  (2)

n 番目の素数を選択する：

Wolfram Language code: DynamicModule[{n = 1000}, {Slider[Dynamic[n], {1, 10^5, 1}], Subscript[p, Dynamic[n]]⟶Dynamic[Prime[n]]}]

π を小数に展開した n 番目の桁を選択する：

Wolfram Language code: DynamicModule[{n = 10000}, {Slider[Dynamic[n], {1, 10^5, 1}], Subscript[π, Dynamic[n]]⟶Dynamic[First@First@RealDigits[Pi, 10, 1, -n]]}]

色の選択装置：

Wolfram Language code: DynamicModule[{red = 0, green = 0, blue = 0}, Column[{Grid[{ {Graphics[{Red, Rectangle[]}, ImageSize -> 30], Slider[Dynamic[red]]}, {Graphics[{Green, Rectangle[]}, ImageSize -> 30], Slider[Dynamic[green]]}, {Graphics[{Blue, Rectangle[]}, ImageSize -> 30], Slider[Dynamic[blue]]}}], Dynamic[Graphics[{RGBColor[Dynamic[red], Dynamic[green], Dynamic[blue]], Disk[]}]]}]]

考えられる問題  (1)

オペレーティングシステムが提供する外観は，他のプラットフォームでは異なることや，利用できないことがある：

Wolfram Language code: Slider[0.5, Appearance -> "UpArrow"]

一般的な外観は，すべてのプラットフォームで利用できる：

Wolfram Language code: Style[Slider[0.5, Appearance -> "UpArrow"], ControlsRendering -> "Generic"]

おもしろい例題  (1)

ランダムなサイズのスライダー：

Wolfram Language code: DynamicModule[{x = RandomReal[]}, Column[Table[Slider[Dynamic[x], ImageSize -> RandomReal[200]], {10}]]]
Wolfram Research (2007), Slider, Wolfram言語関数， https://reference.wolfram.com/language/ref/Slider.html （2008年に更新）.

テキスト

Wolfram Research (2007), Slider, Wolfram言語関数， https://reference.wolfram.com/language/ref/Slider.html （2008年に更新）.

CMS

Wolfram Language. 2007. "Slider." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2008. https://reference.wolfram.com/language/ref/Slider.html.

APA

Wolfram Language. (2007). Slider. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Slider.html

BibTeX

@misc{reference.wolfram_2026_slider, author="Wolfram Research", title="{Slider}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Slider.html}", note=[Accessed: 01-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_slider, organization={Wolfram Research}, title={Slider}, year={2008}, url={https://reference.wolfram.com/language/ref/Slider.html}, note=[Accessed: 01-November-2026]}