WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ConoverTest[{data1,data2,…}]

data1, data2, …の分散が等しいかどうかの検定を行う．

ConoverTest[dspec,]

に対する分散尺度の検定を行う．

ConoverTest[dspec,,"property"]

"property"の値を返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
検定  
レポート  
オプション  
AlternativeHypothesis  
SignificanceLevel  
VerifyTestAssumptions  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

ConoverTest

ConoverTest[{data1,data2,…}]

data1, data2, …の分散が等しいかどうかの検定を行う．

ConoverTest[dspec,]

に対する分散尺度の検定を行う．

ConoverTest[dspec,,"property"]

"property"の値を返す．

詳細とオプション

  • ConoverTestは，帰無仮説 と対立仮説 で検定を行う．
  • {data1,data2}
    {data1,data2,…}すべてが等しいわけではない
  • ただし，σi2は dataiの母分散である．
  • デフォルトで，確率値すなわち 値が返される．
  • 値が小さければ が真である可能性は低い．
  • dspec 中の data は一変量{x1,x2,…}でなければならない．
  • 引数 は任意の正の実数でよい．特に指定されていない限りのデフォルト値は1であり，dspec 内のグループ数が2よりも多い場合は無視される．
  • ConoverTestは data が共通の中央値について対称であると仮定する．
  • ConoverTest[data,,"HypothesisTestData"]は htd["property"]の形で追加的な検定結果と特性の抽出に利用できるHypothesisTestDataオブジェクト htd を返す．
  • ConoverTest[data,,"property"]を使って直接"property"の値を与えることができる．
  • 検定結果のレポートに関連する特性
  • "PValue" 値のリスト
    "PValueTable" 値のフォーマットされた表
    "ShortTestConclusion"検定結果の簡単な説明
    "TestConclusion"検定結果の説明
    "TestData"検定統計と 値のペアのリスト
    "TestDataTable" 値と検定統計のフォーマットされた表
    "TestStatistic"検定統計のリスト
    "TestStatisticTable"検定統計のフォーマットされた表
  • 検定統計はサンプル中央値からの絶対偏差の順位の平方に基づく．
  • サンプル数が 個，つまり datai={xi,1,xi,2,…,xi,ni}での場合，値 xi,jの順位 ri,jはすべての要素 {zi,j}1≤i≤k,1≤j≤ni中の zi,jの順位である．ただし，zi,j=Abs[xi,j-Median[datai]]．検定統計は， が2の場合はで， が2より大きい場合はで与えられる．ただし，, かつ である．
  • の下で，ConoverTestの検定統計は， が2のときはNormalDistribution[0,1]に， が2より大きいときはChiSquareDistribution[k-1]に従うと仮定される．
  • ConoverTestは二乗順位検定と呼ばれることもあり，dataiが正規分布に従っていない場合にはFisherRatioTestの代りとなる．
  • 使用可能なオプション
  • AlternativeHypothesis "Unequal"対立仮説のための不等式
    SignificanceLevel 0.05診断とレポートのための切捨て
    VerifyTestAssumptions Automaticどの診断検定を実行するのかを設定する
  • ConoverTestでは， のときにのみ が棄却されるような切捨て が選ばれる．"TestConclusion"および"ShortTestConclusion"特性に使われる の値はSignificanceLevelオプションで制御される．値 は対称性の検定を含む仮定の診断検定にも使われる．デフォルトで は0.05に設定される．
  • ConoverTestにおけるVerifyTestAssumptionsの名前付き設定
  • "Symmetry"すべてのデータが対称であることを検証する

例題

すべて開く すべて閉じる

例  (2)

2つのデータ集合の分散を等価性について調べる：

Wolfram Language code: data = RandomVariate[LaplaceDistribution[1, 2], {2, 100}];
Wolfram Language code: ConoverTest[data]

さらに特性を抽出するためにHypothesisTestDataオブジェクトを作る：

Wolfram Language code: ℋ = ConoverTest[data, Automatic, "HypothesisTestData"]

調べる特性：

Wolfram Language code: ℋ["Properties"]

2つの母分散比を特定の値について検定する：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, 1], 100]; data2 = RandomVariate[NormalDistribution[0, 2.5], 250];
Wolfram Language code: ConoverTest[{data1, data2}, 1 / 4, "TestDataTable"]
Wolfram Language code: Variance[data1] / Variance[data2]

対立仮説 で検定を行う：

