Wolfram言語＆システムドキュメントセンター

AudioGenerator

AudioGenerator[model]

指定された model の1秒の音声を生成する．

AudioGenerator[model,t]

t 秒の音声を生成する．

AudioGenerator[model,t,"type"]

指定された"type"の音声サンプルを生成する．

詳細とオプション

AudioGeneratorは，振動子やノイズを含む異なるタイプの音声を生成することができる．
model の使用可能な設定

	f	時間の任意の関数 f のサンプルを秒単位で取る
	proc	ランダム過程 proc からサンプルを生成する
	tseries	TimeSeries tseries からサンプルを生成する
	"model"	名前付きの関数"model"からサンプルを生成する

無音
"Silence" 無音(0)信号
振動子

		{"Sin",freq,phase}	正弦波
		{"Triangle",freq,phase}	三角波
		{"Sawtooth",freq,phase}	鋸波
		{"Square",freq,phase}	方形波
		{"Pulse",freq,phase,width}	デューティサイクル width を使った矩形波
		{"Impulse",freq,phase}	インパルス信号

デフォルトで，，，が使われる．
パラメータの freq，phase，width は，スカラー値，Quantity，Audioオブジェクト，TimeSeriesあるいは純関数でよい．
注

		"White"	一定のパワースペクトル密度
		"Pink"	に従うパワースペクトル密度
		"Brown"	に従うパワースペクトル密度
		"Blue"	に従うパワースペクトル密度
		{"Color",α}	に従うパワースペクトル密度．ただし，
		{"White",dist}	dist から値のサンプルを取ったランダムノイズ
		"PeriodicRandomNoise"	振幅が一定でランダム位相の正弦波成分の和

その他
AudioGeneratorは，"Real32"タイプの音声オブジェクトを生成する．"type"の可能な設定についてはAudioの関数ページを参照のこと．
AudioGeneratorにはAudioと同じオプションが使える．

全オプションのリスト

Appearance	Automatic	生成されたプレーヤーの外観
AnnotationRules	None	名前付き注釈のリスト
AudioChannelAssignment	Automatic	出力にどのように音声チャンネルを割り当てるか
AudioOutputDevice	$DefaultAudioOutputDevice	再生に使用する音声出力デバイス
AudioLabel	Automatic	音声オブジェクトに表示するラベル
MetaInformation		音声と関連付けられたメタ情報
SampleRate	Automatic	サンプリングレート
SoundVolume	1	音量

例題

すべて開くすべて閉じる

例 (3)

1秒の正弦波の音声を生成する：

Wolfram Language code: AudioGenerator["Sin"]

任意の関数から信号を生成する：

