Wolfram言語＆システムドキュメントセンター

Minimize

Minimize[f,x]

x について f を記号的に最小にする．

Minimize[f,{x,y,…}]

x, y, … について f を記号的に最小にする．

Minimize[{f,cons},{x,y,…}]

制約条件 cons 下で f を記号的に最小にする．

Minimize[…,x∈rdom]

x が領域 rdom 内にあるように制限する．

Minimize[…,…,dom]

変数を領域 dom（一般にRealsまたはIntegers）に制限する．

Minimize

Minimize[f,x]

x について f を記号的に最小にする．

Minimize[f,{x,y,…}]

x, y, … について f を記号的に最小にする．

Minimize[{f,cons},{x,y,…}]

制約条件 cons 下で f を記号的に最小にする．

Minimize[…,x∈rdom]

x が領域 rdom 内にあるように制限する．

Minimize[…,…,dom]

変数を領域 dom（一般にRealsまたはIntegers）に制限する．

詳細とオプション

Minimizeは上限（インフィマム），記号最適化，および大域的最適化(GO)としても知られている．
Minimizeは与えられた制約条件に従って f の最小値を求める．
Minimizeは，通常，制約条件下で可能な最小値を求めるために使われる．分野によっては，最適な戦略，最良適合，最適な構成等と呼ばれることがある．
Minimizeは{f_min,{x->x_min,y->y_min,…}}の形式のリストを返す．

f および cons が線形あるいは多項式の場合，Minimizeは常に大域的な最小大値を求める．
制約条件 cons は以下の論理結合でよい．

	lhs==rhs	等式
	lhs>rhs, lhs≥rhs, lhs<rhs, lhs≤rhs	不等式 (LessEqual,…)
	lhsrhs, lhsrhs, lhsrhs, lhsrhs	ベクトル不等式 (VectorLessEqual,…)
	Exists[…], ForAll[…]	量化条件
	{x,y,…}∈rdom	領域指定

Minimize[{f,cons},x∈rdom]は，事実上，Minimize[{f,cons∧x∈rdom},x]に等しい．
x∈rdom については，Indexed[x,i]を使って別の座標に言及することができる．
次は，使用可能な領域 rdom である．

	Reals	実数スカラー変数
	Integers	整数スカラー変数
	Vectors[n,dom]	のベクトル変数
	Matrices[{m,n},dom]	の行列変数
	ℛ	幾何領域に制限されたベクトル変数

デフォルトで，すべての変数が実数であるとみなされる．
Minimizeは入力が厳密値の場合は厳密値を返す．入力が近似値の場合は自動的にNMinimizeを呼び出す．
Minimizeは次の形式を返す．

	{f_min,{xx_min,…}}	有限最小値
	{∞,{xIndeterminate,…}}	実行不可能，つまり，制約条件集合が空
	{-∞,{xx_min,…}}	非有界，つまり，f の値は任意に小さくできる

最小値が制約条件で定義した領域のごくわずか外側でのみ，あるいは漸近的にのみ達せられた場合，Minimizeは下限と最も近くの指定可能な点を返す．
たとえ複数の点で同じ最小値に達しても，そのうちの1つだけが返される．
N[Minimize[…]]は，記号的には解けない最適化問題についてはNMinimizeを呼び出す．
Minimize[f,x,WorkingPrecision->n]は n 桁精度で結果を計算する． »

例題

すべて開くすべて閉じる

例 (5)

一変数関数を最小化する：

Wolfram Language code: Minimize[2x ^ 2 - 3x + 5, x]

多変数関数を最小化する：

Wolfram Language code: Minimize[(x y - 3) ^ 2 + 1, {x, y}]

制約条件に従って関数を最小化する：

Wolfram Language code: Minimize[{x - 2y, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

パラメータを含んだ最小化問題：

Wolfram Language code: Minimize[a x ^ 2 + b x + c, x]

幾何学領域上で関数を最小化する：

Wolfram Language code: Minimize[x + y, {x, y}∈Disk[]]

これをプロットする：

Wolfram Language code: Show[ContourPlot[x + y, {x, y}∈Disk[]], Graphics[{Red, PointSize[Large], Point[{x, y} /. Last[%]]}]]

スコープ (36)

基本的な用法 (7)

制約条件のない実数上でを最小にする：

Wolfram Language code: Minimize[Sin[x] + Cos[x], x]

制約条件に従ってを最小にする：

Wolfram Language code: Minimize[{x + 2y, x ^ 2 + 2y ^ 2 ≤ 3 && x + y == 2 && x ≥ 1}, {x, y}]

制約条件は任意の論理結合を含むことがある：

Wolfram Language code: Minimize[{x y, x ^ 2 + y ^ 2 ≤ 1 || (x + 1) ^ 2 + (y - 1) ^ 2 ≤ 2}, {x, y}]

非有界の問題：

Wolfram Language code: Minimize[{x + y, x ≤ y ^ 2}, {x, y}]

実行不可能な問題：

Wolfram Language code: Minimize[{x + y, x ^ 2 + y ^ 2 < 0}, {x, y}]

下限値には達しないかもしれない：

Wolfram Language code: Minimize[Exp[x], x]

ベクトル変数とベクトル不等式を使う：

Wolfram Language code: Minimize[{{1, 1}.v, {{1, 2}, {1, 0}}.v{3, -1}}, v]

一変数の問題 (7)

制約条件なしの一変数多項式最小化：

Wolfram Language code: Minimize[x ^ 4 + 2x ^ 3 + 5x - 7, x]

制約条件付き一変数多項式最小化：

Wolfram Language code: Minimize[{3x ^ 2 - x + 9, 2x ^ 3 + 5x - 7 ≥ 0}, x]

指数対数関数：

Wolfram Language code: Minimize[E ^ (2E ^ x) - Log[x ^ 2 + 1] - 20x, x]

有界の条件上での解析関数：

Wolfram Language code: Minimize[{AiryAi[x + Sin[x]] + Cos[x ^ 2], -5 ≤ x ≤ 5}, x]

Wolfram Language code: Plot[AiryAi[x + Sin[x]] + Cos[x ^ 2], {x, -5, 5}, Epilog -> {Red, Point[{x /. %[[2]], %[[1]]}]}]

Wolfram Language code: Minimize[{BesselJ[2, x] / Gamma[x + 1] + (x + 1) ^ Sin[x], 0 ≤ x ≤ 10}, x]

Wolfram Language code: Plot[BesselJ[2, x] / Gamma[x + 1] + (x + 1) ^ Sin[x], {x, 0, 10}, Epilog -> {Red, Point[{x /. %[[2]], %[[1]]}]}]

周期関数：

Wolfram Language code: Minimize[{Sin[x], -1 / 2 ≤ Cos[x] ≤ 1 / 2}, x]

三角関数と通約可能な周期の組合せ：

Wolfram Language code: Minimize[Sin[E ^ (x / 3) - 3 x] + 2 Cos[2 E ^ (x / 3) - 6 x + 1] ^ 2, x]

周期関数と通約可能な周期の組合せ：

Wolfram Language code: Minimize[Sin[Sqrt[3] x] - Exp[Cos[3 x] + 2], x]

Wolfram Language code: Show[{Plot[Sin[Sqrt[3] x] - Exp[Cos[3 x] + 2], {x, -50, 50}], Graphics[{Red, Line[{{-50, %[[1]]}, {50, %[[1]]}}]}]}]

区分関数：

Wolfram Language code: Minimize[{x - Floor[x + UnitStep[x - 1]], Ceiling[Abs[x]] < 5}, x]

関数の特性情報を使って可解の制約条件がない問題：

Wolfram Language code: Minimize[SinhIntegral[DawsonF[x]], x]

Wolfram Language code: Minimize[BesselJ[7 / 4, x ^ 2 + x + 1], x]

多変数の問題 (9)

多変数線形制約条件付き最小化：

Wolfram Language code: Minimize[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]

線形分数制約条件付き最小化：

Wolfram Language code: Minimize[{(2x + y - z) / (5x - 7y + 3), 0 ≤ x + y + z ≤ 1 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]

制約条件なしの多項式最小化：

Wolfram Language code: Minimize[(x ^ 2 - 2y) ^ 2 - x ^ 2 + 2y - 1, {x, y}]

制約条件付き多項式最適化は常に解くことができる：

Wolfram Language code: Minimize[{x y - 1, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

最小値には到達できないことがある：

Wolfram Language code: Minimize[{x ^ 2 + 1, x y ≥ 1}, {x, y}]

目的関数は境界がないことがある：

Wolfram Language code: Minimize[{x, x y ≤ 1}, {x, y}]

制約条件を満足する点がないことがある：

Wolfram Language code: Minimize[{x, x ^ 2 + y ^ 2 < 0}, {x, y}]

定量化された多項式制約：

Wolfram Language code:

Minimize[{(x + 7)^2 + (y - 8)^2, Subscript[∀, z]Subscript[∃, w]3 z^2 w + (x + y) z^4 - 1 == (x^3 - x y + y^2 - 1) w^2}, {x, y}]

代数的最小化：

Wolfram Language code: Minimize[{Sqrt[x + y] + x , x Sqrt[y] ≥ 1}, {x, y}]

境界付き超越方程式最小化：

Wolfram Language code: Minimize[{E ^ x + Log[y], x Log[y] == 2 && -10 ≤ x ≤ 10 && 1 / 10 ≤ y ≤ 10}, {x, y}]

区分関数最小化：

Wolfram Language code: Minimize[{Max[x - y, Abs[y]], Min[x - 2, x - y ^ 2] ≥ Abs[x y - 1]}, {x, y}]

凸最小化：

Wolfram Language code: Minimize[v.{-1, 1}, {VectorGreaterEqual[{{{1, 0}, {0, 1}, {-1, -2}}.v, {0, 0, -2}}, "ExponentialCone"]}, v]

が半正定でとなるように凸目的関数を最小にする：

Wolfram Language code:

res = Minimize[{-Log[x + y], (⁠|       |       |
| ----- | ----- |
| x + y | 1     |
| 1     | x - y |⁠)Underscript[, {"SemidefiniteCone", 2}]0 && 1 ≤ x ≤ 10 && -1 ≤ y ≤ 1}, {x, y}]

領域と最小化点をプロットする：

Wolfram Language code:

Show[Plot3D[-Log[x + y], {x, 1, 10}, {y, -1, 1}, ...], Graphics3D[{Red, PointSize[0.05], Point[{x, y, -Log[x + y]} /. res[[2]]]}]]

パラメトリック問題 (4)

パラメトリック線形最適化：

Wolfram Language code:

Minimize[{-8x - 7y, -6 x - 4 y ≤ 8 - 5 a - 7 b && 7 x + 5 y ≤ a + 4 b && -x + y ≤ 6 + 4a - 5 b && -4 x + 7 y ≤ -1 - 2 a - 7 b && 5 y ≤ 6 - 9 b}, {x, y}]

最小値はパラメータの連続関数である：

Wolfram Language code: min = %[[1]];Plot3D[min, {a, -3, 3}, {b, 0, 3}]

パラメトリック二次最適化：

Wolfram Language code: Minimize[{(x - 1) ^ 2 + (2y - 1) ^ 2, x + 2y ≤ a + b && 2x - y ≤ a - b + 1 && x - 2y ≤ 2a - b + 1}, {x, y}]

最小値はパラメータの連続関数である：

Wolfram Language code: min = %[[1]];Plot3D[min, {a, -5, 5}, {b, -5, 5}]

制約条件なしのパラメトリック多項式最小化：

Wolfram Language code: Minimize[x ^ 4 + a x ^ 2 + b, x]

制約条件付きパラメトリック多項式最小化：

Wolfram Language code: Minimize[{x ^ 2 + y ^ 2, x ^ 3 + y ^ 2 == a}, {x, y}]

整数上の最適化 (3)

一変数問題：

Wolfram Language code: Minimize[{E ^ x - x ^ 3 Log[x], x > 0}, x, Integers]

Wolfram Language code: Minimize[Sin[2x] + Cos[3x], x, Integers]

Wolfram Language code: Show[{ListPlot[Table[Sin[2x] + Cos[3 x], {x, 0, 10000}]], Graphics[{Red, Line[{{0, %[[1]]}, {10000, %[[1]]}}]}]}]

整数線形計画法：

Wolfram Language code: Minimize[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}, Integers]

整数上の多項式最小化：

Wolfram Language code: Minimize[{x ^ 2 + x y + 1, x y ≥ 1}, {x, y}, Integers]

領域上の最適化 (6)

領域上で最小化する：

Wolfram Language code: ℛ = Cylinder[{{1, 2, 3}, {3, 2, 1}}, 1];

Wolfram Language code: Minimize[z, {x, y, z}∈ℛ]

これをプロットする：

Wolfram Language code: Graphics3D[{{Opacity[0.5], Green, ℛ}, {Red, PointSize[Large], Point[{x, y, z} /. Last[%]]}}]

2領域間の最小距離を求める：

Wolfram Language code:

Subscript[ℛ, 1] = Disk[];
Subscript[ℛ, 2] = InfiniteLine[{{-2, 0}, {0, 2}}];

Wolfram Language code: Minimize[(x - u)^2 + (y - v)^2, {{x, y}∈Subscript[ℛ, 1], {u, v}∈Subscript[ℛ, 2]}]//RootReduce

これをプロットする：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1]}, {Green, Subscript[ℛ, 2]}, {Red, Point[{{x, y}, {u, v}} /. Last[%]]}}]

三角形と楕円が交差する最小のを求める：

Wolfram Language code:

Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Subscript[ℛ, 2] = Disk[{1, 1}, {2r, r}];

Wolfram Language code: Minimize[{r, {x, y}∈Subscript[ℛ, 1] && {x, y}∈Subscript[ℛ, 2]}, {r, x, y}]

これをプロットする：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1], Subscript[ℛ, 2]}, {Red, Point[{x, y}]}} /. Last[%]]

指定された3点を含む円板の最小の半径を求める：

Wolfram Language code: Subscript[ℛ, 3] = Disk[{a, b}, r];

Wolfram Language code: Minimize[{r, ({0, 0} | {1, 0} | {0, 1})∈Subscript[ℛ, 3]}, {a, b, r}]

これをプロットする：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 3]} /. %[[2]], {Red, Point[{{0, 0}, {1, 0}, {0, 1}}]}}]

Circumsphereを使って同じ結果を直接得る：

Wolfram Language code: Circumsphere[{{0, 0}, {1, 0}, {0, 1}}]

を使ってが内のベクトルであると指定する：

Wolfram Language code: ℛ = Sphere[];

Wolfram Language code: Minimize[x.{1, 2, 3}, x∈ℛ]

2領域間の最小距離を求める：

Wolfram Language code:

Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Subscript[ℛ, 2] = Disk[{2, 2}, 1];

Wolfram Language code: Minimize[EuclideanDistance[x, y], {x∈Subscript[ℛ, 1], y∈Subscript[ℛ, 2]}]//RootReduce

これをプロットする：

Wolfram Language code: Graphics[{{LightBlue, Subscript[ℛ, 1], Subscript[ℛ, 2]}, {Red, Point[{x, y}]}} /. %[[2]]]

オプション (2)

Method (1)

Minimizeが円筒代数分解を使うように指定する：

Wolfram Language code: mincad = Minimize[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}, Method -> "CAD"]

ラグランジュ(Lagrange)乗数を使う：

Wolfram Language code: minlm = Minimize[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}, Method -> "LagrangeMultipliers"]

デフォルトメソッドを使う：

Wolfram Language code: mindef = Minimize[{x ^ 2 - y ^ 3 + 2x y, x ^ 2 + y ^ 2 == 1}, {x, y}]

結果はすべて等価である：

Wolfram Language code: RootReduce[mincad] === RootReduce[minlm] === RootReduce[mindef]

WorkingPrecision (1)

厳密解を求めるのには時間がかかる：

Wolfram Language code:

TimeConstrained[Minimize[{x ^ 2 + y ^ 2 + z ^ 2, x ^ 2 - 3 x y z + 9 z ^ 2 + y ^ 2 == E && x y z ≤ Pi}, {x, y, z}], 60]

WorkingPrecision->100とすると，厳密な最小値が得られるが，得られた解は正しくないかもしれない：

Wolfram Language code:

Minimize[{x ^ 2 + y ^ 2 + z ^ 2, x ^ 2 - 3 x y z + 9 z ^ 2 + y ^ 2 == E && x y z ≤ Pi}, {x, y, z}, WorkingPrecision -> 100]//Timing

アプリケーション (10)

基本的なアプリケーション (3)

単位面積を持つ長方形の周囲の長さの最小値を求める：

Wolfram Language code: Minimize[{2x + 2y, x y == 1 && x > 0 && y > 0}, {x, y}]

単位面積を持つ三角形の周囲の長さの最小値を求める：

Wolfram Language code:

triangle = a > 0 && b > 0 && c > 0 && a + b > c && a + c > b && b + c > a;
s = 1 / 2(a + b + c);

Wolfram Language code: Minimize[{a + b + c, triangle && Sqrt[s(s - a)(s - b)(s - c)] ^ 2 == 1}, {a, b, c}]

周囲が最小となる三角形は正三角形である：

Wolfram Language code: %//RootReduce

座標軸上の点から放物線までの距離を求める：

Wolfram Language code: Minimize[{Sqrt[x ^ 2 + (y - c) ^ 2], y == a x ^ 2}, {x, y}]

とのパラメータに特別な関係を想定する：

Wolfram Language code: Assuming[0 < 1 / (2c) < a, Refine@ Minimize[{Sqrt[x ^ 2 + (y - c) ^ 2], y == a x ^ 2}, {x, y}]]

幾何学的距離 (6)

領域 ℛ 内の点から指定された点 p 真での最短距離と，最短距離を実現する点 q は，Minimize[EuclideanDistance[p,q],q∈ℛ]で与えられる．単位Disk[]内からの{1,1}までの最短距離と最近点を求める：

Wolfram Language code:

p = {1, 1};
q = {q1, q2};
ℛ = Disk[];

Wolfram Language code: {d, qrul} = Minimize[EuclideanDistance[p, q], q∈ℛ]//RootReduce

これをプロットする：

Wolfram Language code:

Graphics[{{LightBlue, EdgeForm[Gray], ℛ}, {Green, Circle[p, d]}, {Red, Point[{p, q /. qrul}]}, {Dashed, Line[{p, q /. qrul}]}}]

標準的な単位シンプレックスSimplex[2]内から点{1,3/4}までの最短距離と最近点を求める：

Wolfram Language code:

p = {1, 3 / 4};
q = {q1, q2};
ℛ = Simplex[{{0, 0}, {1, 0}, {0, 1}}];

Wolfram Language code: {d, qrul} = Minimize[EuclideanDistance[p, q], q∈ℛ]

これをプロットする：

Wolfram Language code:

Graphics[{{LightBlue, EdgeForm[Gray], ℛ}, {Green, Circle[p, d]}, {Red, Point[{p, q /. qrul}]}, {Dashed, Line[{p, q /. qrul}]}}]

標準的な単位球Sphere[]から{1,1,1}までの最短距離と最近点を求める：

Wolfram Language code:

p = {1, 1, 1};
q = {q1, q2, q3};
ℛ = Sphere[];

Wolfram Language code: {d, qrul} = Minimize[EuclideanDistance[p, q], q∈ℛ]//RootReduce

これをプロットする：

Wolfram Language code:

Graphics3D[{{Opacity[0.5], ℛ}, {Opacity[0.3], Green, Sphere[p, d]}, {Red, Point[{p, q /. qrul}]}, {Dashed, Line[{p, q /. qrul}]}}]

標準的な単位シンプレックスSimplex[3]内から点{-1/3,1/3,1/3}までの最短距離と最近点を求める：

Wolfram Language code:

p = {-1 / 3, 1 / 3, 1 / 3};
q = {q1, q2, q3};
ℛ = Simplex[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];

Wolfram Language code: {d, qrul} = Minimize[EuclideanDistance[p, q], q∈ℛ]

これをプロットする：

Wolfram Language code:

Graphics3D[{{Opacity[0.5], ℛ}, {Opacity[0.3], Green, Sphere[p, d]}, {Red, Point[{p, q /. qrul}]}, {Dashed, Line[{p, q /. qrul}]}}]

最近点 p∈ および q∈ とその距離は，Minimize[EuclideanDistance[p,q],{p∈,q∈}]え求めることができる．Disk[{0,0}]とRectangle[{3,3}]の最近点および両者の距離を求める：

