WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AnimatedImage[{image1,image2,…}]

各フレームが連続する imageiであるアニメーションを生成する．

AnimatedImage[file]

file からのアニメーション画像を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
データ  
特性  
オプション  
AnimationRepetitions  
AnimationRunning  
DefaultDuration  
FrameRate  
RefreshRate  
アプリケーション  
特性と関係  
インタラクティブな例題  
関連項目
関連するガイド
履歴
引用書式

AnimatedImage

AnimatedImage[{image1,image2,…}]

各フレームが連続する imageiであるアニメーションを生成する．

AnimatedImage[file]

file からのアニメーション画像を表す．

詳細とオプション

  • AnimatedImageは，画像のリストを動的なアニメーションとして表示できる．アニメーション画像は，一般に，GIFやPNG等の形式で保存される．
  • AnimatedImage[file]の file は以下のいずれでもよい．
  • File["file"] または "file"$Pathで検索されるファイル名
    URL["url"] または "url"HTTP，HTTPS，FTP URL
    CloudObject[…]クラウドオブジェクト
    LocalObject[…]ローカルオブジェクト
    Video[…]動画オブジェクト
  • AnimatedImage[…][prop]というシンタックスで特定の特性が取り出せる．
  • 次は，サポートされる特性である．
  • "AnimationRepetitions"アニメーションを繰り返す回数
    "Channels"画像チャンネル数
    "ColorSpace"データについて仮定する色空間
    "DataType"もとになっているデータ型
    "FrameRate"使用するフレームレート
    "ImageCount"画像の数
    "ImageList"すべての画像
    "Interleaving"データがインターリーブされて保存されているかどうか
    "RasterSize"画像の画素次元
    "TotalDuration"合計時間
    "Transparency"画像に透明（アルファ）チャンネルがあるかどうか
  • 次は，使用可能なオプションである．
  • AnimationRepetitions Infinity停止までの実行回数
    AnimationRunning Trueアニメーションが実行中かどうか
    DefaultDuration Automaticデフォルトの継続時間（単位：秒）
    FrameRate Automatic画像を表示するレート
    ImageSizeInherited使用する全体的な画像サイズ
    RasterSizeAutomatic画像フレームの次元
    RefreshRate Automaticデフォルトの1秒あたりのリフレッシュ回数
  • AnimatedImageのInformationには次の特性が含まれる．
  • "AnimationRepetitions"アニメーションを繰り返す回数
    "Channels"画像チャンネル数
    "ColorSpace"データについて仮定する色空間
    "DataType"もとになっているデータ型
    "FrameRate"使用するフレームレート
    "ImageCount"画像の数
    "ImageDimensions"画素次元
    "Interleaving"データがインターリーブされて保存されているかどうか
    "RasterSize"画像の画素次元
    "TotalDuration"合計時間
    "Transparency"画像に透明（アルファ）チャンネルがあるかどうか
  • AnimatedImageをサポートする基本的な画像編集関数には，ColorConvert，ImageCrop，ImagePad，ImageReflect，ImageResize，ImageRotate，ImageTake，ImageTrimがある．
  • VideoとListAnimateを使ってアニメーションにした画像を対応するオブジェクトに変換する．

例題

すべて開く すべて閉じる

例  (3)

画像のリストをアニメーションとして表示する：

Wolfram Language code: AnimatedImage["ExampleData/wave.gif"]

数のリストからアニメーション画像を作成する：

