WOLFRAM

Wolfram 语言与系统参考资料中心

CoxianDistribution[{α1,…,αm-1},{λ1,…,λm}]

表示 m 相位 Coxian 分布，其中相位概率为 αi，速率为 λi.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

CoxianDistribution

CoxianDistribution[{α1,…,αm-1},{λ1,…,λm}]

表示 m 相位 Coxian 分布，其中相位概率为 αi，速率为 λi.

更多信息

  • m 相位 Coxian 分布可以被解释为速率为 λi 的 m 顺序服务相位，其中转至服务相位 i+1 的概率为 αi，结束的概率为 1-αi.
  • 对于 ，数值 和不同速率 的概率密度是指数的线性组合 ，对于 是零.
  • CoxianDistribution 中，αi 是不大于 1 的任意正数，而 λi 是任意正实数.
  • CoxianDistribution 允许 λi 是任意相同单位维度的数量，而 αi 可以是无量纲量. »
  • CoxianDistribution 可以与诸如 Mean、CDF 和 RandomVariate 等函数一起使用.

背景

  • CoxianDistribution[{α1,…,αm-1},{λ1,…,λm}] 表示一个定义在区间 上的，由两个参数向量 (α1,…,αm-1) 和 (λ1,…,λm) 的连续统计分布：Coxian 分布，也被称为 阶段 Coxian 分布. 参数 αi 被称为“阶段概率”且值在区间 上，而参数 λi 被称为“阶段率”且取值为正实数. 这些参数一起决定了该分布的概率密度函数（PDF）的整体形状，而且根据这些参数的值，PDF 可能是单调递减的或是单峰的. 此外，这一分布的 PDF 的尾部很“薄”，意思是说在 值较大时 PDF 的衰减是指数的而不是代数的.（这一行为可通过研究分布的 SurvivalFunction 做精确的定量分析.）满足 XCoxianDistribution[{α1,…,αm-1},{λ1,…,λm}] 的随机变量 有时又被称为有 阶 Coxian 分布.
  • 虽然 Coxian 分布的基础源于数学家 D. R. Cox 在 1950 年代的工作，但目前大量和它相关的知识是通过 1980 年代推广超指数分布的工作建立的. 从数学上精确的说，一个随机变量 具有 阶 Coxian 分布若它从阶段 1 开始且经过不超过 个指数阶段，其中对第 个阶段（它的平均长度是 ）， 以 αi 的概率转移到阶段 i+1，以 1-αi 的概率结束. 许多真实世界的现象行为都可以用 Coxian 分布自然的建模，包括在移动蜂窝网络中的电信业务，中老年保健中心里患者的生存时间，和各种类型的排队系统.
  • RandomVariate 可被用于给出 Coxian 分布的一个或多个机器精度或任意精度（后者可用 WorkingPrecision 选项指定）的伪随机变量. Distributed[x,CoxianDistribution[{α1,…,αm-1},{λ1,…,λm}]]，更简洁的写法是 xCoxianDistribution[{α1,…,αm-1},{λ1,…,λm}]，可被用于声明随机变量 x 是 Coxian 分布的. 这样一个声明之后可用在如 Probability、NProbability、Expectation 以及 NExpectation 这样的函数中.
  • 概率密度函数和累积分布函数可用 PDF[CoxianDistribution[{α1,…,αm-1},{λ1,…,λm}],x] 和 CDF[CoxianDistribution[{α1,…,αm-1},{λ1,…,λm}],x] 求得. 平均数、中位数、方差、原点矩及中心矩可分别用 Mean、Median、Variance、Moment 和 CentralMoment 计算.
  • DistributionFitTest 可被用于测试给定的数据集是否与 Coxian 分布一致，EstimatedDistribution 可被用于根据给定数据估算 Coxian 参数化分布，而 FindDistributionParameters 可拟合数据和 Coxian 分布. ProbabilityPlot 可被用于生成给定数据的 CDF 相对于符号 Coxian 分布的 CDF 的图线，而 QuantilePlot 可被用于生成给定数据的分位数相对于符号 Coxian 分布的分位数的图线.
  • TransformedDistribution 可被用于表示转换的 Coxian 分布，CensoredDistribution 可被用于表示删截后位于上限值和下限值之间的值分布，而 TruncatedDistribution 可被用于表示截断后位于上限值和下限值之间的值分布. CopulaDistribution 可被用于建立包含了 Coxian 分布的高维分布，而 ProductDistribution 可被用于计算包括 Coxian 分布在内的，若干个独立分量分布的联合分布.
  • Coxian 分布和许多其它分布有关. 例如，CoxianDistribution 和 HyperexponentialDistribution 有关，既是从它导数的意义上来讲，也是因为 阶段的分布 CoxianDistribution[{1,…,1},{λ1,…,λm}] 的 PDF 和 ExponentialDistribution[{λ1,…,λm}] 的 PDF 恰好相同. 这样也建立了 CoxianDistribution 和 ExponentialDistribution 之间的联系，意思是 阶段的 CoxianDistribution[{0,…,αm-1},{λ1,…,λm}] 和 ExponentialDistribution[λ1] 有着相同的 PDF. 最后，对任意 λ， 阶段的 CoxianDistribution[{1,…,1},{λ,…,λ}] 的 PDF 和 ErlangDistribution[{m,λ}] 的 PDF 完全相同.

