WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CopulaDistribution[ker,{dist1,dist2,…}]

カーネル分布 ker，周辺分布 dist1, dist2, … のコピュラ分布を表す．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
基本的な用法  
コピュラカーネル  
パラメトリック分布  
ノンパラメトリック分布  
派生分布  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

CopulaDistribution

CopulaDistribution[ker,{dist1,dist2,…}]

カーネル分布 ker，周辺分布 dist1, dist2, … のコピュラ分布を表す．

詳細

  • 累積分布関数は で与えられる．ただし，はカーネル ker の累積分布関数，は distiの累積分布関数である．
  • 周辺分布 distiは任意の一変量分布でよい．
  • 次のカーネル ker を使うことができる．
  • "Product"独立分布
    "Maximal"Frechét–Hoeffding上界
    "Minimal"Frechét–Hoeffding下界
    {"Frank",α}Frankコピュラ
    {"Clayton",c}Clayton–Paretoコピュラ
    {"GumbelHougaard",α}Gumbel–Hougaardコピュラ
    {"FGM",α}Farlie–Gumbel–Morgensternコピュラ
    {"AMH",α}Ali–Mikhail–Haqコピュラ
    {"Binormal",ρ}相関が の二変量ガウス分布
    {"Multinormal",Σ}共分散が の多変量ガウス分布
    {"MultivariateT",Σ,ν}尺度行列 ，自由度 の多変量 分布
  • "Frank"の場合， は二次元の任意の正の数，あるいは，二次元より上の次元では，特定の定数 以下の任意の正の数でよい．
  • "Clayton"の場合は， は任意の正の数でよい．
  • "GumbelHougaard"の場合は， は1以上の任意の実数でよい．
  • "FGM"と"AMH"の場合は， はからまでの任意の実数でよい．
  • "Binormal"，"Multinormal"，"MultivariateT"の母数はそれぞれBinormalDistribution，MultinormalDistribution，MultivariateTDistributionのものと同じである．
  • CopulaDistributionは，Mean，PDF，RandomVariate等の関数とともに使うことができる．

予備知識

  • CopulaDistribution[ker,{dist1,dist2,…,distn}]は，第 周辺分布(MarginalDistribution)が厳密に distjであり，distjに従う確率変量の累積分布関数が一様分布(UniformDistribution)に従う多変量統計分布を表す．一般的なコピュラ分布CopulaDistribution[ker,{dist1,dist2,…,distn}]については，Yj=TransformedDistribution[Fj[x],xdistj]の確率密度関数(PDF)は，Fj[x]が distjの累積分布関数である場合は常にUniformDistribution[]に等しい．コピュラ分布はすべて上記の特性を有するが，特定のコピュラ分布の特徴と動作はそのカーネル ker と周辺分布 dist1,dist2,…,distnに依存する．
  • コピュラ分布は，実際のところ，変数間の依存関係を説明するツールであり，この文脈では，ker を変えることでさまざまな依存度を調べることができる（例：{"FGM",α}は変数間の弱い依存関係の分析ができ，"Product"は独立変数の分析ができる）．コピュラ分布のパラメータ化に使える定義済みのカーネル ker は11個あり，独立・従属カーネル（"Product"，"Maximal"，"Minimal"），アルキメデスカーネル（{"Frank",α}，ただし，のときはで のときは ，についての{"Clayton",c}，についての {"GumbelHougaard",α}，についての{"AMH",α}），分布派生カーネル（BinormalDistributionにおけるような ρ についての{"Binormal",ρ}，MultinormalDistributionにおけるような Σ についての{"Multinormal",Σ}，MultivariateTDistributionにおけるような Σ および ν についての{"MultivariateT",Σ,ν}，非結合カーネル（について{"FGM",α}）の4つのグループに分けることができる．メンバーは定性的あるいは理論的に同じような特性を共有する．
  • Sklarの定理は，関係 を介して任意の結合分布 とその一変量周辺分布 を「カップル」にするコピュラ が存在し，したがって，コピュラ分布が多変量統計のいたるところに存在することを証明した．コピュラ分布は1940年代にまで遡ることができるが，今日使用されている用語と構造の多くは1950年代から1960年代にかけて開発されたものである．コピュラは，その萌芽期より，信頼性理論，気象学，待ち行列理論を含むさまざまな分野における現象のモデル化に使われている．また，生存分析における生存コピュラや金融工学におけるパニックコピュラのように，各分野のツールとなるように特別な目的を持ったコピュラおよびカーネルも開発されている．コピュラ分布は，モンテカルロ理論や応用数学でも，他とは無関係の理論的興味を集めている．
  • CopulaDistribution[ker,{dist1,…,distn}]と他のさまざまな分布の間には，パラメータ ker と distjによって数多くの関係がある．すべての分布 distjについて，CopulaDistribution["Product",{dist1,…,distn}]はProductDistribution[dist1,…,distn]に等しく，2つのNormalDistributionの積コピュラはBinormalDistributionである．さらに，積コピュラは，CopulaDistribution["Product",{dist1,…,distn}]の確率密度分布が，すべての分布 distjについて，CopulaDistribution[{"Binormal",0},{dist1,…,distn}]のそれと厳密に等しいという意味で，ゼロ相関の二項正規コピュラと等しい．分布由来カーネルの中で，NormalDistributionに従う周辺分布のある二項正規コピュラとStudentTDistributionに従う周辺分布のある多変量 コピュラは，それぞれBinormalDistributionとMultivariateTDistributionに等しい．また，アルキメデスコピュラとさまざまな分布の間には定性的に同じような関係が数限りなく存在する．