Wolfram Language code: AudioGenerator[Sin[800 # ^ 2 ]&, 3]

ホワイトノイズを2秒間生成する：

Wolfram Language code: AudioGenerator["White", 2]

スコープ (17)

基本的な用法 (2)

デフォルトで，1秒の音声が生成される：

Wolfram Language code: AudioGenerator["Sin"]//Duration

持続時間を指定する：

Wolfram Language code: AudioGenerator["Sin", 5]//Duration

持続時間を時間の量として指定する：

Wolfram Language code: AudioGenerator["Sin", Quantity[100, "ms"]]//Duration

生成するサンプル数を指定する：

Wolfram Language code: AudioGenerator["Sin", Quantity[4410, "samples"]]//Duration

デフォルトで，生成される音声は"Real32"タイプである：

Wolfram Language code: AudioGenerator["Sin", 1]//AudioType

別のデータ型を指定する：

Wolfram Language code: AudioGenerator["Sin", 5, "SignedInteger8"]//AudioType

モデル指定 (15)

振動子 (5)

2000Hzの正弦波の振動：

Wolfram Language code: AudioGenerator[{"Sin", Quantity[2000, "Hertz"]}]

関数を使って正弦波の周波数を制御する：

Wolfram Language code: AudioGenerator[{"Sin", 1000 + 1000Sin[2 * Pi#]&}]

スペクトログラムを可視化する：

Wolfram Language code: Spectrogram[%, PlotRange -> {All, {0, 3000}}]

正弦波の周波数を別のAudioオブジェクトで制御する：

Wolfram Language code:

freqMod = Import["ExampleData/rule30.wav"];
AudioGenerator[{"Sin", 440 + 2000 * freqMod}]

生成された音声のスペクトログラムを可視化する：

Wolfram Language code: Spectrogram[%, PlotRange -> {All, {0, 2000}}]

TimeSeriesで正弦波の周波数を制御する：

Wolfram Language code:

frequencies = {378, 366, 287, 482, 595, 522, 227, 412, 481, 390};
times = {0.2, 0.5, 0.7, 1.1, 1.4, 1.7, 1.9, 2., 2.4, 2.7};
freqMod = TimeSeries[frequencies, {times}]

Wolfram Language code: AudioGenerator[{"Sin", freqMod}]

別の振動子を生成する：

Wolfram Language code: waveforms = {"Sin", "Triangle", "Sawtooth", "Square", "Pulse", "Impulse"};

Wolfram Language code:

Table[AudioPlot[AudioGenerator[i, .01], PlotTheme -> "Minimal", PlotLabel -> i], 
	{i, waveforms}]//Multicolumn

雑音生成器 (5)

ホワイトノイズを生成する：

Wolfram Language code: AudioGenerator["White"]

ホワイトノイズの値は分布からサンプルすることができる：

Wolfram Language code: Histogram@AudioData@AudioGenerator[{"White", NormalDistribution[]}]

別の種類のノイズを生成する：

Wolfram Language code: noises = {"White", "Pink", "Brown", "Blue", {"Color", 1.5}, "PeriodicRandomNoise"};

Wolfram Language code: Table[AudioPlot[AudioGenerator[i, .01], PlotLabel -> i, PlotTheme -> "Minimal"], {i, noises}]//Multicolumn

ピンク，茶色，青の各ノイズのスペクトルは，α がそれぞれ1，2，である f^-αの分布に従う：

Wolfram Language code:

colors = {"Pink", "Brown", "Blue"};
Periodogram[AudioGenerator /@ colors, 4000, ScalingFunctions -> {"Log10", Automatic}, PlotRange -> {-50, 25}, PlotLegends -> colors, PlotStyle -> {RGBColor[1, 0.5, 0.5], RGBColor[0.772079, 0.431554, 0.102387], RGBColor[0.368417, 0.506779, 0.709798]}]

"PeriodicRandomNoise"のスペクトルは完全に平らである：

Wolfram Language code: Periodogram[AudioGenerator["PeriodicRandomNoise"]]

関数を使う (1)

AudioGeneratorは時間の関数をサポートする：

Wolfram Language code:

f[x_] := Sin[440 2Pi x];
AudioGenerator[f, 2]

過程を使う (2)

ノイズ過程から音声オブジェクトを生成する：

Wolfram Language code: AudioGenerator[FractionalGaussianNoiseProcess[.2]]//AudioNormalize

ランダム過程から生成された音声を使って正弦波の振幅を制御する：

Wolfram Language code: telegraph = AudioGenerator[TelegraphProcess[4], 4];

Wolfram Language code: (1 + telegraph) * \!$\*AudioBox["![Embedded Audio Player](audio://content-ifz6q)"]$

時系列を使う (2)

TimeSeriesから音声オブジェクトを生成する：

Wolfram Language code: AudioGenerator[TimeSeries[Range[10] / 10.]]//AudioPlot

不規則なTimeSeriesから音声オブジェクトを生成する：

Wolfram Language code:

amplitudes = AudioGenerator[TimeSeries[{{0, 1}, {1, 0}, {1.5, .3}, {3, 0}}]];
amplitudes * AudioGenerator["Sin", 3]

Wolfram Language code: AudioPlot@%

オプション (1)

SampleRate (1)

デフォルトで，SampleRate->44100が使われる：

Wolfram Language code: AudioGenerator["Sin"]//AudioSampleRate

別のサンプルレートを指定する：

Wolfram Language code: AudioGenerator["Sin", SampleRate -> 1000]//AudioSampleRate

アプリケーション (8)

ノイズの適用 (2)

音声オブジェクトにノイズを加える：

Wolfram Language code: a = ExampleData[{"Audio", "Cello"}, "Audio"];

Wolfram Language code: noisy = .5a + .03AudioGenerator["White", Duration[a]]

"PeriodicRandomNoise"を使って線形系の周波数応答をテストする：

Wolfram Language code: Periodogram[LowpassFilter[AudioGenerator["PeriodicRandomNoise", .1], 2 Pi 10000]]

時間データからの音声生成 (2)

2社の株価の動向を比較する：

Wolfram Language code:

msft = TimeSeriesRescale[TimeSeries@FinancialData["MSFT", {"Jan. 1, 1990", "Jan. 1, 2018"}], {0, 10}];
aapl = TimeSeriesRescale[TimeSeries@FinancialData["AAPL", {"Jan. 1, 1990", "Jan. 1, 2018"}], {0, 10}];

データをリサンプルし，平滑化する：

Wolfram Language code:

resampledMSFT = QuantityMagnitude@TimeSeriesResample[Round[MovingAverage[msft, 60]], 1 / 8];
resampledAAPL = QuantityMagnitude@TimeSeriesResample[Round[MovingAverage[aapl, 60]], 1 / 8];
ListLinePlot[{resampledMSFT, resampledAAPL}, PlotStyle -> {Automatic, Automatic, PointSize[Large]}, PlotLegends -> {"MSFT", "AAPL"}]

Wolfram Language code: midiToFreq[m_] := 2 ^ ((m - 69) / 12) * 440.;

2つの時系列で制御される音声を生成する：

Wolfram Language code:

res = .8Mean[{AudioGenerator[{"Sin", midiToFreq[.5resampledMSFT + 40]}], AudioGenerator[{"Triangle", midiToFreq[.5resampledAAPL + 40]}]}]

TimeSeriesのリストを使って調和正弦波のリストの振幅を制御する：

Wolfram Language code: duration = 5;

Wolfram Language code: sineBank = Table[AudioGenerator[{"Sin", Quantity[100, "Hertz"] * i, 0}, duration], {i, 10}];

Wolfram Language code:

amplitudes = Table[AudioGenerator[TimeSeries[RandomInteger[{0, 1}, 40], {RandomReal[{0, duration}, 40]}], duration, SampleRate -> 200], 10];

Wolfram Language code: Mean[amplitudes * sineBank]

Wolfram Language code: AudioPlot@%

多周波数の生成 (3)

一連のマルチ周波数(DTMF)トーンを生成して電話番号のダイアル音のシミュレーションを行う：

Wolfram Language code:

keys = {1 -> {697, 1209}, 2 -> {697, 1336}, 3 -> {697, 1477}, 4 -> {770, 1209}, 5 -> {770, 1336}, 6 -> {770, 1477}, 7 -> {852, 1209}, 8 -> {852, 1336}, 9 -> {852, 1477}, 0 -> {941, 1336}};

Wolfram Language code:

dtmf[str_String] := AudioJoin[Table[{Mean[AudioGenerator[{"Sin", #}, Quantity[200, "Milliseconds"]]& /@ (key /. keys)], Quantity[50, "Milliseconds"]}, {key, ToExpression /@ Characters[str]}]]

Wolfram Language code: phoneNumber = "6345789";

Wolfram Language code: dtmf[phoneNumber]

数値キーパッドを作る：

Wolfram Language code:

Grid[Partition[MapIndexed[Labeled[Audio[Mean[AudioGenerator[{"Sin", #}, .1]& /@ #], Appearance -> "Minimal"], First@#2]&, Flatten[Outer[List, {697, 770, 852}, {1209, 1336, 1477}], 1]], 3]]

聴覚の錯覚を作る：

Wolfram Language code:

range = 12;
duration = 20;
lfoFreq = .05;
basePitch = 30;
numOsc = 8;
midiToFreq[m_] := 2 ^ ((m - 69) / 12) * 440.

傾斜を生成して振動子の周波数と振幅を制御する：

Wolfram Language code:

phasors = Table[AudioGenerator[{"Sawtooth", lfoFreq, 2.Pi / numOsc(i - 1.)}, duration, SampleRate -> 500] / 2. + .5, {i, numOsc}];
AudioPlot[phasors, PlotLayout -> "Overlaid", PlotRange -> All]

振動子を制御する周波数を作る．音の高さが線形に増加するように，周波数はそれぞれを厳密に1オクターブ離して指数的に増加させる：

Wolfram Language code:

freqs = Table[midiToFreq[(phasors[[i]]) * 12 * numOsc + basePitch], {i, numOsc}];
AudioPlot[freqs, PlotLayout -> "Overlaid", PlotRange -> All]

振動子を制御する振幅を作る．周波数が最小値になると振幅は0になる：

Wolfram Language code:

amps = Cos[# * Pi - Pi / 2.]& /@ phasors;
AudioPlot[amps, PlotLayout -> "Overlaid", PlotRange -> All]

1つの振動子の周波数と振幅の関係を示す：

Wolfram Language code: AudioPlot[AudioNormalize /@ {freqs[[2]], amps[[2]]}, PlotRange -> All]

作成された周波数と振幅を使って一群の振動子を組み合せる：

Wolfram Language code:

res = Mean[
	Table[amps[[i]]AudioGenerator[{"Sin",   freqs[[i]]}, SampleRate -> 24000], {i, numOsc}]]

Wolfram Language code: Spectrogram[res, 8192, 4096, HannWindow]

周波数と振幅の変調 (1)

AM信号の生成と再構築：

Wolfram Language code: a = \!$\*AudioBox["![Embedded Audio Player](audio://content-eufg8)"]$;

Wolfram Language code: Periodogram[a, 2000, PlotRange -> {{0, 10000}, All}]

22050Hzの正弦曲線で振幅を変調し，コンテンツをスペクトルのハイエンドにシフトする．結果はすでにほとんどの人には聞こえない：

Wolfram Language code: amsignal = a×AudioGenerator[{"Sin", Quantity[22050, "Hertz"]}, Duration@a, SampleRate -> 96000]

Wolfram Language code: Periodogram[amsignal, 2200]

22050Hzで等しい位相の別の正弦曲線でAM振動の変調をもとに戻す：

Wolfram Language code:

result = LowpassFilter[amsignal * AudioGenerator[{"Sin", Quantity[22050, "Hertz"]}, Duration@amsignal, SampleRate -> 96000], Quantity[5000, "Hertz"], 201]

考えられる問題 (2)

振動子があると，周波数はサンプルレートの半分以下になる：

Wolfram Language code: AudioGenerator[{"Sin", 5001}, SampleRate -> 10000]

TimeSeriesは，入力として使用される場合は，非負の数値によるタイムスタンプを必要とする：

Wolfram Language code: ts = TimeSeries[FinancialData["GE", {"Jan. 1, 2015", "Jan. 1, 2016"}]]

Wolfram Language code: AudioGenerator[{"Sin", ts}]//Head

TimeSeriesは，単一のスカラー値の経路を必要とする：

Wolfram Language code: ts = TimeSeries[{{0, {600, 300}}, {1, {400, 300}}}]

Wolfram Language code: AudioGenerator[{"Sin", ts}]//Head

インタラクティブな例題 (3)

振動子の周波数と位相を制御する：

Wolfram Language code:

Manipulate[
	AudioPlot[
	AudioGenerator[{"Sin", freq, phase}, .1]
	], {freq, 10, 100}, {phase, 0, 10}, ContinuousAction -> False]

AudioGenerator[{"Color",α}]のスペクトルは f^-αの分布に従う：

Wolfram Language code:

Manipulate[
	Periodogram[AudioGenerator[{"Color", α}], 2000, ScalingFunctions -> {"Log10", Automatic}, PlotRange -> {-60, 30}], {α, -2, 2}, ContinuousAction -> False]

周波数の変調を使って複雑な音声信号を作成する：

Wolfram Language code:

Manipulate[
	Periodogram[
	AudioGenerator[{"Sin", freq + freqModAmount * modFreq * AudioGenerator[{"Sin", modFreq}]}], 
	ScalingFunctions -> "Absolute", PlotRange -> {{0, 1000}, All}, ImageSize -> Medium], 
	{{freq, 440, "Carrier Frequency"}, -500, 500}, 
	{{modFreq, 100, "Modulation Frequency"}, -200, 200}, 
	{{freqModAmount, 0, "Amount of Frequency Modulation"}, 0, 10}, 
	ControlPlacement -> Top, ContinuousAction -> False
	]

おもしろい例題 (4)

変調信号の周波数をスイープする：

Wolfram Language code: AudioGenerator[{"Sin", 400 + 300 * AudioGenerator[{"Sin", 100 * #&}, 4]}, SampleRate -> 8000]

24を底とするPiの各桁を使って正弦波振動子の一連の周波数を生成する：

Wolfram Language code: digits = First@RealDigits[π, 24, 100]

Wolfram Language code:

midiToFreq[m_] := 2 ^ ((m - 69) / 12) * 440.
AudioGenerator[{"Sin", TimeSeries[midiToFreq[50 + digits], {0, 10}]}, SampleRate -> 8000]

DiscreteMarkovProcessを使って旋律を作る：

Wolfram Language code:

𝒫 = DiscreteMarkovProcess[12, (⁠|          |         |          |         |          |          |         |          |         |          |         |          |
| -------- | ------- | -------- | ------- | -------- | -------- | ------- | -------- | ------- | -------- | ------- | -------- |
| (7/153)  | 0       | (31/153) | (2/153) | (23/153) | (2/51)   | (8/153) | (1/9)    | (1/153) | (25/153) | (5/153) | (28/153) |
| 0        | 0       | (1/3)    | 0       | 0        | 0        | 0       | (1/2)    | 0       | (1/6)    | 0       | 0        |
| (31/111) | 0       | 0        | 0       | (29/111) | (2/37)   | (1/37)  | (8/111)  | 0       | (11/111) | (1/37)  | (20/111) |
| (1/4)    | 0       | (1/12)   | (1/6)   | 0        | 0        | 0       | (1/4)    | 0       | (1/4)    | 0       | 0        |
| (25/128) | (1/128) | (27/128) | 0       | (3/128)  | (23/128) | (5/128) | (21/128) | (1/128) | (5/64)   | (5/128) | (7/128)  |
| (4/113)  | 0       | (19/113) | 0       | (23/113) | 0        | 0       | (35/113) | 0       | (13/113) | 0       | (19/113) |
| (7/29)   | 0       | (2/29)   | (1/29)  | (5/29)   | 0        | 0       | (7/29)   | (2/29)  | (1/29)   | 0       | (4/29)   |
| (15/166) | (3/166) | (2/83)   | (2/83)  | (27/166) | (37/166) | (7/166) | (19/166) | 0       | (15/83)  | (1/166) | (19/166) |
| 0        | 0       | 0        | 0       | (1/14)   | 0        | (1/7)   | (1/14)   | 0       | (1/2)    | 0       | (3/14)   |
| (5/32)   | 0       | (1/16)   | (3/128) | (3/64)   | (11/64)  | (1/128) | (29/128) | (3/64)  | 0        | (1/64)  | (31/128) |
| (5/16)   | 0       | (1/16)   | 0       | (5/16)   | 0        | 0       | (1/8)    | 0       | (3/16)   | 0       | 0        |
| (36/131) | (2/131) | (16/131) | 0       | (6/131)  | (19/131) | (3/131) | (21/131) | (4/131) | (24/131) | 0       | 0        |⁠)];

Wolfram Language code:

midiToFreq[m_] := 2 ^ ((m - 69) / 12) * 440.;AudioGenerator[{"Sin", midiToFreq[59 + TimeSeriesRescale[RandomFunction[𝒫, {0, 50}], {0, 6}]]}, SampleRate -> 8000]

モールス(Morse)信号を使って音声を生成する：

Wolfram Language code:

code = <|"a" -> ".-", "b" -> "-...", "c" -> "-.-.", "d" -> "-..", "e" -> ".", "f" -> "..-.", "g" -> "--.", "h" -> "....", "i" -> "..", "j" -> ".---", "k" -> "-.-", "l" -> ".-..", "m" -> "--", "n" -> "-.", "o" -> "---", "p" -> ".--.", "q" -> "--.-", "r" -> ".-.", "s" -> "...", "t" -> "-", "u" -> "..-", "v" -> "...-", "w" -> ".--", "x" -> "-..-", "y" -> "-.--", "z" -> "--..", "1" -> ".----", "2" -> "..---", "3" -> "...--", "4" -> "....-", "5" -> ".....", "6" -> "-....", "7" -> "--...", "8" -> "---..", "9" -> "----.", "0" -> "-----", "." -> ".-.-.-", "," -> "--..--", "!" -> "-.-.--", "?" -> "..--.."|>;
withgaps = Map[StringRiffle[Characters[#], "_"]&, code];
withpauses = Map[StringInsert[#, "___", -1]&, withgaps];
withspace = AssociateTo[withpauses, " " -> "_______"];
replacements = Map[StringReplace[#, {"-" -> "111", "." -> "1", "_" -> "0"}]&, withspace];

辞書を使ってメッセージを音声信号に翻訳する関数を作成する：

Wolfram Language code:

createMorseSignal[s_String, t_] := Module[{events = Characters[StringReplace[ToLowerCase[s], Normal@replacements]], ts, amps}, 
	ts = TimeSeries[ToExpression@events, {0, (Length[events] - 1) * t, t}];
	amps = AudioGenerator[ts, SampleRate -> 1000];AudioGenerator[{"Sin", 800}, Duration@amps, SampleRate -> 8000]amps
	]

文字列を音声信号に符号化する：

Wolfram Language code: morse = createMorseSignal["hello world", .05]

Wolfram Language code: AudioPlot@%

Top

AudioGenerator

詳細とオプション

全オプションのリスト

例題

例 (3)

スコープ (17)

基本的な用法 (2)

モデル指定 (15)

振動子 (5)

雑音生成器 (5)

関数を使う (1)

過程を使う (2)

時系列を使う (2)

オプション (1)

SampleRate (1)

アプリケーション (8)

ノイズの適用 (2)

時間データからの音声生成 (2)

多周波数の生成 (3)

周波数と振幅の変調 (1)

考えられる問題 (2)

インタラクティブな例題 (3)

おもしろい例題 (4)

関連項目

テクニカルノート

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX