WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Rotate[g,θ]

境界ボックスの中央で反時計回りに θ ラジアン回転された2Dグラフィックスプリミティブあるいはその他の任意のオブジェクト g を表す．

Rotate[g,θ,{x,y}]

点{x,y}の回りで回転させる．

Rotate[g,{u,v}]

原点の回りを回転させて2Dあるいは3Dベクトル u を v に変換する．

Rotate[g,θ,w]

原点に固定された3Dベクトル w の回りで3Dグラフィックスプリミティブを θ ラジアン回転させる．

Rotate[g,θ,w,p]

p に固定された3Dベクトル w の回りを回転させる．

Rotate[g,θ,{u,v}]

3Dベクトル u と v で定義される平面上で角度 θ 回転させる．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
関連するワークフロー
関連リンク
履歴
引用書式

Rotate

Rotate[g,θ]

境界ボックスの中央で反時計回りに θ ラジアン回転された2Dグラフィックスプリミティブあるいはその他の任意のオブジェクト g を表す．

Rotate[g,θ,{x,y}]

点{x,y}の回りで回転させる．

Rotate[g,{u,v}]

原点の回りを回転させて2Dあるいは3Dベクトル u を v に変換する．

Rotate[g,θ,w]

原点に固定された3Dベクトル w の回りで3Dグラフィックスプリミティブを θ ラジアン回転させる．

Rotate[g,θ,w,p]

p に固定された3Dベクトル w の回りを回転させる．

Rotate[g,θ,{u,v}]

3Dベクトル u と v で定義される平面上で角度 θ 回転させる．

詳細とオプション

  • θ Degreeすなわち θ°は角度を度で指定する．
  • Rotateがグラフィックスの外側に現れた場合，Rotate[g,θ]中のオブジェクト g 等は任意の式でよい．
  • g の境界ボックス内で{Left,Bottom}のような特別な点を指定することができる．
  • x の位置はLeft，CenterあるいはRightとして指定できる．y の位置はBottom，CenterあるいはTopとして指定できる．
  • Rotateがグラフィックス内に現れた場合，座標{x,y}はグラフィックスの座標系内にあるとみなされる．
  • Rotateがグラフィックスの外側に現れた場合，座標{x,y}は回転されているオブジェクトの境界ボックスのからの範囲にあるとみなされる．
  • Rotate[g,θ]はRotate[g,θ,{Center,Center}]に等しい．
  • スケールされた座標Scaled[{x,y}]で指定されたオブジェクトについては，Rotateは実質的に対応する通常の座標に対して変換を適用する．
  • Rotateがグラフィックス内に現れた場合，Normal[expr]は，可能であれば，すべてのRotate[gi,…]構文を座標系が明示的に変換された giのバージョンで置き換える．

例題

すべて開く すべて閉じる

例  (3)

正方形を30°回転させる：

Wolfram Language code: Graphics[Rotate[Rectangle[], 30Degree]]

直方体を 軸に沿って30° 回転させる：

Wolfram Language code: Graphics3D[Rotate[Cuboid[], 30Degree, {0, 0, 1}]]

テキストを45°回転させる：

Wolfram Language code: Rotate[Sqrt[b^2 - 4 a c], 45 Degree]

スコープ  (8)

2Dの形に適用された変換：

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, Rotate[{Opacity[.85], Red, gr}, Pi / 6]}]

3Dの形に適用された変換：

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, Rotate[{Opacity[.85], Red, gr}, Pi / 6, {0, 0, 1}, {.5, .5, .5}]}, Boxed -> False]

点に固定されたベクトルの周りの回転：

Wolfram Language code: Graphics3D[Rotate[Cuboid[], Pi, {0, 0, 1}, {1, 1, 1}], Axes -> True, PlotRange -> {{0, 2}, {0, 2}, {0, 2}}]

ベクトルをベクトルにマップする回転：

Wolfram Language code: Graphics3D[Rotate[Cuboid[], {{1, 1, 1}, {0, 0, 1}}]]

ベクトルとで定義された平面での回転：

