Wolfram 语言与系统参考资料中心

ArcTan

参见
- Arg
- Tan
- ArcCot
- ArcTanDegrees
- ArcTanh
- Degree
- TrigToExp
- TrigExpand
- Gudermannian
相关指南
技术笔记
- 一些数学函数
- 初等超越函数
- 参见
  - Arg
  - Tan
  - ArcCot
  - ArcTanDegrees
  - ArcTanh
  - Degree
  - TrigToExp
  - TrigExpand
  - Gudermannian
- 相关指南
- 技术笔记
  - 一些数学函数
  - 初等超越函数

ArcTan

ArcTan[z]

给出复数的反正切函数 .

ArcTan[x,y]

给出的反正切，会考虑点所在的象限.

背景

ArcTan 是反正切函数. 对实数 x，ArcTan[x] 表示满足的弧度值且 . 双变量形式的 ArcTan[x,y] 表示 y/x 的反正切值，这个值还与点落在哪个象限有关. 它实际上给出了这个点所在的角度位置，从正轴算起，表示为一个弧度值. 因此在把笛卡尔坐标转换转换为极坐标时，ArcTan 很有用因为它能找到满足 $x+ⅈ y=TemplateBox[{z}, Abs]ⅇ^(ⅈ phi)$ 的相位值 .
ArcTan 自动逐项作用于列表. 对某些特定变量值，ArcTan 自动计算出精确值. 当给出精确数值表达式作为变量时，ArcTan 可以算出任意精度的数值结果. 对包含 ArcTan 的符号表达式，适用的操作运算有 FunctionExpand、TrigToExp、TrigExpand、Simplify 和 FullSimplify.
对复变量，ArcTan 的定义为 . ArcTan[z] 在复平面上有一个不连续的分支切割.
与之相关的数学函数有 Arg、Tan、ArcCot、ArcTanh 和 Gudermannian.

范例

打开所有单元关闭所有单元

基本范例 (7)

结果以弧度表示：

Wolfram Language code: ArcTan[1]

除以 Degree 得到以度数为单位的结果：

Wolfram Language code: ArcTan[1] / Degree//FullSimplify

ArcTan[x,y] 给出点 {x,y} 的角：

Wolfram Language code: ArcTan[1, 1]

Wolfram Language code: ArcTan[-1, -1]

在实数域子集上绘图：

Wolfram Language code: Plot[ArcTan[x], {x, -5, 5}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ArcTan[z ^ 2], {z, -1 / 2 - I, 1 / 2 + I}, PlotLegends -> Automatic]

在 0 处的级数展开：

Wolfram Language code: Series[ArcTan[x], {x, 0, 15}]

在 Infinity 处的渐近展开：

Wolfram Language code: Series[ArcTan[x], {x, ∞, 5}]

在其中一个奇点处的渐进展开：

Wolfram Language code: Series[ArcTan[x], {x, I, 3}]//FullSimplify

范围 (49)

数值计算 (6)

数值计算：

Wolfram Language code: ArcTan[0.5]

Wolfram Language code: ArcTan[0.5, 2]

高精度求值：

Wolfram Language code: N[ArcTan[1 / 2], 50]

使用双参数的形式求值：

Wolfram Language code: N[ArcTan[2, 1], 50]

输出精度与输入精度一致：

Wolfram Language code: ArcTan[0.50000000000000000000000000000000000000000]

计算复变量：

Wolfram Language code: ArcTan[2.5 + I]

双参数形式支持复数：

Wolfram Language code: ArcTan[2.5 + I, 2]

在高精度条件下高效计算 ArcTan:

Wolfram Language code: ArcTan[0.4`500]//Timing

Wolfram Language code: ArcTan[0.4`100000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ArcTan[Interval[{-1, 3}]]

Wolfram Language code: ArcTan[CenteredInterval[1, 1 / 100]]

Wolfram Language code: ArcTan[CenteredInterval[2 + 3I, (1 + I) / 100]]

或使用 Around 计算一般情况下的统计区间：

Wolfram Language code: ArcTan[Around[.9, 0.1]]

计算数组中每个元素的值：

Wolfram Language code: ArcTan[{{1, Sqrt[3]}, {0, Sqrt[3]}}]

或用 MatrixFunction 以矩阵形式计算 ArcTan 函数：

Wolfram Language code: MatrixFunction[ArcTan[#]&, {{1, Sqrt[3]}, {0, Sqrt[3]}}]

特殊值 (6)

ArcTan 在固定点上的值：

Wolfram Language code: Table[ArcTan[n ], {n, -1, 1}]

整数坐标介于和之间的所有点的角度：

Wolfram Language code: Table[ArcTan[x, y ], {x, -2, 2}, {y, -2, 2}]//Quiet//MatrixForm

在无穷大处的值：

Wolfram Language code: ArcTan[Infinity]

Wolfram Language code: ArcTan[ComplexInfinity]

ArcTan[x,y] 形式的无穷大值：

Wolfram Language code: ArcTan[Infinity, 1]

Wolfram Language code: ArcTan[-1, Infinity]

ArcTan 零点：

Wolfram Language code: ArcTan[0]

求满足方程的的值：

Wolfram Language code: f[x_] := ArcTan[x] - (π/3);

Wolfram Language code: sol = Solve[f[x] == 0, x]

替换为值：

Wolfram Language code: xzero = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[f[x], {x, -2, 2}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可视化 (4)

绘制 ArcTan 函数：

Wolfram Language code: Plot[ArcTan[x], {x, -7, 7}]

在平面上绘制双参数 ArcTan 函数的图形：

Wolfram Language code: Plot3D[ArcTan[x, y], {x, -7, 7}, {y, -7, 7}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[ArcTan[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[ArcTan[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

，绘制极坐标图：

Wolfram Language code:

Table[PolarPlot[ArcTan[k ϕ], {ϕ, -4π, 4π}, Frame -> True, FrameTicks -> {{{-1, 0, 1}, None}, {{-1, 0, 1}, None}}, PlotLabel -> "k=" <> ToString[k], PlotRange -> All], {k, 1, 4}]

函数的属性 (12)

ArcTan 是针对所有实数定义的：

Wolfram Language code: FunctionDomain[ArcTan[x], x]

复定义域：

Wolfram Language code: FunctionDomain[ArcTan[z], z, Complexes]

ArcTan 的值域是区间内的所有实数：

Wolfram Language code: FunctionRange[ArcTan[x], x, y]

参数取复定义域内的值时的值域：

Wolfram Language code: FunctionRange[ArcTan[z], z, y, Complexes]

ArcTan 是奇函数：

Wolfram Language code: ArcTan[-x]

ArcTan 具有镜像属性 $tan^(-1)(TemplateBox[{x}, Conjugate])=TemplateBox[{{{tan, ^, {(, {-, 1}, )}}, (, x, )}}, Conjugate]$ ：

Wolfram Language code: FullSimplify[ArcTan[Conjugate[x]] == Conjugate[ArcTan[x]]]

在实数上是的解析函数：

Wolfram Language code: FunctionAnalytic[ArcTan[x], x]

在复平面上，既不是解析函数也不是亚纯函数：

Wolfram Language code: FunctionAnalytic[ArcTan[x], x, Complexes]

Wolfram Language code: FunctionMeromorphic[ArcTan[x], x]

在实数上不是解析函数：

Wolfram Language code: FunctionAnalytic[ArcTan[x, y], {x, y}]

是递增函数：

Wolfram Language code: FunctionMonotonicity[ArcTan[x], x, StrictInequalities -> True]

ArcTan 是单射函数：

Wolfram Language code: FunctionInjective[ArcTan[x], x]

Wolfram Language code: Plot[{ArcTan[x], 1 / 2}, {x, -5, 5}]

ArcTan 不是满射函数：

Wolfram Language code: FunctionSurjective[ArcTan[x], x]

Wolfram Language code: Plot[{ArcTan[x], 2}, {x, -5, 5}]

ArcTan 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[ArcTan[x], x]

没有奇点和断点：

Wolfram Language code: FunctionSingularities[ArcTan[x], x]

Wolfram Language code: FunctionDiscontinuities[ArcTan[x], x]

时，有奇点：

Wolfram Language code: FunctionSingularities[ArcTan[x, y], {x, y}]

Wolfram Language code: FunctionDiscontinuities[ArcTan[x, y], {x, y}]

ArcTan 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[ArcTan[x], x]

TraditionalForm 格式输出：

Wolfram Language code: ArcTan[x]//TraditionalForm

Wolfram Language code: ArcTan[x, y]//TraditionalForm

微分 (3)

一阶导数：

Wolfram Language code: D[ArcTan[x], x]

高阶导数：

Wolfram Language code: Table[D[ArcTan[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[ArcTan[x], {x, n}]

积分 (3)

ArcTan 的不定积分：

Wolfram Language code: Integrate[ArcTan[x], x]

在以原点为中心的区间上，ArcTan 的定积分为0：

Wolfram Language code: Integrate[ArcTan[x], {x, -1, 1}]

更多积分：

Wolfram Language code: Integrate[x ArcTan[x], x]

Wolfram Language code: Integrate[z ^ k ArcTan[z], z]

级数展开式 (4)

ArcTan 的泰勒展开式：

Wolfram Language code: Series[ArcTan[x], {x, 0, 7}]

绘制 ArcTan 在处的前三个近似式：

Wolfram Language code:

terms = Normal@Table[Series[ArcTan[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{ArcTan[x], terms}, {x, -1, 1}, PlotRange -> {{-1, 1}, All}]

ArcTan 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[ArcTan[x], {x, 0, n}]

在分支点和分支切口处求级数展开式：

Wolfram Language code: Series[ArcTan[x], {x, I, 1}]

Wolfram Language code: Series[ArcTan[x], {x, 2I, 1}]

ArcTan 可被应用于幂级数：

Wolfram Language code: ArcTan[SeriesData[x, 0, {1, 0, 1/3, 0, 2/15, 0, 17/315, 0, 62/2835}, 1, 10, 1]]

积分变换 (3)

用 LaplaceTransform 计算拉普拉斯变换：

Wolfram Language code: LaplaceTransform[ArcTan[t], t, s]

InverseFourierTransform:

Wolfram Language code: InverseFourierTransform[ArcTan[ω], ω, t ]

MellinTransform:

Wolfram Language code: MellinTransform[ArcTan[x], x, s ]

函数属性和化简 (3)

化简含有 ArcTan 的表达式：

Wolfram Language code: TrigExpand[Tan[ArcTan[x] + ArcTan[y]]]//FullSimplify

通过 TrigToExp 用 Log 表示 ArcTan：

Wolfram Language code: TrigToExp[ArcTan[z]]

Wolfram Language code: ExpToTrig[%]

假定实数变量和的情况下进行展开：

Wolfram Language code: ComplexExpand[ArcTan[x + I y]]

函数表示 (5)

使用 ArcCot 表示：

Wolfram Language code: ArcCot[1 / x]//FullSimplify

通过逆 Jacobi 函数表示：

Wolfram Language code: InverseJacobiCS[(1/z), 0]//FullSimplify

Wolfram Language code: InverseJacobiSC[z, 0]//FullSimplify

使用 Hypergeometric2F1 表示：

Wolfram Language code: x Hypergeometric2F1[1 / 2, 1, 3 / 2, -x ^ 2]

ArcTan 可用 MeijerG 表示：

Wolfram Language code: MeijerGReduce[ArcTan[x], x]

Wolfram Language code: Activate[%]

ArcTan 可用 DifferentialRoot　表示：

Wolfram Language code: DifferentialRootReduce[ArcTan[x], x]

应用 (9)

求出带有边 3、4 和斜边 5 的直角三角形的角：

Wolfram Language code: N[{ArcTan[4, 3], ArcTan[3, 4]} / Degree]

总计为 90°：

Wolfram Language code: Total[%]

利用 ArcTan 求出有理函数的积分：

Wolfram Language code: Integrate[1 / (x ^ 2 + 1), x]

用于正切函数的加法定理：

Wolfram Language code: Tan[ArcTan[x] + ArcTan[y]]//TrigExpand//Simplify

求穿过点和的直线的倾角：

Wolfram Language code: {x1, y1} = {0, 0};{x2, y2} = {1, Sqrt[3]};

Wolfram Language code: ArcTan[x2 - x1, y2 - y1]

求解微分方程：

Wolfram Language code: DSolve[{(1 + x^2) y''[x] + 2 x y'[x] == 1, y[0] == 0, y'[0] == 1}, y[x], x]

沿虚轴延伸的 ArcTan 分支线：

Wolfram Language code: Plot3D[Re[ArcTan[x + I y]], {y, -2, 2}, {x, -2.5, 2.5}]

复数的极分解：

Wolfram Language code: {Arg[#], Abs[#]}&[2 + 5I]

正弦-戈登方程的特解：

Wolfram Language code: v[x_, t_] = 4 ArcTan[Exp[(1 / Sqrt[1 - c ^ 2])(x - c t)]];

验证该解：

Wolfram Language code: D[v[x, t], t, t] - D[v[x, t], x, x] + Sin[v[x, t]]//FullSimplify

双曲正切的标准分布的累积分布函数（CDF）是以 ArcTan 的形式给出的：

Wolfram Language code: F[x] := (2 / π) ArcTan[Exp[π x / 2]]

这是 Gudermannian 函数的缩放和移位版本：

Wolfram Language code: FullSimplify[2 / π ArcTan[Exp[π x / 2]] == 1 / 2 + (1 / π)Gudermannian[(π x/2)], x∈Reals]

属性和关系 (5)

利用 TrigToExp 通过 Log 表示 ArcTan：

Wolfram Language code: TrigToExp[ArcTan[z]]

Wolfram Language code: ExpToTrig[%]

利用 FullSimplify 化简带有 ArcTan 的表达式：

Wolfram Language code: FullSimplify[16 ArcTan[1 / 5] - 4 ArcTan[1 / 239]]

ArcTan 给出以弧度为单位的角，ArcSecDegrees 给出相同的角，但以度为单位：

Wolfram Language code: ArcTan[1]

Wolfram Language code: ArcTanDegrees[1]

ArcTan 是某些特殊函数的特殊情况：

Wolfram Language code: x Hypergeometric2F1[1 / 2, 1, 3 / 2, -x ^ 2]

利用 Reduce 求解包含 ArcTan 的不等式：

Wolfram Language code: Reduce[ArcTan[x] > Pi / 3, x]

可能存在的问题 (1)

因为 ArcTan 是一种多值函数，：

Wolfram Language code: ArcTan[Tan[4.]]

它与原始辐角相差一个系数：

Wolfram Language code: (% - 4) / Pi

巧妙范例 (1)

围绕分支点展开：

Wolfram Language code: Series[ArcTan[x], {x, I, 3}]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

ArcTan

更多信息

背景

范例

基本范例 (7)

范围 (49)

数值计算 (6)

特殊值 (6)

可视化 (4)

函数的属性 (12)

微分 (3)

积分 (3)

级数展开式 (4)

积分变换 (3)

函数属性和化简 (3)

函数表示 (5)

应用 (9)

属性和关系 (5)

可能存在的问题 (1)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

ArcTan

更多信息

背景

范例

基本范例 (7)

范围 (49)

数值计算 (6)

特殊值 (6)

可视化 (4)

函数的属性 (12)

微分 (3)

积分 (3)

级数展开式 (4)

积分变换 (3)

函数属性和化简 (3)

函数表示 (5)

应用 (9)

属性和关系 (5)

可能存在的问题 (1)

巧妙范例 (1)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX