WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Triangle[{p1,p2,p3}]

p1，p2，p3 を角の点とする充填三角形を表す．

Triangle[{{p11,p12,p13},…}]

三角形の集合を表す．

詳細とオプション
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
グラフィックス  
指定  
スタイリング  
座標  
領域  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

Triangle

Triangle[{p1,p2,p3}]

p1，p2，p3 を角の点とする充填三角形を表す．

Triangle[{{p11,p12,p13},…}]

三角形の集合を表す．

詳細とオプション

予備知識

  • Triangle[{p1,p2,p3}]は，頂点が p1，p2，p3の塗り潰された三角形を表す．各 piは埋込み次元に対応する長さのリストとして指定される．通常，Triangleの頂点は，長さ2のリスト（2D平面の三角形）あるいは長さ3のリスト（3D空間に埋め込まれた三角形）である．引数のない形のTriangle[]を評価すると，標準的な2単体Triangle[{{0,0},{1,0},{0,1}}]になる．シンタックスTriangle[{{p11,p12,p13},…,{pk1,pk2,pk3}}]を使って複数の三角形の集合を表すことができる．
  • Triangleオブジェクトは，GraphicsおよびGraphics3D, を使って，それぞれ2Dおよび3Dで視覚的にフォーマットすることができる．Triangleオブジェクトの外観は，他のグラフィックスプリミティブと同じように，辺と面の指示子EdgeFormおよびFaceForm，Redのような色指示子，透過性指示子Opacity，スタイルオプションAntialiasingを指定して変更することができる．Textureを使ってTriangleオブジェクトの表面のテクスチャとしてオブジェクトを適用することができ，オプション VertexColors，VertexNormals，VertexTextureCoordinatesを使って追加的なフォーマットを行うことができる．
  • Triangleは計算を行う領域の指定にも使うことができる．Triangle[{p1,p2,p3}]に対してRegionMeasure（およびArea）はTriangleオブジェクトの面積を返すのに対し，RegionDimensionおよびRegionEmbeddingDimensionは，それぞれ2およびLength[pi]を返す．これに加え，GeometricTransformation，あるいはTranslateやRotateのようにより特殊な変換関数を使って，Triangleに適切な幾何変換を適用した結果を表すことができる．
  • Triangleは他の多くのシンボルと関連している．AASTriangle，SSSTriangle，ASATriangle，SASTriangleは，適切な辺と角の指定を使って構築した二次元のTriangleオブジェクトを返す．Triangleは，Triangle[{p1,p2,p3}]がPolygon[{p1,p2,p3}]とSimplex[{p1,p2,p3}]の両方と等価であるという意味で，PolygonとSimplexの両方の特殊ケースである．Triangleの三次元単体一般化はTetrahedronとして実装されている．

例題

すべて開く すべて閉じる

例  (4)

二次元の標準的な三角形：

Wolfram Language code: Graphics[Triangle[]]

三次元での三角形：

Wolfram Language code: Graphics3D[Triangle[{{0, 0, 0}, {1, 0, 0}, {0, 1, 1}}]]

Triangleに適用されたさまざまなスタイル：

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 1}, {2, 0}}]; {Graphics[{Pink, ℛ}], Graphics[{EdgeForm[Thick], Pink, ℛ}], Graphics[{EdgeForm[Dashed], Pink, ℛ}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

面積と重心：

Wolfram Language code: Area[Triangle[{{0, 0}, {1, 0}, {1, 1}}]]
Wolfram Language code: RegionCentroid[Triangle[{{0, 0}, {1, 0}, {1, 1}}]]

スコープ  (18)

グラフィックス  (8)

指定  (3)

2Dにおける標準的な三角形：

Wolfram Language code: Graphics[Triangle[]]

3Dにおける三角形：

Wolfram Language code: Graphics3D[Triangle[{{0, 0, 0}, {1, 0, 0}, {0, 1, 1}}]]

複数の三角形：

Wolfram Language code: t1 = {{0, 0}, {1, 1}, {2, 0}}; t2 = t1 + 3 / 2;
Wolfram Language code: Graphics[Triangle[{t1, t2}]]

スタイリング  (2)

色の指示子は，面の色を指定する：

Wolfram Language code: Table[Graphics[{c, Triangle[]}], {c, {Red, Green, Blue, Yellow}}]

FaceFormとEdgeFormを使って，内部と境界線のスタイルを指定することができる：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Thick, Dashed, Blue]], Triangle[]}]

座標  (3)

Scaledの座標を使う：

Wolfram Language code: Graphics[Triangle[{Scaled[{0.1, 0.1}], Scaled[{0.9, 0.1}], Scaled[{0.1, 0.9}]}], Frame -> True, PlotRange -> {{0, 10}, {0, 10}}]

ImageScaledの座標を使う：

Wolfram Language code: Graphics[Triangle[{ImageScaled[{0, 0}], ImageScaled[{1, 0}], ImageScaled[{0, 1}]}], Frame -> True, PlotRange -> {{0, 10}, {0, 10}}]

Offsetの座標を使う：

Wolfram Language code: Graphics[Triangle[{Offset[{10, 10}, {0, 0}], Offset[{-10, 10}, {1, 0}], Offset[{10, -10}, {0, 1}]}], Frame -> True]

領域  (10)

埋込み次元は，座標の長さである：

Wolfram Language code: RegionEmbeddingDimension[Triangle[{{0, 0}, {1, 0}, {0, 1}}]]
Wolfram Language code: RegionEmbeddingDimension[Triangle[{{0, 0, 0}, {1, 0, 0}, {0, 1, 1}}]]

幾何学的な次元は，それが指定する領域を参照する：

Wolfram Language code: RegionDimension[Triangle[{{0, 0}, {1, 0}, {0, 1}}]]
Wolfram Language code: RegionDimension[Triangle[{{0, 0, 0}, {1, 0, 0}, {0, 1, 1}}]]

帰属判定：

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Wolfram Language code: {RegionMember[ℛ, {0, 0}], RegionMember[ℛ, {1, 1}]}

点の帰属条件を得る：

Wolfram Language code: RegionMember[ℛ, {x, y}]

Area：

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

重心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

点からTriangleまでの距離：

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Wolfram Language code: RegionDistance[ℛ, {1, 1}]

これをプロットする：

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -1, 2}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 3}, {y, -2, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

点から三角形までの符号付き距離：

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Wolfram Language code: SignedRegionDistance[ℛ, {1 / 3, 1 / 3}]

これをプロットする：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -1, 2}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

最近点：

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Wolfram Language code: RegionNearest[ℛ, {1, 1}]

これを可視化する：

Wolfram Language code: pts = Table[{1 / 3, 1 / 3} + {Cos[k 2 π / 16], Sin[k 2 π / 16]}, {k, 0, 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

三角形は有界である：

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 2}, {2, 1}}];
Wolfram Language code: BoundedRegionQ[ℛ]

境界範囲：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{Black, ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.1, Yellow], Cuboid@@Transpose[rr]}}]

三角形上で積分する：

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Wolfram Language code: Integrate[1, {x, y}∈ℛ]
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

三角形上で最適化する：

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Wolfram Language code: Minimize[{(x - 1 / 2)^2(y - 1 / 4)^2 + 1, {x, y}∈ℛ}, {x, y}]

領域上で関数をプロットする：

Wolfram Language code: Plot3D[(x - 1 / 2)^2(y - 1 / 4)^2 + 1, {x, y}∈ℛ]

三角形の制約条件で方程式を解く：

Wolfram Language code: ℛ = Triangle[{{0, 0}, {2, 0}, {0, 2}}];
Wolfram Language code: Reduce[x^2 + y^2 == 1 && {x, y}∈ℛ, {x, y}]

アプリケーション  (6)

2Dにおける標準単体とKuhn単体は三角形である：

Wolfram Language code: standard = Triangle[{{0, 0}, {1, 0}, {0, 1}}]; kuhn = Triangle[{{0, 0}, {1, 0}, {1, 1}}]; {Graphics[standard, PlotLabel -> "Standard"], Graphics[kuhn, PlotLabel -> "Kuhn"]}

正三角形を辺の長さで定義する：

Wolfram Language code: EquilateralTriangle[s_] := Triangle[{{0, 0}, {s, 0}, {(s/2), (Sqrt[3] s/2)}}]
Wolfram Language code: t = EquilateralTriangle[2]

これを可視化する：

Wolfram Language code: Graphics[t]

Areaを計算する：

Wolfram Language code: Area[EquilateralTriangle[s]]

同様にSSSTriangleを使う：

Wolfram Language code: SSSTriangle[s, s, s]

二等辺三角形を底辺の長さと高さで定義する：

Wolfram Language code: IsoscelesTriangle[b_, h_] := Triangle[{{0, 0}, {b, 0}, {(b/2), h}}]
Wolfram Language code: t = IsoscelesTriangle[2, 3]

これを可視化する：

Wolfram Language code: Graphics[t]

Areaを計算する：

Wolfram Language code: Area[IsoscelesTriangle[b, h]]

三角形の垂直二等分線を求める：

Wolfram Language code: pts = {a, b, c} = {{1, 2}, {0, 0}, {3, 0}};
Wolfram Language code: circumCenter = RegionCentroid[Circumsphere[pts]];
Wolfram Language code: bisector = Line[{circumCenter, RegionCentroid[Line[{a, b}]]}];

外心と二等分線を赤で可視化する：

