WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AnnotationValue[obj,key]

オブジェクト obj について key に関連付けられた注釈の値を与える．

AnnotationValue[{obj,itemspec},key]

obj 内の itemspec で指定された項目について key に関連付けられた注釈の値を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
グラフとネットワーク  
グラフの注釈  
頂点の注釈  
辺の注釈  
領域  
音声  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

AnnotationValue

AnnotationValue[obj,key]

オブジェクト obj について key に関連付けられた注釈の値を与える．

AnnotationValue[{obj,itemspec},key]

obj 内の itemspec で指定された項目について key に関連付けられた注釈の値を与える．

詳細

  • オブジェクトまたはオブジェクト内の項目に関連付けられた注釈中の値を取り出して操作するために使われることが多い．
  • AnnotationValueは，オブジェクトとその項目について，key->value という注釈の値 value を与える．
  • 次は，注釈を付けられる項目を含む可能性があるオブジェクトである．
  • Audio時点と時間間隔
    BoundaryMeshRegionメッシュセル
    CSGRegion幾何学領域
    Graph頂点と辺
    MeshRegionメッシュセル
  • オブジェクトの各タイプについての項目指定 itemspec は該当する関数ページを参照のこと．
  • AnnotationValueで要求された名前が見付からない場合はMissingが返される．
  • AnnotationValue[{obj,itemspec},key]は，値がないタグ key については未評価で返される．
  • AnnotationValue[…,key]=val を使って注釈の値を変えることができる．

例題

すべて開く すべて閉じる

例  (3)

注釈が付いた完全グラフを生成する：

Wolfram Language code: g = CompleteGraph[4, VertexLabels -> {1 -> "one"}]

注釈名に関連付けられた注釈の値を取り出す：

Wolfram Language code: AnnotationValue[g, VertexLabels]

注釈の値を変更する：

Wolfram Language code: AnnotationValue[{g, 1}, VertexLabels] = "two";
Wolfram Language code: g

注釈の値の設定を解除する：

Wolfram Language code: AnnotationValue[{g, 1}, VertexLabels]=.;
Wolfram Language code: g

メッシュ内のセルについての内在的なMeshCellMeasure注釈を得る：

Wolfram Language code: mr = MengerMesh[2]
Wolfram Language code: AnnotationValue[{mr, {2, 1}}, MeshCellMeasure]

Audioオブジェクトについての注釈を自動的に計算する：

Wolfram Language code: a = AudioAnnotate[Import["ExampleData/rule30.wav"], "Loud"];

より大きい区間の注釈を取り出す：

Wolfram Language code: AnnotationValue[a, "Loud"]

スコープ  (18)

グラフとネットワーク  (13)

グラフの注釈  (7)

頂点からいくつかの特性を抽出する：

Wolfram Language code: g = CompleteGraph[4, VertexStyle -> {1 -> Blue}, VertexLabels -> {1 -> "one"}, EdgeStyle -> {12 -> Blue}, EdgeLabels -> {12 -> "hello"}]
Wolfram Language code: AnnotationValue[{g, 1}, {VertexStyle, VertexLabels}]

辺から特性を抽出する：

Wolfram Language code: AnnotationValue[{g, 12}, {EdgeStyle, EdgeLabels}]
Wolfram Language code: AnnotationValue[{g, 24}, {EdgeStyle, EdgeLabels}] = {Red, "bye"};
Wolfram Language code: g

頂点の注釈の設定を解除する：

Wolfram Language code: g = CompleteGraph[4, VertexStyle -> {1 -> Blue}, VertexLabels -> {1 -> "one"}, EdgeStyle -> {12 -> Blue}, EdgeLabels -> {12 -> "hello"}]
Wolfram Language code: AnnotationValue[{g, 1}, VertexLabels]=.;
Wolfram Language code: g

辺の注釈の設定を解除する：

Wolfram Language code: AnnotationValue[{g, 12}, EdgeLabels]=.;
Wolfram Language code: g

AnnotationValueは無向グラフに使うことができる：

Wolfram Language code: AnnotationValue[{[image], 12}, EdgeStyle]

有向グラフに使う：

Wolfram Language code: AnnotationValue[{[image], 12}, EdgeStyle]

多重グラフに使う：

Wolfram Language code: AnnotationValue[{[image], 12}, EdgeStyle]

混合グラフに使う：

Wolfram Language code: AnnotationValue[{[image], 12}, EdgeStyle]

重み付きグラフに使う：

Wolfram Language code: AnnotationValue[{[image], 12}, EdgeWeight]

頂点の注釈  (3)

標準的な頂点の注釈にはVertexStyleが含まれる：

Wolfram Language code: g = CompleteGraph[4, VertexSize -> Small]
Wolfram Language code: AnnotationValue[{g, 4}, VertexStyle] = Red;
Wolfram Language code: g

VertexLabels：

Wolfram Language code: AnnotationValue[{g, 1}, VertexLabels] = "one";
Wolfram Language code: g

VertexSize：

Wolfram Language code: AnnotationValue[{g, 1}, VertexSize] = Large;
Wolfram Language code: g

VertexShape：

Wolfram Language code: AnnotationValue[{g, 1}, VertexShape] = [image];
Wolfram Language code: g

VertexShapeFunction：

Wolfram Language code: AnnotationValue[{g, 2}, VertexShapeFunction] = "Square";
Wolfram Language code: g

不可視の注釈にはVertexWeightが含まれる：

Wolfram Language code: AnnotationValue[{g, 1}, VertexWeight] = 100;
Wolfram Language code: AnnotationValue[{g, 1}, VertexWeight]

カスタムの注釈を設定する：

Wolfram Language code: g = CompleteGraph[4];
Wolfram Language code: AnnotationValue[{g, 2}, "Material"] = "Wood";
Wolfram Language code: AnnotationValue[{g, 2}, "Material"]

頂点1の注釈値を設定する：

Wolfram Language code: g = CompleteGraph[4]
Wolfram Language code: AnnotationValue[{g, 1}, VertexLabels] = "vertex";
Wolfram Language code: g

頂点1の注釈値を取り出す：

Wolfram Language code: AnnotationValue[{%, 1}, VertexLabels]

辺の注釈  (3)

標準的な辺の注釈にはEdgeStyleが含まれる：

Wolfram Language code: g = CompleteGraph[4]
Wolfram Language code: AnnotationValue[{g, 12}, EdgeStyle] = Brown;
Wolfram Language code: g

EdgeLabels：

Wolfram Language code: AnnotationValue[{g, 12}, EdgeLabels] = 12;
Wolfram Language code: g

EdgeShapeFunction：

Wolfram Language code: AnnotationValue[{g, 34}, EdgeShapeFunction] = {"HalfFilledDoubleArrow", "ArrowSize" -> .2};
Wolfram Language code: g

不可視の注釈にはEdgeWeightが含まれる：

Wolfram Language code: AnnotationValue[{g, 12}, EdgeWeight] = 42;
Wolfram Language code: AnnotationValue[{g, 12}, EdgeWeight]

カスタムの注釈を設定する：

Wolfram Language code: g = CompleteGraph[4];
Wolfram Language code: AnnotationValue[{g, 24}, "Resistance"] = 50.;
Wolfram Language code: AnnotationValue[{g, 24}, "Resistance"]

辺12についての注釈値を設定する：

Wolfram Language code: g = CompleteGraph[4]
Wolfram Language code: AnnotationValue[{g, 12}, EdgeLabels] = "edge";
Wolfram Language code: g

辺12の注釈値を取り出す：

Wolfram Language code: AnnotationValue[{g, 12}, EdgeLabels]

領域  (3)

CSGRegionから注釈を取り出す：

Wolfram Language code: CSGRegion["Union", {Style[Ball[], Red], Style[Cuboid[], Blue]}]
Wolfram Language code: AnnotationValue[{%, {1}}, "CSGRegionStyle"]

注釈を編集する：

Wolfram Language code: csg = CSGRegion["Union", {Ball[], Cuboid[]}]
Wolfram Language code: AnnotationValue[csg, "CSGRegionStyle"] = Red;
Wolfram Language code: csg

注釈を削除する：

Wolfram Language code: csg = CSGRegion["Union", {Style[Ball[], Red], Style[Cuboid[], Blue]}]
Wolfram Language code: AnnotationValue[{csg, {1}}, "CSGRegionStyle"]=.;
Wolfram Language code: csg

音声  (2)

Audioオブジェクトの注釈：

Wolfram Language code: a = Import["ExampleData/rule30.wav"]; a = Annotate[a, "Label" -> {.3 -> "val1", .6 -> "val2"}]

AnnotationValueを使って注釈を取り出す：

Wolfram Language code: AnnotationValue[a, "Label"]

AudioAnnotateを使ってAudioオブジェクトに注釈を付ける：

Wolfram Language code: a = Import["ExampleData/rule30.wav"]; a = AudioAnnotate[a, {"Loud", "Transients"}]

AnnotationValueを使って複数の注釈を取り出す：

Wolfram Language code: AnnotationValue[a, {"Loud", "Transients"}]//Column

アプリケーション  (5)

Doを使っていくつかの注釈値を設定する：

Wolfram Language code: g = CompleteGraph[8, VertexSize -> Medium]
Wolfram Language code: Do[AnnotationValue[{g, v}, VertexStyle] = StandardGray, {v, {4, 5, 6, 7, 8}}]
Wolfram Language code: g

あるいは，項目ごとに異なる注釈を設定する：

Wolfram Language code: Do[AnnotationValue[{g, v[[1]]}, VertexStyle] = v[[2]], {v, {{1, Red}, {2, Green}, {3, Blue}, {6, Orange}}}]
Wolfram Language code: g

Tableを使って注釈値のリストを構築する：

Wolfram Language code: Table[AnnotationValue[{g, v}, VertexStyle], {v, VertexList[g]}]
Wolfram Language code: GraphicsGrid[{Graphics[{#, Disk[]}]& /@ %}]

重み付きグラフを作成する：

Wolfram Language code: g = CompleteGraph[5]

辺の重みを設定する：

Wolfram Language code: Do[AnnotationValue[{g, e}, EdgeWeight] = RandomReal[], {e, EdgeList[g]}]
Wolfram Language code: Table[AnnotationValue[{g, e}, EdgeWeight], {e, EdgeList[g]}]

重みのスケールを計算する：

Wolfram Language code: {min, max} = {Min[#], Max[#]}&@%

辺の重みを反映する辺の太さを設定する：

Wolfram Language code: Do[AnnotationValue[{g, e}, EdgeStyle] = AbsoluteThickness[Rescale[AnnotationValue[{g, e}, EdgeWeight], {min, max}, {1, 4}]], {e, EdgeList[g]}]
Wolfram Language code: g

パスをハイライトし，始点と終点をマークする：

Wolfram Language code: g = CompleteGraph[5]

パスに沿った頂点を選択する：

Wolfram Language code: path = {3, 4, 1, 5, 2};

パスに沿った辺のスタイルと始点および終点の頂点ラベルを設定することでハイライトする：

Wolfram Language code: Do[AnnotationValue[{g, e}, EdgeStyle] = Red, {e, EdgeList[PathGraph[path]]}]
Wolfram Language code: AnnotationValue[{g, path[[1]]}, VertexLabels] = "Start"; AnnotationValue[{g, path[[-1]]}, VertexLabels] = "End";
Wolfram Language code: g

EdgeListが与える順に辺を動的にハイライトする：

Wolfram Language code: Dynamic[g, Initialization :> (g = GridGraph[{5, 5}])]

1秒に5回更新する：

Wolfram Language code: Do[AnnotationValue[{g, e}, EdgeStyle] = Directive[Thick, Blue]; Pause[0.2], {e, EdgeList[g]}]//AbsoluteTiming

幅優先走査を動的に可視化する：

Wolfram Language code: Dynamic[g, Initialization :> (g = CompleteKaryTree[3, 3, ImageSize -> Medium, VertexSize -> Medium])]
Wolfram Language code: BreadthFirstScan[g, {"DiscoverVertex" -> ((AnnotationValue[{g, #}, VertexStyle] = Red;Pause[0.25]) &), "FrontierEdge" -> ((AnnotationValue[{g, #}, EdgeStyle] = Blue;Pause[0.25]) &) }];

特性と関係  (5)

Annotationをラッパーとして使ってGraph等の関数内の注釈を指定する：

Wolfram Language code: Graph[{Annotation[1, {VertexSize -> Medium, VertexStyle -> Red}], 2, 3}, {12, 23, 31}]

AnnotationValueは，未定義の注釈については$Failedを返す：

Wolfram Language code: AnnotationValue[{CompleteGraph[4], 1}, VertexWeight]

AnnotationKeysを使って注釈があるかどうかを調べる：

Wolfram Language code: g = CompleteGraph[4, VertexLabels -> {1 -> one, 4 -> four}]
Wolfram Language code: MemberQ[AnnotationKeys[{g, 1}], VertexLabels]

頂点ラベルの規則を生成する：

Wolfram Language code: Cases[VertexList[g], v_ /; MemberQ[AnnotationKeys[{g, v}], VertexLabels] :> v -> AnnotationValue[{g, v}, VertexLabels]]

Annotateを使ってもとのグラフを変えずに注釈を設定する：

Wolfram Language code: g = CompleteGraph[4]
Wolfram Language code: Annotate[{g, 1}, VertexSize -> Medium]

もとのグラフは変わっていない：

Wolfram Language code: g

AnnotationDeleteを使ってもとのグラフを変えずに注釈を削除する：

Wolfram Language code: g = CompleteGraph[4, VertexStyle -> {1 -> Red}, VertexSize -> Small]
Wolfram Language code: AnnotationDelete[{g, 1}, VertexStyle]

もとのグラフは変わっていない：

Wolfram Language code: g

考えられる問題  (2)

AnnotationValueは，未定義の注釈については$Failedを返す：

Wolfram Language code: g = CompleteGraph[4, VertexSize -> {1 -> Small}]
Wolfram Language code: AnnotationValue[{g, 1}, vertexSize]

AnnotationKeysを使って注釈があるかどうかを調べる：

Wolfram Language code: MemberQ[AnnotationKeys[{g, 1}], VertexSize]
Wolfram Language code: MemberQ[AnnotationKeys[{g, 1}], vertexSize]

AnnotationValueは，注釈の値が存在していても$Failedを返すことがある：

Wolfram Language code: g = Graph[{Annotation[1, "Result" -> $Failed], 2, 3}, {12, 23, 31}]
Wolfram Language code: AnnotationValue[{g, 1}, "Result"]

AnnotationKeysを使って実際の注釈の値をチェックする：

Wolfram Language code: MemberQ[AnnotationKeys[{g, 1}], "Result"]
Wolfram Research (2020), AnnotationValue, Wolfram言語関数， https://reference.wolfram.com/language/ref/AnnotationValue.html （2025年に更新）.

テキスト

Wolfram Research (2020), AnnotationValue, Wolfram言語関数， https://reference.wolfram.com/language/ref/AnnotationValue.html （2025年に更新）.

CMS

Wolfram Language. 2020. "AnnotationValue." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/AnnotationValue.html.

APA

Wolfram Language. (2020). AnnotationValue. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AnnotationValue.html

BibTeX

@misc{reference.wolfram_2026_annotationvalue, author="Wolfram Research", title="{AnnotationValue}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/AnnotationValue.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_annotationvalue, organization={Wolfram Research}, title={AnnotationValue}, year={2025}, url={https://reference.wolfram.com/language/ref/AnnotationValue.html}, note=[Accessed: 07-August-2026]}