WOLFRAM

Wolfram 语言与系统参考资料中心

ConoverTest[{data1,data2,…}]

检验 data1 和 data2 的方差是否相等.

ConoverTest[dspec,]

检验一个离散量数和 的关系.

ConoverTest[dspec,,"property"]

返回 "property" 的值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
检验  
报告  
选项  
AlternativeHypothesis  
SignificanceLevel  
VerifyTestAssumptions  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

ConoverTest

ConoverTest[{data1,data2,…}]

检验 data1 和 data2 的方差是否相等.

ConoverTest[dspec,]

检验一个离散量数和 的关系.

ConoverTest[dspec,,"property"]

返回 "property" 的值.

更多信息和选项

  • ConoverTest 检验零假设 与备择假设 ：
  • {data1,data2}
    {data1,data2,…}不是都相等
  • 其中 σi2 是 datai 的总体方差.
  • 默认情况下，返回一个概率值或者 值.
  • 一个较小的 值表明 不可能为真.
  • dspec 中的 data 必须是单变量 {x1,x2,…}.
  • 变量 可以是任意正实数. 如果没有指定， 的默认值为 1，如果 dspec 中的组数大于 2，则将其忽略.
  • ConoverTest 假设 data 关于一个共同的中位数对称.
  • ConoverTest[data,,"HypothesisTestData"] 返回一个 HypothesisTestData 对象 htd，使用 htd["property"] 的形式可以用来提取额外检验结果和属性.
  • ConoverTest[data,,"property"] 可以用于直接给出 "property" 值.
  • 与检验结果的报告相关的属性包括：
  • "PValue" 值组成的列表
    "PValueTable" 值组成的格式化表格
    "ShortTestConclusion"检验结论的简短描述
    "TestConclusion"检验结论的描述
    "TestData"检验统计量和 值对组成的列表
    "TestDataTable" 值和检验统计量组成的格式化表格
    "TestStatistic"检验统计量组成的列表
    "TestStatisticTable"检验统计量组成的格式化表格
  • 检验统计量基于样本中位数绝对偏差的平方等级.
  • 对于有 个样本的情况，，其中 datai={xi,1,xi,2,…,xi,ni}，值 xi,j 的秩 ri,j 是 zi,j 在所有元素 {zi,j}1≤i≤k,1≤j≤ni 中的秩，其中 zi,j=Abs[xi,j-Median[datai]]. 等于 2 时，检验统计量为 ， 大于 2 时，为 ，其中 ，，.
  • 在零假设 条件下， 等于 2 时，假定 ConoverTest 的检验统计量服从 NormalDistribution[0,1]， 大于 2 时，服从 ChiSquareDistribution[k-1].
  • ConoverTest 有时候被称为平方秩检验，并且当 datai 不服从正态分布时，可以作为 FisherRatioTest 的一种可能的替换.
  • 可以使用以下选项：
  • AlternativeHypothesis "Unequal"备择假定的不等性
    SignificanceLevel 0.05用于诊断和报告的分界点
    VerifyTestAssumptions Automatic设置要运行哪个诊断检验
  • 对于 ConoverTest，选择一个临界值 ，使得只有当 时，拒绝 . 用于 "TestConclusion" 和 "ShortTestConclusion" 属性的 值由 SignificanceLevel 选项控制. 值也用于包括对称性检验的假设的诊断检验中. 默认情况下， 设置为 0.05.
  • 在 ConoverTest 中，VerifyTestAssumptions 的已命名设置包括：
  • "Symmetry"验证所有数据都是对称的

范例

打开所有单元 关闭所有单元

基本范例  (2)

检验两个数据总体集合的方差的相等性：

Wolfram Language code: data = RandomVariate[LaplaceDistribution[1, 2], {2, 100}];
Wolfram Language code: ConoverTest[data]

创建一个 HypothesisTestData 对象，用于进一步的属性提取：

Wolfram Language code: ℋ = ConoverTest[data, Automatic, "HypothesisTestData"]

检验属性：

Wolfram Language code: ℋ["Properties"]

检验两个数据总体集合的方差比率与一个特定值的关系：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, 1], 100]; data2 = RandomVariate[NormalDistribution[0, 2.5], 250];
Wolfram Language code: ConoverTest[{data1, data2}, 1 / 4, "TestDataTable"]
Wolfram Language code: Variance[data1] / Variance[data2]

对备择假设 执行检验：

Wolfram Language code: ConoverTest[{data1, data2}, 1 / 4, AlternativeHypothesis -> "Less"]

范围  (8)

检验  (6)

比较两个数据总体的方差：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, 3], 500]; data2 = RandomVariate[NormalDistribution[1, 3], 500];

在零假设 条件下， 值在 [0,1] 之间均匀分布：

Wolfram Language code: ConoverTest[{data1, data2}]

Conover 检验 值样本的直方图：

Wolfram Language code: sample = Table[Quiet@ConoverTest[{RandomVariate[NormalDistribution[0, 3], 100], RandomVariate[NormalDistribution[1, 3], 100]}], {5 10 ^ 3}];
Wolfram Language code: Histogram[sample, Automatic, PDF]

当 为假时， 值通常较小：

Wolfram Language code: data3 = RandomVariate[NormalDistribution[10, 1], 350];
Wolfram Language code: ConoverTest[{data1, data3}]

检验两个数据总体的方差比率是否等于一个特定的值：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, 2], 500]; data2 = RandomVariate[NormalDistribution[0, 1], 500];
Wolfram Language code: Subscript[σ, 0] = 4;

以下形式是等价的：

Wolfram Language code: ConoverTest[{data1, data2}, Subscript[σ, 0]]
Wolfram Language code: ConoverTest[{data2, data1}, 1 / Subscript[σ, 0]]

当确定 时，需要考虑数据集的顺序：

Wolfram Language code: ConoverTest[{data2, data1}, Subscript[σ, 0]]

检验三个总体的方差是否相等：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[10, 1], 500]; data2 = RandomVariate[NormalDistribution[0, 1], 200]; data3 = RandomVariate[NormalDistribution[-3, 1], 400];
Wolfram Language code: ConoverTest[{data1, data2, data3}]

创建一个 HypothesisTestData 对象，用于重复属性提取：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 10^4}];
Wolfram Language code: ℋ = ConoverTest[data, 1, "HypothesisTestData"];

可用于提取的属性：

Wolfram Language code: ℋ["Properties"]

从一个 HypothesisTestData 对象提取某些属性：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 10^4}];
Wolfram Language code: ℋ = ConoverTest[data, 1, "HypothesisTestData"];

值和检验统计量：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatistic"]

同时提取任意数目的属性：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 100}];
Wolfram Language code: ℋ = ConoverTest[data, 1, "HypothesisTestData"];

值和检验统计量：

Wolfram Language code: ℋ["PValue", "TestStatistic"]

报告  (2)

将检验结果制作成表格：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 10^3}];
Wolfram Language code: ℋ = ConoverTest[data, 1, "HypothesisTestData"];
Wolfram Language code: ℋ["TestDataTable"]

使用 "TestData" 可以提取表格中的值：

Wolfram Language code: ℋ["TestData"]

将 值或者检验统计量制作成表格：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {3, 10^4}];
Wolfram Language code: ℋ = ConoverTest[data, 1, "HypothesisTestData"];
Wolfram Language code: ℋ["PValueTable"]

来自表格的 值：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatisticTable"]

来自表格的检验统计量：

Wolfram Language code: ℋ["TestStatistic"]

选项  (6)

AlternativeHypothesis  (3)

默认情况下，执行一个双侧检验：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 100}];
Wolfram Language code: ConoverTest[data, 1, AlternativeHypothesis -> "Unequal"]
Wolfram Language code: ConoverTest[data, 1, AlternativeHypothesis -> Automatic]

执行一个双侧检验或者一个单侧检验：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, 1], 100]; data2 = RandomVariate[NormalDistribution[0, 1.5], 100];
Wolfram Language code: Variance[data1] / Variance[data2]

检验 ⟷ :

Wolfram Language code: ConoverTest[{data1, data2}, 1, AlternativeHypothesis -> "Unequal"]

检验 ⟷ :

Wolfram Language code: ConoverTest[{data1, data2}, 1, AlternativeHypothesis -> "Less"]

检验 ⟷ :

Wolfram Language code: ConoverTest[{data1, data2}, 1, AlternativeHypothesis -> "Greater"]

当均值为零时，执行单侧检验：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, .9], 100]; data2 = RandomVariate[NormalDistribution[0, 1], 100];
Wolfram Language code: Variance[data1] / Variance[data2]

检验 ⟷ :

Wolfram Language code: ConoverTest[{data1, data2}, .75, AlternativeHypothesis -> "Less"]

检验 ⟷ :

Wolfram Language code: ConoverTest[{data1, data2}, 1.5, AlternativeHypothesis -> "Less"]

SignificanceLevel  (1)

对 "TestConclusion" 和 "ShortTestConclusion" 也使用显著性水平：

Wolfram Language code: data = BlockRandom[SeedRandom[1];RandomVariate[NormalDistribution[0, 1], {2, 100}]];
Wolfram Language code: ℋ1 = ConoverTest[data, 2, "HypothesisTestData", SignificanceLevel -> .05];
Wolfram Language code: ℋ2 = ConoverTest[data, 2, "HypothesisTestData", SignificanceLevel -> .01];
Wolfram Language code: ℋ1["TestConclusion"]
Wolfram Language code: ℋ2["TestConclusion"]
Wolfram Language code: ℋ1["ShortTestConclusion"]
Wolfram Language code: ℋ2["ShortTestConclusion"]

VerifyTestAssumptions  (2)

使用 All 或者 None，可以以分组方式控制诊断：

Wolfram Language code: BlockRandom[SeedRandom[4];data1 = RandomVariate[ExponentialDistribution[1 / Sqrt[3]], 1000]; data2 = RandomVariate[NormalDistribution[0, Sqrt[3]], 1000]];

验证所有假定：

Wolfram Language code: ConoverTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> All]

不对假定进行检查：

Wolfram Language code: ConoverTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> None]

诊断可以独立控制：

Wolfram Language code: BlockRandom[SeedRandom[2];data1 = RandomVariate[ExponentialDistribution[1 / Sqrt[3]], 1000]; data2 = RandomVariate[NormalDistribution[0, Sqrt[3]], 1000]];

检查对称性：

Wolfram Language code: ConoverTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> "Symmetry"]

设置对称假设为 True：

Wolfram Language code: ConoverTest[{data1, data2}, 1 / 4, VerifyTestAssumptions -> "Symmetry" -> True]

应用  (1)

比较 90 年代前期和 90 年代后期标普 500 指数的每日点变化的方差：

Wolfram Language code: sp90to95 = FinancialData["SP500", {{1990, 1}, {1994, 12, 31}}]; sp95to00 = FinancialData["SP500", {{1995, 1}, {1999, 12, 31}}];
Wolfram Language code: DateListPlot[{sp90to95, sp95to00}]

明显地，数据不服从正态分布：

Wolfram Language code: DistributionFitTest /@ {spA = Differences[sp90to95], spB = Differences[sp95to00]}
Wolfram Language code: SmoothHistogram[{spA, spB}, PlotRange -> All]

90 年代前期的方差比后期的方差明显小：

Wolfram Language code: ConoverTest[{spA, spB}, 1, "TestDataTable"]

属性和关系  (8)