Wolfram Language code: 𝒫 = Disk[{0, 0}]; 𝒬 = Rectangle[{3, 3}];

Wolfram Language code: {d, pqrul} = Minimize[EuclideanDistance[p, q], {p∈𝒫, q∈𝒬}]//RootReduce

これをプロットする：

Wolfram Language code: Graphics[{{LightBlue, EdgeForm[Gray], 𝒫, 𝒬}, {Red, Point[{p, q} /. pqrul]}, {Dashed, Line[{p, q} /. pqrul]}}]

Line[{{0,0,0},{1,1,1}}]内とBall[{5,5,0},1]内の最近点と両者の距離を求める：

Wolfram Language code: 𝒫 = Line[{{0, 0, 0}, {1, 1, 1}}]; 𝒬 = Ball[{5, 5, 0}, 1];

Wolfram Language code: {d, pqrul} = Minimize[EuclideanDistance[p, q], {p∈𝒫, q∈𝒬}]//RootReduce

これをプロットする：

Wolfram Language code: Graphics3D[{{𝒫, {Opacity[0.5], 𝒬}}, {Red, Point[{p, q} /. pqrul]}, {Dashed, Line[{p, q} /. pqrul]}}]

幾何学的中心 (1)

ℛ⊆ⁿが全次元の領域である場合，Chebyshev center は ℛ の最大内接球の中心である．ℛ の最大内接球の中心と半径はMinimize[SignedRegionDistance[ℛ,p], p∈ℛ]で求めることができる．Rectangle[]について，最大内接球のChebyshev Centerと半径を求める：

Wolfram Language code: ℛ = Rectangle[];p = {p1, p2};

Wolfram Language code: {d, prul} = Minimize[SignedRegionDistance[ℛ, p], p∈ℛ]

Wolfram Language code: Graphics[{{LightBlue, EdgeForm[Gray], ℛ}, {Green, Circle[p /. prul, -d]}, {Red, Point[p /. prul]}}]

Triangle[]について，最大内接球のChebyshev Centerと半径を求める：

Wolfram Language code: ℛ = Triangle[];

Wolfram Language code: {d, prul} = Minimize[SignedRegionDistance[ℛ, p], p∈ℛ]

Wolfram Language code: Graphics[{{LightBlue, EdgeForm[Gray], ℛ}, {Green, Circle[p /. prul, -d]}, {Red, Point[p /. prul]}}]

特性と関係 (6)

Minimizeは目的関数の厳密な大域的最小値を与える：

Wolfram Language code: f = Expand[Product[(x - i)(x - 100 - i), {i, 5}]];

Wolfram Language code: Minimize[f, x]

Wolfram Language code: Plot[f, {x, 0, 100}, Epilog -> {PointSize[Medium], Green, Point[{x /. %[[2]], %[[1]]}]}]

NMinimizeは大域的最小値を数値的に求めようとするが，極小値が求まることもある：

Wolfram Language code: NMinimize[f, x]

Wolfram Language code: Plot[f, {x, 0.5, 5.5}, Epilog -> {PointSize[Medium], Red, Point[{x /. %[[2]], %[[1]]}]}]

FindMinimumは初期値によって極小値を求める：

Wolfram Language code: FindMinimum[f, {x, #}]& /@ {1, 50}

Wolfram Language code:

Plot[f, {x, 0, 100}, Epilog -> {PointSize[Medium], {Red, Point[{x /. %[[1, 2]], %[[1, 1]]}]}, {Green, Point[{x /. %[[2, 2]], %[[2, 1]]}]}}]

メッセージで特に指示がない限り，最小点は制約条件を満たす：

Wolfram Language code: m = Minimize[{(x - 2) ^ 2 + (y - 3 / 2) ^ 2, x ^ 2 + y ^ 2 ≤ 1}, {x, y}]

Wolfram Language code: x ^ 2 + y ^ 2 ≤ 1 /. m[[2]]

与えられた点は点{2,}からの距離を最小にする：

Wolfram Language code:

RegionPlot[x ^ 2 + y ^ 2 ≤ 1, {x, -1.2, 2.2}, {y, -1.2, 2.2}, Epilog -> {PointSize[Medium], {Red, Point[{x, y} /. m[[2]]]}, {Green, Point[{2, 3 / 2}]}}]

最小値に達しなかった場合，Minimizeは境界上の点を返すことがある：

Wolfram Language code: Minimize[{(x - 2) ^ 2 + (y - 3 / 2) ^ 2, x ^ 2 + y ^ 2 < 1}, {x, y}]

ここでは，y が無限大に向かうと目的関数は最小値に向かう傾向にある：

Wolfram Language code: Minimize[{x, x y == 1 && x > 0}, {x, y}]

Minimizeは線形計画法問題を解くことができる：

Wolfram Language code: Minimize[{2x + 3y - z, 1 ≤ x + y + z ≤ 2 && 1 ≤ x - y + z ≤ 2 && x - y - z == 3}, {x, y, z}]

LinearProgrammingを使って，行列表記で与えられた同じ問題を解くことができる：

Wolfram Language code:

c = {2, 3, -1};
m = {{1, 1, 1}, {1, 1, 1}, {1, -1, 1}, {1, -1, 1}, {1, -1, -1}};
b = {{1, 1}, {2, -1}, {1, 1}, {2, -1}, {3, 0}};

Wolfram Language code: LinearProgramming[c, m, b, -Infinity]

以下で最小値を計算する：

Wolfram Language code: c.%

RegionDistanceおよびRegionNearestを使って距離と最近点を計算する：

Wolfram Language code:

ℛ = Cone[{{1, 2, 3}, {4, 5, 6}}, 3];
p = {5, 4, 3};

Wolfram Language code: RegionDistance[ℛ, p]//RootReduce

Wolfram Language code: RegionNearest[ℛ, p]//RootReduce

どちらもMinimizeを使って計算することができる：

Wolfram Language code: Minimize[Norm[{x, y, z} - p], {x, y, z}∈ℛ]//RootReduce

Wolfram Language code: Graphics3D[{ℛ, {PointSize[Large], {Green, Point[p]}, {Red, Point[{x, y, z} /. %[[2]]]}}}]

RegionBoundsを使って境界ボックスを計算する：

Wolfram Language code:

f = x^4 + 3 x^2 y + 2 x^2 y^2 - y^3 + y^4 ≤ 0;
ℛ = ImplicitRegion@@{f, {x, y}}

Wolfram Language code: RegionBounds[ℛ]

MaximizeおよびMinimizeを使って同じ境界を計算する：

Wolfram Language code: {{x1, x2}, {y1, y2}} = {Minimize[#, {x, y}∈ℛ][[1]], Maximize[#, {x, y}∈ℛ][[1]]}& /@ {x, y}

Wolfram Language code: Show[{Graphics[{LightBlue, Rectangle[{x1, y1}, {x2, y2}]}], RegionPlot[f, {x, x1 - 1, x2 + 1}, {y, y1 - 1, y2 + 1}]}]

考えられる問題 (1)

Minimizeの入力に使われる関数はすべて実数値を持たなければならない：

Wolfram Language code: Minimize[{x + y, Sqrt[x] - Sqrt[y] == 0}, {x, y}]

方程式は満足されるが二乗根が実数ではない値は使えない：

Wolfram Language code: {Sqrt[x] - Sqrt[y] == 0, Sqrt[x], Sqrt[y]} /. {x -> -1, y -> -1}

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Minimize

詳細とオプション

例題

例 (5)

スコープ (36)

基本的な用法 (7)

一変数の問題 (7)

多変数の問題 (9)

パラメトリック問題 (4)

整数上の最適化 (3)

領域上の最適化 (6)

オプション (2)

Method (1)

WorkingPrecision (1)

アプリケーション (10)

基本的なアプリケーション (3)

幾何学的距離 (6)

幾何学的中心 (1)

特性と関係 (6)

考えられる問題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

Minimize

詳細とオプション

例題

例 (5)

スコープ (36)

基本的な用法 (7)

一変数の問題 (7)

多変数の問題 (9)

パラメトリック問題 (4)

整数上の最適化 (3)

領域上の最適化 (6)

オプション (2)

Method (1)

WorkingPrecision (1)

アプリケーション (10)

基本的なアプリケーション (3)

幾何学的距離 (6)

幾何学的中心 (1)

特性と関係 (6)

考えられる問題 (1)

関連項目

テクニカルノート

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX