WOLFRAM

Wolfram 语言与系统参考资料中心

CopulaDistribution[ker,{dist1,dist2,…}]

表示核分布为 ker、边缘分布为 dist1、dist2、… 的 Copula 分布.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
基本用途  
Copula 核  
参数分布  
非参数分布  
导出分布  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

CopulaDistribution

CopulaDistribution[ker,{dist1,dist2,…}]

表示核分布为 ker、边缘分布为 dist1、dist2、… 的 Copula 分布.

更多信息

  • 累积分布函数由 给出，其中 为核 ker 的累积分布函数， 为 disti 的累积分布函数.
  • 边际分布 disti 可为任一单变量分布.
  • 可以使用下列核 ker：
  • "Product"独立分布
    "Maximal"Frechét–Hoeffding 上界
    "Minimal"Frechét–Hoeffding 下界
    {"Frank",α}Frank copula
    {"Clayton",c}Clayton–Pareto copula
    {"GumbelHougaard",α}Gumbel–Hougaard copula
    {"FGM",α}Farlie–Gumbel–Morgenstern copula
    {"AMH",α}Ali–Mikhail–Haq copula
    {"Binormal",ρ}相关系数为 的二元高斯分布
    {"Multinormal",Σ}协方差为 的多变量高斯分布
    {"MultivariateT",Σ,ν}缩放矩阵为 、自由度为 的多变量 分布
  • 对于 "Frank"，二维情况下， 可以是任何正数，高于二维的情况下，则可以是任何小于或等于某个常数 的正数.
  • 对于 "Clayton"， 可以是任意正数.
  • 对于 "GumbelHougaard"， 可以是任意大于或者等于 1 的实数.
  • 对于 "FGM" 和 "AMH"， 可以是任意 和 之间的实数.
  • "Binormal"、"Multinormal" 和 "MultivariateT" 的参数分别与 BinormalDistribution、MultinormalDistribution 和 MultivariateTDistribution 的参数相同.
  • CopulaDistribution 可与 Mean、PDF 以及 RandomVariate 等函数联合使用.

背景

  • CopulaDistribution[ker,{dist1,dist2,…,distn}] 表示一个第 个边际分布（MarginalDistribution）为 distj 的多变量统计分布，并且 distj 分布随机变量的 CDF 遵循均匀分布（UniformDistribution）. 对于更一般的 copula 分布 CopulaDistribution[ker,{dist1,dist2,…,distn}] 而言，当 Fj[x] 是 distj 的 CDF 时 Yj=TransformedDistribution[Fj[x],xdistj] 的概率密度函数（PDF）等价于 UniformDistribution[]. 尽管所有 copula 分布都有上述属性，但一个具体 copula 分布的特性和行为取决于其核 ker 及其边缘 dist1,dist2,…,distn.
  • 事实上，copula 是描述变量之间的依赖性的工具，在这里，改变 ker 可以对不同依存度进行研究（比如 {"FGM",α} 能最好地对弱变量关联建模，而 "Product" 允许对独立变量的分析）. 有 11 个可用于参数化一个 copula 分布的预定义的核 ker. 这 11 个核可以被大致分成四组，包括独立-依赖核（"Product"、 "Maximal" 和 "Minimal"）；阿基米德核（{"Frank",α}，其中 时 ， 时 ， 时的 {"Clayton",c}， 时的 {"GumbelHougaard",α} 和 时的 {"AMH",α}）；分布衍生核（{"Binormal",ρ} 其中 ρ 如 BinormalDistribution 中的， {"Multinormal",Σ} 其中 Σ 如 MultinormalDistribution 中的、 ν 如 MultivariateTDistribution 中的）；和非关联核（{"FGM",α} 其中 ），其成员有相似的定性的或理论上的属性.
  • Sklar 理论证明了存在一个 copula ，它通过关联 将任意联合分布 和其单变量边缘 结合并由此证明 copula 分布在多变量统计中是普遍存在的. 尽管今天使用的很多术语和装置是在 1950 到 1960 年代发展起来的，copula 分布可以追溯至 1940 年代. 起初，copula 被用于对可靠性理论、气象学和排队论中的现象建模，后来开发出特殊定义的 copula 和核作为生存分析（通过survival copulas）和数学金融（通过 panic copulas）等领域中的工具. Copula 分布在蒙特卡罗理论和应用数学中也有独立的理论兴趣.
  • 根据参数 ker 和 distj，CopulaDistribution[ker,{dist1,…,distn}] 和各种其他分布之间存在很多关系. 对所有分布 distj， CopulaDistribution["Product",{dist1,…,distn}] 等价于 ProductDistribution[dist1,…,distn]，同样的 NormalDistribution 的两个实例的积 copula 是 BinormalDistribution. 另外，对所有的 distj 分布， CopulaDistribution["Product",{dist1,…,distn}] 的 PDF 与 CopulaDistribution[{"Binormal",0},{dist1,…,distn}] 的 PDF 是一样的， 就此意义而言积 copula 等价于有零关联的双正态. 在分布衍生核中，有 NormalDistribution 边缘的双正态 copula 等价于有 StudentTDistribution 边缘的多变量 -copula，相应的，无数定性的类似关系存在于阿基米德 copula 和各种分布之间.