范例

打开所有单元 关闭所有单元

基本范例  (4)

概率密度函数：

Wolfram Language code: Plot[Table[PDF[CoxianDistribution[α, {.2, 1.2, .8}], x], {α, {{.6, .4}, {.3, .9}, {.1, .7}}}]//Evaluate, {x, 0, 6}, Filling -> Axis]
Wolfram Language code: PDF[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], x]//Simplify

累积分布函数：

Wolfram Language code: Plot[Table[CDF[CoxianDistribution[α, {.2, 1.2, .8}], x], {α, {{.6, .4}, {.3, .9}, {.1, .7}}}]//Evaluate, {x, 0, 6}, Filling -> Axis]
Wolfram Language code: CDF[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], x]//Simplify

均值和方差：

Wolfram Language code: Mean[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}]]//Together
Wolfram Language code: Variance[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}]]//Together

中位数可以通过数值计算得到：

Wolfram Language code: Median[CoxianDistribution[{.4, .7}, {1, 2, 3}]]

范围  (8)

生成服从 Coxian 分布的伪随机数据集：

Wolfram Language code: data = RandomVariate[CoxianDistribution[{.6, .3, .1}, {1, .3, .2, .8}], 10 ^ 4];

比较直方图和概率密度函数：

Wolfram Language code: Show[Histogram[data, {0, 10, .5}, "PDF"], Plot[PDF[CoxianDistribution[{.6, .3, .1}, {1, .3, .2, .8}], x], {x, 0, 10}, PlotStyle -> Thick]]

分布参数估计：

Wolfram Language code: sample = RandomVariate[CoxianDistribution[{.8, .1}, {.3, .2, .8}], 10 ^ 2];

从样本数据估计分布参数：

Wolfram Language code: edist = EstimatedDistribution[sample, CoxianDistribution[{.8, .1}, {m, n, k}]]

比较样本的密度直方图和估计分布的概率密度函数：

Wolfram Language code: Show[Histogram[sample, 20, "PDF"], Plot[PDF[edist, x], {x, 0, 35}, PlotStyle -> Thick, PlotRange -> All]]

偏度：

Wolfram Language code: Plot3D[Skewness[CoxianDistribution[{α, β}, {.3, 2, 1.4}]], {α, 0, 1}, {β, 0, 1}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic]
Wolfram Language code: Skewness[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}]]//FullSimplify[#, Subscript[λ, 1] > 0 && Subscript[λ, 2] > 0 && Subscript[λ, 3] > 0]&

峰度：

Wolfram Language code: Plot3D[Kurtosis[CoxianDistribution[{α, β}, {.3, 2, 1.4}]], {α, 0, 1}, {β, 0, 1}, MeshFunctions -> {#3&}, MeshShading -> ColorData[35, "ColorList"], AxesLabel -> Automatic]
Wolfram Language code: Kurtosis[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}]]//FullSimplify[#, Subscript[λ, 1] > 0 && Subscript[λ, 2] > 0 && Subscript[λ, 3] > 0]&

在解析形式下，以参数的函数形式表示的不同矩：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment:

Wolfram Language code: FormulaGrid[Table[Moment[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], k]//Simplify, {k, 3}], M]

CentralMoment:

Wolfram Language code: FormulaGrid[Table[CentralMoment[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], k]//Simplify, {k, 3}], CM]

FactorialMoment:

Wolfram Language code: FormulaGrid[Table[FactorialMoment[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], k]//Simplify, {k, 3}], FM]

Cumulant:

Wolfram Language code: FormulaGrid[Table[Simplify@Cumulant[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], k], {k, 3}], C]

风险函数：

Wolfram Language code: Plot[Table[HazardFunction[CoxianDistribution[α, {.1, .8, 2}], x], {α, {{.6, .4}, {.3, .9}, {.1, .7}}}]//Evaluate, {x, 0, 8}, Filling -> Axis]
Wolfram Language code: HazardFunction[CoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], x]//Simplify

分位数函数：

Wolfram Language code: Plot[Table[Quantile[CoxianDistribution[αvec, {1, .1, 2}], q], {αvec, {{.1, .4}, {.3, .9}, {.9, .3}}}]//Evaluate, {q, 0, 1}, Filling -> Axis]

在参数中持续使用 Quantity 生成 QuantityDistribution：

Wolfram Language code: rates = {Quantity[5, 1/"Weeks"], Quantity[6, 1/"Weeks"], Quantity[7, 1/"Weeks"]}; time𝒟 = CoxianDistribution[{2 / 5, 1 / 4}, rates]

求中位时间：

Wolfram Language code: Median[time𝒟]//N
Wolfram Language code: UnitConvert[%, "Days"]

应用  (2)

客户进入有两个服务位置的前馈排队系统，指数服务时间分别的比率分别是每小时 25 和 28 个客人. 在第一个服务位置接受服务后，该客人提前离开系统的概率是 ；否则，该客户继续进入下一个服务位置. 求该客人停留在系统中超过 5 分钟的概率：

Wolfram Language code: serviceTime𝒟 = CoxianDistribution[{Quantity[25, "Percent"]}, {Quantity[25, "per hour"], Quantity[28, "per hour"]}]
Wolfram Language code: p = Probability[t > Quantity[5, "Minutes"], tserviceTime𝒟]
Wolfram Language code: UnitConvert[p, "Percent"]//N

从瞬态开始的连续马尔可夫链进入唯一吸收状态的首次经过时间 (first passage time) 通常由 Coxian 混合分布描述：

Wolfram Language code: {α1, α2} = {2 / 3, 1 / 2}; {r1, r2, r3} = {2, 3, 4}; ctmp = ContinuousMarkovProcess[1, (⁠| | | | | | - | -- | -- | ------ | | 0 | α1 | 0 | 1 - α1 | | 0 | 0 | α2 | 1 - α2 | | 0 | 0 | 0 | 1 | | 0 | 0 | 0 | 1 |⁠), {r1, r2, r3, 0}];
Wolfram Language code: Graph[ctmp]

该系统到达吸收状态之前的首次经过时间遵循 Coxian 分布：

Wolfram Language code: {{absorbingState}} = MarkovProcessProperties[ctmp, "AbsorbingClasses"]
Wolfram Language code: time𝒟 = FirstPassageTimeDistribution[ctmp, absorbingState]

属性和关系  (5)

在通过正因子进行缩放的情况下，CoxianDistribution 是闭合的：

Wolfram Language code: TransformedDistribution[k * u, uCoxianDistribution[{Subscript[α, 1], Subscript[α, 2]}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}]]

与其他分布的关系：

所有相位概率等于 1 的 Coxian 分布是 HypoexponentialDistribution：

Wolfram Language code: PDF[CoxianDistribution[{1, 1}, {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], x]
Wolfram Language code: PDF[HypoexponentialDistribution[{Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 3]}], x]
Wolfram Language code: % - %%//Simplify

具有相同比率和相位概率为1的 Coxian 分布是 ErlangDistribution：

Wolfram Language code: PDF[CoxianDistribution[{1, 1}, {λ, λ, λ}], x]
Wolfram Language code: PDF[ErlangDistribution[3, λ], x]
Wolfram Language code: Simplify[% - %]

第一相位概率为0的 Coxian 分布是 ExponentialDistribution：

Wolfram Language code: PDF[CoxianDistribution[{0, α, β}, {Subscript[λ, 1] , Subscript[λ, 2], Subscript[λ, 3], Subscript[λ, 4]}], x]
Wolfram Language code: PDF[ExponentialDistribution[Subscript[λ, 1]], x]
Wolfram Language code: Simplify[% - %]

巧妙范例  (1)

不同 λ 值的有 CDF 等高线的 PDF：

Wolfram Language code: cdf = Function[{x, λ}, Evaluate[CDF[CoxianDistribution[{.8, .1}, {.3, .2, λ}], x]]]; ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975}; cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];
Wolfram Language code: Legended[Plot3D[PDF[CoxianDistribution[{.8, .1}, {.3, .2, λ}], x], {x, 0, 30}, {λ, 0.2, 4}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], MeshShading -> cl, AxesLabel -> Automatic, BaseStyle -> Opacity[0.9], ImageSize -> 400, PlotRange -> All], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]
Wolfram Research (2012)，CoxianDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoxianDistribution.html （更新于 2016 年）.

文本

Wolfram Research (2012)，CoxianDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoxianDistribution.html （更新于 2016 年）.

CMS

Wolfram 语言. 2012. "CoxianDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/CoxianDistribution.html.

APA

Wolfram 语言. (2012). CoxianDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CoxianDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_coxiandistribution, author="Wolfram Research", title="{CoxianDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/CoxianDistribution.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coxiandistribution, organization={Wolfram Research}, title={CoxianDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/CoxianDistribution.html}, note=[Accessed: 13-September-2026]}