例題

すべて開く すべて閉じる

例  (3)

積コピュラを定義する：

Wolfram Language code: 𝒟 = CopulaDistribution["Product", {GeometricDistribution[.3], PoissonDistribution[4]}];
Wolfram Language code: DiscretePlot3D[PDF[𝒟, {x, y}], {x, 0, 9}, {y, 0, 9}, ExtentSize -> Full]

Farlie–Gumbel–Morgenstern(FGM)コピュラを定義する：

Wolfram Language code: 𝒟 = CopulaDistribution[{"FGM", .2}, {NormalDistribution[-1, 2], NormalDistribution[1, 1 / 2]}];
Wolfram Language code: Plot3D[PDF[𝒟, {x, y}]//Evaluate, {x, -6, 3}, {y, -1, 3}]

三次元最大コピュラを定義する：

Wolfram Language code: 𝒟 = CopulaDistribution["Maximal", Table[UniformDistribution[], {i, 3}]];
Wolfram Language code: CDF[𝒟, {x, y, z}]//FullSimplify

スコープ  (32)

基本的な用法  (6)

2つの正規分布を使って積コピュラを定義する：

Wolfram Language code: 𝒟 = CopulaDistribution["Product", {NormalDistribution[2, 3], NormalDistribution[4, 5]} ];

確率密度関数：

Wolfram Language code: Plot3D[PDF[𝒟, {x, y}], {x, -10, 12}, {y, -10, 14}, PlotRange -> All]
Wolfram Language code: PDF[𝒟, {x, y}]

累積分布関数：

Wolfram Language code: Plot3D[CDF[𝒟, {x, y}], {x, -15, 35}, {y, -10, 40}, PlotRange -> All]
Wolfram Language code: CDF[𝒟, {x, y}]

2つの一様分布を使ってFrankコピュラを定義する：

Wolfram Language code: 𝒟 = CopulaDistribution[{"Frank", 6}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]} ];

確率ベクトルを生成する：

Wolfram Language code: data = RandomVariate[𝒟, 10 ^ 4];
Wolfram Language code: Histogram3D[data, {{0, 1, 0.1}, {0, 1, 0.1}}, "PDF"]

平均と分散を比較する：

Wolfram Language code: {Mean[𝒟]//N, Mean[data]}
Wolfram Language code: {Variance[𝒟]//N, Variance[data]}

ベータ分布に従うFGMコピュラを定義する：

Wolfram Language code: 𝒟 = CopulaDistribution[{"FGM", -.7}, {BetaDistribution[2, 1], BetaDistribution[3, 1]}];
Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 1}, {y, 0, 1}]
Wolfram Language code: PDF[𝒟, {x, y}]

モーメントとモーメント母関数：

Wolfram Language code: Moment[𝒟, {r, k}]
Wolfram Language code: MomentGeneratingFunction[𝒟, {s, t}]

離散成分を持つ最大コピュラを定義する：