范例

打开所有单元 关闭所有单元

基本范例  (3)

定义一个乘积 copula：

Wolfram Language code: 𝒟 = CopulaDistribution["Product", {GeometricDistribution[.3], PoissonDistribution[4]}];
Wolfram Language code: DiscretePlot3D[PDF[𝒟, {x, y}], {x, 0, 9}, {y, 0, 9}, ExtentSize -> Full]

定义一个 Farlie–Gumbel–Morgenstern copula：

Wolfram Language code: 𝒟 = CopulaDistribution[{"FGM", .2}, {NormalDistribution[-1, 2], NormalDistribution[1, 1 / 2]}];
Wolfram Language code: Plot3D[PDF[𝒟, {x, y}]//Evaluate, {x, -6, 3}, {y, -1, 3}]

定义一个三维最大 copula：

Wolfram Language code: 𝒟 = CopulaDistribution["Maximal", Table[UniformDistribution[], {i, 3}]];
Wolfram Language code: CDF[𝒟, {x, y, z}]//FullSimplify

范围  (32)

基本用途  (6)

利用两个正态分布定义一个乘积 Copula：

Wolfram Language code: 𝒟 = CopulaDistribution["Product", {NormalDistribution[2, 3], NormalDistribution[4, 5]} ];

概率密度函数：

Wolfram Language code: Plot3D[PDF[𝒟, {x, y}], {x, -10, 12}, {y, -10, 14}, PlotRange -> All]
Wolfram Language code: PDF[𝒟, {x, y}]

累积分布函数：

Wolfram Language code: Plot3D[CDF[𝒟, {x, y}], {x, -15, 35}, {y, -10, 40}, PlotRange -> All]
Wolfram Language code: CDF[𝒟, {x, y}]

利用两个均匀分布定义一个 Frank copula：

Wolfram Language code: 𝒟 = CopulaDistribution[{"Frank", 6}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]} ];

生成随机向量：

Wolfram Language code: data = RandomVariate[𝒟, 10 ^ 4];
Wolfram Language code: Histogram3D[data, {{0, 1, 0.1}, {0, 1, 0.1}}, "PDF"]

比较均值和方差：

Wolfram Language code: {Mean[𝒟]//N, Mean[data]}
Wolfram Language code: {Variance[𝒟]//N, Variance[data]}

利用贝塔分布定义一个 FGM copula：

Wolfram Language code: 𝒟 = CopulaDistribution[{"FGM", -.7}, {BetaDistribution[2, 1], BetaDistribution[3, 1]}];
Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 1}, {y, 0, 1}]
Wolfram Language code: PDF[𝒟, {x, y}]

矩和矩母函数：

Wolfram Language code: Moment[𝒟, {r, k}]
Wolfram Language code: MomentGeneratingFunction[𝒟, {s, t}]

定义具有离散分量的最大 copula：

Wolfram Language code: 𝒟 = CopulaDistribution["Maximal", {GeometricDistribution[.3], BinomialDistribution[5, .4]}];

概率密度函数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 8}, {y, 0, 8}, ExtentSize -> Full]

计算概率和期望值：

Wolfram Language code: NProbability[x + y < 1 / 3, {x, y}𝒟]
Wolfram Language code: NExpectation[x ^ 3 + y ^ 4, {x, y}𝒟]

利用泊松分布定义一个最小 copula：

Wolfram Language code: 𝒟 = CopulaDistribution["Minimal", {PoissonDistribution[9], PoissonDistribution[3]}];

概率密度函数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 16}, {y, 0, 16}, ExtentSize -> Full]

按照分量计算统计属性：

Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]
Wolfram Language code: Skewness[𝒟]
Wolfram Language code: Kurtosis[𝒟]

估计分布参数：

Wolfram Language code: 𝒞 = CopulaDistribution[{"Binormal", ρ}, {UniformDistribution[{0, 1}], NormalDistribution[]}];
Wolfram Language code: data = Block[{ρ = .2}, RandomVariate[𝒞, 10 ^ 3]];
Wolfram Language code: EstimatedDistribution[data, 𝒞]

Copula 核  (11)

一个乘积 copula：

Wolfram Language code: 𝒟 = CopulaDistribution["Product", {UniformDistribution[], UniformDistribution[]}];

概率密度函数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}, PlotRange -> All]
Wolfram Language code: PDF[𝒟, {x, y}]

累积分布函数：

Wolfram Language code: CDF[𝒟, {x, y}]

一个最大 copula：

Wolfram Language code: 𝒟 = CopulaDistribution["Maximal", {UniformDistribution[], UniformDistribution[]}];

累积分布函数：

Wolfram Language code: Plot3D[Evaluate[CDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}, Exclusions -> None]
Wolfram Language code: CDF[𝒟, {x, y}]

一个最小 copula：

Wolfram Language code: 𝒟 = CopulaDistribution["Minimal", {UniformDistribution[], UniformDistribution[]}];

累积分布函数：

Wolfram Language code: Plot3D[Evaluate[CDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}, Exclusions -> None]
Wolfram Language code: CDF[𝒟, {x, y}]

一个 Frank copula：

Wolfram Language code: 𝒟 = CopulaDistribution[{"Frank", 3}, {UniformDistribution[], UniformDistribution[]}];

概率密度函数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}]
Wolfram Language code: PDF[𝒟, {x, y}]

累积分布函数：

Wolfram Language code: CDF[𝒟, {x, y}]

一个 Clayton copula：

Wolfram Language code: 𝒟 = CopulaDistribution[{"Clayton", 3}, {UniformDistribution[], UniformDistribution[]}];

概率密度函数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}]
Wolfram Language code: PDF[𝒟, {x, y}]

累积分布函数：

Wolfram Language code: CDF[𝒟, {x, y}]

一个 Gumbel–Hougaard copula：

Wolfram Language code: 𝒟 = CopulaDistribution[{"GumbelHougaard", 3}, {UniformDistribution[], UniformDistribution[]}];

概率密度函数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}]
Wolfram Language code: PDF[𝒟, {x, y}]//PiecewiseExpand

累积分布函数：

Wolfram Language code: CDF[𝒟, {x, y}]

一个 Farlie–Gordon–Morgenstern copula：

Wolfram Language code: 𝒟 = CopulaDistribution[{"FGM", 1 / 3}, {UniformDistribution[], UniformDistribution[]}];

概率密度函数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}]
Wolfram Language code: PDF[𝒟, {x, y}]//PiecewiseExpand

累积分布函数：

Wolfram Language code: CDF[𝒟, {x, y}]//Simplify

一个 Ali–Mikhail–Haque copula：

Wolfram Language code: 𝒟 = CopulaDistribution[{"AMH", 2 / 3}, {UniformDistribution[], UniformDistribution[]}];

概率密度函数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}]
Wolfram Language code: PDF[𝒟, {x, y}]//PiecewiseExpand

累积分布函数：

Wolfram Language code: CDF[𝒟, {x, y}]//Simplify

一个二元正态 copula：

Wolfram Language code: 𝒟 = CopulaDistribution[{"Binormal", 1 / 2}, {UniformDistribution[], UniformDistribution[]}];
Wolfram Language code: PDF[𝒟, {x, y}]

概率密度函数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.1}, {y, -0.2, 1.1}]
Wolfram Language code: PDF[𝒟, {x, y}]

一个多元正态 copula：

Wolfram Language code: 𝒟 = CopulaDistribution[{"Multinormal", {{4, -1 / 2}, {-1 / 2, 3}}}, {UniformDistribution[], UniformDistribution[]}];

概率密度函数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.2, 1.2}, {y, -0.2, 1.2}]
Wolfram Language code: PDF[𝒟, {x, y}]//Simplify

一个多元学生 copula：

Wolfram Language code: 𝒟 = CopulaDistribution[{"MultivariateT", {{1, 2 / 3}, {2 / 3, 5}}, 2}, {UniformDistribution[], UniformDistribution[]}];

概率密度函数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -0.1, 1.1}, {y, -0.1, 1.1}, Exclusions -> {{x(1 - x) == 0, 0 ≤ y ≤ 1}, {y(1 - y) == 0, 0 ≤ x ≤ 1}}]
Wolfram Language code: PDF[𝒟, {1 / 3, 2 / 3}]//Simplify

参数分布  (4)

利用贝塔分布作为边缘分布定义一个最小 copula：

Wolfram Language code: 𝒟 = CopulaDistribution["Minimal", {BetaDistribution[2, 3], BetaDistribution[3, 2]}];

累积分布函数：

Wolfram Language code: Plot3D[Evaluate[CDF[𝒟, {x, y}]], {x, 0, 1}, {y, 0, 1}, Exclusions -> None]
Wolfram Language code: CDF[𝒟, {x, y}]

生存函数：

Wolfram Language code: SurvivalFunction[𝒟, {x, y}]

利用不同的连续边缘分布定义一个最大 copula：

Wolfram Language code: 𝒟 = CopulaDistribution["Maximal", {GammaDistribution[3, 2 / 3], ExponentialDistribution[2]}];

累积分布函数：

Wolfram Language code: Plot3D[CDF[𝒟, {x, y}], {x, 0, 6}, {y, 0, 6}, Exclusions -> None]
Wolfram Language code: CDF[𝒟, {x, y}]

均值和方差：

Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]

偏度和峰度：

Wolfram Language code: Skewness[𝒟]
Wolfram Language code: Kurtosis[𝒟]

利用泊松边缘分布定义一个 copula：

Wolfram Language code: 𝒟 = CopulaDistribution[{"FGM", 1 / 3}, {PoissonDistribution[2], PoissonDistribution[3]}];

概率密度函数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 9}, {y, 0, 9}, ExtentSize -> 0.5]

风险函数：

Wolfram Language code: DiscretePlot3D[Evaluate[HazardFunction[𝒟, {x, y}]], {x, 0, 9}, {y, 0, 9}, ExtentSize -> 0.5]

利用负二项分布作为边缘分布定义一个 copula：

Wolfram Language code: 𝒟 = CopulaDistribution[{"Frank", 1 / 4}, {NegativeBinomialDistribution[10, .8], NegativeBinomialDistribution[10, .5]}];

概率密度函数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 10}, {y, 0, 20}, ExtentSize -> 0.5]

生成随机数：

Wolfram Language code: Histogram3D[RandomVariate[𝒟, 10 ^ 4], {{-0.5, 10.5, 1}, {-0.5, 20.5, 1}}, "PDF"]

非参数分布  (3)

利用 SmoothKernelDistribution 定义一个 copula：

Wolfram Language code: skd1 = SmoothKernelDistribution[RandomVariate[FrechetDistribution[2, 3], 10 ^ 3]]; skd2 = SmoothKernelDistribution[RandomVariate[NormalDistribution[], 10 ^ 3]]; 𝒟 = CopulaDistribution[{"AMH", -0.3}, {skd1, skd2}];

概率密度函数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 10}, {y, -3, 3}]

均值和方差：

Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]

利用 EmpiricalDistribution 定义一个 copula：

Wolfram Language code: ed1 = EmpiricalDistribution[RandomVariate[BorelTannerDistribution[.3, 10], 20]]; ed2 = EmpiricalDistribution[RandomVariate[PoissonDistribution[9], 10]]; 𝒟 = CopulaDistribution[{"Frank", 20}, {ed1, ed2}];

概率密度函数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 9, 20}, {y, 4, 14}, PlotRange -> All, ExtentSize -> 2 / 3]

利用 HistogramDistribution 定义一个 copula：

Wolfram Language code: hd = HistogramDistribution[RandomVariate[NormalDistribution[], 10 ^ 2]]; 𝒟 = CopulaDistribution[{"Clayton", 3}, {hd, LaplaceDistribution[0, 1]}];

绘制概率密度函数的图线：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -3, 3}, {y, -3, 3}, PlotRange -> All, ExclusionsStyle -> {None, Black}]

累积分布函数：

Wolfram Language code: Plot3D[Evaluate[CDF[𝒟, {x, y}]], {x, -3, 3}, {y, -3, 3}, PlotRange -> All, ExclusionsStyle -> {None, Black}]

导出分布  (8)

利用 TruncatedDistribution 作为边缘分布定义一个 copula 分布：

Wolfram Language code: 𝒯 = TruncatedDistribution[{0, 1}, ExponentialDistribution[2]]; 𝒟 = CopulaDistribution[{"Frank", 100}, {𝒯, UniformDistribution[{0, 1}]}];

概率密度函数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 1}, {y, 0, 1}, PlotRange -> All]
Wolfram Language code: PDF[𝒟, {x, y}]

利用 CensoredDistribution 作为一个边缘分布定义一个 copula 分布：

Wolfram Language code: 𝒞 = CensoredDistribution[{3, 7}, PoissonDistribution[5]]; 𝒟 = CopulaDistribution[{"Clayton", 14}, {BenfordDistribution[8], 𝒞}];

概率密度函数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 8}, {y, 2, 8}, ExtentSize -> 1 / 2]

均值和方差：

Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]//N

利用 MixtureDistribution 作为一个边缘分布定义一个 copula：

Wolfram Language code: ℳ = MixtureDistribution[{1, 2}, {NormalDistribution[-1.5, 1 / 2], NormalDistribution[1.5, 1 / 2]}]; 𝒟 = CopulaDistribution[{"AMH", 0.3}, {ℳ, NormalDistribution[]}];

概率密度函数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -3, 3}, {y, -3, 3}, PlotRange -> All]

累积分布函数：

Wolfram Language code: CDF[𝒟, {x, y}]

利用 ParameterMixtureDistribution 作为一个边缘分布定义一个 copula：

Wolfram Language code: ℳ = ParameterMixtureDistribution[GeometricDistribution[p], pBetaDistribution[.3, 4]]; 𝒟 = CopulaDistribution[{"AMH", -.7}, {ℳ, PoissonDistribution[8]}];

概率密度函数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 10}, {y, 0, 16}, ExtentSize -> 1 / 2]

风险函数：

Wolfram Language code: DiscretePlot3D[Evaluate[HazardFunction[𝒟, {x, y}]], {x, 5, 20}, {y, 5, 20}, ExtentSize -> 1 / 2]

利用 OrderDistribution 作为一个边缘分布定义一个 copula：

Wolfram Language code: 𝒪 = OrderDistribution[{GumbelDistribution[3, 2], 10}, 5]; 𝒟 = CopulaDistribution[{"Clayton", 3}, {𝒪, CauchyDistribution[0, 1]}];

概率密度函数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -2, 5}, {y, -3, 3}, PlotRange -> All]

累积分布函数：

Wolfram Language code: CDF[𝒟, {x, y}]//FullSimplify

利用 TransformedDistribution 作为一个边缘分布定义一个 copula：

Wolfram Language code: 𝒯 = TransformedDistribution[u ^ 3 + u, uNormalDistribution[]]; 𝒟 = CopulaDistribution[{"FGM", -0.5}, {𝒯, NormalDistribution[]}];

概率密度函数：

Wolfram Language code: Plot3D[Evaluate[PDF[𝒟, {x, y}]], {x, -3, 3}, {y, -3, 3}, PlotRange -> All]

均值和方差：

Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]

偏度和峰度：

Wolfram Language code: Skewness[𝒟]
Wolfram Language code: Kurtosis[𝒟]

利用 MarginalDistribution 作为一个边缘分布定义一个 copula：

Wolfram Language code: 𝒹 = NegativeMultinomialDistribution[2, {.2, .3, .4}]; ℳ1 = MarginalDistribution[𝒹, 1]; ℳ2 = MarginalDistribution[𝒹, 2]; 𝒟 = CopulaDistribution["Product", {ℳ1, ℳ2}];

概率密度函数：

Wolfram Language code: DiscretePlot3D[Evaluate[PDF[𝒟, {x, y}]], {x, 0, 10}, {y, 0, 10}, ExtentSize -> 1 / 2]

有 QuantityDistribution 边缘的 copula 估值到 QuantityDistribution：

Wolfram Language code: 𝒹1 = NormalDistribution[Quantity[0, "Meters"], Quantity[0.2, "Meters"]]; 𝒹2 = QuantityDistribution[StudentTDistribution[3], "Seconds"];
Wolfram Language code: 𝒟 = CopulaDistribution[{"MultivariateT", {{1, 1 / 3}, {1 / 3, 1}}, 10}, {𝒹1, 𝒹2}]

均值和方差：

Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]

应用  (6)

一个系统由四个组件组成，每个组件的生命期服从参数为 的指数分布. 与失效时间的依赖关系根据参数为 α1/3 的 Farlie–Gumbel–Morgenstern copula建模. 求没有任何组件在 500 小时前失效的概率：

Wolfram Language code: comp𝒟 = ExponentialDistribution[Quantity[1/1000, 1/"Hours"]];
Wolfram Language code: joint𝒟 = CopulaDistribution[{"FGM", 1 / 3}, {comp𝒟, comp𝒟, comp𝒟, comp𝒟}];
Wolfram Language code: SurvivalFunction[joint𝒟, {Quantity[500, "Hours"], Quantity[500, "Hours"], Quantity[500, "Hours"], Quantity[500, "Hours"]}]//Simplify
Wolfram Language code: N[%]
Wolfram Language code: ExactlyK[k_, v_] := BooleanCountingFunction[{k}, Length[v]]@@v

求在 1000 个小时后有一个组件失效的概率：

Wolfram Language code: Table[NProbability[ExactlyK[m, {t1 > Quantity[1000, "Hours"], t2 > Quantity[1000, "Hours"], t3 > Quantity[1000, "Hours"], t4 > Quantity[1000, "Hours"]}], {t1, t2, t3, t4}joint𝒟], {m, 0, 4}]//Quiet
Wolfram Language code: Total[%]

假定两个资产的值服从漂移率为 和 ，波动率为 和 的几何布朗运动. 假定两个资产的初始值都为 1，求在时间 时，这两个资产的联合累积分布函数的边界值：

Wolfram Language code: 𝒞min = CopulaDistribution["Minimal", {LogNormalDistribution[Log[1] + (Subscript[μ, X] - 1 / 2 Subscript[σ, X] ^ 2)T, Subscript[σ, X] Sqrt[T] ], LogNormalDistribution[Log[1] + (Subscript[μ, Y] - 1 / 2 Subscript[σ, Y] ^ 2)T, Subscript[σ, Y]Sqrt[T]]}]; 𝒞max = CopulaDistribution["Maximal", {LogNormalDistribution[Log[1] + (Subscript[μ, X] - 1 / 2 Subscript[σ, X] ^ 2)T, Subscript[σ, X] Sqrt[T]], LogNormalDistribution[Log[1] + (Subscript[μ, Y] - 1 / 2 Subscript[σ, Y] ^ 2)T, Subscript[σ, Y]Sqrt[T]]}];

下界：

Wolfram Language code: CDF[𝒞min, {x, y}]

上界：

Wolfram Language code: CDF[𝒞max, {x, y}]

假定下面的值比较累积分布函数的图线：

Wolfram Language code: values = {Subscript[μ, X] -> 0, Subscript[μ, Y] -> 0, Subscript[σ, X] -> 0.2, Subscript[σ, Y] -> 0.2, T -> 5};
Wolfram Language code: Plot3D[CDF[First[#] /. values, {x, y}]//Evaluate, {x, 0.3, 2}, {y, 0.3, 2}, Exclusions -> None, PlotLabel -> Last[#]]& /@ {{𝒞min, "minimal"}, {𝒞max, "maximal"}}

两家公司有债务 和 ，初始资产都是 1. 假定资产值服从漂移率为 和 ，波动率为 和 的几何布朗运动. 假定一个 Frank copula，求在时间 时默认的联合概率：

Wolfram Language code: values = {Subscript[μ, X] -> 0, Subscript[μ, Y] -> 0, Subscript[σ, X] -> 0.3, Subscript[σ, Y] -> 0.2, T -> 6, Subscript[d, 1] -> 0.5, Subscript[d, 2] -> 0.6}; 𝒟 = CopulaDistribution[{"Frank", α}, {LogNormalDistribution[Log[1] + (Subscript[μ, X] - 1 / 2 Subscript[σ, X] ^ 2)T, Subscript[σ, X] Sqrt[T]], LogNormalDistribution[Log[1] + (Subscript[μ, Y] - 1 / 2 Subscript[σ, Y] ^ 2)T, Subscript[σ, Y]Sqrt[T]]}] /. values;

默认的概率依赖于 α：

Wolfram Language code: CDF[𝒟, {0.5, 0.6}]//FullSimplify
Wolfram Language code: Plot[CDF[𝒟, {0.5, 0.6}], {α, 0, 100}, Filling -> Axis]

极限值：

Wolfram Language code: Limit[CDF[𝒟, {0.5, 0.6}], α -> 0, Direction -> -1]
Wolfram Language code: Limit[CDF[𝒟, {0.5, 0.6}], α -> ∞]

一个柯西 copula 是自由度为 1 的多变量学生 copula：

Wolfram Language code: CauchyCopula = CopulaDistribution[{"MultivariateT", {{1, 2 / 3}, {2 / 3, 5}}, 1}, {UniformDistribution[], UniformDistribution[]}];

概率密度函数：

Wolfram Language code: Plot3D[PDF[CauchyCopula, {x, y}], {x, -0.1, 1.1}, {y, -0.1, 1.1}, Exclusions -> {{x(1 - x) == 0, 0 ≤ y ≤ 1}, {y(1 - y) == 0, 0 ≤ x ≤ 1}}, Evaluated -> True]
Wolfram Language code: PDF[CauchyCopula, {x, y}]//FullSimplify[#, 0 < x < 1 / 2 && 0 < y < 1 / 2]&//TraditionalForm

利用一个散点图，将密度可视化：

Wolfram Language code: sample = RandomVariate[CauchyCopula, 3000]; ListPlot[sample]

对于不同的参数值，定义一个 Gumbel–Hougaard copula：

Wolfram Language code: 𝒟[α_] = CopulaDistribution[{"GumbelHougaard", α}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}];

显示参数值如何影响值之间的依赖关系：

Wolfram Language code: Table[ListPlot[RandomVariate[𝒟[α], 10 ^ 3], PlotLabel -> Row[{"α = ", α}]], {α, {1, 3, 10, 60}}]

Gumbel 双变量逻辑斯蒂分布是具有逻辑斯蒂边际分布的 AMH Copula：

Wolfram Language code: GumbelLogistic𝒟 = CopulaDistribution[{"AMH", 1}, {LogisticDistribution[], LogisticDistribution[]}];

可视化其概率密度函数：

Wolfram Language code: pdf = PDF[GumbelLogistic𝒟, {x, y}]//Simplify
Wolfram Language code: Plot3D[pdf, {x, -5, 4}, {y, -5, 4}]

累积分布函数具有单变量逻辑斯蒂分布的 CDF 结构：

Wolfram Language code: CDF[GumbelLogistic𝒟, {x, y}] == (1 + Exp[-x] + Exp[-y])^-1//Simplify

属性和关系  (5)

两个正态分布的乘积 copula 分布是一个二元正态分布：

Wolfram Language code: PDF[CopulaDistribution["Product", {NormalDistribution[μ1, σ1], NormalDistribution[μ2, σ2]} ], {x, y}]
Wolfram Language code: PDF[BinormalDistribution[{μ1, μ2}, {σ1, σ2}, 0], {x, y}]
Wolfram Language code: % - %%//FullSimplify

乘积 copula 等价于相关度为零的二元正态 copula：

Wolfram Language code: PDF[CopulaDistribution["Product", {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}], {x, y}]
Wolfram Language code: PDF[CopulaDistribution[{"Binormal", 0}, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}], {x, y}]//PiecewiseExpand
Wolfram Language code: % - %%//Simplify

具有正态边缘分布的二项 copula 是一个 BinormalDistribution：

Wolfram Language code: 𝒞 = CopulaDistribution[{"Binormal", ρ}, {NormalDistribution[μ1, σ1], NormalDistribution[μ2, σ2]}];
Wolfram Language code: PDF[𝒞, {x, y}]
Wolfram Language code: PDF[BinormalDistribution[{μ1, μ2}, {σ1, σ2}, ρ], {x, y}]
Wolfram Language code: FullSimplify[% - %%]

具有学生 边缘分布的多元 copula 是一个 MultivariateTDistribution：

Wolfram Language code: 𝒞 = CopulaDistribution[{"MultivariateT", {{1, ρ}, {ρ, 1}}, ν}, {StudentTDistribution[ν], StudentTDistribution[ν]}];
Wolfram Language code: PDF[𝒞, {x, y}]//Simplify
Wolfram Language code: PDF[MultivariateTDistribution[{{1, ρ}, {ρ, 1}}, ν], {x, y}]//Simplify
Wolfram Language code: FullSimplify[% - %%, ν > 0 && 0 < ρ < 1 && x∈Reals && y∈Reals]

一个 copula 的 MarginalDistribution 返回分量分布：

Wolfram Language code: 𝒟 = CopulaDistribution["Minimal", {BetaDistribution[α, β], ExponentialDistribution[λ]}];
Wolfram Language code: MarginalDistribution[𝒟, 1]
Wolfram Language code: MarginalDistribution[𝒟, 2]

可能存在的问题  (1)

CopulaDistribution 不接受 ProductDistribution 作边缘：

Wolfram Language code: 𝒫 = ProductDistribution[ExponentialDistribution[2], UniformDistribution[{0, 1}]]; 𝒟 = CopulaDistribution[{"FGM", .9}, {𝒫, NormalDistribution[]}];
Wolfram Language code: RandomVariate[𝒟]

在列表中输入所有分布的正确语法：

Wolfram Language code: 𝒞 = CopulaDistribution[{"FGM", .9}, {ExponentialDistribution[2], UniformDistribution[{0, 1}], NormalDistribution[]}];
Wolfram Language code: PDF[𝒞, {x, y, z}]
Wolfram Language code: Mean[𝒞]

巧妙范例  (2)

具有均匀边缘分布的一些 copula 核：

Wolfram Language code: ParallelTable[Plot3D[CDF[CopulaDistribution[c, {UniformDistribution[{0, 1}], UniformDistribution[{0, 1}]}], {x, y}]//Evaluate, {x, -0.1, 1.1}, {y, -0.1, 1.1}, PlotLabel -> c, Mesh -> None, ColorFunction -> "Pastel", Ticks -> None], {c, {"Minimal", "Maximal", "Product", {"Frank", 1 / 2}, {"Clayton", 5}, {"GumbelHougaard", 2}, {"FGM", 1 / 3}, {"AMH", 1 / 2}, {"Binormal", 1 / 2}}}]

具有不同边缘分布的一个 Frank copula：

Wolfram Language code: Table[Plot3D[CDF[CopulaDistribution[{"Frank", 1 / 2}, {UniformDistribution[{0, 1}], d}], {x, y}]//Evaluate, {x, 0, 1}, {y, -3, 3}, PlotLabel -> d, Mesh -> None, ColorFunction -> "SandyTerrain", PlotRange -> All], {d, {UniformDistribution[{0, 1}], ExponentialDistribution[2], NormalDistribution[0, 1], LaplaceDistribution[0, 1], GumbelDistribution[1, 2], WeibullDistribution[2, 1]}}]
Wolfram Research (2010)，CopulaDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CopulaDistribution.html （更新于 2016 年）.

文本

Wolfram Research (2010)，CopulaDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CopulaDistribution.html （更新于 2016 年）.

CMS

Wolfram 语言. 2010. "CopulaDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/CopulaDistribution.html.

APA

Wolfram 语言. (2010). CopulaDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CopulaDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_copuladistribution, author="Wolfram Research", title="{CopulaDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/CopulaDistribution.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_copuladistribution, organization={Wolfram Research}, title={CopulaDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/CopulaDistribution.html}, note=[Accessed: 06-September-2026]}