WOLFRAM

Wolfram 语言与系统参考资料中心

BenktanderWeibullDistribution[a,b]

表示参数为 a 和 b 的第二类 Benktander 分布.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

BenktanderWeibullDistribution

BenktanderWeibullDistribution[a,b]

表示参数为 a 和 b 的第二类 Benktander 分布.

更多信息

背景

范例

打开所有单元 关闭所有单元

基本范例  (4)

概率密度函数：

Wolfram Language code: Plot[Table[PDF[BenktanderWeibullDistribution[a, 0.5], x], {a, {0.5, 1, 2}}]//Evaluate, {x, 1, 3}, Filling -> Axis]
Wolfram Language code: Plot[Evaluate@Table[PDF[BenktanderWeibullDistribution[0.5, b], x], {b, {0.1, 0.5, 0.7}}], {x, 1, 3}, Filling -> Axis]
Wolfram Language code: PDF[BenktanderWeibullDistribution[a, b], x]

累积分布函数：

Wolfram Language code: Plot[Table[CDF[BenktanderWeibullDistribution[a, 0.5], x], {a, {0.5, 1, 2}}]//Evaluate, {x, 1, 3}, Filling -> Axis]
Wolfram Language code: Plot[Table[CDF[BenktanderWeibullDistribution[0.5, b], x], {b, {0.1, 0.5, 0.7}}]//Evaluate, {x, 1, 3}, Filling -> Axis]
Wolfram Language code: CDF[BenktanderWeibullDistribution[a, b], x]

均值和方差：

Wolfram Language code: Mean[BenktanderWeibullDistribution[a, b]]
Wolfram Language code: Variance[BenktanderWeibullDistribution[a, b]]

中位数：

Wolfram Language code: Median[BenktanderWeibullDistribution[a, b]]

范围  (8)

生成一组服从 Benktander-Weibull 分布的伪随机数样本：

Wolfram Language code: data = RandomVariate[BenktanderWeibullDistribution[2, 0.4], 10 ^ 4];

比较其直方图与概率密度函数：

Wolfram Language code: Show[ Histogram[data, {1, 3, 0.2}, "PDF"], Plot[PDF[BenktanderWeibullDistribution[2, 0.4], x], {x, 1, 3}, PlotStyle -> Thick]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[BenktanderWeibullDistribution[4, .3], 10 ^ 3];

从样本数据估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, BenktanderWeibullDistribution[a, b]]

比较样本的密度直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[sample, {1, 2.5, 0.1}, "PDF"], Plot[PDF[edist, x], {x, 1, 2}, PlotStyle -> Thick]]

偏度：

Wolfram Language code: Plot3D[Skewness[BenktanderWeibullDistribution[a, b]], {a, 0, 10}, {b, 0, 1}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {-3, -1, 1}]
Wolfram Language code: Skewness[BenktanderWeibullDistribution[a, b]]

峰度：

Wolfram Language code: Plot3D[Kurtosis[BenktanderWeibullDistribution[a, b]], {a, 0, 10}, {b, 0, 1}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic, ViewPoint -> {3, -1, 2}]
Wolfram Language code: Kurtosis[BenktanderWeibullDistribution[a, b]]

以参数的函数形式表示不同矩的解析式：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment:

Wolfram Language code: FormulaGrid[Table[Moment[BenktanderWeibullDistribution[a, b], r]//Together, {r, 3}], M]

具有符号式阶数的解析式：

Wolfram Language code: Moment[BenktanderWeibullDistribution[a, b], r]

CentralMoment:

Wolfram Language code: FormulaGrid[Table[CentralMoment[BenktanderWeibullDistribution[a, b], r]//FullSimplify, {r, 3}], CM]

FactorialMoment:

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BenktanderWeibullDistribution[a, b], r]//FullSimplify, {r, 3}], FM]

Cumulant:

Wolfram Language code: FormulaGrid[Table[Cumulant[BenktanderWeibullDistribution[a, b], r]//FullSimplify, {r, 3}], C]

风险函数：

Wolfram Language code: Plot[Table[HazardFunction[BenktanderWeibullDistribution[a, .4], x], {a, {1, 2, 3}}]//Evaluate, {x, 1, 4}, Filling -> Axis, AxesOrigin -> {1, 0}]
Wolfram Language code: Plot[Table[HazardFunction[BenktanderWeibullDistribution[4, b], x], {b, {.1, .5, .7}}]//Evaluate, {x, 1, 3}, Filling -> Axis, AxesOrigin -> {1, 1}]
Wolfram Language code: HazardFunction[BenktanderWeibullDistribution[a, b], x]

分位数函数：

Wolfram Language code: Plot[Table[Quantile[BenktanderWeibullDistribution[a, .4], q], {a, {1, 2, 3}}]//Evaluate, {q, 0, 1}, Filling -> Axis]
Wolfram Language code: Plot[Table[Quantile[BenktanderWeibullDistribution[.1, b], q], {b, {.1, .5, .7}}]//Evaluate, {q, 0, 1}, Filling -> Axis]
Wolfram Language code: Quantile[BenktanderWeibullDistribution[a, b], q]

使用无量纲的 Quantity 来定义 BenktanderWeibullDistribution：

Wolfram Language code: 𝒟 = BenktanderWeibullDistribution[Quantity[2*1, "Dozens"], 19]

应用  (2)

计算 Benktander 第二类分布的平均超限函数：

Wolfram Language code: Subscript[e, BII] = Expectation[x - sx > s, xBenktanderWeibullDistribution[a, b], Assumptions -> s > 1]

对于较大的 ，它逼近一个韦伯分布：

Wolfram Language code: Expectation[x - sx > s, xWeibullDistribution[β, α], Assumptions -> s > 1]

现在，把不完全 函数用它在较大参数值时的近似替换：

Wolfram Language code: % /. Exp[x_]Gamma[a_, x_] -> (Series[Exp[x]Gamma[a, x], {x, ∞, 2}]//Normal)//PowerExpand//Simplify

求与 Benktander 第二类分布相关联的稳态更新分布：

Wolfram Language code: StanionaryRenewalDistribution[dist_, lb_] := ProbabilityDistribution[{"CDF", (1 - Expectation[Max[x - t, 0], xdist] / (Mean[dist] - lb))}, {t, lb, Infinity}, Assumptions -> DistributionParameterAssumptions[dist]]
Wolfram Language code: srdist = StanionaryRenewalDistribution[BenktanderWeibullDistribution[a, b], 1]//Simplify

生存函数：

Wolfram Language code: SurvivalFunction[srdist, x]//FullSimplify

与一个被删截的 WeibullDistribution 比较：

Wolfram Language code: SurvivalFunction[TruncatedDistribution[{1, ∞}, WeibullDistribution[b, (b / a) ^ (1 / b)]], x]//PowerExpand//FullSimplify
Wolfram Language code: % - %%

属性和关系  (5)

对于 ，BenktanderWeibullDistribution 是亚指数的：

Wolfram Language code: Limit[Exp[c x]Refine[PDF[BenktanderWeibullDistribution[a, b], x], x > 1], x -> ∞, Assumptions -> c > 0 && a > 0 && 0 < b < 1]

与其它分布的关系：

当 时，Benktander 第二类分布简化为一个被删截的 ExponentialDistribution：

Wolfram Language code: PDF[BenktanderWeibullDistribution[a, 1], x]
Wolfram Language code: PDF[TruncatedDistribution[{1, Infinity}, ExponentialDistribution[a]], x]
Wolfram Language code: FullSimplify[% - %%, x > 1]

经过平移的 ExponentialDistribution 是一个 Benktander 第二类分布：

Wolfram Language code: TransformedDistribution[u + 1, uExponentialDistribution[λ]]

ParetoDistribution 是 Benktander 第二类分布的一个极限情况：

Wolfram Language code: Limit[PDF[BenktanderWeibullDistribution[a, b], x], b -> 0]
Wolfram Language code: PDF[ParetoDistribution[1, a + 1], x]
Wolfram Language code: % - %%

巧妙范例  (1)

取不同 a 值时的概率密度函数与累积分布函数等高图：

Wolfram Language code: dist = BenktanderWeibullDistribution[a, 0.5];cdf = Function[{x, a}, Evaluate[CDF[dist, x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[dist, x], {x, 1, 2.4}, {a, 3, 7}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], PlotRange -> All, MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2010)，BenktanderWeibullDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BenktanderWeibullDistribution.html （更新于 2016 年）.

文本

Wolfram Research (2010)，BenktanderWeibullDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BenktanderWeibullDistribution.html （更新于 2016 年）.

CMS

Wolfram 语言. 2010. "BenktanderWeibullDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/BenktanderWeibullDistribution.html.

APA

Wolfram 语言. (2010). BenktanderWeibullDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BenktanderWeibullDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_benktanderweibulldistribution, author="Wolfram Research", title="{BenktanderWeibullDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/BenktanderWeibullDistribution.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_benktanderweibulldistribution, organization={Wolfram Research}, title={BenktanderWeibullDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/BenktanderWeibullDistribution.html}, note=[Accessed: 09-August-2026]}