WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

アップグレード情報

WaveletExplorer

バージョン8で，Wavelet Explorerアドオンの機能はWolframシステムに統合された．

ウェーブレットフィルタ

次はWavelet Explorerで利用できるフィルタ，およびバージョン8における同等の形式のリストである．

HaarFilter[]WaveletFilterCoefficients[HaarWavelet[]]
DaubechiesFilter[n]WaveletFilterCoefficients[DaubechiesWavelet[n]]
LeastAsymmetricFilter[n]WaveletFilterCoefficients[SymletWavelet[n]]
CoifletFilter[n]WaveletFilterCoefficients[CoifletWavelet[n]]
ShannonFilter[lim]WaveletFilterCoefficients[ShannonWavelet[lim]]
MeyerFilter[n,lim]WaveletFilterCoefficients[MeyerWavelet[n,lim]]
SplineFilter[n,lim]WaveletFilterCoefficients[BattleLemarieWavelet[n,lim]]
BiorthogonalSplineFilter[n,m]WaveletFilterCoefficients[BiorthogonalSplineWavelet[n,m]]
HighpassFilter[h]WaveletFilterCoefficients[wave,"PrimalHighpass"]
同等の組込み関数

ウェーブレット係数を計算するためには，組込み関数WaveletFilterCoefficientsを使う．

Wavelet Explorer Needs["Wavelets`Wavelets`"] DaubechiesFilter[2]
Wolfram Language code: WaveletFilterCoefficients[DaubechiesWavelet[2]]

すべてのウェーブレット係数は，Wavelet Explorerからの結果と相対的にでスケールされる．したがって，同等の値を得るためには，結果を倍しなければならない．

