WOLFRAM

Wolfram 语言与系统参考资料中心

Rotate[g,θ]

代表二维图形指令或绕边框盒的中心逆时针旋转 θ 弧度的任意的 g 对象.

Rotate[g,θ,{x,y}]

关于点 {x,y} 进行旋转.

Rotate[g,{u,v}]

绕原点旋转，变换二维或三维矢量 u 至 v.

Rotate[g,θ,w]

绕固定在原点的三维矢量 w 旋转三维图元 θ 弧度.

Rotate[g,θ,w,p]

绕固定在 p 的三维矢量 w 旋转.

Rotate[g,θ,{u,v}]

在三维矢量 u 和 v 跨越的平面内旋转角度θ.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
相关的工作流程
相关链接
历史
按以下格式引用：

Rotate

Rotate[g,θ]

代表二维图形指令或绕边框盒的中心逆时针旋转 θ 弧度的任意的 g 对象.

Rotate[g,θ,{x,y}]

关于点 {x,y} 进行旋转.

Rotate[g,{u,v}]

绕原点旋转，变换二维或三维矢量 u 至 v.

Rotate[g,θ,w]

绕固定在原点的三维矢量 w 旋转三维图元 θ 弧度.

Rotate[g,θ,w,p]

绕固定在 p 的三维矢量 w 旋转.

Rotate[g,θ,{u,v}]

在三维矢量 u 和 v 跨越的平面内旋转角度θ.

更多信息和选项

  • θ Degree 或 θ° 指定角度数.
  • 如果 Rotate 出现在视图的外围，在 Rotate[g,θ] 等中的对象 g 可以为任何表达式.
  • 你可以在 g 的边框内指定特殊点诸如： {Left,Bottom}.
  • x 的位置可以指定为 Left， Center 或 Right； y 的位置可以指定为 Bottom， Center 或 Top.
  • 如果 Rotate 出现在视图的内部，坐标 {x,y} 采用视图的坐标系统.
  • 如果 Rotate 出现在视图的外围，坐标 {x,y} 采用 到 的范围与旋转对象边框交叉.
  • Rotate[g,θ] 相等于 Rotate[g,θ,{Center,Center}].
  • 对于用调整坐标 Scaled[{x,y}] 指定的对象， Rotate 有效地把它转化为相应的普通坐标.
  • 如果 Rotate 出现在图形的内部，如果可能， Normal[expr] 替代所有由 gi 变体，其中有明确的坐标发生了变化，构成的Rotate[gi,…].

范例

打开所有单元 关闭所有单元

基本范例  (3)

正方形旋转 30° ：

Wolfram Language code: Graphics[Rotate[Rectangle[], 30Degree]]

立方体绕 轴旋转 30° ：

Wolfram Language code: Graphics3D[Rotate[Cuboid[], 30Degree, {0, 0, 1}]]

文本的旋转 45° ：

Wolfram Language code: Rotate[Sqrt[b^2 - 4 a c], 45 Degree]

范围  (8)

变换适用于二维形状：

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, Rotate[{Opacity[.85], Red, gr}, Pi / 6]}]

变换适用于三维形状：

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, Rotate[{Opacity[.85], Red, gr}, Pi / 6, {0, 0, 1}, {.5, .5, .5}]}, Boxed -> False]

围绕锚定在点 的矢量 的旋转：

Wolfram Language code: Graphics3D[Rotate[Cuboid[], Pi, {0, 0, 1}, {1, 1, 1}], Axes -> True, PlotRange -> {{0, 2}, {0, 2}, {0, 2}}]

旋转映射向量 到向量 ：

Wolfram Language code: Graphics3D[Rotate[Cuboid[], {{1, 1, 1}, {0, 0, 1}}]]

在向量 和 组成的平面旋转：

Wolfram Language code: Graphics3D[Rotate[Cylinder[], Pi / 2, {{1, 1, 0}, {0, 0, 1}}]]

旋转文本：

Wolfram Language code: Graphics[Rotate[Style[Text["Mathematica"], 24], -Pi / 4]]

在调整坐标中旋转物体：

Wolfram Language code: Graphics[Rotate[Circle[Scaled[{1, 0}]], Pi, {0, 0}], Axes -> True]

保持长方形的右下角的固定：

Wolfram Language code: Graphics[{Circle[], Rotate[Rectangle[], Pi / 4, {Right, Bottom}]}, Axes -> True]

应用  (2)

垂直文本格：

Wolfram Language code: Grid[{ {Rotate["Primary", 90°, {1, 1}], "Red"}, {, "Blue"}, {, "Yellow"}, {Rotate["Secondary", 90°, {1, 1}], "Purple"}, {, "Green"}, {, "Orange"} }, Frame -> All, Alignment -> Left]

菱形格：

Wolfram Language code: Rotate[Grid[Table[Rotate[{i, j}, 45°], {i, 0, 2}, {j, 0, 2}], Frame -> All], -45°]

属性和关系  (1)

在可能的情况下， Normal 将明确地变换坐标：

Wolfram Language code: Normal@Rotate[Cylinder[], Pi / 4, {1, 0, 0}]

可能存在的问题  (4)

Rotate 用周围框作为默认旋转中心：

Wolfram Language code: Graphics[{Opacity[0.5], Rotate[Rectangle[], Pi / 3]}, Axes -> True]

明确指定一个旋转中心：

Wolfram Language code: Graphics[{Opacity[0.5], Rotate[Rectangle[], Pi / 3, {0, 0}]}, Axes -> True]

转换物体可能移出视图外：

Wolfram Language code: Graphics[Rotate[Circle[], Pi / 2, Right], Axes -> True]

为了显示转换物体，调整 PlotRange ：

Wolfram Language code: Graphics[Rotate[Circle[], Pi / 2, Right], Axes -> True, PlotRange -> 2]

旋转基线的中心以文本周围的基线为中心：

Wolfram Language code: Row[{"abc", Rotate["ghi", 90°], "xyz"}, " "]

对于不规则的排列，指定一个明确的旋转中心：

Wolfram Language code: Row[{"abc", Rotate["ghi", 90°, {Left, Baseline}], "xyz"}, " "]

由于文本边界框是用直线围着的，连续旋转可以引入额外的空格：

Wolfram Language code: NestList[Style[Rotate[#, 30 Degree], Background -> RGBColor[1, 0, 0, 0.2]]&, "R", 8]

巧妙范例  (2)

正多边形的旋转：

Wolfram Language code: Graphics[Outer[Rotate[Rotate[Line[{{1, 0}, {Sqrt[3], 1} / 2}], #, {0, 0}], #2, {1, 0}]&, Pi / 6Range[12], Pi / 6Range[12]]]

嵌套的，旋转平方根：

Wolfram Language code: Nest[Rotate[Sqrt[#], 90°]&, 2, 8]
Wolfram Research (2007)，Rotate，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Rotate.html （更新于 2008 年）.

文本

Wolfram Research (2007)，Rotate，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Rotate.html （更新于 2008 年）.

CMS

Wolfram 语言. 2007. "Rotate." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2008. https://reference.wolfram.com/language/ref/Rotate.html.

APA

Wolfram 语言. (2007). Rotate. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Rotate.html 年

BibTeX

@misc{reference.wolfram_2026_rotate, author="Wolfram Research", title="{Rotate}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Rotate.html}", note=[Accessed: 06-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_rotate, organization={Wolfram Research}, title={Rotate}, year={2008}, url={https://reference.wolfram.com/language/ref/Rotate.html}, note=[Accessed: 06-November-2026]}