WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BesagL[pdata,r]

半径 r にある点データ pdata についてBesagの 関数 を推定する．

BesagL[pproc,r]

点過程 pproc について を計算する．

BesagL[bdata,r]

ビン分割されたデータ bdata について を計算する．

BesagL[pspec]

異なる半径 r に繰り返し適用可能な関数 を生成する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
点データ  
点過程  
オプション  
SpatialBoundaryCorrection  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

BesagL

BesagL[pdata,r]

半径 r にある点データ pdata についてBesagの 関数 を推定する．

BesagL[pproc,r]

点過程 pproc について を計算する．

BesagL[bdata,r]

ビン分割されたデータ bdata について を計算する．

BesagL[pspec]

異なる半径 r に繰り返し適用可能な関数 を生成する．

詳細とオプション

  • BesagLは，完全に空間ランダムな参照過程との比較を簡単にするRipleyK関数の変換である．
  • BesagL はと定義される，ただし，はRipleyK， は空間次元，は内の単位球の体積である．
  • BesagLは距離 r 内の点集合の空間的均一性を測定する．次は，ポアソン(Poisson)点過程との比較である．
  • ポアソン過程よりも分散している
    ポアソン過程に似ている．つまり，完全に空間ランダムである
    ポアソン過程よりもクラスタ化している
  • 半径 r は単一の値でも値のリストでもよい．半径 r が指定されていないと，BesagLは 関数を繰り返し評価するために使えるPointStatisticFunctionを返す．
  • 点 pdata の形状は以下でよい．
  • {p1,p2,…}点 pi
    GeoPosition[…],GeoPositionXYZ[…],…グラフィックスの点
    SpatialPointData[…]空間点集合
    {pts,reg}点集合 pts と観測領域 reg
  • 観測領域 reg は，与えられていないとRipleyRassonRegionを使って自動的に計算される．
  • 点過程 pproc は以下の形でよい．
  • proc点過程 proc
    {proc,reg}点過程 proc および観測領域 reg
  • 観測領域 reg はパラメータフリーでSpatialObservationRegionQでなければならない．
  • ビン分割された bdata はSpatialBinnedPointDataからのもので，区分一定密度関数を持つInhomogeneousPoissonPointProcessとして扱われる．
  • pdata については，はお互いに距離 r 内にある他とは異なるペアを数えることで計算される．
  • pproc については，は厳密な式を使って，あるいはシミュレーションで点データを生成することで計算される．
  • 次は，使用可能なオプションである．
  • MethodAutomatic使用するメソッド
    SpatialBoundaryCorrection Automatic使用する境界補正
  • SpatialBoundaryCorrectionには以下の設定を使うことができる．
  • Automatic自動決定された境界補正
    None境界補正なし
    "BorderMargin"観測領域の内部余白
    "Ripley"境界からの点の距離に依存する重みを使う

例題

すべて開く すべて閉じる

例  (3)

与えられた距離におけるBesagの 関数を推定する：

Wolfram Language code: region = Ball[{0, 0}]; pts = RandomPoint[region, 100];
Wolfram Language code: BesagL[{pts, region}, 0.2]

距離範囲内のBesagの 関数を推定する：

Wolfram Language code: spd = SpatialPointData[RandomReal[1, {500, 3}]]
Wolfram Language code: rspec = Range[0.1, 0.4, 0.01];
Wolfram Language code: est = BesagL[spd, rspec];

ListPlotで結果を可視化する：

Wolfram Language code: ListPlot[est, DataRange -> MinMax[rspec], AxesLabel -> {r}, Filling -> Axis]

クラスタ点過程のBesagの 関数：

Wolfram Language code: lfun = BesagL[CauchyPointProcess[μ, λ, b, 2], r]

与えられたパラメータ値で関数を可視化する：

Wolfram Language code: Plot[lfun /. {μ -> 3, λ -> 2, b -> 1}, {r, 0, 3}, AxesLabel -> Automatic]

スコープ  (10)

点データ  (5)

Besagの 関数を距離0.2で推定する：

Wolfram Language code: region = Rectangle[{0, 0}, {1, 2}]; pts = RandomPoint[region, 100];
Wolfram Language code: BesagL[{pts, region}, 0.2]

Besagの 関数についての経験的推定を与えられた距離のリストから入手する：

Wolfram Language code: BesagL[{pts, region}, {0.1, 0.3, 0.05, 0.23}]

BesagLをSpatialPointDataと一緒に使う：

Wolfram Language code: spd = SpatialPointData[RandomReal[1, {500, 2}]]
Wolfram Language code: res = BesagL[spd, {0.01, 0.02}]

後で使うためにPointStatisticFunctionを作る：

Wolfram Language code: reg = Disk[]; pts = RandomPoint[Disk[], 100];
Wolfram Language code: psf = BesagL[{pts, reg}]
Wolfram Language code: psf[0.5]

観測領域を明示的には与えずにBesagの 関数を推定する：

