WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CoxianDistribution[{α1,…,αm-1},{λ1,…,λm}]

位相確率 αi，比率 λiの m 位相コックス(Cox)型分布を表す．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

CoxianDistribution

CoxianDistribution[{α1,…,αm-1},{λ1,…,λm}]

位相確率 αi，比率 λiの m 位相コックス(Cox)型分布を表す．

詳細

  • m 位相コックス型分布は比率 λiの m 連続サービス位相と解釈することができる．ただし，これは，確率 αiでサービス位相 i+1まで続け，確率1-αiで終了するものとする．
  • 値 と明確な比率 の確率密度は，では指数関数 の線形結合であり，ではゼロである．
  • CoxianDistributionでは，αiは1より小さい任意の正の数で λiは任意の正の実数である．
  • CoxianDistributiondえは，λiは単位次元が等しい任意の数量でよく，αiは無次元量でよい． »
  • CoxianDistributionはMean，CDF，RandomVariate等の関数とともに使うことができる．

予備知識

  • CoxianDistribution[{α1,…,αm-1},{λ1,…,λm}]は，区間上で定義され，2つのベクトル(α1,…,αm-1)および(λ1,…,λm)でパラメータ化された， 位相コックス型分布として知られる連続統計分布を表す．母数 αiが「位相確率」と呼ばれ，その値は区間内にあるのに対し，母数 λiは「位相率」と呼ばれ，正の実数値を持つ．これら2つの母数は，一緒になって，確率密度関数(PDF)の全体的な形を決定する．PDFは，その値によって，単調減少か単峰性である．加えて，PDFの裾部は，PDFが の大きい値について，代数的にというよりも，むしろ指数関数的に減少するという意味において「薄い」．（この動作は，分布のSurvivalFunctionを分析することによって，定量的に厳密にできる）．XCoxianDistribution[{α1,…,αm-1},{λ1,…,λm}]を満足する確率変数 は，次数 のコックス型分布に従うと言われることがある．
  • コックス型分布の基礎は，1950年代における数学者D. R. コックスの業績によって築かれたが，現在の知識コーパスの大部分は，1980年代に始まる超指数分布の一般化についての研究を通して確立された．数学的正確さを期すならば，確率変数 が位相1から始まって 以上の指数関数的位相にならないのであれば，この確率変数は次数 のコックス型分布に従う．ただし， 番目の位相（平均長がに等しい）について， は確率 αiで位相 i+1まで連続し，確率1-αiで終了する．携帯電話ネットワークのトラヒック，患者が高齢者施設に滞在する期間，さまざまなタイプの待ち行列等を含む現実世界の数多くの現象が，コックス型分布で自然にモデル化されるような動作をする．
  • RandomVariateを使ってコックス型分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,CoxianDistribution[{α1,…,αm-1},{λ1,…,λm}]]（より簡略すると xCoxianDistribution[{α1,…,αm-1},{λ1,…,λm}]）を使って，確率変数 x がコックス型分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
  • 確率密度関数および累積分布関数は，PDF[CoxianDistribution[{α1,…,αm-1},{λ1,…,λm}],x]およびCDF[CoxianDistribution[{α1,…,αm-1},{λ1,…,λm}],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
  • DistributionFitTestを使って，与えられたデータ集合がコックス型分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからコックス型のパラメトリック分布を推定することが，FindDistributionParametersを使ってデータをコックス型分布にフィットすることができる．ProbabilityPlotを使って記号コックス型分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号コックス型分布の変位値に対する与えられたデータの変位値のプロットを生成することができる
  • TransformedDistributionを使って変換されたコックス型分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってコックス型分布を含む高次元分布を構築することが，ProductDistributionを使ってコックス型分布を含む独立成分分布の結合分布を計算することができる．
  • コックス型分布は他の数多くの分布と関係がある．例えば，CoxianDistributionとHyperexponentialDistributionは，その派生分布において，また位相 の分布CoxianDistribution[{1,…,1},{λ1,…,λm}]のPDFがExponentialDistribution[{λ1,…,λm}]のそれと等しいという意味で関係がある．このことは，CoxianDistributionとExponentialDistributionをも結び付け，この結びつきは，位相 のCoxianDistribution[{0,…,αm-1},{λ1,…,λm}] がExponentialDistribution[λ1]と同じPDFを持つとことに注目することで厳密になる．最後に，任意の λ について， 位相分布CoxianDistribution[{1,…,1},{λ,…,λ}]のPDFはErlangDistribution[{m,λ}]のそれに等しい．

例題

すべて開く すべて閉じる

例  (4)

確率密度関数：

Wolfram Language code: Plot[Table[PDF[CoxianDistribution[α, {.2, 1.2, .8}], x], {α, {{.6, .4}, {.3, .9}, {.1, .7}}}]//Evaluate, {x, 0, 6}, Filling -> Axis]
Wolfram Language code: PDF[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], x]//Simplify

累積分布関数：

Wolfram Language code: Plot[Table[CDF[CoxianDistribution[α, {.2, 1.2, .8}], x], {α, {{.6, .4}, {.3, .9}, {.1, .7}}}]//Evaluate, {x, 0, 6}, Filling -> Axis]
Wolfram Language code: CDF[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], x]//Simplify

平均と分散：

Wolfram Language code: Mean[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}]]//Together
Wolfram Language code: Variance[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}]]//Together

中央値は数値的に求めることができる：

Wolfram Language code: Median[CoxianDistribution[{.4, .7}, {1, 2, 3}]]

スコープ  (8)

コックス型分布から擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[CoxianDistribution[{.6, .3, .1}, {1, .3, .2, .8}], 10 ^ 4];

そのヒストグラムを確率密度関数と比較する：

Wolfram Language code: Show[Histogram[data, {0, 10, .5}, "PDF"], Plot[PDF[CoxianDistribution[{.6, .3, .1}, {1, .3, .2, .8}], x], {x, 0, 10}, PlotStyle -> Thick]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[CoxianDistribution[{.8, .1}, {.3, .2, .8}], 10 ^ 2];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, CoxianDistribution[{.8, .1}, {m, n, k}]]

サンプルの密度ヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, 20, "PDF"], Plot[PDF[edist, x], {x, 0, 35}, PlotStyle -> Thick, PlotRange -> All]]

歪度：

Wolfram Language code: Plot3D[Skewness[CoxianDistribution[{α, β}, {.3, 2, 1.4}]], {α, 0, 1}, {β, 0, 1}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic]
Wolfram Language code: Skewness[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}]]//FullSimplify[#, Subscript[λ, 1] > 0 && Subscript[λ, 2] > 0 && Subscript[λ, 3] > 0]&

尖度：

Wolfram Language code: Plot3D[Kurtosis[CoxianDistribution[{α, β}, {.3, 2, 1.4}]], {α, 0, 1}, {β, 0, 1}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic]
Wolfram Language code: Kurtosis[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}]]//FullSimplify[#, Subscript[λ, 1] > 0 && Subscript[λ, 2] > 0 && Subscript[λ, 3] > 0]&

母数の関数としての閉じた形の異なるモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], k]//Simplify, {k, 3}], M]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], k]//Simplify, {k, 3}], CM]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], k]//Simplify, {k, 3}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Simplify@Cumulant[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], k], {k, 3}], C]

ハザード関数：

Wolfram Language code: Plot[Table[HazardFunction[CoxianDistribution[α, {.1, .8, 2}], x], {α, {{.6, .4}, {.3, .9}, {.1, .7}}}]//Evaluate, {x, 0, 8}, Filling -> Axis]
Wolfram Language code: HazardFunction[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], x]//Simplify

分位関数：

Wolfram Language code: Plot[Table[Quantile[CoxianDistribution[αvec, {1, .1, 2}], q], {αvec, {{.1, .4}, {.3, .9}, {.9, .3}}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

母数でQuantityを一貫して使うとQuantityDistributionが与えられる：

Wolfram Language code: rates = {Quantity[5, 1/"Weeks"], Quantity[6, 1/"Weeks"], Quantity[7, 1/"Weeks"]}; time𝒟 = CoxianDistribution[{2 / 5, 1 / 4}, rates]

時間の中央値を求める：

Wolfram Language code: Median[time𝒟]//N
Wolfram Language code: UnitConvert[%, "Days"]

アプリケーション  (2)

顧客が1時間にそれぞれ25人と28人でサービス時間が指数的な2ヶ所のサービス位置がある正方向送りキューシステムに入る．最初のサービスを受けた後，次を待たずにシステムを去る顧客の確率はである．それ以外は次のサービス位置に移動する．顧客が5分以上システムに留まる確率を求める：

Wolfram Language code: serviceTime𝒟 = CoxianDistribution[{Quantity[25, "Percent"]}, {Quantity[25, "per hour"], Quantity[28, "per hour"]}]
Wolfram Language code: p = Probability[t > Quantity[5, "Minutes"], tserviceTime𝒟]
Wolfram Language code: UnitConvert[p, "Percent"]//N

連続マルコフ連鎖が過渡状態から始めて唯一の吸収状態になるまでの最初の通過時間は，一般にコックス型分布の混合分布で表される：

Wolfram Language code: {α1, α2} = {2 / 3, 1 / 2}; {r1, r2, r3} = {2, 3, 4}; ctmp = ContinuousMarkovProcess[1, (⁠| | | | | | - | -- | -- | ------ | | 0 | α1 | 0 | 1 - α1 | | 0 | 0 | α2 | 1 - α2 | | 0 | 0 | 0 | 1 | | 0 | 0 | 0 | 1 |⁠), {r1, r2, r3, 0}];
Wolfram Language code: Graph[ctmp]

この系がはじめて吸収状態に至るまでの時間はコックス型分布に従う：

Wolfram Language code: {{absorbingState}} = MarkovProcessProperties[ctmp, "AbsorbingClasses"]
Wolfram Language code: time𝒟 = FirstPassageTimeDistribution[ctmp, absorbingState]

特性と関係  (5)

CoxianDistributionは正の因数によるスケーリングの下では閉じている：

Wolfram Language code: TransformedDistribution[k * u, uCoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}]]

他の分布との関係：

すべての位相確率が1と等しいコックス型分布はHypoexponentialDistributionである：

Wolfram Language code: PDF[CoxianDistribution[{1, 1}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], x]
Wolfram Language code: PDF[HypoexponentialDistribution[{Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], x]
Wolfram Language code: % - %%//Simplify

比率が等しく位相確率が1のコックス型分布はErlangDistributionである：

Wolfram Language code: PDF[CoxianDistribution[{1, 1}, {λ, λ, λ}], x]
Wolfram Language code: PDF[ErlangDistribution[3, λ], x]
Wolfram Language code: Simplify[% - %]

第1位相確率が0のコックス型分布はExponentialDistributionである：

Wolfram Language code: PDF[CoxianDistribution[{0, α, β}, {Subscript[λ, 1] , Subscript[λ, 2], Subscript[λ, 3], Subscript[λ, 4]}], x]
Wolfram Language code: PDF[ExponentialDistribution[Subscript[λ, 1]], x]
Wolfram Language code: Simplify[% - %]

おもしろい例題  (1)

累積分布関数の等高線を持つ λ のさまざまな値についての確率密度関数：

Wolfram Language code: cdf = Function[{x, λ}, Evaluate[CDF[CoxianDistribution[{.8, .1}, {.3, .2, λ}], x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[CoxianDistribution[{.8, .1}, {.3, .2, λ}], x], {x, 0, 30}, {λ, 0.2, 4}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> All], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2012), CoxianDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoxianDistribution.html （2016年に更新）.

テキスト

Wolfram Research (2012), CoxianDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoxianDistribution.html （2016年に更新）.

CMS

Wolfram Language. 2012. "CoxianDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/CoxianDistribution.html.

APA

Wolfram Language. (2012). CoxianDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoxianDistribution.html

BibTeX

@misc{reference.wolfram_2026_coxiandistribution, author="Wolfram Research", title="{CoxianDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/CoxianDistribution.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coxiandistribution, organization={Wolfram Research}, title={CoxianDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/CoxianDistribution.html}, note=[Accessed: 15-September-2026]}