Wolfram Language code: 𝒟 = CopulaDistribution["Maximal", {GeometricDistribution[.3], BinomialDistribution[5, .4]}];

確率密度関数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 8}, {y, 0, 8}, ExtentSize -> Full]

確率と期待値を計算する：

Wolfram Language code: NProbability[x + y < 1 / 3, {x, y}𝒟]
Wolfram Language code: NExpectation[x ^ 3 + y ^ 4, {x, y}𝒟]

ポアソン分布に従う最小コピュラを定義する：

Wolfram Language code: 𝒟 = CopulaDistribution["Minimal", {PoissonDistribution[9], PoissonDistribution[3]}];

確率密度関数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 16}, {y, 0, 16}, ExtentSize -> Full]

統計特性は成分ごとに計算される：

Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]
Wolfram Language code: Skewness[𝒟]
Wolfram Language code: Kurtosis[𝒟]

分布母数を推定する：

Wolfram Language code: 𝒞 = CopulaDistribution[{"Binormal", ρ}, {UniformDistribution[{0, 1}], NormalDistribution[]}];
Wolfram Language code: data = Block[{ρ = .2}, RandomVariate[𝒞, 10 ^ 3]];
Wolfram Language code: EstimatedDistribution[data, 𝒞]

コピュラカーネル  (11)

積コピュラ：

Wolfram Language code: 𝒟 = CopulaDistribution["Product", {UniformDistribution[], UniformDistribution[]}];

確率密度関数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}, PlotRange -> All]
Wolfram Language code: PDF[𝒟, {x, y}]

累積分布関数：

Wolfram Language code: CDF[𝒟, {x, y}]

最大コピュラ：

Wolfram Language code: 𝒟 = CopulaDistribution["Maximal", {UniformDistribution[], UniformDistribution[]}];

累積分布関数：

Wolfram Language code: Plot3D[Evaluate[CDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}, Exclusions -> None]
Wolfram Language code: CDF[𝒟, {x, y}]

最小コピュラ：

Wolfram Language code: 𝒟 = CopulaDistribution["Minimal", {UniformDistribution[], UniformDistribution[]}];

累積分布関数：

Wolfram Language code: Plot3D[Evaluate[CDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}, Exclusions -> None]
Wolfram Language code: CDF[𝒟, {x, y}]

Frankコピュラ：

Wolfram Language code: 𝒟 = CopulaDistribution[{"Frank", 3}, {UniformDistribution[], UniformDistribution[]}];

確率密度関数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}]
Wolfram Language code: PDF[𝒟, {x, y}]

累積分布関数：

Wolfram Language code: CDF[𝒟, {x, y}]

Claytonコピュラ：

Wolfram Language code: 𝒟 = CopulaDistribution[{"Clayton", 3}, {UniformDistribution[], UniformDistribution[]}];

確率密度関数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}]
Wolfram Language code: PDF[𝒟, {x, y}]

累積分布関数：

Wolfram Language code: CDF[𝒟, {x, y}]

Gumbel–Hougaardコピュラ：

Wolfram Language code: 𝒟 = CopulaDistribution[{"GumbelHougaard", 3}, {UniformDistribution[], UniformDistribution[]}];

確率密度関数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}]
Wolfram Language code: PDF[𝒟, {x, y}]//PiecewiseExpand

累積分布関数：

Wolfram Language code: CDF[𝒟, {x, y}]

Farlie-Gordon-Morgensternコピュラ：

Wolfram Language code: 𝒟 = CopulaDistribution[{"FGM", 1 / 3}, {UniformDistribution[], UniformDistribution[]}];

確率密度関数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}]
Wolfram Language code: PDF[𝒟, {x, y}]//PiecewiseExpand

累積分布関数：

Wolfram Language code: CDF[𝒟, {x, y}]//Simplify

Ali–Mikhail–Haqueコピュラ：

Wolfram Language code: 𝒟 = CopulaDistribution[{"AMH", 2 / 3}, {UniformDistribution[], UniformDistribution[]}];

確率密度関数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}]
Wolfram Language code: PDF[𝒟, {x, y}]//PiecewiseExpand

累積分布関数：

Wolfram Language code: CDF[𝒟, {x, y}]//Simplify

二変量正規コピュラ：