Wolfram Language code: ConoverTest[{data1, data2}, 1 / 4, AlternativeHypothesis -> "Less"]

スコープ  (8)

検定  (6)

2つの母分散を比べる：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, 3], 500]; data2 = RandomVariate[NormalDistribution[1, 3], 500];

の下， 値は[0,1]で一様に分布している：

Wolfram Language code: ConoverTest[{data1, data2}]

Conover検定の 値のサンプルのヒストグラム：

Wolfram Language code: sample = Table[Quiet@ConoverTest[{RandomVariate[NormalDistribution[0, 3], 100], RandomVariate[NormalDistribution[1, 3], 100]}], {5 10 ^ 3}];
Wolfram Language code: Histogram[sample, Automatic, PDF]

が偽のときは， 値は小さいことが多い：

Wolfram Language code: data3 = RandomVariate[NormalDistribution[10, 1], 350];
Wolfram Language code: ConoverTest[{data1, data3}]

2つの母分散比が特定の値であるかどうかを検定する：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, 2], 500]; data2 = RandomVariate[NormalDistribution[0, 1], 500];
Wolfram Language code: Subscript[σ, 0] = 4;

以下の形式は等しい：

Wolfram Language code: ConoverTest[{data1, data2}, Subscript[σ, 0]]
Wolfram Language code: ConoverTest[{data2, data1}, 1 / Subscript[σ, 0]]

を決定する場合には，データ集合の順序を考慮すべきである：

Wolfram Language code: ConoverTest[{data2, data1}, Subscript[σ, 0]]

3つの母集団の分散が同一であるかどうかの検定を行う：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[10, 1], 500]; data2 = RandomVariate[NormalDistribution[0, 1], 200]; data3 = RandomVariate[NormalDistribution[-3, 1], 400];
Wolfram Language code: ConoverTest[{data1, data2, data3}]

繰り返し特性を抽出するためにHypothesisTestDataオブジェクトを作成する：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 10^4}];
Wolfram Language code: ℋ = ConoverTest[data, 1, "HypothesisTestData"];

抽出に使える特性：

Wolfram Language code: ℋ["Properties"]

HypothesisTestDataオブジェクトから特性をいくつか抽出する：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 10^4}];
Wolfram Language code: ℋ = ConoverTest[data, 1, "HypothesisTestData"];

値と検定統計：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatistic"]

任意数の特性を同時に抽出する：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 100}];
Wolfram Language code: ℋ = ConoverTest[data, 1, "HypothesisTestData"];

値と検定統計：

Wolfram Language code: ℋ["PValue", "TestStatistic"]

レポート  (2)

検定結果を表にする：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 10^3}];
Wolfram Language code: ℋ = ConoverTest[data, 1, "HypothesisTestData"];
Wolfram Language code: ℋ["TestDataTable"]

表の値は，"TestData"を使って抽出できる：

Wolfram Language code: ℋ["TestData"]

値あるいは検定統計を表にする：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {3, 10^4}];
Wolfram Language code: ℋ = ConoverTest[data, 1, "HypothesisTestData"];
Wolfram Language code: ℋ["PValueTable"]

表からの 値：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatisticTable"]

表からの検定統計：

Wolfram Language code: ℋ["TestStatistic"]

オプション  (6)

AlternativeHypothesis  (3)

デフォルトで両側検定が行われる：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 100}];
Wolfram Language code: ConoverTest[data, 1, AlternativeHypothesis -> "Unequal"]
Wolfram Language code: ConoverTest[data, 1, AlternativeHypothesis -> Automatic]

両側検定を行う．あるいは2つの片側検定のうちの1つを代りに行う：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, 1], 100]; data2 = RandomVariate[NormalDistribution[0, 1.5], 100];
Wolfram Language code: Variance[data1] / Variance[data2]

対 を検定する：

Wolfram Language code: ConoverTest[{data1, data2}, 1, AlternativeHypothesis -> "Unequal"]

対 を検定する：

Wolfram Language code: ConoverTest[{data1, data2}, 1, AlternativeHypothesis -> "Less"]

対 を検定する：

Wolfram Language code: ConoverTest[{data1, data2}, 1, AlternativeHypothesis -> "Greater"]

ヌル値が与えられている場合に，片側検定を代りに行う：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, .9], 100]; data2 = RandomVariate[NormalDistribution[0, 1], 100];
Wolfram Language code: Variance[data1] / Variance[data2]

対 を検定する：