Wolfram Language code: Graphics[{{LightGray, Circumsphere[pts]}, {LightBlue, Triangle[pts]}, {Dashed, Red, bisector}, {Green, Point[pts]}, {Red, PointSize[Large], Point[circumCenter]}}]

三角形の性質を測る方法の1つに半径と辺の比を求めるものがある：

Wolfram Language code: RadiusEdgeRatio[Triangle[pl_]] := Last[Circumsphere[pl]] / Min[Norm /@ Subsets[pl, {2}]]
Wolfram Language code: RadiusEdgeRatio[Triangle[{{0, 0}, {1, 0}, {1, 1}}]]

小さい比は，三角形が異常に薄くはないことを示す：

Wolfram Language code: t1 = Triangle[{{0, 0}, {1, 0}, {1, 1}}]; t2 = Triangle[{{0, 0}, {10, 0}, {1, 1}}]; {Graphics[t1, PlotLabel -> N@RadiusEdgeRatio[t1]], Graphics[t2, PlotLabel -> N@RadiusEdgeRatio[t2]]}

三角形は4つの部分三角形に分割できる：

Wolfram Language code: SymmetricSubdivision[Triangle[pl_], k_] /; 0 ≤ k < 2 ^ Length[pl] := Module[{n = Length[pl] - 1, i0, bl, pos}, i0 = DigitCount[k, 2, 1]; bl = IntegerDigits[k, 2, n]; pos = FoldList[If[#2 == 0, #1 + {0, 1}, #1 + {1, 0}]&, {0, i0}, Reverse[bl]]; Triangle@Map[Mean, Extract[pl, #]& /@ Map[{#}&, pos + 1, {2}]] ]
Wolfram Language code: Graphics[SymmetricSubdivision[Triangle[{{0, 0}, {1, 0}, {1, 1}}], #]& /@ Range[0, 3], BaseStyle -> Directive[LightBlue, EdgeForm[Gray]]]

これは，繰り返し行うことができる：

Wolfram Language code: NestedSymmetricSubdivision[Triangle[pl_], level_Integer] /; level == 0 := Triangle[pl] NestedSymmetricSubdivision[Triangle[pl_], level_Integer] /; level > 0 := Flatten[NestedSymmetricSubdivision[SymmetricSubdivision[Triangle[pl], #], level - 1]& /@ Range[0, 3], 1]
Wolfram Language code: Graphics[NestedSymmetricSubdivision[Triangle[{{0, 0}, {1, 0}, {1, 1}}], 3], BaseStyle -> Directive[LightBlue, EdgeForm[Gray]]]

特性と関係  (5)

Triangleは，Polygonの特殊形である：

Wolfram Language code: Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}]; Subscript[ℛ, 2] = Polygon[{{0, 0}, {1, 0}, {0, 1}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Triangleは，Simplexの特殊形である：

Wolfram Language code: Subscript[ℛ, 1] = Triangle[{{0, 0}, {1, 0}, {0, 1}}]; Subscript[ℛ, 2] = Simplex[{{0, 0}, {1, 0}, {0, 1}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegionは，任意のTriangleの領域を表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[0 ≤ x ≤ 1 && 0 ≤ y ≤ 1 - x, {x, y}]; Subscript[ℛ, 2] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegionは，任意のTriangleの領域を表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{u, v}, {{u, 0, 1}, {v, 0, 1 - u}}]; Subscript[ℛ, 2] = Triangle[{{0, 0}, {1, 0}, {0, 1}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

BoundaryMeshRegionは，任意のTriangleの領域を表すことができる：

Wolfram Language code: BoundaryMeshRegion[{{0, 0}, {1, 0}, {0, 1}}, Line[{1, 2, 3, 1}]]

おもしろい例題  (1)

ランダムな三角形の集まり：

Wolfram Language code: Graphics[{EdgeForm[Black], Table[{Hue[RandomReal[]], Triangle[RandomReal[2, {3, 2}]]}, {20}]}]
Wolfram Research (2014), Triangle, Wolfram言語関数， https://reference.wolfram.com/language/ref/Triangle.html （2019年に更新）.

テキスト

Wolfram Research (2014), Triangle, Wolfram言語関数， https://reference.wolfram.com/language/ref/Triangle.html （2019年に更新）.

CMS

Wolfram Language. 2014. "Triangle." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/Triangle.html.

APA

Wolfram Language. (2014). Triangle. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Triangle.html

BibTeX

@misc{reference.wolfram_2026_triangle, author="Wolfram Research", title="{Triangle}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Triangle.html}", note=[Accessed: 04-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_triangle, organization={Wolfram Research}, title={Triangle}, year={2019}, url={https://reference.wolfram.com/language/ref/Triangle.html}, note=[Accessed: 04-November-2026]}