ArcTan

ArcTan[z]

複素数の逆正接を与える．

ArcTan[x,y]

どの象限に点があるかを考慮し，の逆正接を与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
答はラジアンで求まる．
が実数のとき，答は必ず〜の範囲にある．
特別な引数の場合，ArcTanは自動的に厳密値を計算する．
ArcTanは任意の数値精度で評価できる．
ArcTanは自動的にリストに関数の並列的な適用を行う．
ArcTan[z]は，複素平面上，〜そして〜の範囲で不連続な分枝切断線を持つ．
またはが複素数のとき，ArcTan[x,y]は，を意味する．のときにArcTan[x,y]は，およびを満たす数を見出す．
ArcTanはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

ArcTanは，逆正接関数である．実数 x については，ArcTan[x]は，となるラジアン角度測定値を表す．2つの引数を取る形式であるArcTan[x,y]は，点がある象限を考慮に入れて，y/x の逆正接を表す．このため，正の軸から測定された点の角度位置（ラジアンで表される）を返す．ArcTanは，直交座標系から極座標系に変換する場合に，またフェーザ表記 $x+ⅈ y=TemplateBox[{z}, Abs]ⅇ^(ⅈ phi)$ の位相を求める場合に，便利である．
ArcTanは，自動的にリストに縫い込まれる．特別な厳密値の引数の場合，ArcTanは自動的に厳密値を計算する．引数として厳密な数式が与えられている場合には，ArcTanは任意の数値精度に評価してもよい．ArcTanを含む記号式の操作に有効な関数には，FunctionExpand，TrigToExp，TrigExpand，Simplify，FullSimplifyがある．
ArcTanは，複素引数については，を通して定義される．
ArcTan[z]は，複素平面上に不連続な分枝切断線を持つ．関連する数学関数には，Arg，Tan，ArcCot，ArcTanh，Gudermannianがある．

例題

すべて開くすべて閉じる

例 (7)

結果はラジアンである：

Wolfram Language code: ArcTan[1]

Degreeで割って結果を度で得る：

Wolfram Language code: ArcTan[1] / Degree//FullSimplify

ArcTan[x,y]は点{x,y}の角度を与える：

Wolfram Language code: ArcTan[1, 1]

Wolfram Language code: ArcTan[-1, -1]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ArcTan[x], {x, -5, 5}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ArcTan[z ^ 2], {z, -1 / 2 - I, 1 / 2 + I}, PlotLegends -> Automatic]

0における級数展開：

Wolfram Language code: Series[ArcTan[x], {x, 0, 15}]

Infinityにおける漸近展開：

Wolfram Language code: Series[ArcTan[x], {x, ∞, 5}]

特異点の一つにおける漸近展開：

Wolfram Language code: Series[ArcTan[x], {x, I, 3}]//FullSimplify

スコープ (49)

数値評価 (6)

数値的に評価する：

Wolfram Language code: ArcTan[0.5]

Wolfram Language code: ArcTan[0.5, 2]

高精度で評価する：

Wolfram Language code: N[ArcTan[1 / 2], 50]

2引数の形式を使って評価する：

Wolfram Language code: N[ArcTan[2, 1], 50]

出力精度は入力精度に従う：

Wolfram Language code: ArcTan[0.50000000000000000000000000000000000000000]

複素引数について評価する：

Wolfram Language code: ArcTan[2.5 + I]

2引数形式は複素数をサポートする：

Wolfram Language code: ArcTan[2.5 + I, 2]

ArcTanを高精度で効率よく評価する：

