WOLFRAM

Wolfram 语言与系统参考资料中心

BesagL[pdata,r]

为在半径 r 的点数据 pdata 计算 Besag 的 函数 .

BesagL[pproc,r]

为点过程 pproc 计算 .

BesagL[bdata,r]

为分箱数据 bdata 计算 .

BesagL[pspec]

生成可重复应用于不同半径 r 的函数 .

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
点数据  
点过程  
选项  
SpatialBoundaryCorrection  
应用  
属性和关系  
可能出现的问题  
参见
相关指南
历史
按以下格式引用：

BesagL

BesagL[pdata,r]

为在半径 r 的点数据 pdata 计算 Besag 的 函数 .

BesagL[pproc,r]

为点过程 pproc 计算 .

BesagL[bdata,r]

为分箱数据 bdata 计算 .

BesagL[pspec]

生成可重复应用于不同半径 r 的函数 .

更多信息和选项

  • BesagL 是 RipleyK 函数的一个变形，可以让与空间上随机参考过程对比变得更简单 .
  • BesagL 定义为 ，其中 是 RipleyK， 是空间维度，而 是 中单元球体的体积.
  • BesagL 度量范围 r 内点集的空间同质性. 与泊松点过程对比，我们有：
  • 比泊松更离散
    类似泊松，即为完全空间随机
    比泊松更聚集
  • 半径 r 可为单个值或一列表的值. 在没有指定半径 r 的情况下，BesagL 返回一个可以用于重复计算 函数的 PointStatisticFunction.
  • 点 pdata 可有如下形式：
  • {p1,p2,…}点 pi
    GeoPosition[…],GeoPositionXYZ[…],…地理点
    SpatialPointData[…]空间点集
    {pts,reg}点集 pts 和观察区域 reg
  • 若未给定观察区域 reg，则会自动使用 RipleyRassonRegion 计算出一个区域.
  • 点过程 pproc 可有如下形式：
  • proc一个点过程 proc
    {proc,reg}一个点过程 proc 和观察区域 reg
  • 观察区域 reg 应该没有参数且 SpatialObservationRegionQ.
  • 分箱数据 bdata 来自于 SpatialBinnedPointData 且被看做是一个带分段的常密度函数的 InhomogeneousPoissonPointProcess.
  • 对于 pdata 而言，通过对相互距离不超过 r 范围内的不同点对进行计数计算出 .
  • 对于 pproc 而言，通过使用精确的公式或模拟生成点数据的方式计算出 .
  • 可以给出下列选项：
  • MethodAutomatic用什么方法
    SpatialBoundaryCorrection Automatic用什么边界校正
  • 下列设置可在 SpatialBoundaryCorrection 中使用：
  • Automatic自动决定边界校正
    None无边界校正
    "BorderMargin"对观察区域使用内部边缘
    "Ripley"根据点到边界的距离使用权重

范例

打开所有单元 关闭所有单元

基本范例  (3)

在给定距离计算 Besag 的 函数：

Wolfram Language code: region = Ball[{0, 0}]; pts = RandomPoint[region, 100];
Wolfram Language code: BesagL[{pts, region}, 0.2]

在一个距离范围内计算 Besag 函数：

Wolfram Language code: spd = SpatialPointData[RandomReal[1, {500, 3}]]
Wolfram Language code: rspec = Range[0.1, 0.4, 0.01];
Wolfram Language code: est = BesagL[spd, rspec];

用 ListPlot 可视化结果：

Wolfram Language code: ListPlot[est, DataRange -> MinMax[rspec], AxesLabel -> {r}, Filling -> Axis]

聚点过程的 Besag 函数：

Wolfram Language code: lfun = BesagL[CauchyPointProcess[μ, λ, b, 2], r]

可视化给定参数值得函数：

Wolfram Language code: Plot[lfun /. {μ -> 3, λ -> 2, b -> 1}, {r, 0, 3}, AxesLabel -> Automatic]

范围  (10)

点数据  (5)

计算距离为 0.2 的 Besag 函数：

Wolfram Language code: region = Rectangle[{0, 0}, {1, 2}]; pts = RandomPoint[region, 100];
Wolfram Language code: BesagL[{pts, region}, 0.2]

从给定距离列表中获取 Besag 函数的经验估值：

Wolfram Language code: BesagL[{pts, region}, {0.1, 0.3, 0.05, 0.23}]

使用带有 SpatialPointData 的 BesagL：

Wolfram Language code: spd = SpatialPointData[RandomReal[1, {500, 2}]]
Wolfram Language code: res = BesagL[spd, {0.01, 0.02}]

创建一个 PointStatisticFunction 以便将来使用：

Wolfram Language code: reg = Disk[]; pts = RandomPoint[Disk[], 100];
Wolfram Language code: psf = BesagL[{pts, reg}]
Wolfram Language code: psf[0.5]

