BenktanderWeibullDistribution

母数が a と b のタイプIIのベンクタンダー(Benktander)分布を表す．

詳細

ベンクタンダー・ワイブル分布における値の確率密度はのときに比例する．
BenktanderWeibullDistributionでは，a は任意の正の実数でよく，でよい．
BenktanderWeibullDistributionでは，a と b は無次元量でよい． »
BenktanderWeibullDistributionは，Mean，CDF，RandomVariate等の関数とともに使うことができる．

予備知識

BenktanderWeibullDistribution[a,b]は，区間で定義され，正の値 a および b （）でパラメータ化される，連続統計分布を表す．パラメータ a および b は，ベンクタンダー・ワイブル分布の確率密度関数(PDF)の全体的な形を決定する．ただし，PDFは単調減少であり，そのようなすべてのパラメータについて区間の最左境界に近付く特異点を持つ可能性がある．BenktanderWeibullDistributionのPDFの裾部は（の大きい値については，PDFが指数的よりも遅く減少するという意味で）「重い」．しかし，この分布は「裾部が重い」というよりも「準指数的」であるとみなされている．（この動作は，分布のSurvivalFunctionを解析することで数量的に正確にすることができる．）
ベンクタンダー・ワイブル分布は，経験的平均超過関数がパレート分布と指数分布の「中間的」分布の必要性を示唆していることに気付いた，スウェーデンの保険数理士であるGunnar Benktanderによって考案された．ベンクタンダー・ワイブル分布は，保険数理のアプリケーションにおける資産の損失のモデル化に最もよく使われている．さらに，ベンクタンダー・ワイブル分布のような半指数分布は，ランダムウォークの特性を研究する上でも有益である．ベンクタンダー・ワイブル分布は，タイプIIのベンクタンダー分布と呼ばれることがある．タイプIはベンクタンダー・ジブラ分布として知られ，Wolfram言語ではBenktanderGibratDistributionとして実装されている．どちらの分布も，両分布のPDFが数量的に似ている点でワイブル分布に「近い」とみなされている．
RandomVariateを使ってベンクタンダー・ワイブル分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,BenktanderWeibullDistribution[a,b]]（より簡略すると xBenktanderWeibullDistribution[a,b]）を使って，確率変数 x がベンクタンダー・ワイブル分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
確率密度関数および累積分布関数は，PDF[BenktanderWeibullDistribution[a,b],x]およびCDF[BenktanderWeibullDistribution[a,b],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
DistributionFitTestを使って，与えられたデータ集合がベンクタンダー・ワイブル分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからベンクタンダー・ワイブルパラメトリック分布を推定することが，FindDistributionParametersを使ってデータをベンクタンダー・ワイブル分布にフィットすることができる．ProbabilityPlotを使って記号ベンクタンダー・ワイブル分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号ベンクタンダー・ワイブル分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
TransformedDistributionを使って変換されたベンクタンダー・ワイブル分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってベンクタンダー・ワイブル分布を含む高次元分布を構築することが，ProductDistributionを使ってベンクタンダー・ワイブル分布を含む独立成分分布の結合分布を計算することができる．
BenktanderWeibullDistributionは，数多くの他の統計分布と関連している．例えば，先に記したように，BenktanderWeibullDistributionとBenktanderGibratDistributionは，ParetoDistributionとExponentialDistributionの中間分布であるとみなされる同じ分布「族」に属する．定性的には，BenktanderWeibullDistributionのPDFはWeibullDistributionのそれに類似しており，これによってBenktanderWeibullDistributionとGammaDistribution，RayleighDistribution，MaxStableDistribution，MinStableDistribution，ExtremeValueDistribution，GumbelDistribution，FrechetDistributionを含む数多くの分布との（定性）関係が導かれる．BenktanderWeibullDistribution[a,1]は，ExponentialDistribution[a]の切断バージョン（ x についての前者のPDFがPDF[TruncatedDistribution[{1,Infinity},ExponentialDistribution[a]],x]と厳密に等しいという意味において）である．同様に，BenktanderWeibullDistributionはシフトされたExponentialDistributionと見ることができる．ParetoDistributionは，b が0に近付くにつれてBenktanderWeibullDistribution[a,b]のPDFがParetoDistribution[1,a+1]のそれに近付くという意味で，BenktanderWeibullDistributionの極限のケースであるとみなされる．この事実は，b が0に近付くにつれてBenktanderWeibullDistribution[a,b]とBenktanderGibratDistribution[a,b]の両方のPDFが同じ極限関数に近付くことを暗に示している．さらに，ベンクタンダー・ワイブル分布に関連する定常再生分布の生存分布は，切断ワイブル分布TruncatedDistribution[{1,∞},WeibullDistribution[b,(b/a)^1/b]]の生存関数とその領域上で全く同じ式を持つ．

例題

すべて開くすべて閉じる

例 (4)

確率密度関数：

Wolfram Language code: Plot[Table[PDF[BenktanderWeibullDistribution[a, 0.5], x], {a, {0.5, 1, 2}}]//Evaluate, {x, 1, 3}, Filling -> Axis]

Wolfram Language code: Plot[Evaluate@Table[PDF[BenktanderWeibullDistribution[0.5, b], x], {b, {0.1, 0.5, 0.7}}], {x, 1, 3}, Filling -> Axis]

Wolfram Language code: PDF[BenktanderWeibullDistribution[a, b], x]

累積分布関数：

Wolfram Language code: Plot[Table[CDF[BenktanderWeibullDistribution[a, 0.5], x], {a, {0.5, 1, 2}}]//Evaluate, {x, 1, 3}, Filling -> Axis]

Wolfram Language code: Plot[Table[CDF[BenktanderWeibullDistribution[0.5, b], x], {b, {0.1, 0.5, 0.7}}]//Evaluate, {x, 1, 3}, Filling -> Axis]

Wolfram Language code: CDF[BenktanderWeibullDistribution[a, b], x]

平均と分散：

Wolfram Language code: Mean[BenktanderWeibullDistribution[a, b]]

Wolfram Language code: Variance[BenktanderWeibullDistribution[a, b]]

中央値：

Wolfram Language code: Median[BenktanderWeibullDistribution[a, b]]

スコープ (8)

ベンクタンダー・ワイブル分布から擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[BenktanderWeibullDistribution[2, 0.4], 10 ^ 4];

そのヒストグラムを確率密度関数と比較する：

Wolfram Language code:

Show[
	Histogram[data, {1, 3, 0.2}, "PDF"], 
	Plot[PDF[BenktanderWeibullDistribution[2, 0.4], x], {x, 1, 3}, PlotStyle -> Thick]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[BenktanderWeibullDistribution[4, .3], 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, BenktanderWeibullDistribution[a, b]]

サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, {1, 2.5, 0.1}, "PDF"], Plot[PDF[edist, x], {x, 1, 2}, PlotStyle -> Thick]]

歪度：

Wolfram Language code:

Plot3D[Skewness[BenktanderWeibullDistribution[a, b]], {a, 0, 10}, {b, 0, 1}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {-3, -1, 1}]

Wolfram Language code: Skewness[BenktanderWeibullDistribution[a, b]]

尖度：

Wolfram Language code:

Plot3D[Kurtosis[BenktanderWeibullDistribution[a, b]], {a, 0, 10}, {b, 0, 1}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {3, -1, 2}]

Wolfram Language code: Kurtosis[BenktanderWeibullDistribution[a, b]]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[BenktanderWeibullDistribution[a, b], r]//Together, {r, 3}], M]

記号次数の閉じた形：

Wolfram Language code: Moment[BenktanderWeibullDistribution[a, b], r]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[BenktanderWeibullDistribution[a, b], r]//FullSimplify, {r, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BenktanderWeibullDistribution[a, b], r]//FullSimplify, {r, 3}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[BenktanderWeibullDistribution[a, b], r]//FullSimplify, {r, 3}], C]

ハザード関数：

Wolfram Language code:

Plot[Table[HazardFunction[BenktanderWeibullDistribution[a, .4], x], {a, {1, 2, 3}}]//Evaluate, {x, 1, 4}, Filling -> Axis, AxesOrigin -> {1, 0}]

Wolfram Language code:

Plot[Table[HazardFunction[BenktanderWeibullDistribution[4, b], x], {b, {.1, .5, .7}}]//Evaluate, {x, 1, 3}, Filling -> Axis, AxesOrigin -> {1, 1}]

Wolfram Language code: HazardFunction[BenktanderWeibullDistribution[a, b], x]

分位関数：

Wolfram Language code: Plot[Table[Quantile[BenktanderWeibullDistribution[a, .4], q], {a, {1, 2, 3}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code: Plot[Table[Quantile[BenktanderWeibullDistribution[.1, b], q], {b, {.1, .5, .7}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

Wolfram Language code: Quantile[BenktanderWeibullDistribution[a, b], q]

無次元のQuantityを使ってBenktanderWeibullDistributionを定義する：

Wolfram Language code: 𝒟 = BenktanderWeibullDistribution[Quantity[2*1, "Dozens"], 19]

アプリケーション (2)

タイプIIのベンクタンダー分布について平均超過関数を計算する：

Wolfram Language code: Subscript[e, BII] = Expectation[x - sx > s, xBenktanderWeibullDistribution[a, b], Assumptions -> s > 1]

大きいの値に対しては，平均超過関数はワイブル分布のものに近付く：

Wolfram Language code: Expectation[x - sx > s, xWeibullDistribution[β, α], Assumptions -> s > 1]

不完全関数を大きい引数でのその漸近解析で置換する：

Wolfram Language code: % /. Exp[x_]Gamma[a_, x_] -> (Series[Exp[x]Gamma[a, x], {x, ∞, 2}]//Normal)//PowerExpand//Simplify

タイプIIのベンクタンダー分布に関連する定常再生分布を求める：

Wolfram Language code:

StanionaryRenewalDistribution[dist_, lb_] := ProbabilityDistribution[{"CDF", (1 - Expectation[Max[x - t, 0], xdist] / (Mean[dist] - lb))}, {t, lb, Infinity}, Assumptions -> DistributionParameterAssumptions[dist]]

Wolfram Language code: srdist = StanionaryRenewalDistribution[BenktanderWeibullDistribution[a, b], 1]//Simplify

生存関数：

Wolfram Language code: SurvivalFunction[srdist, x]//FullSimplify

切断WeibullDistributionと比較する：

Wolfram Language code:

SurvivalFunction[TruncatedDistribution[{1, ∞}, WeibullDistribution[b, (b / a) ^ (1 / b)]], x]//PowerExpand//FullSimplify

Wolfram Language code: % - %%

特性と関係 (5)

ではBenktanderWeibullDistributionは準指数的である：

Wolfram Language code:

Limit[Exp[c x]Refine[PDF[BenktanderWeibullDistribution[a, b], x], x > 1], x -> ∞, Assumptions -> c > 0 && a > 0 && 0 < b < 1]

他の分布との関係：

のとき，タイプIiのベンクタンダー分布は切断ExponentialDistributionに簡約される：

Wolfram Language code: PDF[BenktanderWeibullDistribution[a, 1], x]

Wolfram Language code: PDF[TruncatedDistribution[{1, Infinity}, ExponentialDistribution[a]], x]

Wolfram Language code: FullSimplify[% - %%, x > 1]

シフトされたExponentialDistributionはタイプIIのベンクタンダー分布である：

Wolfram Language code: TransformedDistribution[u + 1, uExponentialDistribution[λ]]

ParetoDistributionはタイプIIのベンクタンダー分布の極限のケースである：

Wolfram Language code: Limit[PDF[BenktanderWeibullDistribution[a, b], x], b -> 0]

Wolfram Language code: PDF[ParetoDistribution[1, a + 1], x]

Wolfram Language code: % - %%

おもしろい例題 (1)

累積分布関数の等高線を持つ a のさまざまな値についての確率密度関数：

Wolfram Language code:

dist = BenktanderWeibullDistribution[a, 0.5];cdf = Function[{x, a}, Evaluate[CDF[dist, x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];

Wolfram Language code:

Legended[Plot3D[PDF[dist, x], {x, 1, 2.4}, {a, 3, 7}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], PlotRange -> All, MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

BenktanderWeibullDistribution

詳細

予備知識

例題

例 (4)

スコープ (8)

アプリケーション (2)

特性と関係 (5)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

BenktanderWeibullDistribution

詳細

予備知識

例題

例 (4)

スコープ (8)

アプリケーション (2)

特性と関係 (5)

おもしろい例題 (1)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX