WOLFRAM

Wolfram 语言与系统参考资料中心

Total[list]

给出 list 中元素的和.

Total[list,n]

计算 n 层的和.

Total[list,{n}]

计算第 n 层的和.

Total[list,{n1,n2}]

计算第 n1 层至第 n2 层的元素和.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Method  
AllowedHeads  
应用  
属性和关系  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Total

Total[list]

给出 list 中元素的和.

Total[list,n]

计算 n 层的和.

Total[list,{n}]

计算第 n 层的和.

Total[list,{n1,n2}]

计算第 n1 层至第 n2 层的元素和.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (1)

列表中元素的和：

Wolfram Language code: Total[{a, b, c, d}]

范围  (6)

用精确算术求和（不展开圆周率等符号数值）：

Wolfram Language code: list = {Pi, 1, 4, E, 7, 8};
Wolfram Language code: Total[list]

使用机器精度：

Wolfram Language code: Total[N[list]]

用 47 位有效数字的结果：

Wolfram Language code: Total[N[list, 47]]

计算矩阵的每一列：

Wolfram Language code: m = (⁠| | | | | :- | :- | :- | | 1 | 2 | 3 | | 4 | 5 | 6 | | 7 | 8 | 9 |⁠);
Wolfram Language code: Total[m]

计算矩阵的每一行：

Wolfram Language code: Total[m, {2}]

计算矩阵所有元素：

Wolfram Language code: Total[m, 2]

在第一维计算包括加入部分在内的和：

Wolfram Language code: t = Array[Subscript[a, ##]&, {2, 3, 4}]
Wolfram Language code: Total[t]

仅计算最后一维的和：

Wolfram Language code: Total[t, {-1}]

计算最后两维的和：

Wolfram Language code: Total[t, {-2, -1}]

全部相加，除了最后一维：

Wolfram Language code: Total[t, -2]

计算所有元素的和：

Wolfram Language code: Total[t, Infinity]

计算不齐数组的最后一维：

Wolfram Language code: a = {{1, 2, 3}, {4, 5}, {6}};
Wolfram Language code: Total[a, {-1}]

计算所有元素的和：

Wolfram Language code: Total[a, Infinity]

列表中元素长度不一，因此无法计算第一维的和：

Wolfram Language code: Total[a]

计算稀疏矩阵的每一列：

Wolfram Language code: s = SparseArray[{{i_, i_} -> -2, {i_, j_} /; Abs[i - j] == 1 -> 1}, {10, 10}]
Wolfram Language code: Total[s]
Wolfram Language code: Total[Normal[s]]

计算每一行：

Wolfram Language code: Total[s, {2}]

计算几个稀疏向量：

Wolfram Language code: list = Table[SparseArray[{2 ^ i} -> 1, {100}], {i, 6}]
Wolfram Language code: Total[list]

计算全部向量的和：

Wolfram Language code: Total[list, Infinity]

选项  (2)

Method  (1)

用 Method->"CompensatedSummation" 降低求和中的累积误差：

Wolfram Language code: x = ConstantArray[.1, 10 ^ 6];
Wolfram Language code: Total[x, Method -> "CompensatedSummation"] - 10 ^ 5

若非如此，累积误差将无法消除：

Wolfram Language code: Total[x] - 10 ^ 5

AllowedHeads  (1)

Total[expr,AllowedHeads->Inherited] 适用于任何标头：

Wolfram Language code: Total[f[1, 2, 1], AllowedHeads -> Inherited]

计算导数级的和：

Wolfram Language code: Total[Derivative[1, 2, 1], AllowedHeads -> Inherited]

应用  (3)

由单项式生成多项式：

Wolfram Language code: Total[{x ^ 2, 3x ^ 3, 1}]

下面显示矩阵的迹等于其特征值的和：

Wolfram Language code: m = RandomReal[1, {10, 10}];
Wolfram Language code: Tr[m]
Wolfram Language code: Total[Eigenvalues[m]]

寻找本身等于其约数和的"完美"数： [更多信息]：

Wolfram Language code: perfectQ[x_Integer] := (Total[Divisors[x]] == 2x)
Wolfram Language code: Last[Reap[Do[If[perfectQ[x], Sow[x]], {x, 1, 10000}]]]

属性和关系  (2)

Total[list] 等价于 Apply[Plus,list]：

Wolfram Language code: list = RandomInteger[9, {10}]
Wolfram Language code: Total[list]
Wolfram Language code: Apply[Plus, list]

Total[list,k] 等价于 Total[Flatten[list,k-1]]：

Wolfram Language code: t = Array[Subscript[a, ##]&, {2, 3, 4, 2}]
Wolfram Language code: Table[Total[t, k] === Total[Flatten[t, k - 1]], {k, 1, ArrayDepth[t]}]
Wolfram Research (2003)，Total，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Total.html （更新于 2019 年）.

文本

Wolfram Research (2003)，Total，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Total.html （更新于 2019 年）.

CMS

Wolfram 语言. 2003. "Total." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2019. https://reference.wolfram.com/language/ref/Total.html.

APA

Wolfram 语言. (2003). Total. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Total.html 年

BibTeX

@misc{reference.wolfram_2026_total, author="Wolfram Research", title="{Total}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Total.html}", note=[Accessed: 11-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_total, organization={Wolfram Research}, title={Total}, year={2019}, url={https://reference.wolfram.com/language/ref/Total.html}, note=[Accessed: 11-November-2026]}