Wolfram Language code: ConoverTest[{data1, data2}, .75, AlternativeHypothesis -> "Less"]

対 を検定する：

Wolfram Language code: ConoverTest[{data1, data2}, 1.5, AlternativeHypothesis -> "Less"]

SignificanceLevel  (1)

有意水準は"TestConclusion"と"ShortTestConclusion"に使われる：

Wolfram Language code: data = BlockRandom[SeedRandom[1];RandomVariate[NormalDistribution[0, 1], {2, 100}]];
Wolfram Language code: ℋ1 = ConoverTest[data, 2, "HypothesisTestData", SignificanceLevel -> .05];
Wolfram Language code: ℋ2 = ConoverTest[data, 2, "HypothesisTestData", SignificanceLevel -> .01];
Wolfram Language code: ℋ1["TestConclusion"]
Wolfram Language code: ℋ2["TestConclusion"]
Wolfram Language code: ℋ1["ShortTestConclusion"]
Wolfram Language code: ℋ2["ShortTestConclusion"]

VerifyTestAssumptions  (2)

診断は，AllあるいはNoneを使ってまとめて制御することができる：

Wolfram Language code: BlockRandom[SeedRandom[4];data1 = RandomVariate[ExponentialDistribution[1 / Sqrt[3]], 1000]; data2 = RandomVariate[NormalDistribution[0, Sqrt[3]], 1000]];

すべての仮定を検証する：

Wolfram Language code: ConoverTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> All]

どの仮定もチェックしない：

Wolfram Language code: ConoverTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> None]

診断は個々に制御することができる：

Wolfram Language code: BlockRandom[SeedRandom[2];data1 = RandomVariate[ExponentialDistribution[1 / Sqrt[3]], 1000]; data2 = RandomVariate[NormalDistribution[0, Sqrt[3]], 1000]];

対称性をチェックする：

Wolfram Language code: ConoverTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> "Symmetry"]

対称性の仮定をTrueに設定する：

Wolfram Language code: ConoverTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> "Symmetry" -> True]

アプリケーション  (1)

1990年代の前半と後半において，S&P 500の日々の点の変化の分散を比べる：

Wolfram Language code: sp90to95 = FinancialData["SP500", {{1990, 1}, {1994, 12, 31}}]; sp95to00 = FinancialData["SP500", {{1995, 1}, {1999, 12, 31}}];
Wolfram Language code: DateListPlot[{sp90to95, sp95to00}]

データは明らかに正規分布に従っていない：

Wolfram Language code: DistributionFitTest /@ {spA = Differences[sp90to95], spB = Differences[sp95to00]}
Wolfram Language code: SmoothHistogram[{spA, spB}, PlotRange -> All]

1990年代前半における変動量は，後半よりもかなり低い：

Wolfram Language code: ConoverTest[{spA, spB}, 1, "TestDataTable"]

特性と関係  (8)

