WOLFRAM

Wolfram 语言与系统参考资料中心

ExponentialGeneratingFunction[expr,n,x]

给出 x 序列的指数母函数，其中第 n 项由表达式 expr 给出.

ExponentialGeneratingFunction[expr,{n1,n2,…},{x1,x2,…}]

给出 x1，x2，… 序列的多维指数母函数，其中第 n1，n2，… 项由 expr 给出.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
特殊序列  
推广和延伸  
选项  
GenerateConditions  
Method  
VerifyConvergence  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

ExponentialGeneratingFunction

ExponentialGeneratingFunction[expr,n,x]

给出 x 序列的指数母函数，其中第 n 项由表达式 expr 给出.

ExponentialGeneratingFunction[expr,{n1,n2,…},{x1,x2,…}]

给出 x1，x2，… 序列的多维指数母函数，其中第 n1，n2，… 项由 expr 给出.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (1)

序列的指数母函数，其中第 n 项是 1：

Wolfram Language code: ExponentialGeneratingFunction[1, n, x]

序列中的第 项是 ：

Wolfram Language code: Series[%, {x, 0, 10}]

范围  (19)

基本用法  (6)

单变量序列的指数生成函数：

Wolfram Language code: ExponentialGeneratingFunction[a ^ n, n, z]

多变量序列的指数生成函数：

Wolfram Language code: ExponentialGeneratingFunction[a ^ (n + m), {n, m}, {z, w}]

计算一个常见的指数生成函数：

Wolfram Language code: F = ExponentialGeneratingFunction[n (n + 1)(-1 / 2) ^ n, n, z]

用 Plot3D、ContourPlot 或 DensityPlot 来绘制幅值：

Wolfram Language code: Block[{z = u + I v}, Table[plot[Abs[F], {u, -2, 2}, {v, -2, 2}], {plot, {Plot3D, ContourPlot, DensityPlot}}]]

绘制复相位：

Wolfram Language code: Block[{z = u + I v}, Table[plot[Arg[F], {u, -2, 2}, {v, -2, 2}], {plot, {Plot3D, ContourPlot, DensityPlot}}]]

产生区域收敛的条件：

Wolfram Language code: ExponentialGeneratingFunction[a n!, n, z, GenerateConditions -> True]

，绘制区域：

Wolfram Language code: With[{z = u + I v}, RegionPlot[Abs[z] < 1, {u, -2, 2}, {v, -2, 2}]]

计算某点处的指数生成函数：

Wolfram Language code: F = ExponentialGeneratingFunction[Sin[n 2Pi / 3](2 / 3) ^ n, n, Exp[I ω]]

绘制频谱：

Wolfram Language code: LogPlot[Abs[F] ^ 2, {ω, 0, 2π}, Ticks -> {{0, π, 2π}, Automatic}]

相位：

Wolfram Language code: Plot[Arg[F], {ω, 0, 2π}, Ticks -> {{0, π, 2π}, Automatic}]

绘制频谱，同时绘制彩色相位：

Wolfram Language code: LogPlot[Abs[F] ^ 2, {ω, 0, 2π}, Ticks -> {{0, π, 2π}, Automatic}, ColorFunction -> Function[ω, Evaluate@Hue[Arg[F] / (2Pi) + 1 / 2]], ColorFunctionScaling -> False, Filling -> Axis]

用 ParametricPlot3D 在复平面绘制频谱：

Wolfram Language code: ParametricPlot3D[{Cos[ω], Sin[ω], Log[10, Abs[F] ^ 2]}, {ω, 0, 2π}, BoxRatios -> {1, 1, 1}]

ExponentialGeneratingFunction 将使用包括线性的几个属性：

Wolfram Language code: ExponentialGeneratingFunction[a f[n] + b g[n], n, z]

与指数相乘：

Wolfram Language code: {ExponentialGeneratingFunction[a ^ n f[n], n, z], ExponentialGeneratingFunction[b ^ (-n)f[n], n, z]}
Wolfram Language code: ExponentialGeneratingFunction[Exp[I ω n]f[n], n, z]

与多项式相乘：

Wolfram Language code: {ExponentialGeneratingFunction[ n f[n], n, z], ExponentialGeneratingFunction[n(n + 1) f[n], n, z]}

共轭：

Wolfram Language code: ExponentialGeneratingFunction[Conjugate[f[n]], n, z]

ExponentialGeneratingFunction 自动作用于列表的各项：

Wolfram Language code: ExponentialGeneratingFunction[{a ^ n, b ^ n}, n, z]
Wolfram Language code: ExponentialGeneratingFunction[{{a ^ n, b ^ n}, {n, n ^ 2}}, n, z]

方程：

Wolfram Language code: ExponentialGeneratingFunction[a ^ n == f[n], n, z]

规则：

Wolfram Language code: ExponentialGeneratingFunction[f[n] -> a ^ n, n, z]

特殊序列  (13)

离散单位阶跃序列：

Wolfram Language code: {ExponentialGeneratingFunction[UnitStep[n], n, z], ExponentialGeneratingFunction[UnitStep[n - 3], n, z]}
Wolfram Language code: Table[DiscretePlot[f, {n, -10, 10}], {f, {UnitStep[n], UnitStep[n - 3]}}]

离散斜坡序列：

Wolfram Language code: {ExponentialGeneratingFunction[n UnitStep[n], n, z], ExponentialGeneratingFunction[(n - 3)UnitStep[n - 3], n, z]}
Wolfram Language code: Table[DiscretePlot[f, {n, -10, 10}], {f, {n UnitStep[n], (n - 3)UnitStep[n - 3]}}]

多项式：

Wolfram Language code: {ExponentialGeneratingFunction[n, n, z], ExponentialGeneratingFunction[n ^ 2, n, z]}

阶乘多项式：

Wolfram Language code: ExponentialGeneratingFunction[Pochhammer[n, Range[0, 3]], n, z]
Wolfram Language code: ExponentialGeneratingFunction[FactorialPower[n, Range[0, 3]], n, z]

指数函数：

Wolfram Language code: ExponentialGeneratingFunction[a ^ n, n, z]
Wolfram Language code: ExponentialGeneratingFunction[a ^ n UnitStep[n - 2], n, x]

指数多项式：

Wolfram Language code: {ExponentialGeneratingFunction[n a ^ n, n, z], ExponentialGeneratingFunction[n ^ 2 a ^ n, n, z]}
Wolfram Language code: Table[DiscretePlot[f, {n, 0, 40}], {f, {n (10 / 12) ^ n, n ^ 2 (10 / 12) ^ n}}]

阶乘指数多项式：

Wolfram Language code: ExponentialGeneratingFunction[Pochhammer[n, Range[0, 3]] a ^ n, n, z]
Wolfram Language code: ExponentialGeneratingFunction[FactorialPower[n, Range[0, 3]] a ^ n, n, z]

三角函数：

Wolfram Language code: {ExponentialGeneratingFunction[Sin[ω n + ϕ], n, z], ExponentialGeneratingFunction[Cos[ω n + ϕ], n, z]}
Wolfram Language code: Table[DiscretePlot[f, {n, -20, 20}], {f, {Sin[2π / 10 n], Cos[2π / 10 n]}}]

三角函数、指数函数和多项式：

Wolfram Language code: {ExponentialGeneratingFunction[(5 / 6) ^ n Sin[ω n], n, z], ExponentialGeneratingFunction[n (5 / 6) ^ n Sin[ω n], n, z]}
Wolfram Language code: Table[DiscretePlot[f, {n, 0, 20}], {f, {(5 / 6) ^ n Sin[2π / 10 n], n (5 / 6) ^ n Sin[2π / 10 n]}}]

以上输入的组合：

Wolfram Language code: ExponentialGeneratingFunction[n ^ 2 a ^ n + b ^ n Sin[ω n] UnitStep[n - 2], n, z]
Wolfram Language code: DiscretePlot[n ^ 2 (5 / 6) ^ n + (11 / 12) ^ n 20Sin[2Pi / 10 n]UnitStep[n - 2], {n, 0, 50}]

表示分段定义信号的不同的方式：

Wolfram Language code: ExponentialGeneratingFunction[n (UnitStep[n] - UnitStep[n - 6]) + a ^ n UnitStep[n - 6], n, z]
Wolfram Language code: ExponentialGeneratingFunction[Piecewise[{{n, n ≤ 5}, {a ^ n, True}}], n, z]
Wolfram Language code: Simplify[%% - %]

有理函数：

Wolfram Language code: ExponentialGeneratingFunction[1 / (n + 1), n, z]
Wolfram Language code: ExponentialGeneratingFunction[(n^2 + n + 1) / (n + 1) ^ 2, n, z]
Wolfram Language code: ExponentialGeneratingFunction[FactorialPower[n, -2], n, z]

有理指数函数：

Wolfram Language code: ExponentialGeneratingFunction[a ^ n / (n + 1) ^ 2, n, z]
Wolfram Language code: ExponentialGeneratingFunction[a ^ n FactorialPower[n, -2], n, z]

超几何项序列：

Wolfram Language code: ExponentialGeneratingFunction[1 / n!, n, z]

对于超几何项序列，DiscreteRatio 是有理式：

Wolfram Language code: DiscreteRatio[1 / n!, n]

许多函数都给出了超几何项：

Wolfram Language code: hl = {a ^ n, n!, Gamma[n], Pochhammer[a, n], FactorialPower[a, n], Binomial[n, a], Binomial[b, n], CatalanNumber[n]};
Wolfram Language code: DiscreteRatio[hl, n]

乘积也是超几何项：

Wolfram Language code: DiscreteRatio[Times@@RandomChoice[hl, 3], n]

超几何项的变换：

Wolfram Language code: ExponentialGeneratingFunction[(2^-2 + n/Gamma[(1/2) + n]), n, z]
Wolfram Language code: ExponentialGeneratingFunction[n / Binomial[2n, n], n, z]
Wolfram Language code: ExponentialGeneratingFunction[(FactorialPower[a1, n]/FactorialPower[b1, n]FactorialPower[b2, n]), n, z]
Wolfram Language code: ExponentialGeneratingFunction[Pochhammer[n, k], n, x]
Wolfram Language code: ExponentialGeneratingFunction[n! / CatalanNumber[n], n, x]

完整序列：

Wolfram Language code: ExponentialGeneratingFunction[LegendreP[n, a], n, z]

完整序列由线性差分方程定义：

Wolfram Language code: DifferenceRootReduce[LegendreP[n, a], n]

许多索引形式的特殊函数是完整序列：

Wolfram Language code: ExponentialGeneratingFunction[ChebyshevT[n, x], n, z]
Wolfram Language code: ExponentialGeneratingFunction[ChebyshevU[2n, x] ^ 2, n, z]

DifferenceRoot 推广可得 DifferentialRoot 函数：

Wolfram Language code: ExponentialGeneratingFunction[DifferenceRoot[Function[{y, m}, {y[m + 2] == y[m + 1] + y[m], y[0] == 0, y[1] == 1}]][n], n, z]

特殊序列：

Wolfram Language code: ExponentialGeneratingFunction[BernoulliB[n], n, x]
Wolfram Language code: ExponentialGeneratingFunction[EulerE[n], n, x]
Wolfram Language code: ExponentialGeneratingFunction[Fibonacci[n] / n!, n, z]
Wolfram Language code: ExponentialGeneratingFunction[HarmonicNumber[n] / n!, n, z]

周期序列：

Wolfram Language code: ExponentialGeneratingFunction[Mod[n, 3], n, z]
Wolfram Language code: ExponentialGeneratingFunction[Exp[n 2π I / 3], n, z]
Wolfram Language code: ExponentialGeneratingFunction[Mod[n ^ 2, 5] ^ 3, n, x]

多变量指数生成函数：

Wolfram Language code: ExponentialGeneratingFunction[a^n + m, {n, m}, {u, v}]
Wolfram Language code: ExponentialGeneratingFunction[n ^ 2 m ^ 3, {n, m}, {u, v}]
Wolfram Language code: ExponentialGeneratingFunction[a^n + mn ^ 2 m ^ 3, {n, m}, {u, v}]
Wolfram Language code: ExponentialGeneratingFunction[Sin[n + m]a ^ n, {n, m}, {u, v}]
Wolfram Language code: ExponentialGeneratingFunction[m / (n + 1), {n, m}, {u, v}]
Wolfram Language code: ExponentialGeneratingFunction[Mod[n + m, 2], {n, m}, {u, v}]

推广和延伸  (1)

计算某个点的指数母函数：

Wolfram Language code: ExponentialGeneratingFunction[1, n, 0.5]
Wolfram Language code: ExponentialGeneratingFunction[1, n, 1 / z]

选项  (5)

GenerateConditions  (1)

缺省下，在母函数收敛处没有给出条件：

Wolfram Language code: ExponentialGeneratingFunction[(n + 1)!, n, x]

用 GenerateConditions 生成有效条件：

Wolfram Language code: ExponentialGeneratingFunction[(n + 1)!, n, x, GenerateConditions -> True]

Method  (1)

不同的方法可能产生不同的公式：

Wolfram Language code: ExponentialGeneratingFunction[Fibonacci[n], n, z]
Wolfram Language code: ExponentialGeneratingFunction[Fibonacci[n], n, z, Method -> "Holonomic"]

VerifyConvergence  (3)

设置 VerifyConvergence 为 False，将母函数视为形式对象：

Wolfram Language code: ExponentialGeneratingFunction[n! 2 ^ n, n, x, VerifyConvergence -> False]

设置 VerifyConvergence 为 True，将验证收敛半径非零：

Wolfram Language code: ExponentialGeneratingFunction[n ! 2 ^ n, n, x, VerifyConvergence -> True]

另外设置 GenerateConditions 为 True，将显示收敛条件：

Wolfram Language code: ExponentialGeneratingFunction[n ! 2 ^ n, n, x, VerifyConvergence -> True, GenerateConditions -> True]

属性和关系  (3)

ExponentialGeneratingFunction 有效计算一个无穷和：

Wolfram Language code: ExponentialGeneratingFunction[n ^ 2, n, z]
Wolfram Language code: Sum[n ^ 2 / n! z ^ n, {n, 0, Infinity}]

线性:

Wolfram Language code: ExponentialGeneratingFunction[a f[n] + b g[n], n, z]

ExponentialGeneratingFunction 与 GeneratingFunction 密切相关：

Wolfram Language code: {ExponentialGeneratingFunction[n, n, z], GeneratingFunction[n / n!, n, z]}

ZTransform：

Wolfram Language code: {ExponentialGeneratingFunction[n, n, z], ZTransform[n / n!, n, 1 / z]}

FourierSequenceTransform：

Wolfram Language code: {ExponentialGeneratingFunction[n, n, Exp[-I ω]], FourierSequenceTransform[n UnitStep[n] / n!, n, ω]}

可能存在的问题  (1)

对于有些参数值，ExponentialGeneratingFunction 可能不收敛：

Wolfram Language code: {Sum[a ^ n n! x ^ n / n! /. {a -> 2, x -> 1}, {n, 0, ∞}], ExponentialGeneratingFunction[2 ^ n n!, n, 1]}
Wolfram Language code: ExponentialGeneratingFunction[a ^ n n!, n, x]

使用 GenerateConditions 得到收敛区域：

Wolfram Language code: ExponentialGeneratingFunction[n! a ^ n, n, x, GenerateConditions -> True]

巧妙范例  (1)

创建一组指数母函数：

Wolfram Language code: flist = {{UnitStep[n + 1 / 2], n, z}, {n ^ 2 + 2, n, z}, {1 / (2n + 1), n, z}, {Sin[a n], n, z}, {ChebyshevT[n, a], n, z}, {HarmonicNumber[n] / n!, n, z}, {a ^ n Sin[n], n, z}, {Mod[n, 4], n, z}, {Power[m, n], {m, n}, {u, v}}, {m / (n + 1), {m, n}, {u, v}}};
Wolfram Language code: Grid[Prepend[{#[[1]], ExponentialGeneratingFunction@@#}& /@ flist, {f, "Exponential Generating Function"}], IconizedObject[«Grid options»]]//TraditionalForm
Wolfram Research (2008)，ExponentialGeneratingFunction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ExponentialGeneratingFunction.html.

文本

Wolfram Research (2008)，ExponentialGeneratingFunction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ExponentialGeneratingFunction.html.

CMS

Wolfram 语言. 2008. "ExponentialGeneratingFunction." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ExponentialGeneratingFunction.html.

APA

Wolfram 语言. (2008). ExponentialGeneratingFunction. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ExponentialGeneratingFunction.html 年

BibTeX

@misc{reference.wolfram_2026_exponentialgeneratingfunction, author="Wolfram Research", title="{ExponentialGeneratingFunction}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/ExponentialGeneratingFunction.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_exponentialgeneratingfunction, organization={Wolfram Research}, title={ExponentialGeneratingFunction}, year={2008}, url={https://reference.wolfram.com/language/ref/ExponentialGeneratingFunction.html}, note=[Accessed: 11-September-2026]}