在不明确提供观察区域的情况下计算 Besag 函数：

Wolfram Language code: BlockRandom[SeedRandom[1]; pts = RandomReal[1, {100, 2}]];
Wolfram Language code: psf = BesagL[pts]

由 Ripley–Rasson 估计量生成的观察区域：

Wolfram Language code: psf["ObservationRegion"]

在距离 0.3 处计算 函数：

Wolfram Language code: psf[0.3]

使用有 GeoPosition 的 BesagL：

Wolfram Language code: pts = RandomGeoPosition[GeoDisk[GeoPosition[{0, 0}], Quantity[10, "Kilometers"]], 10 ^ 2]
Wolfram Language code: psf = BesagL[pts]

绘制点统计函数：

Wolfram Language code: ListPlot[Table[{x, psf[x]}, {x, Quantity[0, "km"], psf["MaxRadius"], Quantity[.1, "km"]}], AxesLabel -> {"km"}]

点过程  (5)

PoissonPointProcess 的 Besag 函数不取决于密度或维度：

Wolfram Language code: proc = PoissonPointProcess[μ, d];
Wolfram Language code: BesagL[proc, r]

带有指定维度的集群过程 ThomasPointProcess 的 Besag 函数：

Wolfram Language code: proc2D = ThomasPointProcess[μ, λ, σ, 2];
Wolfram Language code: BesagL[proc2D, r]

三维中：

Wolfram Language code: proc3D = ThomasPointProcess[μ, λ, σ, 3];
Wolfram Language code: BesagL[proc3D, r]

带有指定维度的集群过程 MaternPointProcess 的 Besag 函数：

Wolfram Language code: proc2D = MaternPointProcess[μ, λ, rad, 2];
Wolfram Language code: BesagL[proc2D, r]

三维中：

Wolfram Language code: proc3D = MaternPointProcess[μ, λ, rad, 3];
Wolfram Language code: BesagL[proc3D, rad]

集群过程 CauchyPointProcess 的 Besag 函数：

Wolfram Language code: proc = CauchyPointProcess[μ, λ, b, dim];
Wolfram Language code: BesagL[proc, r]

集群过程 VarianceGammaPointProcess 的 Besag 函数：

Wolfram Language code: proc = VarianceGammaPointProcess[μ, λ, α, β, dim];
Wolfram Language code: BesagL[proc, r]

选项  (2)

SpatialBoundaryCorrection  (2)

没有边界校正的 BesagL 估计量会有偏误，且除非在较大点集的情况下否则不应使用：

Wolfram Language code: region = Rectangle[{0, 0}, {2, 1}]; pts = RandomPoint[region, 100];
Wolfram Language code: r = 0.2;
Wolfram Language code: BesagL[{pts, region}, r, SpatialBoundaryCorrection -> "None"]

默认方法 "BorderMargin" 只包括到边界距离为 的点：

Wolfram Language code: inregion = Rectangle[{r, r}, {2 - r, 1 - r}]; Show[RegionPlot[{region, inregion}, AspectRatio -> Automatic], ListPlot[pts]]
Wolfram Language code: BesagL[{pts, region}, r, SpatialBoundaryCorrection -> "BorderMargin"]

边界校正方法 "Ripley" 对每对点都取权重使该估计量无偏：

Wolfram Language code: BesagL[{pts, region}, r, SpatialBoundaryCorrection -> "Ripley"]

比较不同的边界校正方法：

Wolfram Language code: reg = Ball[{0, 0, 0}]; pts = RandomPoint[reg, 200];

用三种不同的方法计算 Besag 函数的值：

Wolfram Language code: rad = Range[0.01, 0.5, 0.02]; m = {"None", "BorderMargin", "Ripley"};
Wolfram Language code: data = BesagL[{pts, reg}, rad, SpatialBoundaryCorrection -> #]& /@ m;

可视化结果，并与理论值相比较：

Wolfram Language code: val = BesagL[PoissonPointProcess[λ, 3], r]
Wolfram Language code: Show[ListPlot[data, DataRange -> MinMax[rad], PlotLegends -> m], Plot[val, {r, 0, 0.5}, PlotStyle -> Gray, PlotLegends -> {val}], AxesLabel -> {r}]

应用  (5)

由于 Besag 函数在距离上累计，因此是单调递增函数：

Wolfram Language code: region = Ellipsoid[{0, 0}, {2, 3}]; pts = RandomPoint[region, 500];
Wolfram Language code: fun = BesagL[pts]
Wolfram Language code: Plot[fun[r], {r, 0, 1}, AxesLabel -> Automatic]

完全空间随机的 Besag 函数

Wolfram Language code: region[d_] := Ball[d] pts[d_] := RandomPoint[region[d], 1000]

计算数个维度的 Besag 函数：

Wolfram Language code: rspec = Range[0.02, 0.8, 0.02]; data = Table[BesagL[{pts[d], region[d]}, rspec], {d, 1, 5}];

可视化结果：

Wolfram Language code: ListLinePlot[data, DataRange -> MinMax[rspec], AxesLabel -> {r}, PlotLegends -> (Row[{#, "D"}]& /@ Range[5])]

在硬核点过程中的点的距离不能比硬核半径 更近：

Wolfram Language code: region = Ellipsoid[{0, 0}, {1, 2}]; radii = {0.05, 0.1, 0.15}; spds = Table[RandomPointConfiguration[HardcorePointProcess[200, R, 2], region, Method -> {"MCMC", "LengthOfRun" -> 30000}], {R, radii}];
Wolfram Language code: Table[Graphics[Point[spds[[k]]["Points"]], PlotRange -> {{-1, 1}, {-2, 2}}, Frame -> True, FrameLabel -> Row[{"hard-core R = ", radii[[k]]}]], {k, 3}]

计算 Besag 函数的值：

Wolfram Language code: rspec = Range[0.01, 0.3, 0.01]; data = Table[BesagL[spd, rspec], {spd, spds}];

可视化结果：

Wolfram Language code: ListLinePlot[data, DataRange -> MinMax[rspec], AxesLabel -> {r}, PlotLegends -> (Row[{"hard-core R = ", #}]& /@ radii)]

为三个样本计算硬核半径估量：

Wolfram Language code: Map[rspec[[FirstPosition[#, _ ? Positive]]]&, data]//Flatten

集群数据的 Besag 高于完全空间随机数据. 下面是某个集群过程的样本：

Wolfram Language code: reg = Rectangle[{0, 0}, {4, 4}]; ptsT = RandomPointConfiguration[ThomasPointProcess[30, 20, .5, 2], reg];

从相同强度的泊松点过程中生成一个控制样本：

Wolfram Language code: ptsP = RandomPointConfiguration[PoissonPointProcess[30, 2], reg];
Wolfram Language code: ListPlot /@ {ptsP, ptsT}

比较 Besag 函数：

Wolfram Language code: rspec = Range[0.02, 2, 0.02];
Wolfram Language code: ListLinePlot[{BesagL[ptsP, rspec], BesagL[ptsT, rspec]}, PlotLegends -> {"Poisson", "Thomas"}, DataRange -> MinMax[rspec], AxesLabel -> {r}]

使用 Besag 函数计算 PairCorrelationG：

Wolfram Language code: reg = Disk[]; pts = RandomPoint[reg, 10 ^ 3];

数据中的对关联：

Wolfram Language code: rlist = Range[0.01, 0.2, 0.01];
Wolfram Language code: pc = PairCorrelationG[{pts, reg}, rlist];

计算 Besag 函数：

Wolfram Language code: besagL = BesagL[pts]

计算对关联：

Wolfram Language code: pcL = PairCorrelationG[{besagL, {0, 0.2, 0.01}}, rlist];

比较从数据中计算出的对关联估值：

Wolfram Language code: ListLinePlot[{pc, pcL}, DataRange -> MinMax@rlist, PlotLegends -> {"PC from data", "PC estimated from K"}, AxesLabel -> {r}]

属性和关系  (1)

BesagL 是稳定方差 RipleyK: ，其中 是 Ripley's 函数， 是空间维度， 是 中单位球的体积：

Wolfram Language code: region = Ball[{0, 0, 0}]; pts = RandomPoint[region, 100];
Wolfram Language code: v1 = RipleyK[{pts, region}, 0.2]; v2 = BesagL[{pts, region}, 0.2]; Power[v1 / (4Pi / 3), 1 / 3] == v2

可能出现的问题  (1)

有边界校正的经验 BesagL 函数可能不是递增的（尤其对于较小的集合而言）：

Wolfram Language code: region = Rectangle[]; SeedRandom["spatial"]; data = RandomPoint[region, 30];
Wolfram Language code: Plot[BesagL[{data, region}][r], {r, 0, 1 / 2}]

未校正的 BesagL 是递增的：

Wolfram Language code: Plot[BesagL[{data, region}, r, SpatialBoundaryCorrection -> None], {r, 0, 1 / 2}]
Wolfram Research (2020)，BesagL，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BesagL.html.

文本

Wolfram Research (2020)，BesagL，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BesagL.html.

CMS

Wolfram 语言. 2020. "BesagL." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BesagL.html.

APA

Wolfram 语言. (2020). BesagL. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BesagL.html 年

BibTeX

@misc{reference.wolfram_2026_besagl, author="Wolfram Research", title="{BesagL}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/BesagL.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_besagl, organization={Wolfram Research}, title={BesagL}, year={2020}, url={https://reference.wolfram.com/language/ref/BesagL.html}, note=[Accessed: 10-September-2026]}