Wolfram 语言与系统参考资料中心

ArcCot

ArcCot[z]

给出复数的反余切 .

背景

ArcCot 是反余切函数. 对于实数，ArcCot[x] 代表使得的弧度角（0除外）.
ArcCot 自动逐项作用于列表. 对某些特定变量值，ArcCot 自动计算出精确值. 当给出精确数值表达式作为变量时，ArcCot 可以算出任意精度的数值结果. 对包含 ArcCot 的符号表达式，适用的操作运算有 FunctionExpand、TrigToExp、TrigExpand、Simplify 和 FullSimplify.
对复变量，ArcCot 的定义为 . ArcCot[z] 在复平面上有一个不连续的分支切割.
与之相关的数学函数有 Cot、ArcTan 和 ArcCoth.

范例

打开所有单元关闭所有单元

基本范例 (5)

结果以弧度表示：

Wolfram Language code: ArcCot[1]

除以 Degree 已得到以度为单位的结果：

Wolfram Language code: ArcCot[0] / Degree//FullSimplify

在实数域子集上绘图：

Wolfram Language code: Plot[ArcCot[x], {x, -5, 5}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcCot[z], {z, -3 - 2I, 3 + 2I}, PlotLegends -> Automatic]

在 Infinity 处的渐近展开：

Wolfram Language code: Series[ArcCot[x], {x, ∞, 5}]

奇点处的渐近展开：

Wolfram Language code: Series[ArcCot[x], {x, I, 3}, Assumptions -> x > 0]//FullSimplify

范围 (46)

数值计算 (6)

数值计算：

Wolfram Language code: ArcCot[2.5]

高精度求值：

Wolfram Language code: N[ArcCot[2 / 3], 50]

输出精度与输入精度一致：

Wolfram Language code: ArcCot[0.66666666666666666666666666666666666666666667]

对复变量进行计算：

Wolfram Language code: ArcCot[1.5 + 0.3I]

在高精度条件下高效计算 ArcCot：

Wolfram Language code: ArcCot[2.5`500]//Timing

Wolfram Language code: ArcCot[2.5`100000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ArcCot[Interval[{1, Sqrt[3]}]]

Wolfram Language code: ArcCot[CenteredInterval[1, 1 / 100]]

Wolfram Language code: ArcCot[CenteredInterval[1 + 2I, (1 + I) / 100]]

或使用 Around 计算一般情况下的统计区间：

Wolfram Language code: ArcCot[Around[.9, 0.1]]

计算数组中每个元素的值：

Wolfram Language code: ArcCot[{{1, Sqrt[3]}, {0, Sqrt[3]}}]

或用 MatrixFunction 以矩阵形式计算 ArcCot 函数：

Wolfram Language code: MatrixFunction[ArcCot[#]&, {{1, Sqrt[3]}, {0, Sqrt[3]}}]

特殊值 (4)

ArcCot 在固定点上的值：

Wolfram Language code: Table[ArcCot[(n /2)], {n, -2, 2}]

无穷处的值：

Wolfram Language code: ArcCot[Infinity]

Wolfram Language code: ArcCot[ComplexInfinity]

ArcCot 的奇点：

Wolfram Language code: {ArcCot[I ], ArcCot[-I ]}

求满足方程的值：

Wolfram Language code: f[x_] := ArcCot[x] - (π/3);

Wolfram Language code: sol = Solve[f[x] == 0, x]

替换为值：

Wolfram Language code: xzero = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[f[x], {x, 0, 2}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可视化 (3)

绘制 ArcCot 函数：

Wolfram Language code: Plot[ArcCot[x], {x, -10, 10}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcCot[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcCot[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

，绘制极坐标图：

Wolfram Language code:

Table[PolarPlot[ArcCot[k ϕ], {ϕ, -3π, 3π}, Sequence[Frame -> True, FrameTicks -> {{{-1, 0, 1}, None}, {{-1, 0, 1}, None}}, PlotRange -> {All, {-1, 1}}, PlotLabel -> "k=" <> ToString[k], PlotRange -> All]], {k, 1, 4}]

函数属性 (12)

ArcCot 是针对所有实数定义的：

Wolfram Language code: FunctionDomain[ArcCot[x], x]

复定义域：

Wolfram Language code: FunctionDomain[ArcCot[z], z, Complexes]

ArcCot 的值域是区间上的所有实数值：

Wolfram Language code: FunctionRange[ArcCot[x], x, y]

复定义域参数的值域范围：

Wolfram Language code: FunctionRange[ArcCot[z], z, y, Complexes]

ArcCot 是一个奇函数：

Wolfram Language code: ArcCot[-x]

ArcCot 具有镜像属性 $cot^(-1)(TemplateBox[{x}, Conjugate])=TemplateBox[{{{cot, ^, {(, {-, 1}, )}}, (, x, )}}, Conjugate]$ ：

Wolfram Language code: FullSimplify[ArcCot[Conjugate[x]] == Conjugate[ArcCot[x]]]

ArcCot 不是解析函数：

Wolfram Language code: FunctionAnalytic[ArcCot[x], x]

也不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[ArcCot[x], x]

ArcCot 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[ArcCot[x], x]

ArcCot 是单射函数：

Wolfram Language code: FunctionInjective[ArcCot[x], x]

Wolfram Language code: Plot[{ArcCot[x], 1 / 2}, {x, -2π, 2π}]

ArcCot 不是满射函数：

Wolfram Language code: FunctionSurjective[ArcCot[x], x]

Wolfram Language code: Plot[{ArcCot[x], 2, 0}, {x, -π, π}]

ArcCot 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[ArcCot[x], x]

ArcCot 在零处有奇点和断点：

Wolfram Language code: FunctionSingularities[ArcCot[x], x]

Wolfram Language code: FunctionDiscontinuities[ArcCot[x], x]

ArcCot 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[ArcCot[x], x]

TraditionalForm 格式输出：

Wolfram Language code: ArcCot[x]//TraditionalForm

微分 (3)

一阶导数：

Wolfram Language code: D[ArcCot[x], x]

高阶导数：

Wolfram Language code: Table[D[ArcCot[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[ArcCot[x], {x, n}]

积分 (3)

ArcCot 的不定积分：

Wolfram Language code: Integrate[ArcCot[x], x]

在以原点为中心的区间内，ArcCot 的定积分为0：

Wolfram Language code: Integrate[ArcCot[x], {x, -1, 1}]

更多积分：

Wolfram Language code: Integrate[x ArcCot[x], x]

Wolfram Language code: Integrate[z ^ k ArcCot[z], z]

级数展开式 (4)

使用 Series 求泰勒级数展开式：

Wolfram Language code: Series[ArcCot[x], {x, 1, 7}]

绘制 ArcCot 在处的前三个近似式：

Wolfram Language code:

terms = Normal@Table[Series[ArcCot[x], {x, 1, m}], {m, 1, 5, 2}];
Plot[{ArcCot[x], terms}, {x, 0, 2}]

ArcCot 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[ArcCot[x], {x, 0, n}]

在分支点和分支切口处求级数展开式：

Wolfram Language code: Series[ArcCot[x], {x, I, 1}]

Wolfram Language code: Series[ArcCot[x], {x, I / 2, 1}]

ArcCot 可被应用于幂级数：

Wolfram Language code: ArcCot[SeriesData[x, 0, {1, 0, -1/3, 0, -1/45, 0, -2/945, 0, -1/4725, 0, -2/93555}, -1, 10, 1]]

积分转换 (3)

用 InverseLaplaceTransform 计算拉普拉斯逆变换：

Wolfram Language code: InverseLaplaceTransform[ArcCot[s], s, t]

InverseFourierTransform：

Wolfram Language code: InverseFourierTransform[ArcCot[ω], ω, t ]

MellinTransform：

Wolfram Language code: MellinTransform[ArcCot[x], x, s ]

函数恒等式和化简 (3)

化简含有 ArcCot 的表达式：

Wolfram Language code: FullSimplify[Tan[ArcCot[x]]]

通过 TrigToExp 用 Log 表示 ArcCot：

Wolfram Language code: TrigToExp[ArcCot[z]]

Wolfram Language code: ExpToTrig[%]//FullSimplify

假定实数变量和的情况下进行展开：

Wolfram Language code: ComplexExpand[ArcCot[x + I y]]

函数表示 (5)

使用 ArcTan 表示：

Wolfram Language code: ArcTan[1 / x]//FullSimplify

通过逆 Jacobi 函数表示：

Wolfram Language code: InverseJacobiCS[z, 0]//FullSimplify

Wolfram Language code: InverseJacobiSC[(1/z), 0]//FullSimplify

用 MeijerG 表示：

Wolfram Language code: (HypergeometricPFQ[{1, (1/2)}, {(3/2)}, -(1/z^2)]/z)//FullSimplify

使用 Hypergeometric2F1 表示：

Wolfram Language code: MeijerGReduce[ArcCot[x], x]

Wolfram Language code: Activate[%]//FullSimplify

也可用 DifferentialRoot 来表示 ArcCot：

Wolfram Language code: DifferentialRootReduce[ArcCot[x], x]

应用 (4)

求直角边为 3、4，斜边为 5 的直角三角形的角：

Wolfram Language code: N[{ArcCot[4 / 3], ArcCot[3 / 4]} / Degree]

两者之和为 90°：

Wolfram Language code: Total[%]

用于余切函数的加法定理：

Wolfram Language code: Cot[ArcCot[x] + ArcCot[y]]//TrigExpand//Simplify

求解一个微分方程：

Wolfram Language code: DSolve[{(1 + x^2) y''[x] + 2 x y'[x] == ArcCot[x], y[0] == 0, y'[0] == 1}, y[x], x]

ArcCot 的分支切割是沿虚轴延伸的：

Wolfram Language code: Plot3D[Re[ArcCot[x + I y]], {y, -2, 2}, {x, -2.5, 2.5}]

属性和关系 (4)

利用 TrigToExp 通过 Log 表示 ArcCot：

Wolfram Language code: TrigToExp[ArcCot[z]]

Wolfram Language code: ExpToTrig[%]//FullSimplify

利用 FullSimplify 化简带有 ArcCot 的表达式：

Wolfram Language code: FullSimplify[16 ArcCot[5] - 4 ArcCot[239]]

ArcCot 给出以弧度为单位的角，ArcSecDegrees 给出相同的角，但以度为单位：

Wolfram Language code: ArcCot[1]

Wolfram Language code: ArcCotDegrees[1]

利用 Reduce 求解包含 ArcCot 的不等式：

Wolfram Language code: Reduce[ArcCot[x] > Pi / 3, x]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

ArcCot

更多信息

背景

范例

基本范例 (5)

范围 (46)

数值计算 (6)

特殊值 (4)

可视化 (3)

函数属性 (12)

微分 (3)

积分 (3)

级数展开式 (4)

积分转换 (3)

函数恒等式和化简 (3)

函数表示 (5)

应用 (4)

属性和关系 (4)

文本

CMS

APA

BibTeX

BibLaTeX

ArcCot

更多信息

背景

范例

基本范例 (5)

范围 (46)

数值计算 (6)

特殊值 (4)

可视化 (3)

函数属性 (12)

微分 (3)

积分 (3)

级数展开式 (4)

积分转换 (3)

函数恒等式和化简 (3)

函数表示 (5)

应用 (4)

属性和关系 (4)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX