WOLFRAM

Wolfram 语言与系统参考资料中心

Association[key1val1,key2val2,…] 或 key1val1,key2val2,…

表示键和值之间的关联.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
构建与提取  
模式匹配运算  
属性和关系  
可能存在的问题  
参见
相关指南
相关的工作流程
相关链接
历史
按以下格式引用：

Association

Association[key1val1,key2val2,…] 或 key1val1,key2val2,…

表示键和值之间的关联.

更多信息

  • 与已知键 k 关联 assoc 的值可以使用 assoc[key] 提取. »
  • 关联就像一个符号式索引的列表. 与已知 key 关联的值可使用部分指定 Key[key] 提取. 如果 k 是字符串，Key 可以省略.
  • 如果 key 不出现在 assoc 中，assoc[key] 生成 Missing["KeyAbsent",key]. »
  • 如果 assoc 是一个值为关联的符号，则可通过 assoc[key]=val 来建立或重置 key 与 val 的关系. »
  • 典型的列表运算（如 Map、Select 和 Sort）应用于关联中的值，而键保持不变. »
  • Association[{key1val1,…}] 给出 <|key1val1,…|>. »
  • 如果有多个元素具有相同的键，除最后一个元素外的所有元素都将被丢弃. 相反，Merge 对于重复键则生成值的列表.
  • 关联可以使用符号 \[LeftAssociation] 和 \[RightAssociation]输入. 可用 <| 和 |> 键入.
  • Normal 将 Association 转换为规则列表. »
  • KeyValuePattern 可用于表示包括特定元素的关联的模式. »

范例

打开所有单元 关闭所有单元

基本范例  (4)

一个关联，其中键 a 与值 x 关联，键 b 与值 y 关联，等等：

Wolfram Language code: <|a -> x, b -> y, c -> z|>

提取与键 b 关联的值：

Wolfram Language code: %[b]

将规则列表转换为关联：

Wolfram Language code: Association[{a -> x, b -> y, c -> z}]

可通过重置值来修改关联:

Wolfram Language code: assoc = <|a -> x, b -> y, c -> z|>
Wolfram Language code: assoc[b] = w

现在，键 b 的值为 w，而不是 y：

Wolfram Language code: assoc

使用延迟规则可防止值在关联构建过程中被计算：

Wolfram Language code: <|a -> 1 + 1, b -> 2 + 2, c :> 3 + 3, d :> 4 + 4|>

值在提取时被计算：

Wolfram Language code: %[c]

范围  (17)

构建与提取  (9)

关联可以用任意表达式作为键，包括关联：

Wolfram Language code: Keys[<|{2, 3} -> x, RGBColor[0.95, 0.43, 0.96] -> y, <|a -> 1, b -> 2|> -> z|>]

添加关联：

Wolfram Language code: Append[<|a -> x, b -> y, c -> z|>, d -> w]

关联适用于任何数目的元素：

Wolfram Language code: assoc = Association[Table[i -> i ^ 2, {i, 10000}]];

从关联中提取值是高效的：

Wolfram Language code: assoc[10000]//EchoTiming
2.`*^-6

缺失的元素用 Missing 表示：

Wolfram Language code: <|a -> x, b -> y, c -> z|>[d]

Lookup 允许给出缺省值：

Wolfram Language code: Lookup[<|a -> x, b -> y, c -> z|>, d, q]

用 Part 从关联中提取值：

Wolfram Language code: assoc = <|a -> x, b -> {y, z}|>; assoc[[Key[b]]]

提取值的一部分：

Wolfram Language code: assoc[[Key[b], 1]]

无论层级，只要是关联，Key[k] 部分指定都适用：

Wolfram Language code: {5, 7, assoc}[[3, Key[b], 2]]

提取关联中第三个值：

Wolfram Language code: assoc = <|3 -> a, 1 -> b, 2 -> c|>; assoc[[3]]

提取与键 3 关联的值：

Wolfram Language code: assoc[[Key[3]]]

获取由关联的第二和第三部分组成的子关联：

Wolfram Language code: assoc = <|3 -> a, 1 -> b, 2 -> c|>; assoc[[{2, 3}]]

用键 2 和 3 完成操作：

Wolfram Language code: assoc[[{Key[2], Key[3]}]]

提取与键 {2,3} 关联的值：

Wolfram Language code: assoc[[Key[{2, 3}]]]

用 Extract 提取值：

Wolfram Language code: assoc = <|a -> 1 + 1, b -> 2 + 2, c :> 3 + 3, d :> 4 + 4|>; Extract[assoc, Key[c]]

获取该值但不执行计算：

Wolfram Language code: assoc = <|a -> 1 + 1, b -> 2 + 2, c :> 3 + 3, d :> 4 + 4|>; Extract[assoc, Key[c], Hold]

将关联分离为键列表和值列表：

Wolfram Language code: Comap[{Keys, Values}, <|a -> 1, b -> 2, c -> 3|>]

将其转换为有序的数据对列表：

Wolfram Language code: Transpose[%]

模式匹配运算  (8)

关联可用于模式匹配：

Wolfram Language code: MatchQ[<|a -> 1|>, <|_ -> _|>]
Wolfram Language code: Replace[<|a -> 1|>, <|a -> x_|> -> x]

来自关联的确切键和值：

Wolfram Language code: <|1 -> 2|> /. <|a_ -> b_|> :> {a, b}

替换函数的自变量：

Wolfram Language code: f[<|1 -> 2, 3 -> 4|>] /. f[<|a_ -> b_, ___|>] :> f[a, b]

挑取具有特定键的规则：

Wolfram Language code: <|1 -> 2, 2 -> 3, 3 -> 4, 5 -> 6|> /. <|___, 3 -> b_, ___|> :> f[b]

仅滤出长度为 2 的关联：

Wolfram Language code: Cases[{<|1 -> x|>, <|1 -> x, 2 -> y|>, <|1 -> x, 2 -> y, 3 -> z|>}, <|_, _|>]

使用关联作为自变量，定义函数：

Wolfram Language code: g[<|k_ -> v_|>] := v
Wolfram Language code: g[<|1 -> 2|>]

使用嵌套关联作为函数自变量：

Wolfram Language code: h[<|k_ -> <|k2_ -> v2_|>|>] := {k, k2, v2}
Wolfram Language code: h[<|1 -> <|2 -> 3|>|>]

KeyValuePattern 允许匹配关联中的任意元素：

Wolfram Language code: MatchQ[<|a -> 1, b -> 2, c -> 3|>, KeyValuePattern[b -> 2]]

KeyValuePattern 匹配出现在关联中任意位置的元素：

Wolfram Language code: Replace[<|a -> 1, b -> 2, c -> 3|>, KeyValuePattern[{a -> x_, c -> y_}] :> {x, y}]

属性和关系  (9)

对于常见的列表操作，键是“透明”的：

Wolfram Language code: Map[f, <|a -> 4, b -> 2, c -> 1, d -> 5|>]
Wolfram Language code: Sort[<|a -> 4, b -> 2, c -> 1, d -> 5|>]
Wolfram Language code: Select[<|a -> 4, b -> 2, c -> 1, d -> 5|>, # > 3&]
Wolfram Language code: Total[<|a -> 4, b -> 2, c -> 1, d -> 5|>]

Values 从关联中提取值：

Wolfram Language code: Values[<|a -> x, b -> y, c -> z|>]

Keys 从关联中提取键：

Wolfram Language code: Keys[<|a -> x, b -> y, c -> z|>]

Normal 将关联变成规则的列表：

Wolfram Language code: Normal[<|a -> x, b -> y, c -> z|>]

Position 给出关联中的键：

Wolfram Language code: Position[<|a -> 4, b -> 2, c -> 1, d -> 5|>, 2]

关联中的值可以像部分一样被提取:

Wolfram Language code: <|a -> x, b -> y, c -> z|>[[Key[b]]]

如果关联中的键是字符串，不需要显式的 Key 来将其作为部分提取：

Wolfram Language code: <|"a" -> x, "b" -> y, "c" -> z|>[["b"]]

数值部分的指定在结构上作用于关联：

Wolfram Language code: <|a -> x, b -> y, c -> z|>[[2]]

关联仅保留重复键的最后一个实例：

Wolfram Language code: <|a -> x, a -> xp, b -> y, c -> z, c -> zp|>
Wolfram Language code: Join[<|a -> x, b -> y, c -> z|>, <|a -> xp, c -> zp|>]

当关联被修改时，会创建一个新副本：

Wolfram Language code: v = w = <|a -> 1, b -> 2|>
Wolfram Language code: v[a] = 3

v 被修改；w 不变：

Wolfram Language code: {v, w}

关联的长度可以为零：

Wolfram Language code: <||>
Wolfram Language code: Length[%]

可能存在的问题  (2)

在结构式函数中，Association 仅算作一个层，而不是两个：

Wolfram Language code: Level[<|a -> x, b -> y|>, {1}]
Wolfram Language code: Depth[<|a -> x, b -> y|>]

规则列表为两层：

Wolfram Language code: Level[{a -> x, b -> y}, {1}]
Wolfram Language code: Depth[{a -> x, b -> y}]

替换关联的标头会丢失键：

Wolfram Language code: ReplacePart[<|"x" -> 1, "y" -> 2|>, {0} -> List]

提取来自关联的规则：

Wolfram Language code: Normal[<|"x" -> 1, "y" -> 2|>]
Wolfram Research (2014)，Association，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Association.html （更新于 2016 年）.

文本

Wolfram Research (2014)，Association，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Association.html （更新于 2016 年）.

CMS

Wolfram 语言. 2014. "Association." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/Association.html.

APA

Wolfram 语言. (2014). Association. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Association.html 年

BibTeX

@misc{reference.wolfram_2026_association, author="Wolfram Research", title="{Association}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/Association.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_association, organization={Wolfram Research}, title={Association}, year={2016}, url={https://reference.wolfram.com/language/ref/Association.html}, note=[Accessed: 17-August-2026]}