WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ConformAudio[{audio1,audio2,…}]

すべての audioiの，持続時間，データ型，チャンネル数を含む特性が適合である，音声オブジェクトのリストを返す．

ConformAudio[{audio1,audio2,…},spec]

指定された spec のすべての音声オブジェクトを返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

ConformAudio

ConformAudio[{audio1,audio2,…}]

すべての audioiの，持続時間，データ型，チャンネル数を含む特性が適合である，音声オブジェクトのリストを返す．

ConformAudio[{audio1,audio2,…},spec]

指定された spec のすべての音声オブジェクトを返す．

詳細とオプション

  • ConformAudioは，分類，次元削減，より大きい音声オブジェクトの構築等，なんらかの形で一様な音声オブジェクトを必要とするアルゴリズムの，前処理段階として使われることが多い．
  • 音声指定 spec は次のいずれかでよい．
  • audioaudio から適合特性を取る
    duration秒単位の持続時間
    audiotypeAudioTypeにおけるような音声タイプ
    {spec1,spec2,…}複数特定の指定
  • デフォルトで，すべての audioiに保存されたデータを表す最小の audiotype が使われる．
  • ConformAudio[{audio1,audio2,…}]は，最長の audioiの持続時間になるようにすべての音声を充填する．
  • ConformAudioにはAudioと同じオプションに以下の追加・変更を加えたものが使える． [全オプションのリスト]
  • AudioOutputDeviceAutomatic再生に使用するデフォルトの音声出力デバイス
    SampleRateAutomaticサンプルレート
    Padding0AudioPadで使用可能な充填方法
  • SampleRate->Automaticは，デフォルトで，すべての audioi の中から最も高いサンプルレートを取る．

    • 全オプションのリスト

例題

すべて開く すべて閉じる

例  (1)

音声オブジェクトのリストを適合させる：

Wolfram Language code: in = {AudioGenerator["White", 1, "Real32"], ExampleData[{"Sound", "Piano"}, "Audio"]}; out = ConformAudio[in];

結果の特性は適合している：

Wolfram Language code: props = {AudioLength, AudioChannels, Duration, AudioType, AudioSampleRate};TableForm[Table[p[a], {p, props}, {a, Flatten[{in, First@out}]}], TableHeadings -> {props, {"audio 1", "audio 2", "conformed"}}, TableDepth -> 2]

スコープ  (8)

異なる長さの音声の長さを合わせる：

Wolfram Language code: list = {AudioGenerator["Sin", 1], AudioGenerator["White", 2]};
Wolfram Language code: ConformAudio[list]
Wolfram Language code: Duration[%]

サンプルレートが異なる音声のサンプルレートを合わせる：

Wolfram Language code: list = {AudioGenerator["Sin", SampleRate -> 44100], AudioGenerator["White", SampleRate -> 22050]}; ConformAudio[list]
Wolfram Language code: AudioSampleRate[%]

データ型が異なる音声のデータ型を合わせる：

Wolfram Language code: list = {AudioGenerator["Sin", 1, "SignedInteger16"], AudioGenerator["White", 1, "Real32"]}; ConformAudio[list]
Wolfram Language code: AudioType /@ %

チャンネル数が異なる音声のチャンネル数を合わせる：

Wolfram Language code: list = {AudioGenerator["Sin"], AudioPan@AudioGenerator["White"]}; ConformAudio[list]
Wolfram Language code: AudioChannels /@ %

別のAudioオブジェクトを使って操作を指定して音声を合わせる：

Wolfram Language code: list = {AudioGenerator["Sin", 1, "SignedInteger16"], AudioGenerator["Sin", 2, "SignedInteger8"]}; out = ConformAudio[list, AudioGenerator["Sin", 1.5, "Real32"]];
Wolfram Language code: props = {AudioLength, AudioChannels, Duration, AudioType, AudioSampleRate};TableForm[Table[p[a], {p, props}, {a, Most@Join[list, out]}], TableHeadings -> {props, {"audio 1", "audio 2", "conformed"}}, TableDepth -> 2]

指定した持続時間を使って音声を合わせる：

Wolfram Language code: list = {AudioGenerator["Sin", 1, "SignedInteger16"], AudioGenerator["Sin", 2, "SignedInteger8"]}; out = ConformAudio[list, .1];
Wolfram Language code: props = {AudioLength, AudioChannels, Duration, AudioType, AudioSampleRate};TableForm[Table[p[a], {p, props}, {a, Most@Join[list, out]}], TableHeadings -> {props, {"audio 1", "audio 2", "conformed"}}, TableDepth -> 2]

指定した音声タイプを使って音声を合わせる：

Wolfram Language code: list = {AudioGenerator["Sin", 1, "SignedInteger16"], AudioGenerator["Sin", 2, "SignedInteger8"]}; out = ConformAudio[list, "Real64"];
Wolfram Language code: props = {AudioLength, AudioChannels, Duration, AudioType, AudioSampleRate};TableForm[Table[p[a], {p, props}, {a, Most@Join[list, out]}], TableHeadings -> {props, {"audio 1", "audio 2", "conformed"}}, TableDepth -> 2]

指定のリストを使って音声を合わせる：

Wolfram Language code: list = {AudioGenerator["Sin", 1, "SignedInteger16"], AudioGenerator["Sin", 2, "SignedInteger8"]}; out = ConformAudio[list, {.1, "Real32"}];
Wolfram Language code: props = {AudioLength, AudioChannels, Duration, AudioType, AudioSampleRate};TableForm[Table[p[a], {p, props}, {a, Most@Join[list, out]}], TableHeadings -> {props, {"audio 1", "audio 2", "conformed"}}, TableDepth -> 2]

特性と関係  (1)

ConformAudioを使って音声信号のサンプルを取り直す：

Wolfram Language code: a = AudioGenerator["Sin"]; First@ConformAudio[{a}, SampleRate -> 8000] == AudioResample[a, 8000]
Wolfram Research (2016), ConformAudio, Wolfram言語関数， https://reference.wolfram.com/language/ref/ConformAudio.html （2017年に更新）.

テキスト

Wolfram Research (2016), ConformAudio, Wolfram言語関数， https://reference.wolfram.com/language/ref/ConformAudio.html （2017年に更新）.

CMS

Wolfram Language. 2016. "ConformAudio." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/ConformAudio.html.

APA

Wolfram Language. (2016). ConformAudio. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ConformAudio.html

BibTeX

@misc{reference.wolfram_2026_conformaudio, author="Wolfram Research", title="{ConformAudio}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/ConformAudio.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_conformaudio, organization={Wolfram Research}, title={ConformAudio}, year={2017}, url={https://reference.wolfram.com/language/ref/ConformAudio.html}, note=[Accessed: 12-September-2026]}