WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BeniniDistribution[α,β,σ]

形状母数が α と β，尺度母数が σ のBenini分布を表す．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

BeniniDistribution

BeniniDistribution[α,β,σ]

形状母数が α と β，尺度母数が σ のBenini分布を表す．

詳細

予備知識

  • BeniniDistribution[α,β,σ] は，区間上で定義され，確率密度関数(PDF)の全体的な動作を決定する「形状母数」として知られる2つの正の値 αおよび β でパラメータ化される連続統計分布を表す．σ は，Benini分布のPDFの水平位置を決めるために「局所母数」と呼ばれる正の値である．σ は，値が大きくなるとPDFの全体的な高さが低くなることから，「スケーリング母数」と呼ばれることもある．Benini分布のPDFは，α および β の値によって，単調減少か領域の最左境界に特異値が近付く可能性がある単峰型になる．PDFの裾部は母数 α および β によって，（PDFが の大きい値について，指数的ではなく代数的に減少するという意味で）「厚い」か，あるいは「薄い」（PDFが の大きい値について指数的に減少する）．（この動作は関数のSurvivalFunctionを解析することで，数量的に正確にできる．）
  • Benini分布は，式中の二次多項式が，ParetoDistributionの構築に，Vilfredo Paretoが使った一次多項式よりも，モデルへのよりよいフィットを与えることが多いことに気づいたイタリアの統計学者Rodolfo Beniniによって考案された．その考案以来，Benini分布は，保険数理における故障率の考察や経済学における収入分布含む数多くの現象を測定できる潜在能力によって，数多くの分野で基本ツールになっている．
  • RandomVariateを使ってBenini分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,BeniniDistribution[α,β,σ]]（より簡略すると xBeniniDistribution[α,β,σ]）を使って，確率変数 x がBenini分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
  • 確率密度関数および累積分布関数は，PDF[BeniniDistribution[α,β,σ],x]およびCDF[BeniniDistribution[α,β,σ],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
  • DistributionFitTestを使って，与えられたデータ集合がBenini分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからBeniniパラメトリック分布を推定することが，FindDistributionParametersを使ってデータをBenini分布にフィットすることができる．ProbabilityPlotを使って記号Benini分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号Benini分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
  • TransformedDistributionを使って変換されたBenini分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってBenini分布を含む高次元分布を構築することが，ProductDistributionを使ってBenini分布を含む独立成分分布の結合分布を計算することができる．
  • Benini分布は他の数多くの分布と関連している．先に記したように，BeniniDistributionはParetoDistributionの自然な一般化であり，PDF[BeniniDistribution[α,0,σ],x]は，厳密に，PDF[ParetoDistribution[α,σ],x]に等しい．BeniniDistributionは，確率変量 が XRayleighDistribution[σ]を満足するのであるならExp[X]BeniniDistribution[0,1/(2σ2),1]である，という意味においてRayleighDistributionの変換でもある．BeniniDistributionは，WeibullDistributionに従って分布した変量の対数のCDFがBenini分布に従う変量のCDFと等しいという意味で，対数ワイブル分布として言及されることがある．そして，この関係のために，BeniniDistributionはGammaDistribution，ExponentialDistribution，MaxStableDistribution，MinStableDistribution，GumbelDistribution，FrechetDistribution，UniformDistributionとも密接な関係がある．

例題

すべて開く すべて閉じる

例  (4)

確率密度関数：

Wolfram Language code: Plot[Table[PDF[BeniniDistribution[α, 3, 4], x], {α, {0.5, 3, 5}}]//Evaluate, {x, 4, 7}, AxesOrigin -> {4, 0}, Filling -> Axis]
Wolfram Language code: Plot[Table[PDF[BeniniDistribution[3, β, 4], x], {β, {15, 45, 100}}]//Evaluate, {x, 4, 6}, Filling -> Axis]
Wolfram Language code: PDF[BeniniDistribution[α, β, σ], x]

累積分布関数：

Wolfram Language code: Plot[Table[CDF[BeniniDistribution[α, 3, 4], x], {α, {0.5, 3, 5}}]//Evaluate, {x, 4, 7}, Filling -> Axis]
Wolfram Language code: Plot[Table[CDF[BeniniDistribution[3, β, 4], x], {β, {15, 45, 100}}]//Evaluate, {x, 4, 6}, Filling -> Axis]
Wolfram Language code: CDF[BeniniDistribution[α, β, σ], x]

平均と分散：

Wolfram Language code: Mean[BeniniDistribution[α, β, σ]]
Wolfram Language code: Variance[BeniniDistribution[α, β, σ]]

中央値：

Wolfram Language code: Median[BeniniDistribution[α, β, σ]]

スコープ  (8)

Benini分布から擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[BeniniDistribution[2.5, 50, 4], 10 ^ 4];

そのヒストグラムを確率密度関数と比べる：

Wolfram Language code: Show[ Histogram[data, 20, "PDF"], Plot[PDF[BeniniDistribution[2.5, 50, 4], x], {x, 4, 6}, PlotStyle -> Thick]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[BeniniDistribution[2, 30, 3], 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, BeniniDistribution[α, β, 3]]

サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, 20, "PDF"], Plot[PDF[edist, x], {x, 2, 5}, PlotStyle -> Thick]]

歪度は形状母数によって変化する：

Wolfram Language code: Plot3D[Skewness[BeniniDistribution[α, β, 2]], {α, 0.1, 18}, {β, 0.1, 3}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {-15, 8, 3}]

尖度は形状母数によって変化する：

Wolfram Language code: Plot3D[Kurtosis[BeniniDistribution[α, β, 2]], {α, 0.1, 18}, {β, 0.1, 3}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {-15, 8, 3}]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[BeniniDistribution[α, β, σ], k], {k, 3}], M]

記号次数の閉じた形：

Wolfram Language code: Moment[BeniniDistribution[α, β, σ], k]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[BeniniDistribution[α, β, σ], k]//Together, {k, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BeniniDistribution[α, β, σ], k]//Together, {k, 3}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[BeniniDistribution[α, β, σ], k]//Together, {k, 3}], C]

ハザード関数：

Wolfram Language code: Plot[Table[HazardFunction[BeniniDistribution[α, 1 / 2, 2], x], {α, {0.1, 0.5, 2}}]//Evaluate, {x, 2, 6}, Filling -> Axis]
Wolfram Language code: Plot[Table[HazardFunction[BeniniDistribution[1 / 3, β, 2], x], {β, {0.1, 0.5, 1.5}}]//Evaluate, {x, 2, 6}, Filling -> Axis]
Wolfram Language code: HazardFunction[BeniniDistribution[α, β, σ], x]

分位関数：

Wolfram Language code: Plot[Table[Quantile[BeniniDistribution[α, 1.5, 2], q], {α, {1, 2, 6}}]//Evaluate, {q, 0, 1}, Filling -> Axis]
Wolfram Language code: Plot[Table[Quantile[BeniniDistribution[.3, β, 2], q], {β, {1, 2, 6}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

母数でQuantityを一貫して使うとQuantityDistributionが与えられる：

Wolfram Language code: weight𝒟 = BeniniDistribution[1, 5, Quantity[2.3, "Kilograms"]]

重さの中央値を求める：

Wolfram Language code: Median[weight𝒟]

アプリケーション  (3)

BeniniDistributionを使って猫の体重をモデル化することができる：

Wolfram Language code: ExampleData[{"Statistics", "FisherCats"}, "ColumnDescriptions"]
Wolfram Language code: catsWeight = QuantityArray[ExampleData[{"Statistics", "FisherCats"}][[All, 2]], "Kilograms"];

Benini分布をデータにフィットする：

Wolfram Language code: edist = EstimatedDistribution[catsWeight, BeniniDistribution[α, β, σ], PrecisionGoal -> 5]

データのヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[catsWeight, 20, "PDF"], Plot[PDF[edist, Quantity[x, "Kilograms"]], {x, 0, 5}, PlotStyle -> Thick]]

猫の平均体重を求める：

Wolfram Language code: Mean[edist]

猫の体重の中央値を求める：

Wolfram Language code: Median[edist]

推定分布は右側の裾部が重いことを示す：

Wolfram Language code: Limit[Exp[λ x]SurvivalFunction[edist, Quantity[x, "Kilograms"]], x -> ∞, Assumptions -> λ > 0]

猫の体重が少なくとも3kgである確率を求める：

Wolfram Language code: Probability[x ≥ Quantity[3, "Kilograms"], xedist]

30匹の猫の体重のシミュレーションをする：

Wolfram Language code: sample = RandomVariate[edist, 30]; m = Mean[edist]; ListPlot[{sample, {{0, m}, {30, m}}}, Joined -> {False, True}, Filling -> Axis, AxesLabel -> Automatic]

BeniniDistributionは損失のモデル化に使うことができる：

Wolfram Language code: USHurricaneLoss = ExampleData[{"Statistics", "USHurricaneLoss"}];
Wolfram Language code: ExampleData[{"Statistics", "USHurricaneLoss"}, "Description"]
Wolfram Language code: TableForm[USHurricaneLoss]

明らかな外れ値である最も被害の大きかったハリケーンアンドリューを除き，通貨単位を加える：

Wolfram Language code: hurricaneLoss = QuantityArray[Rest[USHurricaneLoss[[All, 4]]], "Mega" "USDollars"]; hurricaneLoss = UnitConvert[hurricaneLoss, "Giga""USDollars"];

一般化されたベータ分布をデータにフィットする：

Wolfram Language code: edist = EstimatedDistribution[hurricaneLoss, BeniniDistribution[α, β, σ]]

データのヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[hurricaneLoss, 20, "PDF", AxesLabel -> Automatic], Plot[PDF[edist, Quantity[x, "Giga" "USDollars"]], {x, .1, 7}, PlotStyle -> Thick, PlotRange -> All]]

ハリケーンによる損失が30億ドルを超える確率を求める：

Wolfram Language code: NProbability[x > ["3 billion US dollars"], xedist]

ハリケーンによる損失の平均をUSドルで求める：

Wolfram Language code: Mean[edist]

これから来る強力な30のハリケーンの予想される損失のシミュレーションを単位を百万USドルとして行う：

Wolfram Language code: ListPlot[RandomVariate[edist, 30], Filling -> Axis, AxesLabel -> Automatic]

BenktanderGibratDistributionと関連する定常更新分布を求める：

Wolfram Language code: StanionaryRenewalDistribution[dist_, lb_] := ProbabilityDistribution[{"CDF", (1 - Expectation[Max[x - t, 0], xdist] / (Mean[dist] - lb))}, {t, lb, Infinity}, Assumptions -> DistributionParameterAssumptions[dist]]
Wolfram Language code: dist = StanionaryRenewalDistribution[BenktanderGibratDistribution[a, b], 1]//Simplify

確率密度関数：

Wolfram Language code: PDF[dist, x]

BeniniDistributionと比較する：

Wolfram Language code: PDF[BeniniDistribution[a, b, 1], x]//Simplify
Wolfram Language code: % - %%//FullSimplify[#, x < 1 || x > 1]&

特性と関係  (5)

Benini分布は正の因子によるスケーリングの下では閉じている：

Wolfram Language code: TransformedDistribution[k * u, uBeniniDistribution[α, β, σ]]

σ 母数は尺度母数と位置母数の両方として作用する：

Wolfram Language code: Plot[Table[PDF[BeniniDistribution[0.8, 4, σ], x], {σ, 1, 5}]//Evaluate, {x, 0, 10}, PlotRange -> All, Filling -> Axis, PlotLegends -> Map[TraditionalForm[σ == #]&, Range[5]]]

他の分布との関係：

ParetoDistributionはBeniniDistributionの特殊ケースである：

Wolfram Language code: CDF[ParetoDistribution[σ, α], x]
Wolfram Language code: CDF[BeniniDistribution[α, 0, σ], x]
Wolfram Language code: % - %%

Benini分布はRayleighDistributionを変換したものである：

Wolfram Language code: 𝒟 = TransformedDistribution[Exp[u], uRayleighDistribution[σ]];
Wolfram Language code: PDF[𝒟, x]
Wolfram Language code: PDF[BeniniDistribution[0, 1 / (2σ ^ 2), 1], x]
Wolfram Language code: FullSimplify[% - %%, x > 1]

おもしろい例題  (1)

累積分布関数の等高線を持つ α のさまざまな値についての確率密度関数：

Wolfram Language code: dist = BeniniDistribution[α, 3, 4];cdf = Function[{x, α}, Evaluate[CDF[dist, x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[dist, x], {x, 4, 11}, {α, 1, 3}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], PlotRange -> All, MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2010), BeniniDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/BeniniDistribution.html （2016年に更新）.

テキスト

Wolfram Research (2010), BeniniDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/BeniniDistribution.html （2016年に更新）.

CMS

Wolfram Language. 2010. "BeniniDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/BeniniDistribution.html.

APA

Wolfram Language. (2010). BeniniDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BeniniDistribution.html

BibTeX

@misc{reference.wolfram_2026_beninidistribution, author="Wolfram Research", title="{BeniniDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/BeniniDistribution.html}", note=[Accessed: 19-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_beninidistribution, organization={Wolfram Research}, title={BeniniDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/BeniniDistribution.html}, note=[Accessed: 19-August-2026]}