WOLFRAM

Wolfram 语言与系统参考资料中心

BSplineCurve[{p1,p2,…}]

表示控制点为 pi 的非均匀有理 B 样条曲线.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
指定  
图形  
区域  
选项  
SplineDegree  
SplineKnots  
SplineWeights  
SplineClosed  
属性和关系  
参见
相关指南
历史
按以下格式引用：

BSplineCurve

BSplineCurve[{p1,p2,…}]

表示控制点为 pi 的非均匀有理 B 样条曲线.

更多信息和选项

  • BSplineCurve 也被称为基样条曲线或者非均匀有理 B 样条 (NURBS) 曲线.
  • BSplineCurve 通常用于插值、计算机图形和 CAD 建模.
  • 控制点 pi 是诸如 {x,y} 或 {x,y,z} 这样的普通坐标.
  • BSplineCurve 既可用作几何区域，也可用作图形基元.
  • 在图形中，点 pi 可以是 Scaled、Offset、ImageScaled 和 Dynamic 表达式.
  • 图形渲染受诸如 Thickness、Dashing、JoinForm、CapForm 以及颜色等指令的影响.
  • 可以给出下列选项：
  • SplineDegree Automatic多项式基的次数
    SplineKnots Automatic样条曲线的节点序列
    SplineWeights Automatic控制点的权重
    SplineClosed False是否使样条曲线闭合
  • 默认情况下，BSplineCurve 使用三次样条曲线.
  • 选项 SplineDegree->d 指定底层多项式基的最大次数为 d.
  • 默认情况下，在参数空间内均匀选择节点，并增加其它节点，使得曲线从第一个控制点开始，到最后一个控制点结束.
  • 显式设置 SplineKnots 时，多项式基的次数由指定节点的数目和控制点的数目确定.
  • 在缺省设置 SplineWeights->Automatic 下，所有控制点有相等的权重，相当于一个多项式 B 样条曲线.

范例

打开所有单元 关闭所有单元

基本范例  (2)

二维空间中一个 B 样条曲线和它的控制点：

Wolfram Language code: pts = {{0, 0}, {1, 1}, {2, -1}, {3, 0}, {4, -2}, {5, 1}};
Wolfram Language code: Graphics[{BSplineCurve[pts], Dashed, Gray, Line[pts], Red, Point[pts]}]

三维空间中一个 B 样条曲线和它的控制点：

Wolfram Language code: pts = {{0, 0, 0}, {1, 1, 1}, {2, -1, 1}, {3, 0, 2}, {4, 1, 1}};
Wolfram Language code: Graphics3D[{BSplineCurve[pts], Dashed, Gray, Line[pts], Red, Point[pts]}]

弧长和界限：

Wolfram Language code: reg = BSplineCurve[{{0, 0}, {1, 1}, {2, -1}}];
Wolfram Language code: ArcLength[reg]
Wolfram Language code: RegionBounds[reg]

范围  (25)

基本用法  (3)

模拟线性曲线：

Wolfram Language code: Graphics[BSplineCurve[{{0, 0}, {2, 1}}]]

非线性曲线：

Wolfram Language code: Graphics[BSplineCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]]

模拟开放曲线：

Wolfram Language code: Graphics[BSplineCurve[CirclePoints[4]]]

闭合曲线：

Wolfram Language code: Graphics[BSplineCurve[CirclePoints[4], SplineClosed -> True]]

摘要框：

Wolfram Language code: BSplineCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]

指定  (4)

二次 B 样条曲线需要三个控制点：

Wolfram Language code: Graphics[BSplineCurve[{{-1, 0}, {0, 2}, {1, 0}}]]
Wolfram Language code: Graphics3D[BSplineCurve[{{-1, 0, 0}, {0, 2, 1}, {1, 0, 0}}]]

三次 B 样条曲线需要四个控制点：

Wolfram Language code: Graphics[BSplineCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]]
Wolfram Language code: Graphics3D[BSplineCurve[{{-3, -1, 0}, {6, 5, 5}, {-6, -5, -5}, {3, 1, 0}}]]

通常，一个次数为 d 的 B 样条曲线至少需要 (d+1) 个控制点：

Wolfram Language code: pts = {{0, 0}, {(1/3), (Sqrt[3]/2)}, {(2/3), (Sqrt[3]/2)}, {1, 0}, {(4/3), (Sqrt[3]/2)}, {(5/3), (Sqrt[3]/2)}, {2, 0}};
Wolfram Language code: deg = Length[pts] - 1;
Wolfram Language code: BSplineCurve[pts, SplineDegree -> deg]
Wolfram Language code: Graphics[%]