Wolfram Language code: ArcTan[0.4`500]//Timing

Wolfram Language code: ArcTan[0.4`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ArcTan[Interval[{-1, 3}]]

Wolfram Language code: ArcTan[CenteredInterval[1, 1 / 100]]

Wolfram Language code: ArcTan[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: ArcTan[Around[.9, 0.1]]

配列の要素ごとの値を計算する：

Wolfram Language code: ArcTan[{{1, Sqrt[3]}, {0, Sqrt[3]}}]

MatrixFunctionを使って行列のArcTan関数を計算することもできる：

Wolfram Language code: MatrixFunction[ArcTan[#]&, {{1, Sqrt[3]}, {0, Sqrt[3]}}]

特定の値 (6)

固定点におけるArcTanの値：

Wolfram Language code: Table[ArcTan[n ], {n, -1, 1}]

からまでの整数座標を持つすべての点の角度：

Wolfram Language code: Table[ArcTan[x, y ], {x, -2, 2}, {y, -2, 2}]//Quiet//MatrixForm

無限大における値：

Wolfram Language code: ArcTan[Infinity]

Wolfram Language code: ArcTan[ComplexInfinity]

ArcTan[x,y]形式の無限大における値：

Wolfram Language code: ArcTan[Infinity, 1]

Wolfram Language code: ArcTan[-1, Infinity]

ArcTanの零点：

Wolfram Language code: ArcTan[0]

方程式を満足するの値を求める：

Wolfram Language code: f[x_] := ArcTan[x] - (π/3);

Wolfram Language code: sol = Solve[f[x] == 0, x]

値を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, -2, 2}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可視化 (4)

ArcTan関数をプロットする：

Wolfram Language code: Plot[ArcTan[x], {x, -7, 7}]

2引数のArcTan関数を平面上にプロットする：

Wolfram Language code: Plot3D[ArcTan[x, y], {x, -7, 7}, {y, -7, 7}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ArcTan[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ArcTan[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

の極プロット：

Wolfram Language code:

Table[PolarPlot[ArcTan[k ϕ], {ϕ, -4π, 4π}, Frame -> True, FrameTicks -> {{{-1, 0, 1}, None}, {{-1, 0, 1}, None}}, PlotLabel -> "k=" <> ToString[k], PlotRange -> All], {k, 1, 4}]

関数の特性 (12)

ArcTanはすべての実数値について定義される：

Wolfram Language code: FunctionDomain[ArcTan[x], x]

複素領域：

Wolfram Language code: FunctionDomain[ArcTan[z], z, Complexes]

ArcTanは，区間からのすべての実数値に達する：

Wolfram Language code: FunctionRange[ArcTan[x], x, y]

複素領域からの引数についての関数の範囲：

Wolfram Language code: FunctionRange[ArcTan[z], z, y, Complexes]

ArcTanは奇関数である：

Wolfram Language code: ArcTan[-x]

ArcTanは鏡特性 $tan^(-1)(TemplateBox[{x}, Conjugate])=TemplateBox[{{{tan, ^, {(, {-, 1}, )}}, (, x, )}}, Conjugate]$ を有する：

Wolfram Language code: FullSimplify[ArcTan[Conjugate[x]] == Conjugate[ArcTan[x]]]

は実数上での解析関数である：

Wolfram Language code: FunctionAnalytic[ArcTan[x], x]

複素平面上では解析的でも有理型でもない：

Wolfram Language code: FunctionAnalytic[ArcTan[x], x, Complexes]

Wolfram Language code: FunctionMeromorphic[ArcTan[x], x]

は実数上では解析的ではない：

Wolfram Language code: FunctionAnalytic[ArcTan[x, y], {x, y}]

は増加関数である：

Wolfram Language code: FunctionMonotonicity[ArcTan[x], x, StrictInequalities -> True]

ArcTanは単射である：

Wolfram Language code: FunctionInjective[ArcTan[x], x]

Wolfram Language code: Plot[{ArcTan[x], 1 / 2}, {x, -5, 5}]

ArcTanは全射ではない：

Wolfram Language code: FunctionSurjective[ArcTan[x], x]

Wolfram Language code: Plot[{ArcTan[x], 2}, {x, -5, 5}]

ArcTanは非負でも非正でもない：

Wolfram Language code: FunctionSign[ArcTan[x], x]

は特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[ArcTan[x], x]

Wolfram Language code: FunctionDiscontinuities[ArcTan[x], x]

はのとき特異である：

Wolfram Language code: FunctionSingularities[ArcTan[x, y], {x, y}]

Wolfram Language code: FunctionDiscontinuities[ArcTan[x, y], {x, y}]

ArcTanは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[ArcTan[x], x]

TraditionalFormによる表示：

Wolfram Language code: ArcTan[x]//TraditionalForm

Wolfram Language code: ArcTan[x, y]//TraditionalForm

微分 (3)

一次導関数：

Wolfram Language code: D[ArcTan[x], x]

高次導関数：

Wolfram Language code: Table[D[ArcTan[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[ArcTan[x], {x, n}]

積分 (3)

ArcTanの不定積分：

Wolfram Language code: Integrate[ArcTan[x], x]

原点を中心とする区間上でのArcTanの定積分は0である：

Wolfram Language code: Integrate[ArcTan[x], {x, -1, 1}]

その他の積分例：

Wolfram Language code: Integrate[x ArcTan[x], x]

Wolfram Language code: Integrate[z ^ k ArcTan[z], z]

級数展開 (4)

ArcTanのテイラー(Taylor)展開：

Wolfram Language code: Series[ArcTan[x], {x, 0, 7}]

の周りのArcTanの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[ArcTan[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{ArcTan[x], terms}, {x, -1, 1}, PlotRange -> {{-1, 1}, All}]

ArcTanの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[ArcTan[x], {x, 0, n}]

分岐点と分枝切断線における級数展開を求める：

Wolfram Language code: Series[ArcTan[x], {x, I, 1}]

Wolfram Language code: Series[ArcTan[x], {x, 2I, 1}]

ArcTanはベキ級数に適用できる：

Wolfram Language code: ArcTan[SeriesData[x, 0, {1, 0, 1/3, 0, 2/15, 0, 17/315, 0, 62/2835}, 1, 10, 1]]

積分変換 (3)

LaplaceTransformを使ってラプラス(Laplace)変換を計算する：

Wolfram Language code: LaplaceTransform[ArcTan[t], t, s]

InverseFourierTransform：

Wolfram Language code: InverseFourierTransform[ArcTan[ω], ω, t ]

MellinTransform：

Wolfram Language code: MellinTransform[ArcTan[x], x, s ]

関数の恒等式と簡約 (3)

ArcTanを含む式を簡約する：

Wolfram Language code: TrigExpand[Tan[ArcTan[x] + ArcTan[y]]]//FullSimplify

TrigToExpを使ってArcTanをLogによって表現する：

Wolfram Language code: TrigToExp[ArcTan[z]]

Wolfram Language code: ExpToTrig[%]

実変数およびを仮定して展開する：

Wolfram Language code: ComplexExpand[ArcTan[x + I y]]

関数表現 (5)

ArcCotを使って表現する：

Wolfram Language code: ArcCot[1 / x]//FullSimplify

逆ヤコビ関数を介した表現：

Wolfram Language code: InverseJacobiCS[(1/z), 0]//FullSimplify

Wolfram Language code: InverseJacobiSC[z, 0]//FullSimplify

Hypergeometric2F1を使った表現：

Wolfram Language code: x Hypergeometric2F1[1 / 2, 1, 3 / 2, -x ^ 2]

ArcTanはMeijerGによって表すことができる：

Wolfram Language code: MeijerGReduce[ArcTan[x], x]

Wolfram Language code: Activate[%]

ArcTanはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[ArcTan[x], x]

アプリケーション (9)

辺が3と4で斜辺が5の直角三角形の角度を求める：

Wolfram Language code: N[{ArcTan[4, 3], ArcTan[3, 4]} / Degree]

合計で90°になる：

Wolfram Language code: Total[%]

有理関数の積分をArcTanについて求める：

Wolfram Language code: Integrate[1 / (x ^ 2 + 1), x]

正接関数についての加法定理：

Wolfram Language code: Tan[ArcTan[x] + ArcTan[y]]//TrigExpand//Simplify

2つの点とを通る直線の傾斜角を求める：

Wolfram Language code: {x1, y1} = {0, 0};{x2, y2} = {1, Sqrt[3]};

Wolfram Language code: ArcTan[x2 - x1, y2 - y1]

微分方程式を解く：

Wolfram Language code: DSolve[{(1 + x^2) y''[x] + 2 x y'[x] == 1, y[0] == 0, y'[0] == 1}, y[x], x]

ArcTanの分枝切断線は虚軸に沿っている：

Wolfram Language code: Plot3D[Re[ArcTan[x + I y]], {y, -2, 2}, {x, -2.5, 2.5}]

複素数の極分解：

Wolfram Language code: {Arg[#], Abs[#]}&[2 + 5I]

サイン-ゴルドン(Gordon)方程式の特異解：

Wolfram Language code: v[x_, t_] = 4 ArcTan[Exp[(1 / Sqrt[1 - c ^ 2])(x - c t)]];

解をチェックする：

Wolfram Language code: D[v[x, t], t, t] - D[v[x, t], x, x] + Sin[v[x, t]]//FullSimplify

双曲線正割の標準分布の累積分布関数(CDF)はArcTanによって与えられる：

Wolfram Language code: F[x] := (2 / π) ArcTan[Exp[π x / 2]]

これはGudermannian関数をスケールしてシフトしたものである：

Wolfram Language code: FullSimplify[2 / π ArcTan[Exp[π x / 2]] == 1 / 2 + (1 / π)Gudermannian[(π x/2)], x∈Reals]

特性と関係 (5)

TrigToExpを使ってArcTanをLogで表す：

Wolfram Language code: TrigToExp[ArcTan[z]]

Wolfram Language code: ExpToTrig[%]

FullSimplifyを使ってArcTanを含む式を簡約する：

Wolfram Language code: FullSimplify[16 ArcTan[1 / 5] - 4 ArcTan[1 / 239]]

ArcTanは角度をラジアンで与えるのに対し，ArcTanDegreesは同じ角度を度で与える：

Wolfram Language code: ArcTan[1]

Wolfram Language code: ArcTanDegrees[1]

ArcTanはいくつかの特殊関数の特別な場合である：

Wolfram Language code: x Hypergeometric2F1[1 / 2, 1, 3 / 2, -x ^ 2]

Reduceを使ってArcTanを含む不等式を解く：

Wolfram Language code: Reduce[ArcTan[x] > Pi / 3, x]

考えられる問題 (1)

ArcTanは多価関数であるので，である：

Wolfram Language code: ArcTan[Tan[4.]]

次はもとの引数と倍分異なる：

Wolfram Language code: (% - 4) / Pi

おもしろい例題 (1)

分岐点付近での展開：

Wolfram Language code: Series[ArcTan[x], {x, I, 3}]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ArcTan

詳細

予備知識

例題

例 (7)

スコープ (49)

数値評価 (6)

特定の値 (6)

可視化 (4)

関数の特性 (12)

微分 (3)

積分 (3)

級数展開 (4)

積分変換 (3)

関数の恒等式と簡約 (3)

関数表現 (5)

アプリケーション (9)

特性と関係 (5)

考えられる問題 (1)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

ArcTan

詳細

予備知識

例題

例 (7)

スコープ (49)

数値評価 (6)

特定の値 (6)

可視化 (4)

関数の特性 (12)

微分 (3)

積分 (3)

級数展開 (4)

積分変換 (3)

関数の恒等式と簡約 (3)

関数表現 (5)

アプリケーション (9)

特性と関係 (5)

考えられる問題 (1)

おもしろい例題 (1)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX