WOLFRAM

Wolfram 语言与系统参考资料中心

AnnotationValue[obj,key]

给出与对象 obj 的 key 关联的注释值.

AnnotationValue[{obj,itemspec},key]

给出与 obj 中由 itemspec 指定的项的 key 相关联的注释值.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
图和网络  
图和网络  
顶点注释  
边注释  
区域  
音频  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

AnnotationValue

AnnotationValue[obj,key]

给出与对象 obj 的 key 关联的注释值.

AnnotationValue[{obj,itemspec},key]

给出与 obj 中由 itemspec 指定的项的 key 相关联的注释值.

更多信息

  • 通常用于提取和操作与对象或对象中的项关联的注释中的值.
  • AnnotationValue 给出对象及其项的 key->value 注释中的值 value.
  • 带有可注释项的可能对象：
  • Audio时间点和时间间隔
    BoundaryMeshRegion网格单元
    CSGRegion几何区域
    Graph顶点和边
    MeshRegion网格单元
  • 每种对象类型的项规范 itemspec 在其参考页面给出.
  • 当找不到在 AnnotationValue 中请求的名称时，返回 Missing.
  • 对于无值的标记 key，AnnotationValue[{obj,itemspec},key] 以不计算的形式返回.
  • AnnotationValue[…,key]=val 可用于修改注释值.

范例

打开所有单元 关闭所有单元

基本范例  (3)

生成带有注释的完全图：

Wolfram Language code: g = CompleteGraph[4, VertexLabels -> {1 -> "one"}]

提取与注释名称关联的注释值：

Wolfram Language code: AnnotationValue[g, VertexLabels]

更改注释值：

Wolfram Language code: AnnotationValue[{g, 1}, VertexLabels] = "two";
Wolfram Language code: g

取消注释值：

Wolfram Language code: AnnotationValue[{g, 1}, VertexLabels]=.;
Wolfram Language code: g

获取网格中单元的固有 MeshCellMeasure 注释：

Wolfram Language code: mr = MengerMesh[2]
Wolfram Language code: AnnotationValue[{mr, {2, 1}}, MeshCellMeasure]

自动计算 Audio 对象的注释：

Wolfram Language code: a = AudioAnnotate[Import["ExampleData/rule30.wav"], "Loud"];

提取更响亮时段的注释：

Wolfram Language code: AnnotationValue[a, "Loud"]

范围  (18)

图和网络  (13)

图和网络  (7)

从顶点提取多个属性：

Wolfram Language code: g = CompleteGraph[4, VertexStyle -> {1 -> Blue}, VertexLabels -> {1 -> "one"}, EdgeStyle -> {12 -> Blue}, EdgeLabels -> {12 -> "hello"}]
Wolfram Language code: AnnotationValue[{g, 1}, {VertexStyle, VertexLabels}]

从边：

Wolfram Language code: AnnotationValue[{g, 12}, {EdgeStyle, EdgeLabels}]
Wolfram Language code: AnnotationValue[{g, 24}, {EdgeStyle, EdgeLabels}] = {Red, "bye"};
Wolfram Language code: g

取消对顶点设置的注释：

Wolfram Language code: g = CompleteGraph[4, VertexStyle -> {1 -> Blue}, VertexLabels -> {1 -> "one"}, EdgeStyle -> {12 -> Blue}, EdgeLabels -> {12 -> "hello"}]
Wolfram Language code: AnnotationValue[{g, 1}, VertexLabels]=.;
Wolfram Language code: g

和边：

Wolfram Language code: AnnotationValue[{g, 12}, EdgeLabels]=.;
Wolfram Language code: g

AnnotationValue 适用于无向图：

Wolfram Language code: AnnotationValue[{[image], 12}, EdgeStyle]

有向图：

Wolfram Language code: AnnotationValue[{[image], 12}, EdgeStyle]

多重图：

Wolfram Language code: AnnotationValue[{[image], 12}, EdgeStyle]

混合图：

Wolfram Language code: AnnotationValue[{[image], 12}, EdgeStyle]

加权图：

Wolfram Language code: AnnotationValue[{[image], 12}, EdgeWeight]

顶点注释  (3)

标准顶点注释包括 VertexStyle：

Wolfram Language code: g = CompleteGraph[4, VertexSize -> Small]
Wolfram Language code: AnnotationValue[{g, 4}, VertexStyle] = Red;
Wolfram Language code: g

VertexLabels：

Wolfram Language code: AnnotationValue[{g, 1}, VertexLabels] = "one";
Wolfram Language code: g

VertexSize：

Wolfram Language code: AnnotationValue[{g, 1}, VertexSize] = Large;
Wolfram Language code: g

VertexShape：

Wolfram Language code: AnnotationValue[{g, 1}, VertexShape] = [image];
Wolfram Language code: g

VertexShapeFunction：

Wolfram Language code: AnnotationValue[{g, 2}, VertexShapeFunction] = "Square";
Wolfram Language code: g

非视觉注释包括 VertexWeight：

Wolfram Language code: AnnotationValue[{g, 1}, VertexWeight] = 100;
Wolfram Language code: AnnotationValue[{g, 1}, VertexWeight]

设置自定义注释：

Wolfram Language code: g = CompleteGraph[4];
Wolfram Language code: AnnotationValue[{g, 2}, "Material"] = "Wood";
Wolfram Language code: AnnotationValue[{g, 2}, "Material"]

为顶点1设置注释值：

Wolfram Language code: g = CompleteGraph[4]
Wolfram Language code: AnnotationValue[{g, 1}, VertexLabels] = "vertex";
Wolfram Language code: g

提取顶点1的注释值：

Wolfram Language code: AnnotationValue[{%, 1}, VertexLabels]

边注释  (3)

标准边注释包括 EdgeStyle：

Wolfram Language code: g = CompleteGraph[4]
Wolfram Language code: AnnotationValue[{g, 12}, EdgeStyle] = Brown;
Wolfram Language code: g

EdgeLabels:

Wolfram Language code: AnnotationValue[{g, 12}, EdgeLabels] = 12;
Wolfram Language code: g

EdgeShapeFunction：

Wolfram Language code: AnnotationValue[{g, 34}, EdgeShapeFunction] = {"HalfFilledDoubleArrow", "ArrowSize" -> .2};
Wolfram Language code: g

非视觉注释包括 EdgeWeight：

Wolfram Language code: AnnotationValue[{g, 12}, EdgeWeight] = 42;
Wolfram Language code: AnnotationValue[{g, 12}, EdgeWeight]

设置自定义注释：

Wolfram Language code: g = CompleteGraph[4];
Wolfram Language code: AnnotationValue[{g, 24}, "Resistance"] = 50.;
Wolfram Language code: AnnotationValue[{g, 24}, "Resistance"]

设置边 12 的注释值：

Wolfram Language code: g = CompleteGraph[4]
Wolfram Language code: AnnotationValue[{g, 12}, EdgeLabels] = "edge";
Wolfram Language code: g

提取边 12 的注释值：

Wolfram Language code: AnnotationValue[{g, 12}, EdgeLabels]

区域  (3)

从 CSGRegion 中提取注释：

Wolfram Language code: CSGRegion["Union", {Style[Ball[], Red], Style[Cuboid[], Blue]}]
Wolfram Language code: AnnotationValue[{%, {1}}, "CSGRegionStyle"]

修改注释：

Wolfram Language code: csg = CSGRegion["Union", {Ball[], Cuboid[]}]
Wolfram Language code: AnnotationValue[csg, "CSGRegionStyle"] = Red;
Wolfram Language code: csg

删除注释：

Wolfram Language code: csg = CSGRegion["Union", {Style[Ball[], Red], Style[Cuboid[], Blue]}]
Wolfram Language code: AnnotationValue[{csg, {1}}, "CSGRegionStyle"]=.;
Wolfram Language code: csg

音频  (2)

注释 Audio 对象：

Wolfram Language code: a = Import["ExampleData/rule30.wav"]; a = Annotate[a, "Label" -> {.3 -> "val1", .6 -> "val2"}]

使用 AnnotationValue 提取注释：

Wolfram Language code: AnnotationValue[a, "Label"]

使用 AudioAnnotate 注释 Audio 对象：

Wolfram Language code: a = Import["ExampleData/rule30.wav"]; a = AudioAnnotate[a, {"Loud", "Transients"}]

使用 AnnotationValue 提取多个注释：

Wolfram Language code: AnnotationValue[a, {"Loud", "Transients"}]//Column

应用  (5)

使用 Do 设置多个注释值：

Wolfram Language code: g = CompleteGraph[8, VertexSize -> Medium]
Wolfram Language code: Do[AnnotationValue[{g, v}, VertexStyle] = Black, {v, {4, 5, 6, 7, 8}}]
Wolfram Language code: g

或针对不同项的不同注释值：

Wolfram Language code: Do[AnnotationValue[{g, v[[1]]}, VertexStyle] = v[[2]], {v, {{1, Red}, {2, Green}, {3, Blue}, {6, Orange}}}]
Wolfram Language code: g

使用 Table 建立注释值列表：

Wolfram Language code: Table[AnnotationValue[{g, v}, VertexStyle], {v, VertexList[g]}]
Wolfram Language code: GraphicsGrid[{Graphics[{#, Disk[]}]& /@ %}]

创建加权图：

Wolfram Language code: g = CompleteGraph[5]

设置边的权重：

Wolfram Language code: Do[AnnotationValue[{g, e}, EdgeWeight] = RandomReal[], {e, EdgeList[g]}]
Wolfram Language code: Table[AnnotationValue[{g, e}, EdgeWeight], {e, EdgeList[g]}]

计算权重的尺度：

Wolfram Language code: {min, max} = {Min[#], Max[#]}&@%

设置边的厚度以反映边的权重：

Wolfram Language code: Do[AnnotationValue[{g, e}, EdgeStyle] = AbsoluteThickness[Rescale[AnnotationValue[{g, e}, EdgeWeight], {min, max}, {1, 4}]], {e, EdgeList[g]}]
Wolfram Language code: g

突出显示路径并标记起点和终点：

Wolfram Language code: g = CompleteGraph[5]

沿路径选择顶点：

Wolfram Language code: path = {3, 4, 1, 5, 2};

通过沿起点和终点的路径和顶点标签设置边缘样式来突出显示：

Wolfram Language code: Do[AnnotationValue[{g, e}, EdgeStyle] = Red, {e, EdgeList[PathGraph[path]]}]
Wolfram Language code: AnnotationValue[{g, path[[1]]}, VertexLabels] = "Start"; AnnotationValue[{g, path[[-1]]}, VertexLabels] = "End";
Wolfram Language code: g

按照 EdgeList 给定的顺序动态突出显示边：

Wolfram Language code: Dynamic[g, Initialization :> (g = GridGraph[{5, 5}])]

每秒执行五次更新：

Wolfram Language code: Do[AnnotationValue[{g, e}, EdgeStyle] = Directive[Thick, Blue]; Pause[0.2], {e, EdgeList[g]}]//AbsoluteTiming

动态可视化广度优先搜索：

Wolfram Language code: Dynamic[g, Initialization :> (g = CompleteKaryTree[3, 3, ImageSize -> Medium, VertexSize -> Medium])]
Wolfram Language code: BreadthFirstScan[g, {"DiscoverVertex" -> ((AnnotationValue[{g, #}, VertexStyle] = Red;Pause[0.25]) &), "FrontierEdge" -> ((AnnotationValue[{g, #}, EdgeStyle] = Blue;Pause[0.25]) &) }];

属性和关系  (5)

使用 Annotation 作为包装，在 Graph 之类的函数中指定注释：

Wolfram Language code: Graph[{Annotation[1, {VertexSize -> Medium, VertexStyle -> Red}], 2, 3}, {12, 23, 31}]

对于未定义的注释，AnnotationValue 返回 $Failed：

Wolfram Language code: AnnotationValue[{CompleteGraph[4], 1}, VertexWeight]

使用 AnnotationKeys 测试注释的存在：

Wolfram Language code: g = CompleteGraph[4, VertexLabels -> {1 -> one, 4 -> four}]
Wolfram Language code: MemberQ[AnnotationKeys[{g, 1}], VertexLabels]

生成顶点标签规则列表：

Wolfram Language code: Cases[VertexList[g], v_ /; MemberQ[AnnotationKeys[{g, v}], VertexLabels] :> v -> AnnotationValue[{g, v}, VertexLabels]]

使用 Annotate 设置注释而不更改原始图：

Wolfram Language code: g = CompleteGraph[4]
Wolfram Language code: Annotate[{g, 1}, VertexSize -> Medium]

原始图不变：

Wolfram Language code: g

使用 AnnotationDelete 删除注释而不更改原始图：

Wolfram Language code: g = CompleteGraph[4, VertexStyle -> {1 -> Red}, VertexSize -> Small]
Wolfram Language code: AnnotationDelete[{g, 1}, VertexStyle]

原始图不变：

Wolfram Language code: g

可能存在的问题  (2)

对于未定义注释，AnnotationValue 返回 $Failed：

Wolfram Language code: g = CompleteGraph[4, VertexSize -> {1 -> Small}]
Wolfram Language code: AnnotationValue[{g, 1}, vertexSize]

使用 AnnotationKeys 测试注释的存在：

Wolfram Language code: MemberQ[AnnotationKeys[{g, 1}], VertexSize]
Wolfram Language code: MemberQ[AnnotationKeys[{g, 1}], vertexSize]

即使存在注释值，AnnotationValue 也可能返回 $Failed：

Wolfram Language code: g = Graph[{Annotation[1, "Result" -> $Failed], 2, 3}, {12, 23, 31}]
Wolfram Language code: AnnotationValue[{g, 1}, "Result"]

使用 AnnotationKeys 检查实际注释值：

Wolfram Language code: MemberQ[AnnotationKeys[{g, 1}], "Result"]
Wolfram Research (2020)，AnnotationValue，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AnnotationValue.html （更新于 2025 年）.

文本

Wolfram Research (2020)，AnnotationValue，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AnnotationValue.html （更新于 2025 年）.

CMS

Wolfram 语言. 2020. "AnnotationValue." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/AnnotationValue.html.

APA

Wolfram 语言. (2020). AnnotationValue. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AnnotationValue.html 年

BibTeX

@misc{reference.wolfram_2026_annotationvalue, author="Wolfram Research", title="{AnnotationValue}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/AnnotationValue.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_annotationvalue, organization={Wolfram Research}, title={AnnotationValue}, year={2025}, url={https://reference.wolfram.com/language/ref/AnnotationValue.html}, note=[Accessed: 16-August-2026]}