WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

WikipediaData[article]

指定されたウィキペディアページのテキストを与える．

WikipediaData[{article1,article2,...}]

各記事のテキストを与える．

WikipediaData[article,property,options]

指定されたウィキペディアの記事についての指定された特性の値を，選択的なパラメータで修正して与える．

WikipediaData["Category"category,property,options]

指定されたウィキペディアのカテゴリについての指定された特性の値を，選択的なパラメータで修正して与える．

WikipediaData["PageID"pageid,property,options]

指定されたウィキペディアページの数値IDについての指定された特性の値を，選択的なパラメータで修正して与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Languages  
Metrics  
おもしろい例題  
関連項目
関連するガイド
関連するワークフロー
関連リンク
履歴
引用書式

WikipediaData

WikipediaData[article]

指定されたウィキペディアページのテキストを与える．

WikipediaData[{article1,article2,...}]

各記事のテキストを与える．

WikipediaData[article,property,options]

指定されたウィキペディアの記事についての指定された特性の値を，選択的なパラメータで修正して与える．

WikipediaData["Category"category,property,options]

指定されたウィキペディアのカテゴリについての指定された特性の値を，選択的なパラメータで修正して与える．

WikipediaData["PageID"pageid,property,options]

指定されたウィキペディアページの数値IDについての指定された特性の値を，選択的なパラメータで修正して与える．

詳細とオプション

  • WikipediaDataは，MediaWikiのAPIを使って，記事，カテゴリコンテンツ，メタデータをウィキペディアから取り出す．
  • 記事は，文字列またはWolfram言語実体として指定できる．文字列"RandomArticle"はウィキペディアの記事をランダムに選択する．
  • 記事のコンテンツとメタデータに関する特性
  • "ArticlePlaintext"記事のコンテンツのテキスト版
    "ArticleWikicode"Wikiコードによる記事のコンテンツ
    "ArticleContributors"記事の寄稿者のリスト
    "PageID"ウィキペディアのページID番号
    "SummaryPlaintext"テキストによる記事の概略
    "SummaryWikicode"Wikiコードによる記事の概略
    "Title"記事の見出し
  • リンクされた記事およびWebサイトに関する特性
  • "LinksList"指定された記事で参照されたウィキペディアの記事のリスト
    "LinksRules"指定された記事から飛んでいるリンクを表す規則のリスト
    "BacklinksList"特定の記事を参照しているウィキペディアの記事のリスト
    "BacklinksRules"指定された記事に飛んでいるリンクを表す規則のリスト
    "SeeAlsoList"指定の記事の関連項目セクションで参照されているウィキペディアページのリスト
    "SeeAlsoRules"指定された記事の関連項目セクションで参照されているウィキペディアページの規則のリスト
    "ExternalLinks"指定の記事で参照されている外部URLのリスト
  • カテゴリについての特性
  • "CategoryLinks"指定されたカテゴリとそのサブカテゴリ間のリンクを表す規則のリスト
    "CategoryMembers"指定されたカテゴリに含まれる，サブカテゴリと記事の見出しのリスト
    "CategoryMemberIDs"指定されたカテゴリに含まれる，サブカテゴリと記事のページIDのリスト
    "CategoryArticles"指定されたカテゴリに含まれる記事の見出しのリスト
    "CategoryArticleIDs"指定されたカテゴリに含まれる記事のページIDのリスト
    "ParentCategories"指定されたページが含まれるカテゴリのリスト
  • 他言語版のウィキペディアの，対応するページに関する特性
  • "LanguagesList"対応する生地がある他言語版ウィキペディアのリスト
    "LanguagesURLs"他言語版ウィキペディアの対応記事のURLのリスト
    "LanguagesURLRules"他言語版ウィキペディアの対応記事についての言語-URL規則のリスト
    "TitleTranslation"他言語版ウィキペディアの対応記事についての言語-見出し規則ペアのリスト
    "TitleTranslationRules"他言語版ウィキペディアの対応記事についての言語-見出し規則のリスト
  • 指定されたページと関連するGeoLocation情報を返す特性
  • "GeoPosition"そのページと関連する主GeoPosition
    "GeoNearbyArticles"主GeoPositionがページの指定半径内にある記事の見出しのリスト
    "GeoNearbyDataset"主GeoPositionがページの指定半径内にある記事の情報のデータ集合
  • 画像と画像のメタデータを返す特性
  • "ImageList"指定されたページからのサムネイル画像のリスト
    "ImageDataset"指定されたページからの画像の情報のデータ集合
  • ほとんどのWikipediaDataは，MaxItemsオプションをサポートする．
  • MaxItems500返す結果の数
  • 記事のリンクを返す特性は，次の特性をサポートする．
  • "MaxLevel"1指定されたページから外側に検索するレベル数
    "MaxLevelItems"500各レベルで追跡するリンク数
  • "GeoNearby"特性も次のオプションをサポートするが，これらのオプションは同時に使うことはできない．
  • GeoDistance指定点の周囲の検索半径（最小10メートル，最大1万メートル）．Quantityオブジェクトも使用可
    GeoDisk None半径とGeoDiskからのGeoPositionの情報を使用し，その周辺を検索する（最小10メートル，最大1万メートル）
  • ほとんどのWikipediaData特性がLanguageオプションをサポートする．
  • Language"English"使用するウィキペディアのバージョン（文字列または"Language"実体）
  • Language指定は，以下が考えられる．
  • Languagelanglang で表されるバージョンのウィキペディアから，指定された記事（複数化）を取り出す
    Language{lang1lang2}lang1のウィキペディアで記事が指定された場合に，lang2のウィキペディアから対応する記事を取り出す
  • メトリックデータを返す特性には以下がある．
  • {"DailyPageHits",propval}1日ごとのページ閲覧数の時系列
    {"MonthlyPageHits",propval}1ヶ月ごとのページ閲覧数の時系列
  • 行列データを返す特性は，次の修飾子をサポートする．
  • "Access" 指定されたページへのアクセスに使われるクライアントまたはプラットフォーム
    "Project"指定されたページをホストするWikimediaプロジェクト
    "Agent"指定されたページにアクセスしているエージェントタイプ
  • "Access"修飾子の可能な値には以下がある．
  • "AllAccess"全プラットフォームからのページビュー
    "Desktop"デスクトップクライアントからのページビュー
    "MobileApp"モバイルアプリからのページビュー
    "MobileWeb"モバイルのウェブクライアントからのページビュー
  • "Agent"修飾子の可能な値には以下がある．
  • "AllAgents"全ユーザエージェントからのページビュー
    "User"定期的なユーザからのページビュー
    "Spider"スパイダーからのページビュー
    "Bot"ボットからのページビュー
  • "Project"修飾子の値は，commons.wikimedia.orgのような，特定のWikimediaプロジェクトのベースURLでなければならない．

例題

すべて開く すべて閉じる

例  (4)

ウィキペディアの記事のテキストを得る：

Wolfram Language code: TextSentences[WikipediaData["Moon"]][[ ;; 5]]

複数のウィキペディアの記事からテキストを取り出す：

Wolfram Language code: TextSentences[WikipediaData[{"Mercury (planet)", "Venus", "Earth", "Mars"}]][[All, ;; 1]]

Wolfram言語実体に関連した記事を取り出す：

Wolfram Language code: TextSentences[WikipediaData[Entity["Person", "NeilArmstrong::368kz"]]][[ ;; 2]]

ウィキペディアのページIDで記事を取り出す：

Wolfram Language code: TextSentences[WikipediaData["PageID" -> "5094570", "ArticlePlaintext"]][[1]]

Wolfram言語の実体からウィキペディアの記事の見出しを得る：

Wolfram Language code: WikipediaData[{Entity["Person", "BarackObama::7yj6w"], Entity["Person", "JenniferLawrence::k8f6z"]}, "Title"]

ウィキペディアの記事のページIDを取得する：

Wolfram Language code: WikipediaData[Entity["Person", "BarackObama::7yj6w"], "PageID"]

記事についての生のWikiコードマークアップを取り出す：

Wolfram Language code: code = WikipediaData["Apollo 11", "ArticleWikicode"];
Wolfram Language code: StringSplit[code, " "][[ ;; 10]]

指定の記事にリンクしている，あるいはその記事からリンクされている，ウィキペディアの記事のリストを得る：

Wolfram Language code: WikipediaData["Bill Gates", "LinksList"]//Shallow
Wolfram Language code: WikipediaData["Bill Gates", "BacklinksList"]//Shallow

スコープ  (5)

対応する記事を含むウィキペディア言語版のリストを得る：

Wolfram Language code: WikipediaData["Dracula", "LanguagesList"]

ウィキペディアの他言語版の対応する記事のURLを得る：

Wolfram Language code: WikipediaData["Dracula", "LanguagesURLRules"][[ ;; 5]]

他言語のウィキペディアでの記事の見出しを得る：

Wolfram Language code: WikipediaData["Dracula", "TitleTranslationRules"]

指定されたウィキペディアのカテゴリ内の記事のリストを得る：

Wolfram Language code: WikipediaData["Category" -> "sports cars"]//Shallow

指定されたカテゴリ内の，記事，サブカテゴリ，その他のページのリストを得る：

Wolfram Language code: WikipediaData["Category" -> "Chemistry", "CategoryMembers"]//Shallow

カテゴリ間のリンクを表す規則のリストを得る：

Wolfram Language code: links = WikipediaData["Category" -> "Physics", "CategoryLinks", "MaxLevelItems" -> 10, "MaxLevel" -> 2];
Wolfram Language code: Graph[links, VertexLabels -> Placed["Name", Tooltip], VertexStyle -> {"Physics" -> Red}]

指定されたページがどのカテゴリに属するかを求める：

Wolfram Language code: WikipediaData["Koala", "ParentCategories"]//Shallow

オプション  (6)

Languages  (3)

スペイン語のウィキペディアから記事を取り出す：

Wolfram Language code: WikipediaData["Día de la Independencia de los Estados Unidos", "SummaryPlaintext", Language -> Entity["Language", "Spanish"]]

指定された英語のウィキペディアの記事に対応する記事をスペイン語のウィキペディアから記事を取り出す：

Wolfram Language code: WikipediaData["Independence Day (United States)", "SummaryPlaintext", Language -> {Entity["Language", "English"] -> Entity["Language", "Spanish"]}]

英語のウィキペディアの記事が与えられた場合に，座標がその記事の主座標に最も近いスペイン語の記事を取り出す：

Wolfram Language code: WikipediaData["White House", "GeoNearbyDataset", Language -> {Entity["Language", "English"] -> Entity["Language", "Spanish"]}]

Metrics  (3)

2つのウィキペディアの記事の1日ごとのヒット数を比較する：

Wolfram Language code: data = WikipediaData[{"James McAvoy", "Patrick Stewart"}, "DailyPageHits"]; DateListPlot[data, PlotRange -> All, PlotLegends -> {"McAvoy", "Stewart"}, ImageSize -> 400]

指定された記事の，WebアプリとモバイルWebブラウザからのページヒット数を比較する：

Wolfram Language code: dpagehitsWeb = WikipediaData["White House", {"DailyPageHits", "Access" -> "MobileWeb"}]; dpagehitsApp = WikipediaData["White House", {"DailyPageHits", "Access" -> "MobileApp"}];
Wolfram Language code: DateListPlot[{dpagehitsWeb, dpagehitsApp}, PlotRange -> All, PlotLegends -> {"Mobile web", "Mobile app"}, ImageSize -> 400]

ウィキペディアの記事の英語とスペイン語のバージョンのトラフィックを比較する：

Wolfram Language code: articleEn = WikipediaData["Luis Fonsi", "DailyPageHits"]; articleEs = WikipediaData["Luis Fonsi", "DailyPageHits", Language -> "Spanish"];
Wolfram Language code: DateListPlot[{articleEn, articleEs}, PlotRange -> All, PlotLegends -> {"English", "Spanish"}, ImageSize -> 400]

おもしろい例題  (3)

ページ間のリンクを表す規則のリストを得る：

Wolfram Language code: links = WikipediaData["Graph theory", "BacklinksRules", "MaxLevelItems" -> 20, "MaxLevel" -> 2];
Wolfram Language code: Graph[links, VertexLabels -> Placed["Name", Tooltip], VertexStyle -> {"Graph theory" -> Red}]

ウィキペディアのページのサムネイル画像のリストを得る：

Wolfram Language code: WikipediaData["Mare Tranquillitatis", "ImageList"]
Wolfram Language code: WikipediaData["Mare Tranquillitatis", "ImageDataset"][[All, {"Thumbnail", "User", "Date"}]]

あるページに関連する主GeoPositionを得る：

Wolfram Language code: WikipediaData[{"Mount Everest", "Mare Tranquillitatis", "Olympus Mons"}, "GeoPosition"]

主座標が指定されたページに近い記事のDatasetを得る：

Wolfram Language code: WikipediaData["Eiffel Tower", "GeoNearbyDataset", MaxItems -> 10]

主座標がGeoDisk内にあるウィキペディアの記事を求める：

Wolfram Language code: WikipediaData["GeoNearbyArticles", {GeoDisk -> GeoDisk[{40.0971, -88.2457}, Quantity[1000, "Meters"]]}]
Wolfram Research (2015), WikipediaData, Wolfram言語関数， https://reference.wolfram.com/language/ref/WikipediaData.html （2018年に更新）.

テキスト

Wolfram Research (2015), WikipediaData, Wolfram言語関数， https://reference.wolfram.com/language/ref/WikipediaData.html （2018年に更新）.

CMS

Wolfram Language. 2015. "WikipediaData." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2018. https://reference.wolfram.com/language/ref/WikipediaData.html.

APA

Wolfram Language. (2015). WikipediaData. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/WikipediaData.html

BibTeX

@misc{reference.wolfram_2026_wikipediadata, author="Wolfram Research", title="{WikipediaData}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/WikipediaData.html}", note=[Accessed: 16-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_wikipediadata, organization={Wolfram Research}, title={WikipediaData}, year={2018}, url={https://reference.wolfram.com/language/ref/WikipediaData.html}, note=[Accessed: 16-June-2026]}