在 下，当组数为 2 时，检验统计量服从 NormalDistribution[0,1]：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[-5, 1], {1000, 100}]; data2 = RandomVariate[NormalDistribution[3, 1], {1000, 400}];
Wolfram Language code: T = MapThread[ConoverTest[{#1, #2}, Automatic, "TestStatistic", VerifyTestAssumptions -> None]&, {data1, data2}];
Wolfram Language code: Show[Plot[PDF[NormalDistribution[], x], {x, -4, 4}], SmoothHistogram[T, PlotStyle -> Orange]]
Wolfram Language code: DistributionFitTest[T, NormalDistribution[]]

在零假设 条件下，当组数为 且 时，检验统计量服从 ChiSquareDistribution[k-1]：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[-5, 1], {2000, 600}]; data2 = RandomVariate[NormalDistribution[3, 1], {2000, 500}]; data3 = RandomVariate[NormalDistribution[2, 1], {2000, 400}];
Wolfram Language code: T = MapThread[ConoverTest[{#1, #2, #3}, Automatic, "TestStatistic", VerifyTestAssumptions -> None]&, {data1, data2, data3}];
Wolfram Language code: Show[Histogram[T, Automatic, "PDF"], Plot[PDF[ChiSquareDistribution[2], x], {x, 0, 8}]]
Wolfram Language code: DistributionFitTest[T, ChiSquareDistribution[2]]

与 FisherRatioTest 不同，Conover 检验并不假定正态性成立：

Wolfram Language code: data1 = RandomVariate[LaplaceDistribution[1, 2], {1000, 100}]; data2 = RandomVariate[LaplaceDistribution[1, 2], {1000, 75}];
Wolfram Language code: fisher = MapThread[FisherRatioTest[{#1, #2}, Automatic, VerifyTestAssumptions -> None]&, {data1, data2}];
Wolfram Language code: conover = MapThread[ConoverTest[{#1, #2}, Automatic, VerifyTestAssumptions -> None]&, {data1, data2}];

FisherRatioTest 导致对 -值的低估：

Wolfram Language code: Histogram[{fisher, conover}, Automatic, "PDF"]

Conover 检验假设数据关于一个共同的中位数对称：

Wolfram Language code: data1 = RandomVariate[d1 = NormalDistribution[0, ((25/6))^1 / 2], {1000, 50}]; data2 = RandomVariate[d2 = TriangularDistribution[{-10, 0}], {1000, 50}];
Wolfram Language code: Variance[d1] == Variance[d2]
Wolfram Language code: T = MapThread[ConoverTest[{#1, #2}, Automatic, "TestStatistic", VerifyTestAssumptions -> None]&, {data1, data2}];
Wolfram Language code: Show[Plot[PDF[NormalDistribution[], x], {x, -4, 4}], SmoothHistogram[T, PlotStyle -> Orange]]

当数据不对称时，检验统计量的分布不是标准正态分布：

Wolfram Language code: DistributionFitTest[T, NormalDistribution[]]

ConoverTest 的检验统计量是基于秩的：

Wolfram Language code: n = 1000;m = 750;Subscript[σ, 0] = 2;
Wolfram Language code: data1 = RandomVariate[NormalDistribution[1, Sqrt[6]], n]; data2 = RandomVariate[StudentTDistribution[3], m];

在值不相等的情况下，可以使用 Ordering 计算秩：

Wolfram Language code: ranks = Ordering[Ordering[Join[Abs[data1 - Median[data1]], Sqrt[Subscript[σ, 0]] Abs[data2 - Median[data2]]]]];
Wolfram Language code: R2 = (1/n + m)Underoverscript[∑, i = 1, n + m]ranks[[i]]^2;
Wolfram Language code: R4 = Underoverscript[∑, i = 1, n + m]ranks[[i]]^4;

检验统计量：

Wolfram Language code: (Underoverscript[∑, i = 1, n]ranks[[i]]^2 - n R2) / Sqrt[(m n (-(m + n) R2^2 + R4)/(-1 + m + n) (m + n))]//N
Wolfram Language code: ConoverTest[{data1, data2}, Subscript[σ, 0], "TestStatistic"]

使用 PearsonChiSquareTest 检验数据关于共同的中位数的对称性：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[10, 1], 100]; data2 = RandomVariate[NormalDistribution[3, 2], 150]; data3 = RandomVariate[ExponentialDistribution[10], 135];
Wolfram Language code: SymmTest[d1_, d2_] := Block[{d = Sort[Flatten[{d1 - Median[d1], d2 - Median[d2]}]], c, symmDat}, c = Ceiling[(Length[d]/2)];symmDat = Join[d[[1 ;; c]], -d[[1 ;; c]]];PearsonChiSquareTest[symmDat, d]]
Wolfram Language code: SymmTest[data1, data2]

可以看出数据是对称的，并且没有发出警告信息：

Wolfram Language code: ConoverTest[{data1, data2}, 1, "TestDataTable", VerifyTestAssumptions -> "Symmetry"]
Wolfram Language code: SymmTest[data2, data3]

警告信息中的 值与 PearsonChiSquareTest 中的一致：

Wolfram Language code: ConoverTest[{data2, data3}, 1, "TestDataTable", VerifyTestAssumptions -> "Symmetry"]

当输入是 TimeSeries 时 Conover 检验将忽略时间戳：

Wolfram Language code: ts1 = TemporalData[TimeSeries, {{{1.224578634529677, 0.47929635789978015, 0.6572781300178168, 0.21496048742669355, 0.7299608014554928, -0.2495111111278263, -1.3286551762002712, 0.552725018274874, 0.19272112205837066, 1.1809144012420882, -1.1671 ... 40938613662046, 1.052394590214582, 0.9345044123980388, 0.38537803109557855, -0.48660931166089394, -0.71203560340161}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: ts2 = TemporalData[TimeSeries, {{{-1.2160757838495546, 0.5212591188357838, -0.0932747538180776, -2.306367634798702, -2.5366722726947994, -0.7924813212437647, -2.65435901675047, -1.1098678592653723, -0.7814091835518528, -1.9685555851254093, -0.0 ... 1001061264, -0.1887471329804458, -2.0547107874294928, -1.3896240275653011, -0.5073077090484948, 0.13302942350391606}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: ConoverTest[{ts1, ts2}]
Wolfram Language code: ConoverTest[{ts1["Values"], ts2["Values"]}]

Conover 检验对具有正好两个路径的 TemporalData 的路径结构进行识别：

Wolfram Language code: td = TemporalData[Automatic, {{{1.224578634529677, 0.47929635789978015, 0.6572781300178168, 0.21496048742669355, 0.7299608014554928, -0.2495111111278263, -1.3286551762002712, 0.552725018274874, 0.19272112205837066, 1.1809144012420882, -1.16711 ... 01061264, -0.1887471329804458, -2.0547107874294928, -1.3896240275653011, -0.5073077090484948, 0.13302942350391606}}, {{0, 100, 1}}, 2, {"Continuous", 2}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: ConoverTest[td]

直接使用值：

Wolfram Language code: ConoverTest[td["ValueList"]]

可能存在的问题  (3)

数据应该关于一个共同的中位数对称：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 1000]; data2 = RandomVariate[NormalDistribution[10, 1], 1000]; data3 = RandomVariate[ParetoDistribution[1, 2], 1000];

在考虑位置上的平移后，前两个数据集是对称的：

Wolfram Language code: SmoothHistogram[Join[data1 - Median[data1], data2 - Median[data2]]]
Wolfram Language code: ConoverTest[{data1, data2}, VerifyTestAssumptions -> "Symmetry"]

后两个数据集关于它们共同的中位数不是对称的：

Wolfram Language code: SmoothHistogram[Join[data2 - Median[data2], data3 - Median[data3]], PlotRange -> All]
Wolfram Language code: ConoverTest[{data2, data3}, VerifyTestAssumptions -> "Symmetry"]

当组数超过两个时，Conover 检验忽略参数 ：

Wolfram Language code: data = RandomVariate[NormalDistribution[1, 2], {4, 100}];
Wolfram Language code: Length[data]
Wolfram Language code: ConoverTest[data, 2, "TestDataTable"]

当组数超过两个时，Conover 检验只允许对备择假设进行双侧检验

Wolfram Language code: data = RandomVariate[NormalDistribution[1, 2], {4, 100}];
Wolfram Language code: ConoverTest[data, 1, AlternativeHypothesis -> "Unequal"]
Wolfram Language code: ConoverTest[data, 1, AlternativeHypothesis -> "Greater"]
Wolfram Language code: ConoverTest[data, 1, AlternativeHypothesis -> "Less"]

巧妙范例  (1)

计算零假设 为真时的统计量：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], {250, 100}]; data2 = RandomVariate[NormalDistribution[], {250, 100}];
Wolfram Language code: T1 = MapThread[ConoverTest[{#1, #2}, 1, "TestStatistic"]&, {data1, data2}];

给出特定选择时的检验统计量：

Wolfram Language code: T2 = MapThread[ConoverTest[{#1, #2}, 2, "TestStatistic"]&, {data1, data2}];

比较检验统计量的分布：

Wolfram Language code: SmoothHistogram[{T1, T2}, Filling -> Axis, PlotLegends -> {"SubscriptBox[H, 0] is True", "SubscriptBox[H, 0] is False"}]
Wolfram Research (2010)，ConoverTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ConoverTest.html （更新于 2017 年）.

文本

Wolfram Research (2010)，ConoverTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ConoverTest.html （更新于 2017 年）.

CMS

Wolfram 语言. 2010. "ConoverTest." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2017. https://reference.wolfram.com/language/ref/ConoverTest.html.

APA

Wolfram 语言. (2010). ConoverTest. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ConoverTest.html 年

BibTeX

@misc{reference.wolfram_2026_conovertest, author="Wolfram Research", title="{ConoverTest}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/ConoverTest.html}", note=[Accessed: 05-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_conovertest, organization={Wolfram Research}, title={ConoverTest}, year={2017}, url={https://reference.wolfram.com/language/ref/ConoverTest.html}, note=[Accessed: 05-September-2026]}