控制点越少，生成的曲线次数越低：

Wolfram Language code: BSplineCurve[Take[pts, 4], SplineDegree -> deg]
Wolfram Language code: Graphics[%]

开放的 B 样条曲线：

Wolfram Language code: Graphics[{BSplineCurve[CirclePoints[3]]}]

闭合的：

Wolfram Language code: Graphics[{BSplineCurve[CirclePoints[3], SplineClosed -> True]}]

可通过指定节点来控制曲线的平滑度：

Wolfram Language code: pts = {{0, 0}, {0, 4}, {2, 6}, {4, 0}, {6, 6}, {8, 4}, {8, 0}};
Wolfram Language code: Table[Graphics[BSplineCurve[pts, SplineKnots -> knots]], {knots, {Automatic, {0, 0, 0, 0, 1, 1, 1, 2, 2, 2, 2}}}]

图形  (12)

彩色的曲线：

Wolfram Language code: Table[Graphics[{c, BSplineCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]}], {c, {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}}]

不同粗细的 B 样条曲线：

Wolfram Language code: Table[Graphics[{Thickness[i], BSplineCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{t, BSplineCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]}], {t, {Thin, Thick}}]

相对于 PlotRange 缩放的粗细：

Wolfram Language code: Table[Graphics[{Thickness[i], BSplineCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]}], {i, {.005, .05, .1}}]

以打印阵点表示的粗细：

Wolfram Language code: Table[Graphics[{AbsoluteThickness[i], BSplineCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]}], {i, {1, 5, 10}}]

虚线：

Wolfram Language code: Table[Graphics[{Dashing[i], BSplineCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{d, BSplineCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]}], {d, {Dotted, Dashed, DotDashed}}]

Opacity 指定曲线的透明度：

Wolfram Language code: Table[Graphics[{Opacity[o], BSplineCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]}], {o, {0.1, 0.5, 0.9}}]

在用作 FilledCurve 的边界时，可通过 EdgeForm 指定曲线的样式：

Wolfram Language code: Graphics[{EdgeForm[{StandardBlue, Thick}], Opacity[0.1], FilledCurve[BSplineCurve[CirclePoints[4]]]}]

BSplineCurve 可用作二维图形中 Arrow 的曲线：

Wolfram Language code: Graphics[{Arrowheads[Large], Arrow[BSplineCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]]}]

3D：

Wolfram Language code: Graphics3D[{Arrowheads[Large], Arrow[BSplineCurve[{{-3, -1, 0}, {6, 5, 5}, {-6, -5, -5}, {3, 1, 0}}]]}, Rule[...]]

在三维空间中，BSplineCurve 可用作 Tube 的曲线：

Wolfram Language code: Graphics3D[{Tube[BSplineCurve[{{-3, -1, 0}, {6, 5, 5}, {-6, -5, -5}, {3, 1, 0}}], 0.1]}]

带有 Arrow 的 Tube：

Wolfram Language code: Graphics3D[{Arrowheads[0.2], Arrow[Tube[BSplineCurve[{{-3, -1, 0}, {6, 5, 5}, {-6, -5, -5}, {3, 1, 0}}], 0.1]]}]

BSplineCurve 可用在 GraphicsComplex 中：

Wolfram Language code: Graphics[{GraphicsComplex[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}, BSplineCurve[{1, 2, 3, 4}]]}]

默认情况下，控制点被假定为在世界坐标系中：

Wolfram Language code: pts = {{0, 0}, {(1/4), 1}, {(3/4), 1}, {1, 0}};
Wolfram Language code: Table[Graphics[{BSplineCurve[pts]}, Frame -> True, PlotRange -> {{0, pr}, {0, pr}}], {pr, {1, 2, 4}}]

用 Scaled 来指定相对于 PlotRange 的控制点：

Wolfram Language code: Table[Graphics[{BSplineCurve[Map[Scaled, pts]]}, Frame -> True, PlotRange -> {{0, pr}, {0, pr}}], {pr, {4, 8, 16}}]

用 ImageScaled 来指定相对于整个二维图像区域的控制点：

Wolfram Language code: Table[Graphics[{BSplineCurve[Map[ImageScaled, pts]]}, Frame -> True, PlotRange -> {{0, pr}, {0, pr}}], {pr, {4, 8, 16}}]

用 Offset 设置二维控制点的绝对偏移量：

Wolfram Language code: pts = {{0, 0}, {(1/4), 1}, {(3/4), 1}, {1, 0}};
Wolfram Language code: offsets = {{-80, 0}, {0, 0}, {80, 0}};
Wolfram Language code: Graphics[{Table[BSplineCurve[Map[Offset[offset, #]&, pts]], {offset, offsets}]}, PlotRange -> {{-1.4, 2.4}, {-0.1, 1}}, ImageSize -> 250]

控制点可以是 Dynamic：

Wolfram Language code: DynamicModule[{z = 0, pts}, pts = {{Dynamic[{0, z}], {1, 2}, {3, 2}, {4, 0}}}; {Slider[Dynamic[z], {0, 4}], Graphics[{BSplineCurve[pts]}]}]

区域  (6)

嵌入维度：

Wolfram Language code: RegionEmbeddingDimension[BSplineCurve[{{Subscript[c, 1], Subscript[c, 2]}, {Subscript[c, 3], Subscript[c, 4]}, {Subscript[c, 5], Subscript[c, 6]}}]]

几何维度：

Wolfram Language code: RegionDimension[BSplineCurve[{{Subscript[c, 1], Subscript[c, 2]}, {Subscript[c, 3], Subscript[c, 4]}, {Subscript[c, 5], Subscript[c, 6]}}]]

点成员测试：

Wolfram Language code: reg = BSplineCurve[{{0, 0}, {1, 2}, {3, 2}, {4, 0}}];
Wolfram Language code: {RegionMember[reg, {0, 0}], RegionMember[reg, {0, 1}]}

弧长：

Wolfram Language code: reg = BSplineCurve[{{0, 0}, {1, 2}, {2, 0}}];
Wolfram Language code: {ArcLength[reg], RegionMeasure[reg]}

形心：

Wolfram Language code: c = RegionCentroid[reg]
Wolfram Language code: Show[Region[reg], Graphics[{LightDarkSwitched[Black, White], Point[c]}]]

与点的距离：

Wolfram Language code: reg = BSplineCurve[{{-1, -1}, {0, 1}, {1, -1}}];
Wolfram Language code: {RegionDistance[reg, {-1, -1}], RegionDistance[reg, {2, 2}]}

可视化等距线：

Wolfram Language code: Show[Region[reg], ContourPlot[Evaluate@RegionDistance[reg, {x, y}], {x, -4, 4}, {y, -4, 3}, Contours -> {1, 2, 3}, ...], Frame -> True]

到点的有符号距离：

Wolfram Language code: reg = BSplineCurve[{{-1, -1}, {0, 1}, {1, -1}}];
Wolfram Language code: {SignedRegionDistance[reg, {-1, -1}], SignedRegionDistance[reg, {2, 2}]}

贝塞尔曲线是有界的：

Wolfram Language code: reg = BSplineCurve[{{-1, -1}, {0, 1}, {1, -1}}];
Wolfram Language code: BoundedRegionQ[reg]

计算其边界：

Wolfram Language code: bb = CoordinateBoundingBox[reg]
Wolfram Language code: Show[Region[reg], Graphics[{Opacity[0.1], EdgeForm[Dashed], Cuboid@@bb}]]

选项  (7)

SplineDegree  (1)

默认情况下，一个具有 4 个或更多控制点的 BSplineCurve 将使用 3 次曲线：

Wolfram Language code: pts = Table[{i, (-1) ^ i}, {i, 10}];
Wolfram Language code: {BSplineCurve[Take[pts, 4]], BSplineCurve[Take[pts, 10]]}

控制点较少时，会使用较低的次数：

Wolfram Language code: {BSplineCurve[Take[pts, 2]], BSplineCurve[Take[pts, 3]]}

用 SplineDegree 指定应使用较低的次数：

Wolfram Language code: BSplineCurve[pts, SplineDegree -> 1]

更高的次数：

Wolfram Language code: BSplineCurve[pts, SplineDegree -> 9]

SplineKnots  (4)

在缺省情况下，以确保曲线整体平滑的方式产生节点：

Wolfram Language code: pts = {{0, 0}, {0, 2}, {2, 3}, {4, 0}, {6, 3}, {8, 2}, {8, 0}};
Wolfram Language code: Graphics[{BSplineCurve[pts, SplineKnots -> Automatic], Dashed, Gray, Line[pts], Red, Point[pts]}]

通过重复节点，可以引入切向不连续性：

Wolfram Language code: knots = {0, 0, 0, 0, 1, 1, 1, 2, 2, 2, 2};
Wolfram Language code: Graphics[{BSplineCurve[pts, SplineKnots -> knots], Dashed, Gray, Line[pts], Red, Point[pts]}]

"Clamped" 生成的节点使得曲线能够对第一个和最后一个控制点进行插值：

Wolfram Language code: pts = {{0, 0}, {0, 2}, {2, 3}, {4, 0}, {6, 3}, {8, 2}, {8, 0}};
Wolfram Language code: Graphics[{BSplineCurve[pts, SplineKnots -> "Clamped"], Dashed, Gray, Line[pts], Red, Point[pts]}]

对于一条 d 次曲线，这对应于第一个和最后一个节点值被重复 d+1 次：

Wolfram Language code: knots = {0, 0, 0, 0, 1, 2, 3, 4, 4, 4, 4};
Wolfram Language code: Graphics[{BSplineCurve[pts, SplineKnots -> knots], Dashed, Gray, Line[pts], Red, Point[pts]}]

"Unclamped" 生成均匀节点，使得曲线不对端点进行插值：

Wolfram Language code: pts = {{0, 0}, {0, 2}, {2, 3}, {4, 0}, {6, 3}, {8, 2}, {8, 0}};
Wolfram Language code: Graphics[{BSplineCurve[pts, SplineKnots -> "Unclamped"], Dashed, Gray, Line[pts], Red, Point[pts]}]

对于一条具有 n 个控制点的 d 次曲线，这对应于一个长度为 n+d+1 的连续序列：

Wolfram Language code: knots = {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11};
Wolfram Language code: Graphics[{BSplineCurve[pts, SplineKnots -> knots], Dashed, Gray, Line[pts], Red, Point[pts]}]

与 SplineClosed 组合的非限定节点将产生一个均匀的周期性 B 样条曲线：

Wolfram Language code: pts = {{0, 0}, {1, 0}, {1, 1}, {0, 1}};
Wolfram Language code: Graphics[{BSplineCurve[pts, SplineClosed -> True, SplineKnots -> "Unclamped"], Dashed, Gray, Line[Append[pts, pts[[1]]]], Red, Point[pts]}]

SplineWeights  (1)

在缺省情况下，所有控制点有相等的权重：

Wolfram Language code: pts = {{0, 0}, {1, 1}, {2, -1}, {3, 0}};
Wolfram Language code: Graphics[{BSplineCurve[pts, SplineWeights -> #], Dashed, Gray, Line[pts], Red, Point[pts]}]& /@ {Automatic, {1, 1, 1, 1}}

对一个控制点给出更多的权，曲线将被该点所吸引：

Wolfram Language code: Graphics[{BSplineCurve[pts, SplineWeights -> #], Dashed, Gray, Line[pts], Red, Point[pts]}]& /@ {{1, 0, 0, 1}, {1, 20, 20, 1}}

SplineClosed  (1)

默认情况下，曲线是开放的：

Wolfram Language code: pts = {{0, -(1/2)}, {(Sqrt[3]/2), -(1/2)}, {(Sqrt[3]/2), (1/2)}, {0, (1/2)}, {-(Sqrt[3]/2), (1/2)}, {-(Sqrt[3]/2), -(1/2)}};
Wolfram Language code: Graphics[{BSplineCurve[pts]}]

用 SplineClosed 使曲线闭合：

Wolfram Language code: Graphics[{BSplineCurve[pts, SplineClosed -> True]}]

属性和关系  (13)

次数为 1 的 BSplineCurve 等同于 Line：

Wolfram Language code: pts = {{0, -1}, {2, 1}, {4, -1}, {6, 1}, {8, -1}};
Wolfram Language code: Graphics /@ {BSplineCurve[pts, SplineDegree -> 1], Line[pts]}

一条简单的 BezierCurve 等同于一个具有相同次数的默认 BSplineCurve：

Wolfram Language code: pts = {{-3, 0}, {6, 5}, {-6, -5}, {3, 0}};
Wolfram Language code: Graphics /@ {BezierCurve[pts], BSplineCurve[pts]}

一条复合的 BezierCurve 可以通过一条具有特定 SplineKnots 的 BSplineCurve 来表示：

Wolfram Language code: pts = {{0, 0}, {3, 9}, {7, 9}, {10, 0}, {13, 9}, {17, 9}, {20, 0}};
Wolfram Language code: knots = {0, 0, 0, 0, 1, 1, 1, 2, 2, 2, 2};
Wolfram Language code: Graphics /@ {BezierCurve[pts], BSplineCurve[pts, SplineKnots -> knots]}

BSplineSurface 是 BSplineCurve 的高维形式，它接受一个控制点矩形数组：

Wolfram Language code: pts = (⁠| | | | | --------- | --------- | --------- | | {0, 0, 0} | {0, 4, 4} | {0, 8, 3} | | {4, 0, 4} | {4, 4, 0} | {4, 8, 0} | | {8, 0, 1} | {8, 4, 0} | {8, 8, 3} |⁠);
Wolfram Language code: Graphics3D[{BSplineSurface[pts]}]

下面的 BSplineSurface 的边界由四条 B 样条曲线构成：

Wolfram Language code: bc = Map[BSplineCurve, {pts[[1]], pts[[-1]], pts[[All, 1]], pts[[All, -1]]}];
Wolfram Language code: Graphics3D[{BSplineSurface[pts], Thick, StandardRed, bc}]

BSplineSurface 上的所有等参曲线都是有效的 B 样条曲线：

Wolfram Language code: uc = Table[BSplineCurve[Map[#[u]&, Map[BSplineFunction, pts]]], {u, 0, 1, 1 / 5}]; vc = Table[BSplineCurve[Map[#[v]&, Map[BSplineFunction, Transpose[pts]]]], {v, 0, 1, 1 / 5}];
Wolfram Language code: Graphics3D[{BSplineSurface[pts], Thick, RGBColor[0.14, 0.8, 0.14], uc, RGBColor[0.4, 0.6, 1], vc}]

一个 Circle 可以表示为一个等价的 BSplineCurve：

Wolfram Language code: pts = {{0, -1}, {1, -1}, {1, 1}, {0, 1}, {-1, 1}, {-1, -1}, {0, -1}};
Wolfram Language code: weights = {1, 1 / 2, 1 / 2, 1, 1 / 2, 1 / 2, 1};
Wolfram Language code: knots = {0, 0, 0, 1 / 4, 1 / 2, 1 / 2, 3 / 4, 1, 1, 1};
Wolfram Language code: Graphics /@ {BSplineCurve[pts, SplineDegree -> 2, SplineKnots -> knots, SplineWeights -> weights], Circle[]}

B 样条曲线总是对端点进行插值：

Wolfram Language code: pts = {{0, 0}, {3, 4}, {6, 0}, {9, -4}, {13, 0}, {16, 4}, {19, 0}};
Wolfram Language code: Graphics[{BSplineCurve[pts], Red, Point[{First[pts], Last[pts]}]}]

B 样条曲线位于其控制点的凸包内：

Wolfram Language code: pts = {{0, -1}, {2, 1}, {4, -1}, {6, 1}, {4, 2}, {6, 2}};
Wolfram Language code: hull = ConvexHullMesh[pts, MeshCellStyle -> {0 -> Red, 2 -> Opacity[0.25]}];
Wolfram Language code: Show[hull, Region[BSplineCurve[pts]]]

在三维空间中，具有共面控制点的 B 样条曲线与其控制点位于同一平面内：

Wolfram Language code: pts = {{0, -1, 0}, {1, 6, 0}, {2, -6, 0}, {3, 6, 0}, {4, -1, 0}};
Wolfram Language code: pts//CoplanarPoints
Wolfram Language code: Graphics3D[{InfinitePlane[Take[pts, 3]], BSplineCurve[pts]}, Lighting -> "Accent", ViewPoint -> #]& /@ {2{1, -1, 1}, Front, Top}

BSplineFunction 给出 BSplineCurve 上对应于特定参数值的点：

Wolfram Language code: pts = {{0, 0}, {0, 3}, {3, 3}, {5, 0}, {8, 0}, {8, 3}};
Wolfram Language code: bfunc = BSplineFunction[pts]
Wolfram Language code: samples = Table[bfunc[u], {u, 0, 1, 1 / 10}];
Wolfram Language code: Graphics[{BSplineCurve[pts], StandardRed, PointSize[0.02], Point[samples]}]

B 样条曲线可以通过使用基函数对其控制点进行加权求和来构建：

Wolfram Language code: pts = {{0, -1}, {1, 2}, {2, -2}, {3, -2}, {4, 2}, {5, -1}};
Wolfram Language code: knots = {0, 0, 0, 1 / 4, 1 / 2, 3 / 4, 1, 1, 1};
Wolfram Language code: bspline[t_] := Sum[BSplineBasis[{2, knots}, i, t] * pts[[i + 1]], {i, 0, 5}]
Wolfram Language code: GraphicsRow[{ParametricPlot[bspline[t], {t, 0, 1}, Frame -> True, Axes -> False], Graphics[BSplineCurve[pts, SplineKnots -> knots], Frame -> True]}, ImageSize -> 400]

用 BSplineBasis 来可视化曲线上每个控制点的权重：

Wolfram Language code: weights = Table[BSplineBasis[{2, knots}, i, t], {i, 0, 5}];
Wolfram Language code: Plot[weights, {t, 0, 1}, PlotLegends -> {"SubscriptBox[p, 1]", "SubscriptBox[p, 2]", "SubscriptBox[p, 3]", "SubscriptBox[p, 4]", "SubscriptBox[p, 6]", "SubscriptBox[p, 7]"}]

改变节点会改变控制点对曲线的影响程度：

Wolfram Language code: knots2 = {0, 0, 0, 1 / 4, 1 / 4, 3 / 4, 1, 1, 1};
Wolfram Language code: weights = Table[BSplineBasis[{2, knots2}, i, t], {i, 0, 5}];
Wolfram Language code: Plot[weights, {t, 0, 1}, PlotLegends -> {"SubscriptBox[p, 1]", "SubscriptBox[p, 2]", "SubscriptBox[p, 3]", "SubscriptBox[p, 4]", "SubscriptBox[p, 6]", "SubscriptBox[p, 7]"}]

B 样条曲线具有仿射不变性：

Wolfram Language code: pts = {{0, -2}, {2, 2}, {4, -4}, {6, 1}, {8, -2}};
Wolfram Language code: A = AffineTransform[{{{1, 1}, {0, 2}}, {1, 2}}];
Wolfram Language code: {Graphics[GeometricTransformation[BSplineCurve[pts], A], Frame -> True], Graphics[BSplineCurve[A[pts]], Frame -> True]}

对两条 B 样条曲线的控制点进行平均，等同于对曲线本身进行平均：

Wolfram Language code: pts1 = {{0, -1}, {2, 1}, {4, 2}, {6, 2}, {8, 3}}; pts2 = {{2, -1}, {3, 1}, {4, -1}, {6, 0}, {8, -1}};
Wolfram Language code: Graphics[{Thick, RGBColor[0.4, 0.6, 1], BSplineCurve[pts1], RGBColor[0.98, 0.56, 0.17], BSplineCurve[pts2], RGBColor[0.93, 0.27, 0.27], BSplineCurve[Mean[{pts1, pts2}]]}, Frame -> True]
Wolfram Language code: ParametricPlot[{BSplineFunction[pts1][t], BSplineFunction[pts2][t], Mean[{BSplineFunction[pts1][t], BSplineFunction[pts2][t]}]}, {t, 0, 1}, Frame -> True, Axes -> False, PlotStyle -> {RGBColor[0.4, 0.6, 1], RGBColor[0.98, 0.56, 0.17], RGBColor[0.93, 0.27, 0.27]}]

B 样条曲线可被改为任意更高次数的等效曲线：

Wolfram Language code: quadratic = BSplineCurve[{{0, 0}, {2, 3}, {4, 0}}, SplineDegree -> 2];
Wolfram Language code: cubic = BSplineCurve[{{0, 0}, {(4/3), 2}, {(8/3), 2}, {4, 0}}, SplineDegree -> 3];
Wolfram Language code: Graphics /@ {quadratic, cubic}

SubdivisionRegion 根据控制网格而非控制点生成平滑曲面：

Wolfram Language code: Region /@ {SubdivisionRegion[[image]], BSplineCurve[IconizedObject[«[image]»]]}
Wolfram Research (2008)，BSplineCurve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BSplineCurve.html.

文本

Wolfram Research (2008)，BSplineCurve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BSplineCurve.html.

CMS

Wolfram 语言. 2008. "BSplineCurve." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BSplineCurve.html.

APA

Wolfram 语言. (2008). BSplineCurve. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BSplineCurve.html 年

BibTeX

@misc{reference.wolfram_2026_bsplinecurve, author="Wolfram Research", title="{BSplineCurve}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/BSplineCurve.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_bsplinecurve, organization={Wolfram Research}, title={BSplineCurve}, year={2008}, url={https://reference.wolfram.com/language/ref/BSplineCurve.html}, note=[Accessed: 12-August-2026]}