WOLFRAM

Wolfram 语言与系统参考资料中心

RipleyK[pdata,r]

估计点数据 pdata 在半径 r 内的 Ripley's 函数 .

RipleyK[pproc,r]

计算点过程 pproc 的.

RipleyK[bdata,r]

计算分组过的数据 bdata 的 .

RipleyK[pspec]

生成可重复应用于不同半径 r 的函数 .

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
点数据  
点过程  
选项  
SpatialBoundaryCorrection  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

RipleyK

RipleyK[pdata,r]

估计点数据 pdata 在半径 r 内的 Ripley's 函数 .

RipleyK[pproc,r]

计算点过程 pproc 的.

RipleyK[bdata,r]

计算分组过的数据 bdata 的 .

RipleyK[pspec]

生成可重复应用于不同半径 r 的函数 .

更多信息和选项

  • 积 ，其中 为平均密度，给出期望位于点 r 距离范围内的点数，不计算点本身.
  •     
  • RipleyK 测量半径 r 内的点的空间均匀性. 与泊松点过程相比的结果为：
  • 比泊松点过程更分散
    与泊松点过程相似，即具有完全空间随机性
    比泊松点过程聚类性更强
  • 下面， 是 中单位球体的体积.
  •     
  • 半径 r 可以是单个值或值的列表. 如果没有指定 r，RipleyK 会返回一个 PointStatisticFunction，可用其重复计算 函数.
  • 可用以下形式给出点 pdata：
  • {p1,p2,…}点 pi
    GeoPosition[…],GeoPositionXYZ[…],…地理点
    SpatialPointData[…]空间点集
    {pts,reg}点集 pts 和观察区域 reg
  • 如果没有给出观察区域 reg，则用 RipleyRassonRegion 自动计算区域.
  • 可用以下形式给出点过程 pproc：
  • proc点过程 proc
    {proc,reg}点过程 proc 和观察区域 reg
  • 观察区域 reg 不应含有参数且 SpatialObservationRegionQ 的结果为真.
  • 已分组数据 bdata 来自 SpatialBinnedPointData，且被视为是具有分段恒定强度函数的 InhomogeneousPoissonPointProcess.
  • 对于 pdata，通过统计彼此之间的距离 r 内有多少对不同的点来计算 .
  • 对于 pproc，通过使用精确公式或通过仿真生成点数据来计算 .
  • 可给出以下选项：
  • MethodAutomatic使用什么方法
    SpatialBoundaryCorrection Automatic使用什么样的边界校正
  • 对于 SpatialBoundaryCorrection，可使用以下设置：
  • Automatic自动确定边界校正
    None不进行边界校正
    "BorderMargin"对于观察区域使用内边界
    "Ripley"根据到边界的距离进行加权

范例

打开所有单元 关闭所有单元

基本范例  (3)

给定半径，估计 Ripley's 函数：

Wolfram Language code: region = Ball[{0, 0}]; pts = RandomPoint[region, 100];
Wolfram Language code: RipleyK[{pts, region}, 0.2]

给定距离的范围，估计 Ripley's 函数：

Wolfram Language code: spd = SpatialPointData[RandomReal[1, {500, 3}]]
Wolfram Language code: rspec = Range[0.1, 0.4, 0.01];
Wolfram Language code: est = RipleyK[spd, rspec];

用 ListPlot 可视化结果：

Wolfram Language code: ListPlot[est, DataRange -> MinMax[rspec], AxesLabel -> {r}, Filling -> Axis]

聚类点过程的 Ripley's 函数：

Wolfram Language code: kfun = RipleyK[MaternPointProcess[μ, λ, R, 2], r]

给定参数值，可视化该函数：

Wolfram Language code: Plot[kfun /. {μ -> 3, λ -> 2, R -> 1}, {r, 0, 3}, AxesLabel -> Automatic]

范围  (10)

点数据  (5)

半径为 0.2，估计 Ripley's 函数：

Wolfram Language code: region = Rectangle[{0, 0}, {1, 2}]; pts = RandomPoint[region, 100];
Wolfram Language code: RipleyK[{pts, region}, 0.2]

给定一组距离，获取 Ripley's 函数的经验估计：

Wolfram Language code: RipleyK[{pts, region}, {0.1, 0.3, 0.05, 0.23}]

将 RipleyK 与 SpatialPointData 一起使用：

Wolfram Language code: spd = SpatialPointData[RandomReal[1, {500, 2}]]
Wolfram Language code: res = RipleyK[spd, {0.01, 0.02}]

创建一个 PointStatisticFunction 以备后用：

Wolfram Language code: reg = Disk[]; pts = RandomPoint[Disk[], 100];
Wolfram Language code: psf = RipleyK[{pts, reg}]

计算给定半径的值：

Wolfram Language code: psf[0.5]

在不明确提供观察区域的情况下估计 Ripley's 函数：

Wolfram Language code: BlockRandom[ SeedRandom[1]; pts = RandomReal[1, {100, 2}]];
Wolfram Language code: psf = RipleyK[pts]

由 Ripley–Rasson 估计器生成的观察区域：

Wolfram Language code: psf["ObservationRegion"]

半径为 0.3 时估计的 函数：

Wolfram Language code: psf[0.3]

将 RipleyK 和 GeoPosition 一起使用：

Wolfram Language code: pts = RandomGeoPosition[GeoDisk[GeoPosition[{0, 0}], Quantity[10, "Kilometers"]], 10 ^ 2]
Wolfram Language code: psf = RipleyK[pts]

绘制点的统计函数：

Wolfram Language code: ListPlot[Table[{x, psf[x]}, {x, Quantity[0, "km"], psf["MaxRadius"], Quantity[.1, "km"]}], AxesLabel -> {"km"}]

点过程  (5)

PoissonPointProcess 的 Ripley's 函数有不依赖于强度的解析形式：

Wolfram Language code: proc = PoissonPointProcess[μ, d];
Wolfram Language code: RipleyK[proc, r]

函数与 成正比：

Wolfram Language code: Plot[Table[RipleyK[proc, r], {d, 1, 4}]//Evaluate, {r, 0, 1.3}, AxesLabel -> Automatic, PlotLegends -> (Row[{#, "D"}]& /@ Range[4])]

指定维度的聚类点过程 ThomasPointProcess 的 Ripley's 函数：

Wolfram Language code: proc2D = ThomasPointProcess[μ, λ, σ, 2];
Wolfram Language code: RipleyK[proc2D, r]

总是大于同样密度的二维的 PoissonPointProcess：

Wolfram Language code: RipleyK[PoissonPointProcess[μ, 2], r]
Wolfram Language code: Refine[%% - %, r ≥ 0]

3D：

Wolfram Language code: proc3D = ThomasPointProcess[μ, λ, σ, 3];
Wolfram Language code: RipleyK[proc3D, r]

与相应的泊松点过程相比较：

Wolfram Language code: RipleyK[PoissonPointProcess[μ, 3], r]
Wolfram Language code: Refine[%% - %, r ≥ 0]

指定维度的聚类点过程 MaternPointProcess 的 Ripley's 函数：

Wolfram Language code: proc2D = MaternPointProcess[μ, λ, rad, 2];
Wolfram Language code: RipleyK[proc2D, r]

3D：

Wolfram Language code: proc3D = MaternPointProcess[μ, λ, rad, 3];
Wolfram Language code: RipleyK[proc3D, rad]

聚类过程 CauchyPointProcess 的 Ripley's 函数：

Wolfram Language code: proc = CauchyPointProcess[μ, λ, b, dim];
Wolfram Language code: RipleyK[proc, r]

聚类过程 VarianceGammaPointProcess 的 Ripley's 函数：

Wolfram Language code: proc = VarianceGammaPointProcess[μ, λ, α, β, dim];
Wolfram Language code: RipleyK[proc, r]

选项  (2)

SpatialBoundaryCorrection  (2)

不包含边界校正的 RipleyK 估计器存在偏差，除非是处理较大的点集，否则不应使用：

Wolfram Language code: region = Rectangle[{0, 0}, {2, 1}]; pts = RandomPoint[region, 100];
Wolfram Language code: r = 0.2;
Wolfram Language code: RipleyK[{pts, region}, r, SpatialBoundaryCorrection -> None]

默认方法 "BorderMargin" 仅考虑距边界 的点：

Wolfram Language code: inregion = Rectangle[{r, r}, {2 - r, 1 - r}]; Show[RegionPlot[{region, inregion}, AspectRatio -> Automatic], ListPlot[pts]]
Wolfram Language code: RipleyK[{pts, region}, r, SpatialBoundaryCorrection -> "BorderMargin"]

边界校正方法 "Ripley" 对每个点进行加权，以使估计值无偏差：

Wolfram Language code: RipleyK[{pts, region}, r, SpatialBoundaryCorrection -> "Ripley"]

比较不同的边界校正方法：

Wolfram Language code: reg = Ball[{0, 0, 0}]; pts = RandomPoint[reg, 200];

采用三种不同的校正方法估计 Ripley's 函数的值：

Wolfram Language code: rad = Range[0.01, 0.5, 0.02]; m = {"None", "BorderMargin", "Ripley"};
Wolfram Language code: data = RipleyK[{pts, reg}, rad, SpatialBoundaryCorrection -> #]& /@ m;

可视化结果，与理论值相比较：

Wolfram Language code: val = RipleyK[PoissonPointProcess[λ, 3], r]
Wolfram Language code: Show[ListPlot[data, DataRange -> MinMax[rad], PlotLegends -> m], Plot[val, {r, 0, 0.5}, PlotStyle -> Gray, PlotLegends -> {val}], AxesLabel -> {r}]

应用  (6)

Ripley's 函数在距离上是累积的，因此单调增加：

Wolfram Language code: region = Ellipsoid[{0, 0}, {2, 3}]; pts = RandomPoint[region, 500];
Wolfram Language code: fun = RipleyK[pts]
Wolfram Language code: Plot[fun[r], {r, 0, 1}, AxesLabel -> Automatic]

完全空间随机性布局的 Ripley's 函数：

Wolfram Language code: region[d_] := Ball[d] pts[d_] := RandomPoint[region[d], 500];

几个维度的 Ripley's 函数：

Wolfram Language code: rspec = Range[0.02, 0.8, 0.02]; data = Table[RipleyK[{pts[d], region[d]}, rspec], {d, 1, 5}];

可视化结果：

Wolfram Language code: ListLinePlot[data, DataRange -> MinMax[rspec], AxesLabel -> {r}, PlotLegends -> (Row[{#, "D"}]& /@ Range[5])]

硬核点过程中的点之间的距离不能比硬核半径 更近：

Wolfram Language code: region = Ellipsoid[{0, 0}, {1, 2}]; radii = {0.05, 0.1, 0.15}; spds = Table[RandomPointConfiguration[HardcorePointProcess[200, R, 2], region, Method -> {"MCMC", "LengthOfRun" -> 30000}], {R, radii}];
Wolfram Language code: Table[Graphics[Point[spds[[k]]["Points"]], PlotRange -> {{-1, 1}, {-2, 2}}, Frame -> True, FrameLabel -> Row[{"hard-core R = ", radii[[k]]}]], {k, 3}]

估计 Ripley's 函数的值：

Wolfram Language code: rspec = Range[0.01, 0.3, 0.01]; data = Table[RipleyK[spd, rspec], {spd, spds}];

可视化结果：

Wolfram Language code: ListLinePlot[data, DataRange -> MinMax[rspec], AxesLabel -> {r}, PlotLegends -> (Row[{"hard-core R = ", #}]& /@ radii)]

求三个样本的硬核半径估计值：

Wolfram Language code: Map[rspec[[FirstPosition[#, _ ? Positive]]]&, data]//Flatten

聚类数据的 Ripley's 比完全空间随机的数据的要大. 聚类过程的样本：

Wolfram Language code: reg = Rectangle[{0, 0}, {4, 4}]; ptsT = RandomPointConfiguration[ThomasPointProcess[30, 20, .5, 2], reg];

生成相同强度的泊松点过程的对照样品：

Wolfram Language code: ptsP = RandomPointConfiguration[PoissonPointProcess[30, 2], reg];
Wolfram Language code: ListPlot[#["Points"], AspectRatio -> 1]& /@ {ptsP, ptsT}

比较 RipleyK 函数：

Wolfram Language code: rspec = Range[0.02, 2, 0.02];
Wolfram Language code: ListLinePlot[{RipleyK[ptsP, rspec], RipleyK[ptsT, rspec]}, PlotLegends -> {"Poisson", "Thomas"}, DataRange -> MinMax[rspec], AxesLabel -> {r}]

2000–2015 年，加利福尼亚 4 级及以上地震：

Wolfram Language code: reg = Polygon[Entity["AdministrativeDivision", {"California", "UnitedStates"}]];
Wolfram Language code: series = EarthquakeData[reg, 4, {DateObject[{2000}], DateObject[{2015}]}, "Position"]

提取地震的位置：

Wolfram Language code: data = Normal[series["Values"]];

比较 RipleyK：

Wolfram Language code: psf = RipleyK[data]

数据的平均点密度：

Wolfram Language code: density = Length[data] / GeoArea[reg];

数据中距普通点 2 英里范围内的预期地震次数：

Wolfram Language code: psf[Quantity[2, "Miles"]] * density

用 Ripley's 函数估计 PairCorrelationG：

Wolfram Language code: reg = Disk[]; pts = RandomPoint[reg, 10 ^ 3];

数据的对相关 (pair correlation):

Wolfram Language code: rlist = Range[0.01, 0.2, 0.01];
Wolfram Language code: pc = PairCorrelationG[{pts, reg}, rlist];

计算 Ripley's 函数：

Wolfram Language code: ripleyK = RipleyK[pts]

比较对相关：

Wolfram Language code: pcK = PairCorrelationG[{ripleyK, {0, 0.2, 0.01}}, rlist];

比较估计值，同时显示根据数据算出的对相关：

Wolfram Language code: ListLinePlot[{pc, pcK}, DataRange -> MinMax@rlist, PlotLegends -> {"PC from data", "PC estimated from K"}, AxesLabel -> {r}]

属性和关系  (1)

BesagL 是方差稳定的 RipleyK：，其中 是 Ripley's 函数， 是空间的维度， 是 中单位球体的体积：

Wolfram Language code: region = Ball[{0, 0, 0}]; pts = RandomPoint[region, 100];

比较两个统计量：

Wolfram Language code: v1 = RipleyK[{pts, region}, 0.2]; v2 = BesagL[{pts, region}, 0.2];

查看公式：

Wolfram Language code: Power[v1 / RegionMeasure[Ball[3]], 1 / 3] == v2

可能存在的问题  (1)

带有边界校正的经验 RipleyK 可能不是持续增大的（特别是对较小的点集）：

Wolfram Language code: region = Rectangle[]; data = RandomPoint[region, 30];
Wolfram Language code: Plot[RipleyK[{data, region}][r], {r, 0, 1 / 2}]

未校正的 RipleyK 是持续增大的：

Wolfram Language code: Plot[RipleyK[{data, region}, r, SpatialBoundaryCorrection -> None], {r, 0, 1 / 2}]
Wolfram Research (2020)，RipleyK，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RipleyK.html.

文本

Wolfram Research (2020)，RipleyK，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RipleyK.html.

CMS

Wolfram 语言. 2020. "RipleyK." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/RipleyK.html.

APA

Wolfram 语言. (2020). RipleyK. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/RipleyK.html 年

BibTeX

@misc{reference.wolfram_2026_ripleyk, author="Wolfram Research", title="{RipleyK}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/RipleyK.html}", note=[Accessed: 05-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_ripleyk, organization={Wolfram Research}, title={RipleyK}, year={2020}, url={https://reference.wolfram.com/language/ref/RipleyK.html}, note=[Accessed: 05-November-2026]}