Wolfram Language code: {#[[1]], Sqrt[2]#[[2]]}& /@ WaveletFilterCoefficients[DaubechiesWavelet[2]]

ハイパスフィルタ係数を計算するためには，WaveletFilterCoefficientsに引数"PrimalHighpass"を使う．

Wavelet Explorer Needs["Wavelets`Wavelets`"] HighpassFilter[DaubechiesFilter[2]]
Wolfram Language code: WaveletFilterCoefficients[DaubechiesWavelet[2], "PrimalHighpass"]

スケーリング関数とウェーブレット関数

次はWavelet Explorerで利用できる関数と，バージョン8における同等の形式のリストである．

ScalingFunction[filt,j]WaveletPhi[wave]
Wavelet[wave,j]WaveletPsi[wave]
ShannonPhi[t]WaveletPhi[ShannonWavelet[lim],t]
ShannonPsi[t]WaveletPsi[ShannonWavelet[lim],t]
MeyerPhi[n,t,lim]WaveletPhi[MeyerWavelet[n,lim],t]
MeyerPsi[n,t,lim]WaveletPsi[MeyerWavelet[n,lim],t]
SplinePhi[n,t,lim]WaveletPhi[BattleLemarieWavelet[n,lim],t]
SplinePsi[n,t,lim]WaveletPsi[BattleLemarieWavelet[n,lim],t]
BSpline[n,t]BSplineBasis[{n,{u1,u2,…}},0,t]
DScalingFunction[filt,jmax,m]Dt[WaveletPhi[wave,t],{t,m}]
DWavelet[filt,jmax,m]Dt[WaveletPsi[wave,t],{t,m}]
同等の組込み関数

ScalingFunctionの機能は，WaveletPhiを使って利用することができる．

Wavelet Explorer Needs["Wavelets`Wavelets`"] ListLinePlot[ScalingFunction[DaubechiesFilter[2], 8]]
Wolfram Language code: Plot[WaveletPhi[DaubechiesWavelet[2], x], {x, 0, 3}]

スケール関数の導関数を見付けるためには，DtとWaveletPhiを使う．

Wavelet Explorer Needs["Wavelets`Wavelets`"] ListLinePlot[DScalingFunction[DaubechiesFilter[6], 8, 1]]
Wolfram Language code: Plot[Evaluate[Dt[WaveletPhi[DaubechiesWavelet[6], x], {x, 1}]], {x, 0, 11}, PlotRange -> All]

DWaveletの機能はDtとWaveletPsiを使って利用できる．

Wavelet Explorer Needs["Wavelets`Wavelets`"] ListLinePlot[DWavelet[LeastAsymmetricFilter[10], 8, 1]]
Wolfram Language code: Plot[Evaluate[Dt[WaveletPsi[SymletWavelet[10], x], {x, 1}]], {x, -9, 10}, PlotRange -> {{-5, 5}, All}]

スケール関数とウェーブレット関数の高次の導関数を計算する．

Wolfram Language code: wave = SymletWavelet[10];

WaveletPhiおよびWaveletPsiから出力されたInterpolatingFunctionでは，InterpolationOrderが1に設定されている．したがって，第2導関数は0となる．

Wolfram Language code: func = WaveletPsi[wave, x]
Wolfram Language code: Plot[Evaluate[Dt[func, {x, 2}]], {x, -9, 10}, PlotRange -> {{-5, 5}, All}]

高次のInterpolationOrderで再サンプルし補間することで問題は解決する．

Wavelet Explorer Needs["Wavelets`Wavelets`"] ListLinePlot[DWavelet[LeastAsymmetricFilter[10], 7, 2]]
Wolfram Language code: ifunc = ListInterpolation[Table[WaveletPsi[wave, x], {x, -9, 10, 0.01}], {-9, 10}]
Wolfram Language code: Plot[Evaluate[Dt[ifunc[x], {x, 2}]], {x, -9, 10}, PlotRange -> {{-5, 5}, All}]

BSplineの機能は，組込み関数のBSplineBasisで利用できるようになった．

Wavelet Explorer Needs["Wavelets`Wavelets`"] Plot[Evaluate[BSpline[6, t]], {t, -3, 4}]
Wolfram Language code: bspline[n_, t_] := BSplineBasis[{n, Range[-Floor[(n + 1/2)], Ceiling[(n + 1/2)]]}, 0, t]
Wolfram Language code: Plot[bspline[6, t], {t, -3, 4}, PlotRange -> All]

ウェーブレット変換

次はWavelet Explorerで利用できるウェーブレット変換と，バージョン8における同等の形式のリストである．

WaveletTransform[data,filt,j]DiscreteWaveletTransform[data,wave,j]
InverseWaveletTransform[wd,filt]InverseWaveletTransform[dwd]
WaveletPacketCoefficients[data,filt,j]DiscreteWaveletPacketTransform[data,filt,j]
WaveletPacketTransform[data,filt,l]WaveletBestBasis[DiscreteWaveletPacketTransform[…]]
InverseWaveletPacketTransform[wpdata,filt]InverseWaveletTransform[dwd]
同等の組込み関数．関数MRDecompositionは組込みの機能で直接サポートされていない．

WaveletTransformの機能はDiscreteWaveletTransformで利用できるようになった．

Wavelet Explorer Needs["Wavelets`Wavelets`"] Simplify[WaveletTransform[Range[4], HaarFilter[]]]
Wolfram Language code: Simplify@DiscreteWaveletTransform[Range[4], WorkingPrecision -> ∞][Automatic]

パケット変換を計算するためにはDiscreteWaveletPacketTransformを使う．

Wavelet Explorer Needs["Wavelets`Wavelets`"] wd = WaveletPacketTransform[Range[8], DaubechiesFilter[2], 2]
Wolfram Language code: dwpt = DiscreteWaveletPacketTransform[Range[8], DaubechiesWavelet[2], 2]

逆変換にはInverseWaveletTransformを使う．

Wavelet Explorer InverseWaveletPacketTransform[wd, DaubechiesFilter[2]]
Wolfram Language code: InverseWaveletTransform[dwpt]

MRDecompositionの機能は，次のようにして復元できる．

Wavelet Explorer Needs["Wavelets`Wavelets`"] wd = WaveletTransform[N@Range[8], HaarFilter[]]; MRDecomposition[wd, HaarFilter[]]
Wolfram Language code: dwd = DiscreteWaveletTransform[Range[8]];
Wolfram Language code: InverseWaveletTransform[wd, Automatic, #]& /@ wd["BasisIndex"]
Wolfram Language code: Total[%]

正弦変換と余弦変換

次はWavelet Explorerで利用できる関数と，バージョン8における同等の形式のリストである．

CosTransform[data,n, BasisType->m]FourierDCT[data,m]
SinTransform[data,n,BasisType->m]FourierDST[data,m]
InverseCosTransform[cdata]FourierDCT[cdata,m]
InverseSinTransform[sdata]FourierDST[sdata,m]
同等の組み込み関数．CosPacketCoefficients，SinPacketCoefficients，CosPacketTransform， SinPacketTransform，InverseCosPacketTransform，InverseSinPacketTransform，MalvarTransform，InverseMalvarTransformは組込みの機能では直接サポートされていない．

SinTransformを計算するためには，組込み関数のFourierDSTを使う．

Wavelet Explorer Needs["Wavelets`Wavelets`"] SinTransform[Range[8], Taper -> False]
Wolfram Language code: FourierDST[{Range[8]}, 4]

指定された第2引数を持つSinTransform．

Wavelet Explorer Needs["Wavelets`Wavelets`"] SinTransform[Range[8], 2, Taper -> False]
Wolfram Language code: Map[FourierDST[#, 4]&, Partition[Range[8], 2]]

一次元のSinPacketCoefficientsの機能は，次のようにして復元できる．

Wavelet Explorer Needs["Wavelets`Wavelets`"] SinPacketCoefficients[Range[8], 8, 3, Taper -> False]
Wolfram Language code: sinPacketCoefficients[data_ ? VectorQ, j_Integer, ftype_Integer ? (1 ≤ # ≤ 4&)] := Module[{sdata, l}, (* Split data into octave lengths *) l = 2^Range[j, 0, -1]; sdata = Rest@FoldList[{id, oct}  Flatten[Map[Partition[#, oct]&, id], 1], {data}, l]; (* Map FourierDST over the data *) Map[FourierDST[#, ftype]&, sdata, {2}] ]
Wolfram Language code: sinPacketCoefficients[Range[8], 3, 4]

同様にFourierDCT使ってCosPacketCoefficientsを書くことができる．

Wavelet Explorer Needs["Wavelets`Wavelets`"] CosPacketCoefficients[Range[8], 8, 3, Taper -> False]
Wolfram Language code: cosPacketCoefficients[data_ ? VectorQ, j_Integer, ftype_Integer ? (1 ≤ # ≤ 4&)] := Module[{sdata, l}, (* Split data into octave lengths *) l = 2^Range[j, 0, -1];sdata = Rest[FoldList[Function[{id, oct}, Flatten[(Partition[#1, oct]&) /@ id, 1]], {data}, l]]; (* Split data into octave lengths *) Map[FourierDCT[#1, ftype]&, sdata, {2}]]
Wolfram Language code: cosPacketCoefficients[Range[8], 3, 4]

その他のユーティリティ

次はWavelet Explorerで利用できる関数と，バージョン8における同等の形式のリストである．

PlotCoefficients[wd]WaveletListPlot[dwd]
PhaseSpacePlot[wd]WaveletScalogram[dwd]
ShowBasisPosition[wd]DiscreteWaveletData[…]["BestBasisBlockView"]
PlotCoefficients2D[wd]WaveletMatrixPlot[dwd]
ShowBasisPosition2D[wd]DiscreteWaveletData[…]["BestBasisBlockView"]
WaveletCompress[wd,…]WaveletThreshold[dwd,tspec]
同等の組込み関数．関数GrayCodeOrderとCumulativeEnergyは組込みの機能では直接サポートされていない．

ウェーブレット係数をプロットするためにはWaveletScalogramを使う．

Wavelet Explorer Needs["Wavelets`Wavelets`"] data = Table[Sin[x^3], {x, -6, 6, 12/1023}]; wd = WaveletPacketTransform[data, N@HaarFilter[], 2] PhaseSpacePlot[wd, Frame -> True, FrameTicks -> None, AspectRatio -> 1/2]
Wolfram Language code: dwd = DiscreteWaveletPacketTransform[Table[Sin[x^3], {x, -6, 6, 12 / 1023}], HaarWavelet[], 2]
Wolfram Language code: WaveletScalogram[dwd, Frame -> True, FrameTicks -> None, AspectRatio -> 1 / 2]

データの圧縮にはWaveletThresholdを使う．

Wavelet Explorer Needs["Wavelets`Wavelets`"] wd = WaveletTransform[Range[8], N@HaarFilter[], 3] Reverse@WaveletCompress[wd, 4]
Wolfram Language code: SeedRandom[11]; data = RandomReal[1, {16}];
Wolfram Language code: dwd = DiscreteWaveletTransform[Range[8], HaarWavelet[], 3]
Wolfram Language code: WaveletThreshold[dwd, {"LargestCoefficients", 4}, Automatic][Automatic, "Values"]

関数CumulativeEnergyは次のように書くことができる．

Wavelet Explorer Needs["Wavelets`Wavelets`"] wd = WaveletTransform[N@Range[8], HaarFilter[]]; CumulativeEnergy[wd]
Wolfram Language code: dwd = DiscreteWaveletTransform[Range[8], HaarWavelet[]];
Wolfram Language code: cumulativeEnergy[data_] := Accumulate[Reverse[Sort[Abs[Flatten[data]]]]^2] cumulativeEnergy[data_, n_Integer] := Accumulate[Reverse[Take[Sort[Abs[Flatten[data]]], -n]]^2]
Wolfram Language code: cumulativeEnergy[dwd[Automatic, "Values"]]
Wolfram Language code: cumulativeEnergy[dwd[Automatic, "Values"], 4]