WOLFRAM

Wolfram 语言与系统参考资料中心

ExampleData["type"]

给出指定类型范例名称列表.

ExampleData[{"type","name"}]

给出指定类型指定范例的默认形式.

ExampleData[{"type","name"},"elem"]

给出指定元素或范例的属性.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
图形数据  
动画数据  
图像集合  
Show More Show More
三维几何  
三维图像数据  
数值数据  
统计数据  
文本  
音频  
声音  
应用  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ExampleData

ExampleData["type"]

给出指定类型范例名称列表.

ExampleData[{"type","name"}]

给出指定类型指定范例的默认形式.

ExampleData[{"type","name"},"elem"]

给出指定元素或范例的属性.

更多信息

  • 典型类型包括：
  • "AerialImage"空中摄影图像样本
    "Audio"音频片段样本
    "ColorTexture"颜色纹理样本
    "Dataset"结构化数据集样本
    "Geometry3D"模型和形状的三维几何数据
    "LinearProgramming"线性规划问题
    "MachineLearning"机器学习训练和检验数据
    "Matrix"稀疏或稠密矩阵
    "NetworkGraph"经验图形和网络
    "Sound"声音片段样本
    "Statistics"统计数据集
    "TestAnimation"图像处理用的测试动画
    "TestImage"图像处理用的测试图像
    "TestImage3D"图像处理用的测试三维体
    "TestImageSet"测试图像集合
    "Text"文本段样本
    "Texture"纹理样本
  • ExampleData[{"type","name"},"Properties"] 给出特定范例可用的元素或属性列表.
  • 除了一种范例内容特定的元素，通常也包括以下属性：
  • "Image"范例的基本视觉表现
    "Name"英语名称
  • ExampleData[] 给出范例类型的名称组成的列表.

范例

打开所有单元 关闭所有单元

基本范例  (5)

一个标准影像处理试验图像：

Wolfram Language code: ExampleData[{"TestImage", "House"}]

航天飞机三维几何图：

Wolfram Language code: ExampleData[{"Geometry3D", "SpaceShuttle"}]

美国独立宣言文本前 400 个字符：

Wolfram Language code: StringTake[ExampleData[{"Text", "DeclarationOfIndependence"}], 400]

范例类型列表：

Wolfram Language code: ExampleData[]

一个纹理结构图像范例列表：

Wolfram Language code: ExampleData["Texture"]

范围  (32)

图形数据  (6)

一张五角大楼的航拍照片：

Wolfram Language code: ExampleData[{"AerialImage", "Pentagon"}]

可用属性：

Wolfram Language code: ExampleData[{"AerialImage", "Pentagon"}, "Properties"]

特定属性：

Wolfram Language code: ExampleData[{"AerialImage", "Pentagon"}, "ImageSize"]

原始图像数据的二维傅立叶变换：

Wolfram Language code: MatrixPlot[Abs[Fourier[ExampleData[{"AerialImage", "Pentagon"}, "Data"]]]]

木材纹理结构：

Wolfram Language code: ExampleData[{"Texture", "Wood"}]

有颜色的木头纹理：

Wolfram Language code: ExampleData[{"ColorTexture", "GoldenOak"}]

一张彩色试验图像：

Wolfram Language code: ExampleData[{"TestImage", "Mandrill"}]

一张单色试验图像：

Wolfram Language code: ExampleData[{"TestImage", "Couple2"}]

动画数据  (1)

玩具车动画：

Wolfram Language code: ExampleData[{"TestAnimation", "ToyVehicles"}]

可用属性：

Wolfram Language code: ExampleData[{"TestAnimation", "ToyVehicles"}, "Properties"]

找出前4 帧画面的名称：

Wolfram Language code: Take[ExampleData[{"TestAnimation", "ToyVehicles"}, "Frames"], 4]

提取这些画面：

Wolfram Language code: Show[ExampleData[#], ImageSize -> Tiny]& /@ %

图像集合  (2)

集合中的图像：

Wolfram Language code: ExampleData[{"TestImageSet", "Oxford2011"}]

所有图像集合：

Wolfram Language code: ExampleData["TestImageSet"]

三维几何  (2)

斯坦福兔子：

Wolfram Language code: ExampleData[{"Geometry3D", "StanfordBunny"}]

获取可能属性的列表：

Wolfram Language code: ExampleData[{"Geometry3D", "StanfordBunny"}, "Properties"]
Wolfram Language code: Length[%]

几何表示：

Wolfram Language code: bunny = ExampleData[{"Geometry3D", "StanfordBunny"}, "Region"]

边界：

Wolfram Language code: RegionBounds[bunny]

表面积：

Wolfram Language code: Area[bunny]

三维图像数据  (1)

三维图像的范例：

Wolfram Language code: ExampleData[{"TestImage3D", "CTengine"}]

三维图像的属性：

Wolfram Language code: ExampleData[{"TestImage3D", "CTengine"}, "Properties"]

数值数据  (5)

计算试验矩阵的数量：

Wolfram Language code: Length[ExampleData["Matrix"]]

一个稀疏矩阵的范例：

Wolfram Language code: MatrixPlot[ExampleData[{"Matrix", "FIDAP007"}]]

范例矩阵的属性：

Wolfram Language code: ExampleData[{"Matrix", "FIDAP007"}, "Properties"]

找出一个完整线性编程范例：

Wolfram Language code: ExampleData[{"LinearProgramming", "afiro"}]

为一个线性编程范例绘出约束矩阵：

Wolfram Language code: MatrixPlot[ExampleData[{"LinearProgramming", "bgetam"}, "ConstraintMatrix"]]

统计数据  (6)

求可用的前 10 个统计数据集：

Wolfram Language code: Take[ExampleData["Statistics"], 10]

数据集的可用属性列表：

Wolfram Language code: ExampleData[{"Statistics", "AnimalWeights"}, "Properties"]

这个数据集的前5行包含各种动物的脑子和身体重量：

Wolfram Language code: Take[ExampleData[{"Statistics", "AnimalWeights"}], 5]//MatrixForm

另一方面，使用 "DataElements" 属性：

Wolfram Language code: Take[ExampleData[{"Statistics", "AnimalWeights"}, "DataElements"], 5]//MatrixForm

列类型或者是 "Numeric" 或者是 "Categorical":

Wolfram Language code: ExampleData[{"Statistics", "AnimalWeights"}, "ColumnTypes"]//TableForm

Old Faithful 数据集的描述：

Wolfram Language code: ExampleData[{"Statistics", "OldFaithful"}, "Description"]
Wolfram Language code: ExampleData[{"Statistics", "OldFaithful"}, "LongDescription"]//TraditionalForm

列标题：

Wolfram Language code: ExampleData[{"Statistics", "OldFaithful"}, "ColumnHeadings"]//Column

列描述：

Wolfram Language code: ExampleData[{"Statistics", "OldFaithful"}, "ColumnDescriptions"]//Column

数据集的维度和观测值数目：

Wolfram Language code: ExampleData[{"Statistics", "OldFaithful"}, "Dimensions"]
Wolfram Language code: ExampleData[{"Statistics", "OldFaithful"}, "ObservationCount"]

创建数据集的 SmoothHistogram：

Wolfram Language code: SmoothHistogram[ExampleData[{"Statistics", "BuffaloSnow"}], PlotLabel -> ExampleData[{"Statistics", "BuffaloSnow"}, "Name"]]

计算数值实体的描述统计量：

Wolfram Language code: data = ExampleData[{"Statistics", "CPUPerformance"}];
Wolfram Language code: types = ExampleData[{"Statistics", "CPUPerformance"}, "ColumnTypes"]
Wolfram Language code: headings = ExampleData[{"Statistics", "CPUPerformance"}, "ColumnHeadings"]

选择数值列：

Wolfram Language code: numeric = Pick[Transpose@data, types, "Numeric"];

计算每个特征的 Mean 和 StandardDeviation：

Wolfram Language code: mean = Mean /@ numeric//N; sd = StandardDeviation /@ numeric//N;
Wolfram Language code: TableForm[{mean, sd}, TableHeadings -> {{"Mean", "StDev"}, Pick[headings, types, "Numeric"]}, TableSpacing -> {2, 1.2}, TableAlignments -> Center]

文本  (5)

找出可用的前 10 个范例文本：

Wolfram Language code: Take[ExampleData["Text"], 10]

找出达尔文《物种起源》的前 400 个字符：

Wolfram Language code: StringTake[ExampleData[{"Text", "OriginOfSpecies"}], 400]

属性列表：

Wolfram Language code: ExampleData[{"Text", "OriginOfSpecies"}, "Properties"]

作者与头衔：

Wolfram Language code: ExampleData[{"Text", "OriginOfSpecies"}, "Author"]
Wolfram Language code: ExampleData[{"Text", "OriginOfSpecies"}, "FullTitle"]

《物种起源》的字数：

Wolfram Language code: Length[ExampleData[{"Text", "OriginOfSpecies"}, "Words"]]

利用 "FormattedText" 得到一个带有换行的字符串等等：

Wolfram Language code: StringTake[ExampleData[{"Text", "ToBeOrNotToBe"}, "FormattedText"], 200]

生成一个美国《独立宣言》的格式化笔记本：

Wolfram Language code: NotebookPut[ExampleData[{"Text", "DeclarationOfIndependence"}, "NotebookExpression"]]

生成“拉丁化文本”：

Wolfram Language code: StringTake[ExampleData[{"Text", "LoremIpsum"}], 200]

音频  (3)

音频样本的性质：

Wolfram Language code: ExampleData[{"Sound", "Apollo13Problem"}]

导入一个音频样本：

Wolfram Language code: ExampleData[{"Audio", "Bird"}, "Audio"]

得到音频描述：

Wolfram Language code: ExampleData[{"Audio", "Bird"}, "Description"]

所有音频样本：

Wolfram Language code: ExampleData["Audio"]

声音  (1)

“休士顿，我们遇到问题了”：

Wolfram Language code: ExampleData[{"Sound", "Apollo13Problem"}]

Available properties:

Wolfram Language code: ExampleData[{"Sound", "Apollo13Problem"}, "Properties"]

应用  (5)

格式非常小的《独立宣言》：

Wolfram Language code: Pane[Style[ExampleData[{"Text", "DeclarationOfIndependence"}, "FormattedText"], 3]]

给一幅试验图像重新上色：

Wolfram Language code: ArrayPlot[ExampleData[{"TestImage", "House"}, "GrayLevels"], ColorFunction -> "Rainbow"]

在一幅试验图像中制作灰度等值线图：

Wolfram Language code: ListContourPlot[Reverse[ExampleData[{"TestImage", "House"}, "GrayLevels"]], ColorFunction -> "Pastel", MaxPlotPoints -> 100]

生成包含多个航天飞机的三维图形：

Wolfram Language code: Graphics3D[Table[Translate[ExampleData[{"Geometry3D", "SpaceShuttle"}, "GraphicsComplex"], RandomReal[30, {3}]], {6}]]

绘出《物种起源》的单词频率分布图：

Wolfram Language code: ListLogLogPlot[Reverse[Sort[Last /@ Tally[ExampleData[{"Text", "OriginOfSpecies"}, "Words"]]]], Joined -> True, Filling -> Axis, PlotRange -> All, Frame -> True]

巧妙范例  (3)

从一张试验图像制作一张三维图形：

Wolfram Language code: ListPlot3D[ExampleData[{"TestImage", "Clock"}, "GrayLevels"], PlotStyle -> Yellow, Mesh -> None]

根据一个三维对象的法向量生成一个向量场：

Wolfram Language code: Graphics3D[Line[MapThread[{#, # + #2}&, {ExampleData[{"Geometry3D", "Beethoven"}, "VertexData"], ExampleData[{"Geometry3D", "Beethoven"}, "VertexNormals"]}]]]

哈姆雷特的独白，使重复单词持续变大:

Wolfram Language code: Text[Row[With[{data = ExampleData[{"Text", "ToBeOrNotToBe"}, "Words"]}, MapIndexed[Style[#, 2Count[Take[data, First[#2]], #]]&, data]], " "]]
Wolfram Research (2007)，ExampleData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ExampleData.html （更新于 2016 年）.

文本

Wolfram Research (2007)，ExampleData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ExampleData.html （更新于 2016 年）.

CMS

Wolfram 语言. 2007. "ExampleData." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/ExampleData.html.

APA

Wolfram 语言. (2007). ExampleData. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ExampleData.html 年

BibTeX

@misc{reference.wolfram_2026_exampledata, author="Wolfram Research", title="{ExampleData}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/ExampleData.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_exampledata, organization={Wolfram Research}, title={ExampleData}, year={2016}, url={https://reference.wolfram.com/language/ref/ExampleData.html}, note=[Accessed: 04-September-2026]}