Wolfram Language code: Graphics3D[Rotate[Cylinder[], Pi / 2, {{1, 1, 0}, {0, 0, 1}}]]

テキストを回転させる：

Wolfram Language code: Graphics[Rotate[Style[Text["Mathematica"], 24], -Pi / 4]]

スケールされた座標のオブジェクトを回転させる：

Wolfram Language code: Graphics[Rotate[Circle[Scaled[{1, 0}]], Pi, {0, 0}], Axes -> True]

長方形の下方右のコーナーを固定する：

Wolfram Language code: Graphics[{Circle[], Rotate[Rectangle[], Pi / 4, {Right, Bottom}]}, Axes -> True]

アプリケーション  (2)

垂直方向のテキストが入った格子：

Wolfram Language code: Grid[{ {Rotate["Primary", 90°, {1, 1}], "Red"}, {, "Blue"}, {, "Yellow"}, {Rotate["Secondary", 90°, {1, 1}], "Purple"}, {, "Green"}, {, "Orange"} }, Frame -> All, Alignment -> Left]

ダイヤモンド格子：

Wolfram Language code: Rotate[Grid[Table[Rotate[{i, j}, 45°], {i, 0, 2}, {j, 0, 2}], Frame -> All], -45°]

特性と関係  (1)

Normalは可能であれば座標を明示的に変換する：

Wolfram Language code: Normal@Rotate[Cylinder[], Pi / 4, {1, 0, 0}]

考えられる問題  (4)

デフォルトで，Rotateは境界ボックスの中心を回転の中心として使う：

Wolfram Language code: Graphics[{Opacity[0.5], Rotate[Rectangle[], Pi / 3]}, Axes -> True]

回転の中心を明示的に指定する：

Wolfram Language code: Graphics[{Opacity[0.5], Rotate[Rectangle[], Pi / 3, {0, 0}]}, Axes -> True]

変換によってオブジェクトが見えなくなることがある：

Wolfram Language code: Graphics[Rotate[Circle[], Pi / 2, Right], Axes -> True]

PlotRangeを調整して変換されたオブジェクトを表示する：

Wolfram Language code: Graphics[Rotate[Circle[], Pi / 2, Right], Axes -> True, PlotRange -> 2]

回転されたテキストのベースラインの中心は周囲のテキストのベースラインと揃う：

Wolfram Language code: Row[{"abc", Rotate["ghi", 90°], "xyz"}, " "]

別の揃え方については，回転の明示的な中心を指定する：

Wolfram Language code: Row[{"abc", Rotate["ghi", 90°, {Left, Baseline}], "xyz"}, " "]

テキストの境界ボックスは常に直線的なので，連続する回転によって余分な空間が導入されることがある：

Wolfram Language code: NestList[Style[Rotate[#, 30 Degree], Background -> RGBColor[1, 0, 0, 0.2]]&, "R", 8]

おもしろい例題  (2)

正多角形の回転：

Wolfram Language code: Graphics[Outer[Rotate[Rotate[Line[{{1, 0}, {Sqrt[3], 1} / 2}], #, {0, 0}], #2, {1, 0}]&, Pi / 6Range[12], Pi / 6Range[12]]]

ネストして回転された平方根：

Wolfram Language code: Nest[Rotate[Sqrt[#], 90°]&, 2, 8]
Wolfram Research (2007), Rotate, Wolfram言語関数， https://reference.wolfram.com/language/ref/Rotate.html （2008年に更新）.

テキスト

Wolfram Research (2007), Rotate, Wolfram言語関数， https://reference.wolfram.com/language/ref/Rotate.html （2008年に更新）.

CMS

Wolfram Language. 2007. "Rotate." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2008. https://reference.wolfram.com/language/ref/Rotate.html.

APA

Wolfram Language. (2007). Rotate. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Rotate.html

BibTeX

@misc{reference.wolfram_2026_rotate, author="Wolfram Research", title="{Rotate}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Rotate.html}", note=[Accessed: 13-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_rotate, organization={Wolfram Research}, title={Rotate}, year={2008}, url={https://reference.wolfram.com/language/ref/Rotate.html}, note=[Accessed: 13-November-2026]}