Wolfram Language code: AnimatedImage[Rasterize[Style[#, 40]]& /@ Range[0, 9], FrameRate -> 6]

画像のリストからアニメーション画像を作成する：

Wolfram Language code: t = Table[With[{h = h}, LinearGradientImage[Hue[# + h, .5]&, 50]], {h, 0, 1, .1}]
Wolfram Language code: AnimatedImage[t, FrameRate -> 6]

スコープ  (7)

データ  (4)

画像のリストをアニメーションにする：

Wolfram Language code: list = Table[Image[Hue[h, .8, .9]], {h, 0, 1, 1 / 40}]
Wolfram Language code: AnimatedImage[list, ImageSize -> 50]

ファイルのフレームをアニメーションにする：

Wolfram Language code: AnimatedImage["ExampleData/pearls.png"]
Wolfram Language code: Information[%]

ファイルからインポートされた画像のリストをアニメーションにする：

Wolfram Language code: AnimatedImage[Import["ExampleData/pearls.png", ImageSize -> 100]]

メタデータの中には，フレームの継続時間のようにアニメーション画像の作成時には使われないものもあるので注意のこと：

Wolfram Language code: Information[%]

動画からアニメーション画像を作成する：

Wolfram Language code: AnimatedImage[Video["ExampleData/fish.mp4"]]

特性  (3)

画像のリストを抽出する：

Wolfram Language code: list = AnimatedImage["ExampleData/wave.gif"]["ImageList"];Downsample[list, 5]

フレームレートを抽出する：

Wolfram Language code: AnimatedImage["ExampleData/wave.gif"]["FrameRate"]

アニメーションの合計時間を抽出する：

Wolfram Language code: AnimatedImage["ExampleData/wave.gif"]["TotalDuration"]

この値はいくつかのオプション設定の影響を受ける：

Wolfram Language code: AnimatedImage["ExampleData/wave.gif", FrameRate -> 5]["TotalDuration"]

オプション  (6)

AnimationRepetitions  (1)

AnimationRepetitionsn を使ってアニメーションを n 回だけ再生する：

Wolfram Language code: AnimatedImage["ExampleData/wave.gif", AnimationRepetitions -> 3]

AnimationRepetitions∞を使ってアニメーションを連続的に再生する：

Wolfram Language code: AnimatedImage["ExampleData/wave.gif", AnimationRepetitions -> ∞]

AnimationRunning  (1)

AnimationRunningを使ってデフォルトでアニメーションを実行するかどうかを指定する：

Wolfram Language code: AnimatedImage["ExampleData/pearls.png", AnimationRunning -> True]
Wolfram Language code: AnimatedImage["ExampleData/pearls.png", AnimationRunning -> False]

DefaultDuration  (2)

DefaultDurations を使って1回のアニメーションサイクルの継続時間を制御する：

Wolfram Language code: AnimatedImage[Import["ExampleData/wave.gif"], DefaultDuration -> 2]

5秒以上の動画からアニメーション画像を作成するときは，スニペット動画からアニメーションが作成される：

Wolfram Language code: AnimatedImage[Video["ExampleData/bullfinch.mkv"]]
Wolfram Language code: %["TotalDuration"]

もとの時間と比較する：

Wolfram Language code: Duration@Video["ExampleData/bullfinch.mkv"]

FrameRate  (1)

FrameRaten を使って1秒間に最高で n フレーム表示する：

Wolfram Language code: AnimatedImage["ExampleData/wave.gif", FrameRate -> 40]

RefreshRate  (1)

RefreshRaten を使って1秒間に最高で n 回リフレッシュする：

Wolfram Language code: AnimatedImage["ExampleData/wave.gif", RefreshRate -> 3]

アプリケーション  (2)

アニメーションを構築する：

Wolfram Language code: g = ExampleData[{"Geometry3D", "Cow"}][[1, 2]];
Wolfram Language code: list = Table[Rasterize[Graphics3D[{EdgeForm[], GeometricTransformation[g, RotationTransform[a Degree, {0, 0, 1}]]}, SphericalRegion -> True, Boxed -> False], RasterSize -> 100], {a, 0, 360, 5}];
Wolfram Language code: AnimatedImage[list]

アニメーション画像のフレームを反転させる：

Wolfram Language code: a = AnimatedImage["ExampleData/wave.gif"]
Wolfram Language code: AnimatedImage[ColorNegate /@ a["ImageList"]]

特性と関係  (4)

構造的な画像操作をAnimatedImageに対して直接行う：

Wolfram Language code: a = AnimatedImage["ExampleData/pearls.png"]

すべてのフレームを充填する：

Wolfram Language code: ImagePad[a, 10]

すべてのフレームのサイズを調整する：

Wolfram Language code: ImageResize[a, 100]

ListAnimateを使ってアニメーションのコントロールを表示する：

Wolfram Language code: ListAnimate[AnimatedImage["ExampleData/wave.gif"]]

Videoを使ってアニメーションを動画オブジェクトに変換する：

Wolfram Language code: Video[AnimatedImage["ExampleData/wave.gif"]]

Informationを使ってAnimatedImageオブジェクトについての情報を可視化する：

Wolfram Language code: Information[AnimatedImage["ExampleData/wave.gif"]]

特定の特性を抽出する：

Wolfram Language code: Information[AnimatedImage["ExampleData/wave.gif"], "ImageCount"]

インタラクティブな例題  (1)

Manipulateを使ってアニメーションの設定をインタラクティブに制御する：

Wolfram Language code: Manipulate[AnimatedImage["ExampleData/pearls.png", FrameRate -> fr, RefreshRate -> rr, ImageSize -> size], {{fr, 16, "FrameRate"}, 10, 50}, {{rr, 20, "RefreshRate"}, 2, 20}, {{size, 100, "ImageSize"}, 50, 150}]
Wolfram Research (2020), AnimatedImage, Wolfram言語関数， https://reference.wolfram.com/language/ref/AnimatedImage.html （2021年に更新）.

テキスト

Wolfram Research (2020), AnimatedImage, Wolfram言語関数， https://reference.wolfram.com/language/ref/AnimatedImage.html （2021年に更新）.

CMS

Wolfram Language. 2020. "AnimatedImage." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/AnimatedImage.html.

APA

Wolfram Language. (2020). AnimatedImage. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AnimatedImage.html

BibTeX

@misc{reference.wolfram_2026_animatedimage, author="Wolfram Research", title="{AnimatedImage}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/AnimatedImage.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_animatedimage, organization={Wolfram Research}, title={AnimatedImage}, year={2021}, url={https://reference.wolfram.com/language/ref/AnimatedImage.html}, note=[Accessed: 10-August-2026]}