Wolfram Language code: BlockRandom[SeedRandom[1]; pts = RandomReal[1, {100, 2}]];
Wolfram Language code: psf = BesagL[pts]

Ripley–Rasson推定器によって生成された観測領域：

Wolfram Language code: psf["ObservationRegion"]

関数を距離0.3で推定する：

Wolfram Language code: psf[0.3]

BesagLをGeoPositionと一緒に使う：

Wolfram Language code: pts = RandomGeoPosition[GeoDisk[GeoPosition[{0, 0}], Quantity[10, "Kilometers"]], 10 ^ 2]
Wolfram Language code: psf = BesagL[pts]

点統計関数をプロットする：

Wolfram Language code: ListPlot[Table[{x, psf[x]}, {x, Quantity[0, "km"], psf["MaxRadius"], Quantity[.1, "km"]}], AxesLabel -> {"km"}]

点過程  (5)

PoissonPointProcessについてのBesagの 関数は密度にも次元にも依存しない：

Wolfram Language code: proc = PoissonPointProcess[μ, d];
Wolfram Language code: BesagL[proc, r]

指定の次元のクラスタ過程ThomasPointProcessについてのBesagの 関数：

Wolfram Language code: proc2D = ThomasPointProcess[μ, λ, σ, 2];
Wolfram Language code: BesagL[proc2D, r]

3Dで：

Wolfram Language code: proc3D = ThomasPointProcess[μ, λ, σ, 3];
Wolfram Language code: BesagL[proc3D, r]

指定次元のクラスタ過程MaternPointProcessについてのBesagの 関数：

Wolfram Language code: proc2D = MaternPointProcess[μ, λ, rad, 2];
Wolfram Language code: BesagL[proc2D, r]

3Dで：

Wolfram Language code: proc3D = MaternPointProcess[μ, λ, rad, 3];
Wolfram Language code: BesagL[proc3D, rad]

クラスタ過程CauchyPointProcessについてのBesagの 関数：

Wolfram Language code: proc = CauchyPointProcess[μ, λ, b, dim];
Wolfram Language code: BesagL[proc, r]

クラスタ過程VarianceGammaPointProcessについてのBesagの 関数：

Wolfram Language code: proc = VarianceGammaPointProcess[μ, λ, α, β, dim];
Wolfram Language code: BesagL[proc, r]

オプション  (2)

SpatialBoundaryCorrection  (2)

境界補正がないBesagL推定器にはバイアスがあるので，大きい点集合以外とは使うべきではない：

Wolfram Language code: region = Rectangle[{0, 0}, {2, 1}]; pts = RandomPoint[region, 100];
Wolfram Language code: r = 0.2;
Wolfram Language code: BesagL[{pts, region}, r, SpatialBoundaryCorrection -> "None"]

デフォルトメソッドの"BorderMargin"は境界から距離 の点しか考慮しない：

Wolfram Language code: inregion = Rectangle[{r, r}, {2 - r, 1 - r}]; Show[RegionPlot[{region, inregion}, AspectRatio -> Automatic], ListPlot[pts]]
Wolfram Language code: BesagL[{pts, region}, r, SpatialBoundaryCorrection -> "BorderMargin"]

境界補正法"Ripley"は点の各ペアに重みを付けて推定器のバイアスを除く：

Wolfram Language code: BesagL[{pts, region}, r, SpatialBoundaryCorrection -> "Ripley"]

異なる辺補正法を比較する：

Wolfram Language code: reg = Ball[{0, 0, 0}]; pts = RandomPoint[reg, 200];

Besagの 関数の値を異なる3つの方法で推定する：

Wolfram Language code: rad = Range[0.01, 0.5, 0.02]; m = {"None", "BorderMargin", "Ripley"};
Wolfram Language code: data = BesagL[{pts, reg}, rad, SpatialBoundaryCorrection -> #]& /@ m;

結果を可視化して理論値と比較する：

Wolfram Language code: val = BesagL[PoissonPointProcess[λ, 3], r]
Wolfram Language code: Show[ListPlot[data, DataRange -> MinMax[rad], PlotLegends -> m], Plot[val, {r, 0, 0.5}, PlotStyle -> Gray, PlotLegends -> {val}], AxesLabel -> {r}]

アプリケーション  (5)

Besagの 関数は距離において累積的であり，したがって単調増加である：

Wolfram Language code: region = Ellipsoid[{0, 0}, {2, 3}]; pts = RandomPoint[region, 500];
Wolfram Language code: fun = BesagL[pts]
Wolfram Language code: Plot[fun[r], {r, 0, 1}, AxesLabel -> Automatic]

完全な空間ランダム性についてのBesagの 関数：

Wolfram Language code: region[d_] := Ball[d] pts[d_] := RandomPoint[region[d], 1000]

Besagの 関数をいくつかの次元について計算する：

Wolfram Language code: rspec = Range[0.02, 0.8, 0.02]; data = Table[BesagL[{pts[d], region[d]}, rspec], {d, 1, 5}];

結果を可視化する：

Wolfram Language code: ListLinePlot[data, DataRange -> MinMax[rspec], AxesLabel -> {r}, PlotLegends -> (Row[{#, "D"}]& /@ Range[5])]

ハードコア点過程の点はハードコア半径 より近付けない：

Wolfram Language code: region = Ellipsoid[{0, 0}, {1, 2}]; radii = {0.05, 0.1, 0.15}; spds = Table[RandomPointConfiguration[HardcorePointProcess[200, R, 2], region, Method -> {"MCMC", "LengthOfRun" -> 30000}], {R, radii}];
Wolfram Language code: Table[Graphics[Point[spds[[k]]["Points"]], PlotRange -> {{-1, 1}, {-2, 2}}, Frame -> True, FrameLabel -> Row[{"hard-core R = ", radii[[k]]}]], {k, 3}]

Besagの 関数の値を推定する：

Wolfram Language code: rspec = Range[0.01, 0.3, 0.01]; data = Table[BesagL[spd, rspec], {spd, spds}];

結果を可視化する：

Wolfram Language code: ListLinePlot[data, DataRange -> MinMax[rspec], AxesLabel -> {r}, PlotLegends -> (Row[{"hard-core R = ", #}]& /@ radii)]

3つのサンプルについてハードコア半径の推定を求める：

Wolfram Language code: Map[rspec[[FirstPosition[#, _ ? Positive]]]&, data]//Flatten

クラスタデータについてのBesagの 関数は完全に空間ランダムなデータよりも高い．クラスタ過程からサンプルを取る：

Wolfram Language code: reg = Rectangle[{0, 0}, {4, 4}]; ptsT = RandomPointConfiguration[ThomasPointProcess[30, 20, .5, 2], reg];

ポアソン点過程から同じ強度の比較参照サンプルを生成する：

Wolfram Language code: ptsP = RandomPointConfiguration[PoissonPointProcess[30, 2], reg];
Wolfram Language code: ListPlot /@ {ptsP, ptsT}

Besagの 関数を比較する：

Wolfram Language code: rspec = Range[0.02, 2, 0.02];
Wolfram Language code: ListLinePlot[{BesagL[ptsP, rspec], BesagL[ptsT, rspec]}, PlotLegends -> {"Poisson", "Thomas"}, DataRange -> MinMax[rspec], AxesLabel -> {r}]

Besagの 関数を使ってPairCorrelationGを推定する：

Wolfram Language code: reg = Disk[]; pts = RandomPoint[reg, 10 ^ 3];

データからの対相関：

Wolfram Language code: rlist = Range[0.01, 0.2, 0.01];
Wolfram Language code: pc = PairCorrelationG[{pts, reg}, rlist];

Besagの 関数を計算する：

Wolfram Language code: besagL = BesagL[pts]

対相関を推定する：

Wolfram Language code: pcL = PairCorrelationG[{besagL, {0, 0.2, 0.01}}, rlist];

推定値をデータから計算された対相関と比較する：

Wolfram Language code: ListLinePlot[{pc, pcL}, DataRange -> MinMax@rlist, PlotLegends -> {"PC from data", "PC estimated from K"}, AxesLabel -> {r}]

特性と関係  (1)

BesagLは，分散が安定化されたRipleyKである．，ただし，はRipleyの 関数， は空間次元，はにおける単位球の体積である：

Wolfram Language code: region = Ball[{0, 0, 0}]; pts = RandomPoint[region, 100];
Wolfram Language code: v1 = RipleyK[{pts, region}, 0.2]; v2 = BesagL[{pts, region}, 0.2]; Power[v1 / (4Pi / 3), 1 / 3] == v2

考えられる問題  (1)

境界補正がある経験的BesagLは（特に小さい集合については）増加しない：

Wolfram Language code: region = Rectangle[]; SeedRandom["spatial"]; data = RandomPoint[region, 30];
Wolfram Language code: Plot[BesagL[{data, region}][r], {r, 0, 1 / 2}]

補正なしのBesagLは増加する：

Wolfram Language code: Plot[BesagL[{data, region}, r, SpatialBoundaryCorrection -> None], {r, 0, 1 / 2}]
Wolfram Research (2020), BesagL, Wolfram言語関数， https://reference.wolfram.com/language/ref/BesagL.html.

テキスト

Wolfram Research (2020), BesagL, Wolfram言語関数， https://reference.wolfram.com/language/ref/BesagL.html.

CMS

Wolfram Language. 2020. "BesagL." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BesagL.html.

APA

Wolfram Language. (2020). BesagL. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BesagL.html

BibTeX

@misc{reference.wolfram_2026_besagl, author="Wolfram Research", title="{BesagL}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/BesagL.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_besagl, organization={Wolfram Research}, title={BesagL}, year={2020}, url={https://reference.wolfram.com/language/ref/BesagL.html}, note=[Accessed: 09-August-2026]}