WOLFRAM

Wolfram 语言与系统参考资料中心

BeniniDistribution[α,β,σ]

表示形状参数为 α 和 β、尺度参数为 σ 的 Benini 分布.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

BeniniDistribution

BeniniDistribution[α,β,σ]

表示形状参数为 α 和 β、尺度参数为 σ 的 Benini 分布.

更多信息

背景

  • BeniniDistribution[α,β,σ] 表示一个定义在区间 上的连续统计分布，即 Benini 分布，它有两个正的“形状参数” α、β 用于确定其概率密度函数（PDF）的整体行为. 正数 α 被称为“位置参数”因为它决定了 Benini 分布的 PDF 的位置，而 β 也被称为“比例参数”因为 β 越高对应的 PDF 整体高度越小. 根据 α 和 β 的值，Benini 分布的 PDF 可能是单调递减的，也可能是在定义域最左侧逼近潜在奇点的单峰形状. PDF 的尾部可能是“胖的”（意思是说 PDF 在 值较大时衰减不是指数的而是代数的）或者“瘦的”（PDF 在 值较大时呈指数衰减），这也取决于参数 α 和 β.（这一行为可通过研究分布的 SurvivalFunction 做精确的定量分析.）
  • Benini 分布是由意大利统计学家 Rodolfo Benini 提出的，在构造 ParetoDistribution 时他注意到在表达式 中使用二次多项式比 Vilfredo Pareto 使用的一次多项式能更好的符合模型. 自提出以来，Benini 分布已经成为一些领域的基础工具，因为它具备估测大量现象的潜质，包括精算学中的故障率考虑和经济学中的收入分布.
  • RandomVariate 可被用于给出 Benini 分布的一个或多个机器精度或任意精度（后者可用 WorkingPrecision 选项指定）的伪随机变量. Distributed[x,BeniniDistribution[α,β,σ]]，更简洁的写法是 xBeniniDistribution[α,β,σ]，可被用于声明随机变量 x 是 Benini 分布的. 这样一个声明之后可用在如 Probability、NProbability、Expectation 以及 NExpectation 这样的函数中.
  • 概率密度函数和累积分布函数可用 PDF[BeniniDistribution[α,β,σ],x] 和 CDF[BeniniDistribution[α,β,σ],x] 求得. 平均数、中位数、方差、原点矩及中心矩可分别用 Mean、Median、Variance、Moment 和 CentralMoment 计算.
  • DistributionFitTest 可被用于测试给定的数据集是否与 Benini 分布一致，EstimatedDistribution 可被用于根据给定数据估算 Benini 参数化分布，而 FindDistributionParameters 可拟合数据和 Benini 分布. ProbabilityPlot 可被用于生成给定数据的 CDF 相对于符号 Benini 分布的 CDF 的图线，而 QuantilePlot 可被用于生成给定数据的分位数相对于符号 Benini 分布的分位数的图线.
  • TransformedDistribution 可被用于表示转换的 Benini 分布，CensoredDistribution 可被用于表示删截后位于上限值和下限值之间的值分布，而 TruncatedDistribution 可被用于表示截断后位于上限值和下限值之间的值分布. CopulaDistribution 可被用于建立包含了 Benini 分布的高维分布，而 ProductDistribution 可被用于计算包括 Benini 分布在内的，若干个独立分量分布的联合分布.
  • Benini 分布与许多其它分布密切相关. 如前面所指出，BeniniDistribution 是 ParetoDistribution 的自然推广，而且实际上，PDF[BeniniDistribution[α,0,σ],x] 精确等于 PDF[ParetoDistribution[α,σ],x]. BeniniDistribution 也可以从 RayleighDistribution 经过变换得到，这是说如果随机变量 X 满足 XRayleighDistribution[σ]，则有 Exp[X]BeniniDistribution[0,1/(2σ2),1]. BeniniDistribution 有时也被称为 log-Weibull 分布，这是因为分布为 WeibullDistribution 的随机变量的 CDF 精确等于 Benini 分布的随机变量的 CDF，而且因为这一关系，BeniniDistribution 也和 GammaDistribution、ExponentialDistribution、MaxStableDistribution、MinStableDistribution、GumbelDistribution、FrechetDistribution 以及 UniformDistribution 密切相关.

范例

打开所有单元 关闭所有单元

基本范例  (4)

概率密度函数：

Wolfram Language code: Plot[Table[PDF[BeniniDistribution[α, 3, 4], x], {α, {0.5, 3, 5}}]//Evaluate, {x, 4, 7}, AxesOrigin -> {4, 0}, Filling -> Axis]
Wolfram Language code: Plot[Table[PDF[BeniniDistribution[3, β, 4], x], {β, {15, 45, 100}}]//Evaluate, {x, 4, 6}, Filling -> Axis]
Wolfram Language code: PDF[BeniniDistribution[α, β, σ], x]

累积分布函数：

Wolfram Language code: Plot[Table[CDF[BeniniDistribution[α, 3, 4], x], {α, {0.5, 3, 5}}]//Evaluate, {x, 4, 7}, Filling -> Axis]
Wolfram Language code: Plot[Table[CDF[BeniniDistribution[3, β, 4], x], {β, {15, 45, 100}}]//Evaluate, {x, 4, 6}, Filling -> Axis]
Wolfram Language code: CDF[BeniniDistribution[α, β, σ], x]

均值和方差：

Wolfram Language code: Mean[BeniniDistribution[α, β, σ]]
Wolfram Language code: Variance[BeniniDistribution[α, β, σ]]

中位数：

Wolfram Language code: Median[BeniniDistribution[α, β, σ]]

范围  (8)

生成一组服从 Benini 分布的伪随机数样本：

Wolfram Language code: data = RandomVariate[BeniniDistribution[2.5, 50, 4], 10 ^ 4];

将直方图与概率密度函数（PDF）比较：

Wolfram Language code: Show[ Histogram[data, 20, "PDF"], Plot[PDF[BeniniDistribution[2.5, 50, 4], x], {x, 4, 6}, PlotStyle -> Thick]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[BeniniDistribution[2, 30, 3], 10 ^ 3];

从样本数据估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, BeniniDistribution[α, β, 3]]

比较样本密度直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[sample, 20, "PDF"], Plot[PDF[edist, x], {x, 2, 5}, PlotStyle -> Thick]]

偏度随形状参数变化而变化：

Wolfram Language code: Plot3D[Skewness[BeniniDistribution[α, β, 2]], {α, 0.1, 18}, {β, 0.1, 3}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {-15, 8, 3}]

峰度随形状参数变化而变化：

Wolfram Language code: Plot3D[Kurtosis[BeniniDistribution[α, β, 2]], {α, 0.1, 18}, {β, 0.1, 3}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {-15, 8, 3}]

以参数的函数形式表示不同矩的解析式：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment:

Wolfram Language code: FormulaGrid[Table[Moment[BeniniDistribution[α, β, σ], k], {k, 3}], M]

具有符号式阶数的解析式：

Wolfram Language code: Moment[BeniniDistribution[α, β, σ], k]

CentralMoment:

Wolfram Language code: FormulaGrid[Table[CentralMoment[BeniniDistribution[α, β, σ], k]//Together, {k, 3}], CM]

FactorialMoment:

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BeniniDistribution[α, β, σ], k]//Together, {k, 3}], FM]

Cumulant:

Wolfram Language code: FormulaGrid[Table[Cumulant[BeniniDistribution[α, β, σ], k]//Together, {k, 3}], C]

风险函数：

Wolfram Language code: Plot[Table[HazardFunction[BeniniDistribution[α, 1 / 2, 2], x], {α, {0.1, 0.5, 2}}]//Evaluate, {x, 2, 6}, Filling -> Axis]
Wolfram Language code: Plot[Table[HazardFunction[BeniniDistribution[1 / 3, β, 2], x], {β, {0.1, 0.5, 1.5}}]//Evaluate, {x, 2, 6}, Filling -> Axis]
Wolfram Language code: HazardFunction[BeniniDistribution[α, β, σ], x]

分位数函数：

Wolfram Language code: Plot[Table[Quantile[BeniniDistribution[α, 1.5, 2], q], {α, {1, 2, 6}}]//Evaluate, {q, 0, 1}, Filling -> Axis]
Wolfram Language code: Plot[Table[Quantile[BeniniDistribution[.3, β, 2], q], {β, {1, 2, 6}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Quantity 在参数中的一致性使用生成 QuantityDistribution:

Wolfram Language code: weight𝒟 = BeniniDistribution[1, 5, Quantity[2.3, "Kilograms"]]

求权重中位数：

Wolfram Language code: Median[weight𝒟]

应用  (3)

BeniniDistribution 可以用来对猫的体重进行建模：

Wolfram Language code: ExampleData[{"Statistics", "FisherCats"}, "ColumnDescriptions"]
Wolfram Language code: catsWeight = QuantityArray[ExampleData[{"Statistics", "FisherCats"}][[All, 2]], "Kilograms"];

对数据进行 Benini 分布拟合：

Wolfram Language code: edist = EstimatedDistribution[catsWeight, BeniniDistribution[α, β, σ], PrecisionGoal -> 5]

比较数据直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[catsWeight, 20, "PDF"], Plot[PDF[edist, Quantity[x, "Kilograms"]], {x, 0, 5}, PlotStyle -> Thick]]

求一只猫的平均体重：

Wolfram Language code: Mean[edist]

求一只猫体重的中位数：

Wolfram Language code: Median[edist]

证明估计分布具有一个重右尾：

Wolfram Language code: Limit[Exp[λ x]SurvivalFunction[edist, Quantity[x, "Kilograms"]], x -> ∞, Assumptions -> λ > 0]

求一只猫体重至少3千克的概率：

Wolfram Language code: Probability[x ≥ Quantity[3, "Kilograms"], xedist]

模拟30只猫的体重：

Wolfram Language code: sample = RandomVariate[edist, 30]; m = Mean[edist]; ListPlot[{sample, {{0, m}, {30, m}}}, Joined -> {False, True}, Filling -> Axis, AxesLabel -> Automatic]

BeniniDistribution 可用于对损失额建模：

Wolfram Language code: USHurricaneLoss = ExampleData[{"Statistics", "USHurricaneLoss"}];
Wolfram Language code: ExampleData[{"Statistics", "USHurricaneLoss"}, "Description"]
Wolfram Language code: TableForm[USHurricaneLoss]

删除明显的异常值，即破坏力最大的飓风 Andrew，并添加货币单位：

Wolfram Language code: hurricaneLoss = QuantityArray[Rest[USHurricaneLoss[[All, 4]]], "Mega" "USDollars"]; hurricaneLoss = UnitConvert[hurricaneLoss, "Giga""USDollars"];

对数据进行广义贝塔分布拟合：

Wolfram Language code: edist = EstimatedDistribution[hurricaneLoss, BeniniDistribution[α, β, σ]]

比较数据直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[hurricaneLoss, 20, "PDF", AxesLabel -> Automatic], Plot[PDF[edist, Quantity[x, "Giga" "USDollars"]], {x, .1, 7}, PlotStyle -> Thick, PlotRange -> All]]

求由飓风引起的损失额超过30亿美元的概率：

Wolfram Language code: NProbability[x > ["3 billion US dollars"], xedist]

求平均飓风损失（以美元计）：

Wolfram Language code: Mean[edist]

模拟接下来30个强飓风的可能损失（以百万美元计）：

Wolfram Language code: ListPlot[RandomVariate[edist, 30], Filling -> Axis, AxesLabel -> Automatic]

求与 BenktanderGibratDistribution 相关的平稳更新分布：

Wolfram Language code: StanionaryRenewalDistribution[dist_, lb_] := ProbabilityDistribution[{"CDF", (1 - Expectation[Max[x - t, 0], xdist] / (Mean[dist] - lb))}, {t, lb, Infinity}, Assumptions -> DistributionParameterAssumptions[dist]]
Wolfram Language code: dist = StanionaryRenewalDistribution[BenktanderGibratDistribution[a, b], 1]//Simplify

概率密度函数：

Wolfram Language code: PDF[dist, x]

与 BeniniDistribution 比较：

Wolfram Language code: PDF[BeniniDistribution[a, b, 1], x]//Simplify
Wolfram Language code: % - %%//FullSimplify[#, x < 1 || x > 1]&

属性和关系  (5)

当使用一个正因子为比例进行缩放时，新生成的分布仍然是 Benini 分布：

Wolfram Language code: TransformedDistribution[k * u, uBeniniDistribution[α, β, σ]]

参数 σ 同时用作尺度和定位参数：

Wolfram Language code: Plot[Table[PDF[BeniniDistribution[0.8, 4, σ], x], {σ, 1, 5}]//Evaluate, {x, 0, 10}, PlotRange -> All, Filling -> Axis, PlotLegends -> Map[TraditionalForm[σ == #]&, Range[5]]]

与其它分布的关系：

ParetoDistribution 是一种特殊的 BeniniDistribution：

Wolfram Language code: CDF[ParetoDistribution[σ, α], x]
Wolfram Language code: CDF[BeniniDistribution[α, 0, σ], x]
Wolfram Language code: % - %%

Benini 分布是 RayleighDistribution 的一个变换：

Wolfram Language code: 𝒟 = TransformedDistribution[Exp[u], uRayleighDistribution[σ]];
Wolfram Language code: PDF[𝒟, x]
Wolfram Language code: PDF[BeniniDistribution[0, 1 / (2σ ^ 2), 1], x]
Wolfram Language code: FullSimplify[% - %%, x > 1]

巧妙范例  (1)

取不同 α 值时的概率密度函数与累积分布函数等高图：

Wolfram Language code: dist = BeniniDistribution[α, 3, 4];cdf = Function[{x, α}, Evaluate[CDF[dist, x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[dist, x], {x, 4, 11}, {α, 1, 3}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], PlotRange -> All, MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2010)，BeniniDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BeniniDistribution.html （更新于 2016 年）.

文本

Wolfram Research (2010)，BeniniDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BeniniDistribution.html （更新于 2016 年）.

CMS

Wolfram 语言. 2010. "BeniniDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/BeniniDistribution.html.

APA

Wolfram 语言. (2010). BeniniDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BeniniDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_beninidistribution, author="Wolfram Research", title="{BeniniDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/BeniniDistribution.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_beninidistribution, organization={Wolfram Research}, title={BeniniDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/BeniniDistribution.html}, note=[Accessed: 17-August-2026]}