Wolfram Language code: 𝒟 = CopulaDistribution[{"Binormal", 1 / 2}, {UniformDistribution[], UniformDistribution[]}];
Wolfram Language code: PDF[𝒟, {x, y}]

確率密度関数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.1}, {y, -0.2, 1.1}]
Wolfram Language code: PDF[𝒟, {x, y}]

多変量正規コピュラ：

Wolfram Language code: 𝒟 = CopulaDistribution[{"Multinormal", {{4, -1 / 2}, {-1 / 2, 3}}}, {UniformDistribution[], UniformDistribution[]}];

確率密度関数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}]
Wolfram Language code: PDF[𝒟, {x, y}]//Simplify

多変量スチューデント コピュラ：

Wolfram Language code: 𝒟 = CopulaDistribution[{"MultivariateT", {{1, 2 / 3}, {2 / 3, 5}}, 2}, {UniformDistribution[], UniformDistribution[]}];

確率密度関数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.1, 1.1}, {y, -0.1, 1.1}, Exclusions -> {{x(1 - x) == 0, 0 ≤ y ≤ 1}, {y(1 - y) == 0, 0 ≤ x ≤ 1}}]
Wolfram Language code: PDF[𝒟, {1 / 3, 2 / 3}]//Simplify

パラメトリック分布  (4)

周辺分布がベータ分布である最小コピュラを定義する：

Wolfram Language code: 𝒟 = CopulaDistribution["Minimal", {BetaDistribution[2, 3], BetaDistribution[3, 2]}];

累積分布関数：

Wolfram Language code: Plot3D[Evaluate[CDF[𝒟, {x, y}]], {x, 0, 1}, {y, 0, 1}, Exclusions -> None]
Wolfram Language code: CDF[𝒟, {x, y}]

生存関数：

Wolfram Language code: SurvivalFunction[𝒟, {x, y}]

異なる連続周辺分布の最大コピュラを定義する：

Wolfram Language code: 𝒟 = CopulaDistribution["Maximal", {GammaDistribution[3, 2 / 3], ExponentialDistribution[2]}];

累積分布関数：

Wolfram Language code: Plot3D[CDF[𝒟, {x, y}], {x, 0, 6}, {y, 0, 6}, Exclusions -> None]
Wolfram Language code: CDF[𝒟, {x, y}]

平均と分散：

Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]

歪度と尖度：

Wolfram Language code: Skewness[𝒟]
Wolfram Language code: Kurtosis[𝒟]

ポアソン周辺分布のコピュラを定義する：

Wolfram Language code: 𝒟 = CopulaDistribution[{"FGM", 1 / 3}, {PoissonDistribution[2], PoissonDistribution[3]}];

確率密度関数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 9}, {y, 0, 9}, ExtentSize -> 0.5]

ハザード関数：

Wolfram Language code: DiscretePlot3D[Evaluate[HazardFunction[𝒟, {x, y}]], {x, 0, 9}, {y, 0, 9}, ExtentSize -> 0.5]

負の二項分布が周辺分布のコピュラを定義する：

Wolfram Language code: 𝒟 = CopulaDistribution[{"Frank", 1 / 4}, {NegativeBinomialDistribution[10, .8], NegativeBinomialDistribution[10, .5]}];

確率密度関数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 10}, {y, 0, 20}, ExtentSize -> 0.5]

乱数を生成する：

Wolfram Language code: Histogram3D[RandomVariate[𝒟, 10 ^ 4], {{-0.5, 10.5, 1}, {-0.5, 20.5, 1}}, "PDF"]

ノンパラメトリック分布  (3)

SmoothKernelDistributionのコピュラ分布を定義する：

Wolfram Language code: skd1 = SmoothKernelDistribution[RandomVariate[FrechetDistribution[2, 3], 10 ^ 3]]; skd2 = SmoothKernelDistribution[RandomVariate[NormalDistribution[], 10 ^ 3]]; 𝒟 = CopulaDistribution[{"AMH", -0.3}, {skd1, skd2}];

確率密度関数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 10}, {y, -3, 3}]

平均と分散：

Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]

EmpiricalDistributionのコピュラ分布を定義する：

Wolfram Language code: ed1 = EmpiricalDistribution[RandomVariate[BorelTannerDistribution[.3, 10], 20]]; ed2 = EmpiricalDistribution[RandomVariate[PoissonDistribution[9], 10]]; 𝒟 = CopulaDistribution[{"Frank", 20}, {ed1, ed2}];

