Wolfram言語＆システムドキュメントセンター

CentralFeature

CentralFeature[{x₁,x₂,…}]

要素の中心特徴を与える．

CentralFeature[{x₁v₁,x₂v₂,…}]

中心特徴に対応する v_iを与える．

CentralFeature[data]

data のいくつかの異なる形についての中心特徴を与える．

詳細とオプション

CentralFeatureは位置測度であり，データ中で他のすべての点までの距離の和が最小である点を与える．
CentralFeatureは，重みがない場合は距離の和が，重みがある場合はが最小になる要素を求める．

データ data には次の形と解釈がある．

	{data₁,data₂,…}	数値，地理空間，テキスト，視覚，日付と時間を含むさまざまなフォーマットのデータおよびその組合せのリスト
	{data₁,data₂,…}{v₁,v₂,…}	指標{v₁,v₂,…}を含むデータ
	{data₁,data₂,…}Automatic	v_iを連続する整数 i であるとみなす
	GeoPosition[…]	測地位置の配列
	WeightedData[…]	重み付きデータ

次は使用可能なオプションである．
DistanceFunction Automatic 使用する距離測度
DistanceFunctionの設定は，任意の距離関数，非類似度関数または2点間の距離を定義する関数 f でよい．
デフォルトで，異なるタイプの要素について次の距離関数が使われる．

	EuclideanDistance	数値データ
	ImageDistance	画像
	JaccardDissimilarity	ブールデータ
	EditDistance	テキストと名義的列
	Abs[DateDifference[#1,#2]]&	日付と時間
	ColorDistance	色
	GeoDistance	地理空間データ
	Boole[SameQ[#1,#2]]&	名義データ
	HammingDistance	名義ベクトルデータ
	WarpingDistance	数列

オプションDistanceFunctionがAutomaticのときは，まずConformImagesを使ってすべての画像が一致するようにされる．
デフォルトで，データ要素が混合タイプのベクトルのときは，距離は各タイプについて別々に計算され，Normを使って組み合される．

例題

すべて開くすべて閉じる

例 (2)

ベクトルリスト中の中心特徴を求める：

Wolfram Language code: CentralFeature[{{1., 3., 5.}, {7., 1., 2.}, {9., 3., 1.}, {4., 5., 6.}}]

指定された重み付きのベクトルのリスト中の中心特徴を求める：

Wolfram Language code: CentralFeature[WeightedData[{{1., 3., 5.}, {-4., 1., 2.}, {3., 3., 1.}, {4., 5., 6.}}, {1., 3., 4., 5.}]]

スコープ (9)

出力形式が異なる同じ入力：

Wolfram Language code: data = {{1, 2}, {3, 4}, {8, 7}, {6, 5}, {9, 4}, {1, 3}};

Wolfram Language code: CentralFeature[data]

Wolfram Language code: CentralFeature[data -> Automatic]

Wolfram Language code: CentralFeature[data -> Table[f[i], {i, 6}]]

Wolfram Language code: CentralFeature[{{1, 2} -> g[1], {3, 4} -> g[2], {8, 7} -> g[3], {6, 5} -> g[4], {9, 4} -> g[5], {1, 3} -> g[6]}]

中心特徴はWeightedDataに使うことができる：

Wolfram Language code: wd = WeightedData[{{1., 3.}, {-4., 2.}, {3., 1.}, {5., 6.}}, {1., 3., 4., 5.}];

Wolfram Language code: CentralFeature[wd]

Wolfram Language code: CentralFeature[wd -> {1, 2, 3, 4}]

大きい配列の中心特徴：

Wolfram Language code: CentralFeature[RandomReal[1, {10 ^ 5, 2}]]

重み付きの中心特徴：

Wolfram Language code: CentralFeature[WeightedData[RandomReal[1, {10 ^ 5, 3}], RandomReal[1, 10 ^ 5]]]

単位付き数量を含むデータの中心特徴を求める：

Wolfram Language code: data = Quantity[RandomReal[1, {6, 2}], "Meters"]

Wolfram Language code: CentralFeature[data]

画像のリストの中心特徴を求める：

Wolfram Language code: CentralFeature[{[image], [image], [image], [image], [image], [image], [image], [image], [image], [image]}]

絵のリスト：

Wolfram Language code: CentralFeature[{[image], [image], [image], [image], [image], [image]}]

3D画像のリスト：

Wolfram Language code: CentralFeature[{[image], [image], [image], [image], [image]}]

"String"型のTabularColumnオブジェクトの中心的な特徴を計算する：

Wolfram Language code: col = TabularColumn[{"abcd", "bcde", "abab", "abcdef", "agi"}]

Wolfram Language code: CentralFeature[col]

ブールベクトルの中心特徴を計算する：

Wolfram Language code: CentralFeature[{{True, False, True}, {True, True, True}, {True, False, False}, {False, False, False}}]

日付オブジェクトのリストの中心特徴を計算する：

Wolfram Language code: CentralFeature[{DateObject[{1985, 10, 3}], DateObject[{1989, 5, 30}], DateObject[{1999, 11, 15}], DateObject[]}]

測地位置の中心特徴を計算する：

Wolfram Language code:

cities = {Entity["City", {"Paris", "IleDeFrance", "France"}], Entity["City", {"Sydney", "NewSouthWales", "Australia"}], Entity["City", {"Boston", "Massachusetts", "UnitedStates"}], Entity["City", {"SanFrancisco", "California", "UnitedStates"}], Entity["City", {"Tokyo", "Tokyo", "Japan"}]};

Wolfram Language code: cf = CentralFeature[GeoPosition[cities]]

Wolfram Language code:

GeoGraphics[{GeoPath[Thread[{cf, cities}]], GeoMarker[cities, Gray], GeoMarker[cf, Red]}, GeoProjection -> {"AzimuthalEquidistant", "Centering" -> cf}, GeoRange -> "World", GeoGridLines -> Automatic]

オプション (2)

DistanceFunction (2)

デフォルトで，ユークリッド距離が使われる：

Wolfram Language code: CentralFeature[RandomVariate[NormalDistribution[], {10, 3}]]

ChessboardDistanceは離れている距離が最大の次元のみを考慮する：

Wolfram Language code: CentralFeature[{{1., 3.}, {-2.6, 4.}, {9.2, 5.}, {7.3, -5.}}, DistanceFunction -> ChessboardDistance]

DistanceFunctionは記号で与えることができる：

Wolfram Language code: dist[{u_, v_}, {x_, y_}] := Sqrt[3(u - x) ^ 2 + 2(v - y) ^ 2]

Wolfram Language code: data = {{1.5, .6}, {2, 0}, {1.25, 1.25}, {3., 0.3}};

Wolfram Language code: CentralFeature[data, DistanceFunction -> dist]

純関数として与えることもできる：

Wolfram Language code: CentralFeature[data, DistanceFunction -> (Sqrt[{3, 2}.(#1 - #2) ^ 2]&)]

アプリケーション (4)

外れ値がある場合に多変量の位置のロバスト推定を得る：

Wolfram Language code: data = {{3., -5.}, {2., -5.}, {0., 2.}, {-4., -3.}, {10 ^ 8, -1.}, {8., -20000}};

Wolfram Language code: CentralFeature[data]

極値はMeanに大きく影響する：

Wolfram Language code: Mean[data]

凸多角形からサンプル点を取る：

Wolfram Language code:

poly = Polygon[{{2., -5.}, {0., 2.}, {-4., -3.}, {-5, -7}}];
pts = RandomPoint[poly, 10 ^ 3];

Wolfram Language code: Graphics[{Lighter[Blue, .9], poly, Black, PointSize[Small], Point[pts]}]

ランダムな点の中心特徴を計算することで，多角形の中心を推定する：

Wolfram Language code: cf = CentralFeature[pts]

Wolfram Language code: Graphics[{Lighter[Blue, .9], poly, Black, PointSize[Small], Point[pts], PointSize[0.06], Red, Point[cf]}]

都市の位置に基づいてカリフォルニア州の中心特徴を求める：

Wolfram Language code:

cities = CityData[{All, "California"}];
locations = GeoPosition[CityData[#, "Coordinates"]& /@ cities];

Wolfram Language code: unweighted = cities[[CentralFeature[locations -> Automatic]]]

人口で重みを付けた都市の位置に基づいてカリフォルニア州の中心特徴を求める：

Wolfram Language code: populations = CityData[#, "Population"]& /@ cities;

Wolfram Language code: weighted = cities[[CentralFeature[WeightedData[locations, populations] -> Automatic]]]

都市の位置（灰色），重みなしの中心特徴（赤），重みありの中心特徴（黒）を描画する：

Wolfram Language code:

legend = PointLegend[{Red, Blue}, {"unweighted central feature", "central feature weighted by population"}, LegendMarkerSize -> Large];

Wolfram Language code:

Legended[GeoGraphics[{EdgeForm[Black], FaceForm[Orange], Polygon[Entity["AdministrativeDivision", {"California", "UnitedStates"}]], GrayLevel[.4], PointSize[0.0075], Point[locations], PointSize[0.04], Red, Point[unweighted], Blue, Point[weighted]}, GeoRange -> {{32, 43}, {-125, -114}}, ImageSize -> 350], Placed[legend, "Bottom"]]

オハイオ州で大きい方から8番目までの都市：

Wolfram Language code: cities = CityData[{Large, "Ohio"}]

TravelDistanceに基づいたこれら8都市の中心特徴：

Wolfram Language code: center = CentralFeature[cities, DistanceFunction -> TravelDistance]

TravelDistanceに基づいた，中心特徴から他の都市までの距離の和：

Wolfram Language code: Total[Table[TravelDistance[center, city], {city, cities}]]

都市の位置（灰色）と中心特徴（赤）を描画する：

Wolfram Language code:

GeoGraphics[{EdgeForm[Black], FaceForm[Orange], Polygon[Entity["AdministrativeDivision", {"Ohio", "UnitedStates"}]], Red, TravelDirections[{center, #}, "TravelPath"]& /@ cities, GrayLevel[.4], PointSize[0.03], Point /@ cities, PointSize[0.03], Red, Point[center]}]

特性と関係 (5)

CentralFeatureは多変量の位置測度である：

Wolfram Language code: pts = {{3, -5}, {2, -5}, {0, 2}, {-4, -3}, {-3, 2}, {-5, -5}, {-1, -5}, {-1, -5}, {5, -1}, {-3, 3}, {10, -1}, {8, -2}};

Wolfram Language code: Graphics[{PointSize[0.03], Orange, Point[pts]}]

Wolfram Language code: cf = CentralFeature[pts]

Meanもまた位置測度である：

Wolfram Language code: mean = Mean[pts]

データ点を中心特徴および平均とともに可視化する：

Wolfram Language code:

Graphics[{PointSize[0.03], Orange, Point[pts], Locator[cf], Blue, PointSize[.04], Point[mean], Gray, Text["Central Feature", cf - {0, .8}], Text["Mean", mean + {0, .8}]}, ImageSize -> 250]

CentralFeatureは距離の和を最小にするデータに属する点を求める：

Wolfram Language code: data = {{1., 3.}, {4., 6.}, {9., 2.}, {5., 5.}, {7., -2.}};

Wolfram Language code: cf = CentralFeature[data]

中心特徴を定義から直接計算する：

Wolfram Language code: sumofdists[x_, y_] := Total[Sqrt[Total[(Transpose[data] - {x, y}) ^ 2]]]

Wolfram Language code:

{ind} = Ordering[sumofdists@@@data, 1];
data[[ind]]

距離関数の和をデータ点とともに可視化する：

Wolfram Language code:

sumofdists = Total[Sqrt[Total[(Transpose[data] - {#1, #2}) ^ 2]]]&;
ContourPlot[sumofdists[x, y], {x, 0, 10}, {y, -3, 8}, Contours -> 10, PlotLegends -> Automatic, Epilog -> {PointSize[Large], Black, Point[data], Red, PointSize[Large], Point[cf], White, Text["Central Feature", cf - {0, 0.7}]}]

CentralFeatureは，データの長さが奇数のときは，一変量データのMedianに等しい：

Wolfram Language code: data = RandomReal[1, 1001];

Wolfram Language code: CentralFeature[data] == Median[data]

CentralFeatureは，他のデータ点までの距離の和を最小にするデータ中の要素を求める：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {10, 3}];

Wolfram Language code: MemberQ[data, CentralFeature[data]]

SpatialMedianは，距離の和を最小にする領域内の点を求める：

Wolfram Language code: MemberQ[data, SpatialMedian[data]]

CentralFeatureについての距離の和はSpatialMedianについてのそれ以上である：

Wolfram Language code: sumofdists = Total[Sqrt[Total[(Transpose[data] - #) ^ 2]]]&;

Wolfram Language code: sumofdists[CentralFeature[data]] ≥ sumofdists[SpatialMedian[data]]

辺の重みが0から1までで一様にサンプルされたランダムグラフを作る：

Wolfram Language code:

SeedRandom[7];
graph = RandomGraph[{10, 15}, EdgeWeight -> RandomReal[1, 15]]

GraphCenterを求める：

Wolfram Language code: GraphCenter[graph]

GraphDistanceを使って各頂点ペア間の距離を求める：

Wolfram Language code: distfun = GraphDistance[graph, #1, #2]&;

CentralFeatureを使って中心を求める：

Wolfram Language code: CentralFeature[Range[10], DistanceFunction -> distfun]

考えられる問題 (1)

CentralFeatureは，重みがない2要素のリストについては最初のリストを返す：

Wolfram Language code: data = {GeoPosition[{20, -30}], GeoPosition[{15, 15}]};

Wolfram Language code: CentralFeature[data]

重みがある2要素のリストについては，重みが最高のものが選択されるが，これはを自明に最小化する：

Wolfram Language code: CentralFeature[WeightedData[data, {1, 2}]]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

CentralFeature

詳細とオプション

例題

例 (2)

スコープ (9)

オプション (2)

DistanceFunction (2)

アプリケーション (4)

特性と関係 (5)

考えられる問題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

CentralFeature

詳細とオプション

例題

例 (2)

スコープ (9)

オプション (2)

DistanceFunction (2)

アプリケーション (4)

特性と関係 (5)

考えられる問題 (1)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX