WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Frame

Graphics，Gridおよび関連構文のオプションで，プロットを囲む枠を描くかどうかを指定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
枠の位置  
枠のスタイル  
枠ラベルと枠目盛  
一般化と拡張  
格子枠の位置  
格子枠のスタイル  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連するワークフロー
関連リンク
履歴
引用書式

Frame

Frame

Graphics，Gridおよび関連構文のオプションで，プロットを囲む枠を描くかどうかを指定する．

詳細

  • 次の設定を使うことができる．
  • Trueオブジェクト全体の周囲に枠を描く
    False または None枠は描かない
    AllGrid等の中の各項目の周囲に枠を描く
  • Graphics，Plotおよび関連関数は，Frame->{{left,right},{bottom,top}}で各辺に枠を描くかどうかを指定する．デフォルト設定のFrameTicks->Automaticのときは，枠を描くと必ず目盛マークが付けられる．
  • Gridおよび関連構文はでは設定値のリストを与えることができる．以下はその一般的な例である．
  • {All,False}すべての水平位置に枠（列線）
    {False,All}すべての垂直位置に枠（行線）
    {-1->True}最後の列周囲に枠
    {False,-1->True}最後の行周囲に枠
  • Gridおよび関連構文中のFrameの一般的な設定は次のようにすることができる．
  • specすべての項目に spec を適用
    {specx}連続する水平位置に specxを適用
    {specx,specy}連続する水平および垂直位置に speckを適用
    {specx,specy,rules}個々の i,j 要素への明示的な規則の適用も許容する
  • speckは次の形式を取ることができる．
  • {s1,s2,…,sn}s1から snまでを使い，次にデフォルトを使う
    {{c}}すべての場合に c を使う
    {{c1,c2}}c1と c2を交互に使う
    {{c1,c2,…}}すべての ciを循環的に使う
    {s,{c}}s を使い，次に c を繰り返し使う
    {s1,{c},sn}s1を使い，次に c を繰り返し使うが，最後には snを使う
    {s1,s2,…,{c1,c2,…},sm,…,sn}最初の一続きの siを使い，次に ciを循環的に使い，次に siの最後の一続きを使う
    {s1,s2,…,{},sm,…,sn}最初に siのはじめの一続きを使い，最後に siの最後の一続きを使う
    {i1->v1,i2->v2,…}位置 ikで何を使うかを指定する
    {spec,rules}spec における指定をオーバーライドするために rules を使う
  • {s1,s2,…,{…},sm,…,sn}の形の設定のとき，格子中の項目よりも指定された siの方が多い場合，最初の方の siは最初の方の項目に使われ，最後の方の siは最後の方の項目に使われる．
  • {{imin,imax},{jmin,jmax}}->v の形の規則を使って，格子の範囲の枠を指定することができる．

例題

すべて開く すべて閉じる

例  (4)

プロットの周囲に枠を描く：

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True]

左右の辺に枠を描く：

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> {{True, True}, {False, False}}]

格子の周囲に枠を置く：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> True]

格子中のすべての要素の周囲に枠を描く：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> All]

FrameStyleを使って枠目盛や枠ラベルを含む全体的な枠のスタイルを指定する：

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameStyle -> Directive[Orange, 12]]

スコープ  (9)

枠の位置  (2)

上下の辺に枠を付ける：

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> {{False, False}, {True, True}}]

すべての列に枠を付ける：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> {All, False}]

すべての行に枠を付ける：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> {False, All}]

枠のスタイル  (2)

各枠辺のスタイルを指定する：

Wolfram Language code: Graphics[Circle[], Frame -> True, FrameStyle -> {{Thick, Directive[Thick, Dashed]}, {Blue, Red}}]

格子の枠スタイルを指定する：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> All, FrameStyle -> Directive[Red, Dotted]]

枠ラベルと枠目盛  (5)

下と左の枠辺にラベルを付ける：

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameLabel -> {x, y}]

各辺のラベルを指定する：

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameLabel -> {{y, Sin[x]}, {x, "plot"}}]

枠は付けるが目盛は付けない：

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameTicks -> None]

枠の目盛マークとラベルを自動的に付ける：

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameTicks -> Automatic]

枠の目盛マークを指定位置に付ける：

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Frame -> True, FrameTicks -> {{{-1, 0, 1}, None}, {{0, Pi, 2Pi, 3Pi}, None}}]

一般化と拡張  (10)

格子枠の位置  (6)

第1列には枠を付けず第2列には枠を付ける．その後はデフォルト（枠なし）を繰り返す：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> {{None, True}, None}]

第1列には枠を付けず，第2列および続く列に枠を付ける：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> {{None, {True}}, None}]

第1行には枠を付けず第2行には枠を付ける．その後はデフォルト（枠なし）を繰り返す：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> {None, {None, True}}]

特定の行と列に枠を付ける：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> {3 -> True, 2 -> True}]

最後の列と最後の行に枠を付ける：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> {-1 -> True, -1 -> True}]

1組の要素に枠を付ける：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> {None, None, {{1, 1} -> True, {3, 3} -> True}}]

格子内の小区域に枠を付ける：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> {None, None, {{{1, 3}, {2, 4}} -> True}}]

格子中の個々の要素の周囲に枠を付ける：

Wolfram Language code: Grid[{{Item[a, Frame -> True], b}, {c, d}}]

格子枠のスタイル  (4)

特定のスタイルで行と列に枠を付ける：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> {3 -> Red, 2 -> Directive[Blue, Thick]}]

特定のスタイルで格子の一定範囲に枠を付ける：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> {None, None, {{{1, 3}, {2, 4}} -> Thick, {{3, 4}, {1, 6}} -> Red}}]

個々の要素の周囲にスタイル付きの枠を置く：

Wolfram Language code: Grid[{{Item[a, Frame -> True, FrameStyle -> Directive[Red, Thick]], b}, {c, d}}]

個別にスタイル付けされた枠をFrameStyleとともに使うことができる．優先順位は前者の方が高い：

Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> {{1 -> Red, 3 -> Dashed}, 2 -> Directive[Green, Thin]}, FrameStyle -> Directive[StandardGray, Thick]]

アプリケーション  (1)

対角要素に枠を付ける：

Wolfram Language code: Grid[Partition[Range[100], 10], Frame -> {None, None, Table[{k, k} -> True, {k, 10}]}]

特性と関係  (3)

Dividersは行と列の間の区切り線を個別に指定するために使うことができる：

Wolfram Language code: Grid[Table[x, {4}, {7}], Dividers -> {{True}, {True}}]
Wolfram Language code: Grid[Table[x, {4}, {7}], Frame -> {{True}, {True}}]

2Dでは，枠はグラフィックスの上に描かれる：

Wolfram Language code: Graphics[{Pink, Disk[]}, Frame -> True, PlotRange -> {{0, 1}, {0, 1}}]

Epilog中のオブジェクトは，枠を含む任意のグラフィックスの上に描かれる：

Wolfram Language code: Graphics[{Pink, Disk[]}, Frame -> True, Epilog -> {Blue, Disk[{0, 0}, .5]}, PlotRange -> {{0, 1}, {0, 1}}]

GridLinesは画像を横切る形で格子を置く：

Wolfram Language code: Graphics[Circle[], GridLines -> Automatic, Frame -> True]

おもしろい例題  (1)

左上の部分格子に枠を付ける：

Wolfram Language code: Grid[Partition[Range[100], 10], Frame -> {None, None, Table[{{1, k}, {1, k}} -> True, {k, 10}]}]
Wolfram Research (1991), Frame, Wolfram言語関数， https://reference.wolfram.com/language/ref/Frame.html （2007年に更新）.

テキスト

Wolfram Research (1991), Frame, Wolfram言語関数， https://reference.wolfram.com/language/ref/Frame.html （2007年に更新）.

CMS

Wolfram Language. 1991. "Frame." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2007. https://reference.wolfram.com/language/ref/Frame.html.

APA

Wolfram Language. (1991). Frame. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Frame.html

BibTeX

@misc{reference.wolfram_2026_frame, author="Wolfram Research", title="{Frame}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Frame.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_frame, organization={Wolfram Research}, title={Frame}, year={2007}, url={https://reference.wolfram.com/language/ref/Frame.html}, note=[Accessed: 03-November-2026]}