確率密度関数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 9, 20}, {y, 4, 14}, PlotRange -> All, ExtentSize -> 2 / 3]

HistogramDistributionのコピュラ分布を定義する：

Wolfram Language code: hd = HistogramDistribution[RandomVariate[NormalDistribution[], 10 ^ 2]]; 𝒟 = CopulaDistribution[{"Clayton", 3}, {hd, LaplaceDistribution[0, 1]}];

確率密度関数をプロットする：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -3, 3}, {y, -3, 3}, PlotRange -> All, ExclusionsStyle -> {None, Black}]

累積分布関数をプロットする：

Wolfram Language code: Plot3D[Evaluate[CDF[𝒟, {x, y}]], {x, -3, 3}, {y, -3, 3}, PlotRange -> All, ExclusionsStyle -> {None, Black}]

派生分布  (8)

TruncatedDistributionを周辺分布としてコピュラ分布を定義する：

Wolfram Language code: 𝒯 = TruncatedDistribution[{0, 1}, ExponentialDistribution[2]]; 𝒟 = CopulaDistribution[{"Frank", 100}, {𝒯, UniformDistribution[{0, 1}]}];

確率密度関数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 1}, {y, 0, 1}, PlotRange -> All]
Wolfram Language code: PDF[𝒟, {x, y}]

CensoredDistributionを周辺分布としてコピュラ分布を定義する：

Wolfram Language code: 𝒞 = CensoredDistribution[{3, 7}, PoissonDistribution[5]]; 𝒟 = CopulaDistribution[{"Clayton", 14}, {BenfordDistribution[8], 𝒞}];

確率密度関数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 8}, {y, 2, 8}, ExtentSize -> 1 / 2]

平均と分散：

Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]//N

MixtureDistributionを周辺分布としてコピュラ分布を定義する：

Wolfram Language code: ℳ = MixtureDistribution[{1, 2}, {NormalDistribution[-1.5, 1 / 2], NormalDistribution[1.5, 1 / 2]}]; 𝒟 = CopulaDistribution[{"AMH", 0.3}, {ℳ, NormalDistribution[]}];

確率密度関数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -3, 3}, {y, -3, 3}, PlotRange -> All]

累積分布関数：

Wolfram Language code: CDF[𝒟, {x, y}]

ParameterMixtureDistributionを周辺分布としてコピュラ分布を定義する：

Wolfram Language code: ℳ = ParameterMixtureDistribution[GeometricDistribution[p], pBetaDistribution[.3, 4]]; 𝒟 = CopulaDistribution[{"AMH", -.7}, {ℳ, PoissonDistribution[8]}];

確率密度関数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 10}, {y, 0, 16}, ExtentSize -> 1 / 2]

ハザード関数：

Wolfram Language code: DiscretePlot3D[Evaluate[HazardFunction[𝒟, {x, y}]], {x, 5, 20}, {y, 5, 20}, ExtentSize -> 1 / 2]

OrderDistributionを周辺分布としてコピュラ分布を定義する：

Wolfram Language code: 𝒪 = OrderDistribution[{GumbelDistribution[3, 2], 10}, 5]; 𝒟 = CopulaDistribution[{"Clayton", 3}, {𝒪, CauchyDistribution[0, 1]}];

確率密度関数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -2, 5}, {y, -3, 3}, PlotRange -> All]

累積分布関数：

Wolfram Language code: CDF[𝒟, {x, y}]//FullSimplify

TransformedDistributionを周辺分布としてコピュラ分布を定義する：

Wolfram Language code: 𝒯 = TransformedDistribution[u ^ 3 + u, uNormalDistribution[]]; 𝒟 = CopulaDistribution[{"FGM", -0.5}, {𝒯, NormalDistribution[]}];

確率密度関数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -3, 3}, {y, -3, 3}, PlotRange -> All]

平均と分散：

Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]

歪度と尖度：

Wolfram Language code: Skewness[𝒟]
Wolfram Language code: Kurtosis[𝒟]

MarginalDistributionを周辺分布としてコピュラ分布を定義する：