グループ数が2のとき，検定統計は の下でNormalDistribution[0,1]に従う：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[-5, 1], {1000, 100}]; data2 = RandomVariate[NormalDistribution[3, 1], {1000, 400}];
Wolfram Language code: T = MapThread[ConoverTest[{#1, #2}, Automatic, "TestStatistic", VerifyTestAssumptions -> None]&, {data1, data2}];
Wolfram Language code: Show[Plot[PDF[NormalDistribution[], x], {x, -4, 4}], SmoothHistogram[T, PlotStyle -> Orange]]
Wolfram Language code: DistributionFitTest[T, NormalDistribution[]]

グループ数が ()のとき，検定統計は の下でChiSquareDistribution[k-1]に従う：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[-5, 1], {2000, 600}]; data2 = RandomVariate[NormalDistribution[3, 1], {2000, 500}]; data3 = RandomVariate[NormalDistribution[2, 1], {2000, 400}];
Wolfram Language code: T = MapThread[ConoverTest[{#1, #2, #3}, Automatic, "TestStatistic", VerifyTestAssumptions -> None]&, {data1, data2, data3}];
Wolfram Language code: Show[Histogram[T, Automatic, "PDF"], Plot[PDF[ChiSquareDistribution[2], x], {x, 0, 8}]]
Wolfram Language code: DistributionFitTest[T, ChiSquareDistribution[2]]

FisherRatioTestと違って，Conover検定は正規性を仮定しない：

Wolfram Language code: data1 = RandomVariate[LaplaceDistribution[1, 2], {1000, 100}]; data2 = RandomVariate[LaplaceDistribution[1, 2], {1000, 75}];
Wolfram Language code: fisher = MapThread[FisherRatioTest[{#1, #2}, Automatic, VerifyTestAssumptions -> None]&, {data1, data2}];
Wolfram Language code: conover = MapThread[ConoverTest[{#1, #2}, Automatic, VerifyTestAssumptions -> None]&, {data1, data2}];

FisherRatioTestの結果は， 値を過小評価する：

Wolfram Language code: Histogram[{fisher, conover}, Automatic, "PDF"]

Conover検定は，データが共通の中央値について対称であると仮定する：

Wolfram Language code: data1 = RandomVariate[d1 = NormalDistribution[0, ((25/6))^1 / 2], {1000, 50}]; data2 = RandomVariate[d2 = TriangularDistribution[{-10, 0}], {1000, 50}];
Wolfram Language code: Variance[d1] == Variance[d2]
Wolfram Language code: T = MapThread[ConoverTest[{#1, #2}, Automatic, "TestStatistic", VerifyTestAssumptions -> None]&, {data1, data2}];
Wolfram Language code: Show[Plot[PDF[NormalDistribution[], x], {x, -4, 4}], SmoothHistogram[T, PlotStyle -> Orange]]

検定統計の分布は，データが非対称である場合，標準正規分布に従わない：

Wolfram Language code: DistributionFitTest[T, NormalDistribution[]]

ConoverTestの検定統計は順位に基づく：

Wolfram Language code: n = 1000;m = 750;Subscript[σ, 0] = 2;
Wolfram Language code: data1 = RandomVariate[NormalDistribution[1, Sqrt[6]], n]; data2 = RandomVariate[StudentTDistribution[3], m];

同順位のものがなければ，Orderingを使って順位を計算することができる：

Wolfram Language code: ranks = Ordering[Ordering[Join[Abs[data1 - Median[data1]], Sqrt[Subscript[σ, 0]] Abs[data2 - Median[data2]]]]];
Wolfram Language code: R2 = (1/n + m)Underoverscript[∑, i = 1, n + m]ranks[[i]]^2;
Wolfram Language code: R4 = Underoverscript[∑, i = 1, n + m]ranks[[i]]^4;

検定統計：

Wolfram Language code: (Underoverscript[∑, i = 1, n]ranks[[i]]^2 - n R2) / Sqrt[(m n (-(m + n) R2^2 + R4)/(-1 + m + n) (m + n))]//N
Wolfram Language code: ConoverTest[{data1, data2}, Subscript[σ, 0], "TestStatistic"]

PearsonChiSquareTestを使って，共通の中央値においてデータの対称性を検定する：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[10, 1], 100]; data2 = RandomVariate[NormalDistribution[3, 2], 150]; data3 = RandomVariate[ExponentialDistribution[10], 135];
Wolfram Language code: SymmTest[d1_, d2_] := Block[{d = Sort[Flatten[{d1 - Median[d1], d2 - Median[d2]}]], c, symmDat}, c = Ceiling[(Length[d]/2)];symmDat = Join[d[[1 ;; c]], -d[[1 ;; c]]];PearsonChiSquareTest[symmDat, d]]
Wolfram Language code: SymmTest[data1, data2]

データは対称であり，警告メッセージは出されない：

Wolfram Language code: ConoverTest[{data1, data2}, 1, "TestDataTable", VerifyTestAssumptions -> "Symmetry"]
Wolfram Language code: SymmTest[data2, data3]

警告メッセージの 値は，PearsonChiSquareTestのそれに一致する：

Wolfram Language code: ConoverTest[{data2, data3}, 1, "TestDataTable", VerifyTestAssumptions -> "Symmetry"]

Conover検定は，入力がTimeSeriesのときはタイムスタンプを無視する：

Wolfram Language code: ts1 = TemporalData[TimeSeries, {{{1.224578634529677, 0.47929635789978015, 0.6572781300178168, 0.21496048742669355, 0.7299608014554928, -0.2495111111278263, -1.3286551762002712, 0.552725018274874, 0.19272112205837066, 1.1809144012420882, -1.1671 ... 40938613662046, 1.052394590214582, 0.9345044123980388, 0.38537803109557855, -0.48660931166089394, -0.71203560340161}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: ts2 = TemporalData[TimeSeries, {{{-1.2160757838495546, 0.5212591188357838, -0.0932747538180776, -2.306367634798702, -2.5366722726947994, -0.7924813212437647, -2.65435901675047, -1.1098678592653723, -0.7814091835518528, -1.9685555851254093, -0.0 ... 1001061264, -0.1887471329804458, -2.0547107874294928, -1.3896240275653011, -0.5073077090484948, 0.13302942350391606}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: ConoverTest[{ts1, ts2}]
Wolfram Language code: ConoverTest[{ts1["Values"], ts2["Values"]}]

Conover検定はTemporalDataの経路構造を認識する：

Wolfram Language code: td = TemporalData[Automatic, {{{1.224578634529677, 0.47929635789978015, 0.6572781300178168, 0.21496048742669355, 0.7299608014554928, -0.2495111111278263, -1.3286551762002712, 0.552725018274874, 0.19272112205837066, 1.1809144012420882, -1.16711 ... 01061264, -0.1887471329804458, -2.0547107874294928, -1.3896240275653011, -0.5073077090484948, 0.13302942350391606}}, {{0, 100, 1}}, 2, {"Continuous", 2}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: ConoverTest[td]

値を直接使う：

Wolfram Language code: ConoverTest[td["ValueList"]]

考えられる問題  (3)

データは，共通の中央値において対称でなければならない：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 1000]; data2 = RandomVariate[NormalDistribution[10, 1], 1000]; data3 = RandomVariate[ParetoDistribution[1, 2], 1000];

位置のシフトを考慮に入れると，最初の2つのデータ集合は対称である：

Wolfram Language code: SmoothHistogram[Join[data1 - Median[data1], data2 - Median[data2]]]
Wolfram Language code: ConoverTest[{data1, data2}, VerifyTestAssumptions -> "Symmetry"]

最後2つのデータ集合は，共通の中央値において対称ではない：

Wolfram Language code: SmoothHistogram[Join[data2 - Median[data2], data3 - Median[data3]], PlotRange -> All]
Wolfram Language code: ConoverTest[{data2, data3}, VerifyTestAssumptions -> "Symmetry"]

グループ数が2より多いとき，Conover検定は引数 を無視する：

Wolfram Language code: data = RandomVariate[NormalDistribution[1, 2], {4, 100}];
Wolfram Language code: Length[data]
Wolfram Language code: ConoverTest[data, 2, "TestDataTable"]

データ内に2より多いグループがある場合，Conover検定は対立仮説として両側検定しか認めない：

Wolfram Language code: data = RandomVariate[NormalDistribution[1, 2], {4, 100}];
Wolfram Language code: ConoverTest[data, 1, AlternativeHypothesis -> "Unequal"]
Wolfram Language code: ConoverTest[data, 1, AlternativeHypothesis -> "Greater"]
Wolfram Language code: ConoverTest[data, 1, AlternativeHypothesis -> "Less"]

おもしろい例題  (1)

帰無仮説 が真であるときの統計量を計算する：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], {250, 100}]; data2 = RandomVariate[NormalDistribution[], {250, 100}];
Wolfram Language code: T1 = MapThread[ConoverTest[{#1, #2}, 1, "TestStatistic"]&, {data1, data2}];

特定の対立仮説によって与えられた検定統計：

Wolfram Language code: T2 = MapThread[ConoverTest[{#1, #2}, 2, "TestStatistic"]&, {data1, data2}];

検定統計の分布を比較する：

Wolfram Language code: SmoothHistogram[{T1, T2}, Filling -> Axis, PlotLegends -> {"SubscriptBox[H, 0] is True", "SubscriptBox[H, 0] is False"}]
Wolfram Research (2010), ConoverTest, Wolfram言語関数， https://reference.wolfram.com/language/ref/ConoverTest.html （2017年に更新）.

テキスト

Wolfram Research (2010), ConoverTest, Wolfram言語関数， https://reference.wolfram.com/language/ref/ConoverTest.html （2017年に更新）.

CMS

Wolfram Language. 2010. "ConoverTest." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/ConoverTest.html.

APA

Wolfram Language. (2010). ConoverTest. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ConoverTest.html

BibTeX

@misc{reference.wolfram_2026_conovertest, author="Wolfram Research", title="{ConoverTest}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/ConoverTest.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_conovertest, organization={Wolfram Research}, title={ConoverTest}, year={2017}, url={https://reference.wolfram.com/language/ref/ConoverTest.html}, note=[Accessed: 14-September-2026]}