Wolfram Language code: 𝒹 = NegativeMultinomialDistribution[2, {.2, .3, .4}]; ℳ1 = MarginalDistribution[𝒹, 1]; ℳ2 = MarginalDistribution[𝒹, 2]; 𝒟 = CopulaDistribution["Product", {ℳ1, ℳ2}];

確率密度関数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 10}, {y, 0, 10}, ExtentSize -> 1 / 2]

QuantityDistributionが周辺分布のコピュラ分布を評価するとQuantityDistributionになる：

Wolfram Language code: 𝒹1 = NormalDistribution[Quantity[0, "Meters"], Quantity[0.2, "Meters"]]; 𝒹2 = QuantityDistribution[StudentTDistribution[3], "Seconds"];
Wolfram Language code: 𝒟 = CopulaDistribution[{"MultivariateT", {{1, 1 / 3}, {1 / 3, 1}}, 10}, {𝒹1, 𝒹2}]

平均と分散：

Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]

アプリケーション  (6)

4つの部品からなるシステムがある．それぞれの部品の寿命は1時間あたりを母数として指数的に分布している．故障までの時間に対する依存度はα1/3のFarlie–Gumbel–Morgensternコピュラ分布でモデル化される．500時間経ってもどの部品も故障していない確率を求める：

Wolfram Language code: comp𝒟 = ExponentialDistribution[Quantity[1/1000, 1/"Hours"]];
Wolfram Language code: joint𝒟 = CopulaDistribution[{"FGM", 1 / 3}, {comp𝒟, comp𝒟, comp𝒟, comp𝒟}];
Wolfram Language code: SurvivalFunction[joint𝒟, {Quantity[500, "Hours"], Quantity[500, "Hours"], Quantity[500, "Hours"], Quantity[500, "Hours"]}]//Simplify
Wolfram Language code: N[%]
Wolfram Language code: ExactlyK[k_, v_] := BooleanCountingFunction[{k}, Length[v]]@@v

部品の1つが1000時間後に故障する確率を求める：

Wolfram Language code: Table[NProbability[ExactlyK[m, {t1 > Quantity[1000, "Hours"], t2 > Quantity[1000, "Hours"], t3 > Quantity[1000, "Hours"], t4 > Quantity[1000, "Hours"]}], {t1, t2, t3, t4}joint𝒟], {m, 0, 4}]//Quiet
Wolfram Language code: Total[%]

2つの資産の値がそれぞれドリフト と ，ボラティリティ と で幾何ブラウン運動に従うと仮定する．両方の初期値を1と仮定して，時間 における両方の資産の連結累積分布関数の境界を求める：

Wolfram Language code: 𝒞min = CopulaDistribution["Minimal", {LogNormalDistribution[Log[1] + (Subscript[μ, X] - 1 / 2 Subscript[σ, X] ^ 2)T, Subscript[σ, X] Sqrt[T] ], LogNormalDistribution[Log[1] + (Subscript[μ, Y] - 1 / 2 Subscript[σ, Y] ^ 2)T, Subscript[σ, Y]Sqrt[T]]}]; 𝒞max = CopulaDistribution["Maximal", {LogNormalDistribution[Log[1] + (Subscript[μ, X] - 1 / 2 Subscript[σ, X] ^ 2)T, Subscript[σ, X] Sqrt[T]], LogNormalDistribution[Log[1] + (Subscript[μ, Y] - 1 / 2 Subscript[σ, Y] ^ 2)T, Subscript[σ, Y]Sqrt[T]]}];

下界：

Wolfram Language code: CDF[𝒞min, {x, y}]

上界：

Wolfram Language code: CDF[𝒞max, {x, y}]

以下の値を仮定して累積分布関数のプロットを比較する：

Wolfram Language code: values = {Subscript[μ, X] -> 0, Subscript[μ, Y] -> 0, Subscript[σ, X] -> 0.2, Subscript[σ, Y] -> 0.2, T -> 5};
Wolfram Language code: Plot3D[CDF[First[#] /. values, {x, y}]//Evaluate, {x, 0.3, 2}, {y, 0.3, 2}, Exclusions -> None, PlotLabel -> Last[#]]& /@ {{𝒞min, "minimal"}, {𝒞max, "maximal"}}

2つの会社にそれぞれ と の負債があり，双方とも初期資産が1であったと仮定する．資産の値がそれぞれドリフト と ，ボラティリティ と で幾何ブラウン運動に従うと仮定する．Frankコピュラを仮定して時間 におけるデフォルトの連結確率を求める：

Wolfram Language code: values = {Subscript[μ, X] -> 0, Subscript[μ, Y] -> 0, Subscript[σ, X] -> 0.3, Subscript[σ, Y] -> 0.2, T -> 6, Subscript[d, 1] -> 0.5, Subscript[d, 2] -> 0.6}; 𝒟 = CopulaDistribution[{"Frank", α}, {LogNormalDistribution[Log[1] + (Subscript[μ, X] - 1 / 2 Subscript[σ, X] ^ 2)T, Subscript[σ, X] Sqrt[T]], LogNormalDistribution[Log[1] + (Subscript[μ, Y] - 1 / 2 Subscript[σ, Y] ^ 2)T, Subscript[σ, Y]Sqrt[T]]}] /. values;

α に依存するデフォルト確率：

Wolfram Language code: CDF[𝒟, {0.5, 0.6}]//FullSimplify
Wolfram Language code: Plot[CDF[𝒟, {0.5, 0.6}], {α, 0, 100}, Filling -> Axis]

極限値：

Wolfram Language code: Limit[CDF[𝒟, {0.5, 0.6}], α -> 0, Direction -> -1]
Wolfram Language code: Limit[CDF[𝒟, {0.5, 0.6}], α -> ∞]

コーシーコピュラは自由度1の多変量スチューデント コピュラである：

Wolfram Language code: CauchyCopula = CopulaDistribution[{"MultivariateT", {{1, 2 / 3}, {2 / 3, 5}}, 1}, {UniformDistribution[], UniformDistribution[]}];

確率密度関数：

Wolfram Language code: Plot3D[PDF[CauchyCopula, {x, y}], {x, -0.1, 1.1}, {y, -0.1, 1.1}, Exclusions -> {{x(1 - x) == 0, 0 ≤ y ≤ 1}, {y(1 - y) == 0, 0 ≤ x ≤ 1}}, Evaluated -> True]
Wolfram Language code: PDF[CauchyCopula, {x, y}]//FullSimplify[#, 0 < x < 1 / 2 && 0 < y < 1 / 2]&//TraditionalForm

散布図を使って密度を可視化する：

Wolfram Language code: sample = RandomVariate[CauchyCopula, 3000]; ListPlot[sample]

母数の異なる値についてGumbel–Hougaardコピュラを定義する：

Wolfram Language code: 𝒟[α_] = CopulaDistribution[{"GumbelHougaard", α}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];

母数の値が値間の依存関係にどのように影響するかを示す：

Wolfram Language code: Table[ListPlot[RandomVariate[𝒟[α], 10 ^ 3], PlotLabel -> Row[{"α = ", α}]], {α, {1, 3, 10, 60}}]

Gumbelの二変量ロジスティック分布はロジスティック周辺分布を持つAMHコピュラ分布である：

Wolfram Language code: GumbelLogistic𝒟 = CopulaDistribution[{"AMH", 1}, {LogisticDistribution[], LogisticDistribution[]}];

確率密度関数を可視化する：

Wolfram Language code: pdf = PDF[GumbelLogistic𝒟, {x, y}]//Simplify
Wolfram Language code: Plot3D[pdf, {x, -5, 4}, {y, -5, 4}]

累積分布関数は，一変量ロジスティック分布の累積分布関数の構造を持つ：

Wolfram Language code: CDF[GumbelLogistic𝒟, {x, y}] == (1 + Exp[-x] + Exp[-y])^-1//Simplify

特性と関係  (5)

2つの正規分布の積コピュラ分布は二変量正規分布である：

Wolfram Language code: PDF[CopulaDistribution["Product", {NormalDistribution[μ1, σ1], NormalDistribution[μ2, σ2]} ], {x, y}]
Wolfram Language code: PDF[BinormalDistribution[{μ1, μ2}, {σ1, σ2}, 0], {x, y}]
Wolfram Language code: % - %%//FullSimplify

積コピュラはゼロ相関の二変量正規コピュラに等しい：

Wolfram Language code: PDF[CopulaDistribution["Product", {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}], {x, y}]
Wolfram Language code: PDF[CopulaDistribution[{"Binormal", 0}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}], {x, y}]//PiecewiseExpand
Wolfram Language code: % - %%//Simplify

周辺分布が正規分布の二変量正規コピュラはBinormalDistributionである：

Wolfram Language code: 𝒞 = CopulaDistribution[{"Binormal", ρ}, {NormalDistribution[μ1, σ1], NormalDistribution[μ2, σ2]}];
Wolfram Language code: PDF[𝒞, {x, y}]
Wolfram Language code: PDF[BinormalDistribution[{μ1, μ2}, {σ1, σ2}, ρ], {x, y}]
Wolfram Language code: FullSimplify[% - %%]

周辺分布がスチューデント ’分布の多変量 コピュラはMultivariateTDistributionである：

Wolfram Language code: 𝒞 = CopulaDistribution[{"MultivariateT", {{1, ρ}, {ρ, 1}}, ν}, {StudentTDistribution[ν], StudentTDistribution[ν]}];
Wolfram Language code: PDF[𝒞, {x, y}]//Simplify
Wolfram Language code: PDF[MultivariateTDistribution[{{1, ρ}, {ρ, 1}}, ν], {x, y}]//Simplify
Wolfram Language code: FullSimplify[% - %%, ν > 0 && 0 < ρ < 1 && x∈Reals && y∈Reals]

コピュラのMarginalDistributionは成分分布を返す：

Wolfram Language code: 𝒟 = CopulaDistribution["Minimal", {BetaDistribution[α, β], ExponentialDistribution[λ]}];
Wolfram Language code: MarginalDistribution[𝒟, 1]
Wolfram Language code: MarginalDistribution[𝒟, 2]

考えられる問題  (1)

CopulaDistributionは周辺分布としてProductDistributionを取らない：

Wolfram Language code: 𝒫 = ProductDistribution[ExponentialDistribution[2], UniformDistribution[{0, 1}]]; 𝒟 = CopulaDistribution[{"FGM", .9}, {𝒫, NormalDistribution[]}];
Wolfram Language code: RandomVariate[𝒟]

すべての分布をリストに入れるのが正しいシンタックスである：

Wolfram Language code: 𝒞 = CopulaDistribution[{"FGM", .9}, {ExponentialDistribution[2], UniformDistribution[{0, 1}], NormalDistribution[]}];
Wolfram Language code: PDF[𝒞, {x, y, z}]
Wolfram Language code: Mean[𝒞]

おもしろい例題  (2)

周辺分布が一様分布であるいくつかのコピュラカーネル：

Wolfram Language code: ParallelTable[Plot3D[CDF[CopulaDistribution[c, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}], {x, y}]//Evaluate, {x, -0.1, 1.1}, {y, -0.1, 1.1}, PlotLabel -> c, Mesh -> None, ColorFunction -> "Pastel", Ticks -> None], {c, {"Minimal", "Maximal", "Product", {"Frank", 1 / 2}, {"Clayton", 5}, {"GumbelHougaard", 2}, {"FGM", 1 / 3}, {"AMH", 1 / 2}, {"Binormal", 1 / 2}}}]

周辺分布が異なるFrankコピュラ：

Wolfram Language code: Table[Plot3D[CDF[CopulaDistribution[{"Frank", 1 / 2}, {UniformDistribution[{0, 1}], d}], {x, y}]//Evaluate, {x, 0, 1}, {y, -3, 3}, PlotLabel -> d, Mesh -> None, ColorFunction -> "SandyTerrain", PlotRange -> All], {d, {UniformDistribution[{0, 1}], ExponentialDistribution[2], NormalDistribution[0, 1], LaplaceDistribution[0, 1], GumbelDistribution[1, 2], WeibullDistribution[2, 1]}}]
Wolfram Research (2010), CopulaDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/CopulaDistribution.html （2016年に更新）.

テキスト

Wolfram Research (2010), CopulaDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/CopulaDistribution.html （2016年に更新）.

CMS

Wolfram Language. 2010. "CopulaDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/CopulaDistribution.html.

APA

Wolfram Language. (2010). CopulaDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CopulaDistribution.html

BibTeX

@misc{reference.wolfram_2026_copuladistribution, author="Wolfram Research", title="{CopulaDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/CopulaDistribution.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_copuladistribution, organization={Wolfram Research}, title={CopulaDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/CopulaDistribution.html}, note=[Accessed: 10-September-2026]}