WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BaringhausHenzeTest[data]

Baringhaus–Henze検定を使い，データがMultinormalDistributionに従っているかどうかの検定を行う．

BaringhausHenzeTest[data,MultinormalDistribution[μ,Σ]]

データが，平均ベクトル μ，共分散行列 Σ で分布に従っているかどうかの検定を行う．

BaringhausHenzeTest[data,"property"]

"property"の値を返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
検定  
レポート  
オプション  
Method  
SignificanceLevel  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

BaringhausHenzeTest

BaringhausHenzeTest[data]

Baringhaus–Henze検定を使い，データがMultinormalDistributionに従っているかどうかの検定を行う．

BaringhausHenzeTest[data,MultinormalDistribution[μ,Σ]]

データが，平均ベクトル μ，共分散行列 Σ で分布に従っているかどうかの検定を行う．

BaringhausHenzeTest[data,"property"]

"property"の値を返す．

詳細とオプション

  • BaringhausHenzeTestは，data がMultinormalDistributionから取られたという帰無仮説 とそうではないという対立仮説 で適合度検定を実行する．
  • BaringhausHenzeTestは，Baringhaus–Henze–Epps–Pulley多変量正規性検定，つまりBHEP検定としても知られている．
  • デフォルトで，確率値すなわち 値が返される．
  • 小さい 値は data が多変量正規分布から来ている可能性が低いことを示す．
  • data は，一変量{x1,…,xn}あるいは多変量{{x1,y1,…},…,{xn,yn,…}}でよい．
  • Baringhaus–Henze検定は，事実上，無相関化された標準化 data と標準多変量ガウス特性関数Tβ=Expectation[n Abs[Ψemp[t]-Ψst[t]]2,{t1,…,td}]の間の距離 に基づく経験特性関数検定統計 Tβを使う．ただし，=ProductDistribution[{NormalDistribution[0,β],d}]である． »
  • β 母数は正で，経験分布の平滑化を決定する．これは自動的に決定されるが，Method設定で変えることもできる．
  • BaringhausHenzeTest[data,MultinormalDistribution[μ,Σ],"HypothesisTestData"]はHypothesisTestDataオブジェクト htd を返す．これは，htd["property"]として追加的な検定結果および特性の抽出に使うことができる．
  • BaringhausHenzeTest[data,MultinormalDistribution[μ,Σ],"property"]を使って直接"property"の値を与えることができる．
  • 検定結果のレポートに関連する特性
  • "PValue" 値
    "PValueTable""PValue"のフォーマットされたバージョン
    "ShortTestConclusion"検定結果の簡単な説明
    "TestConclusion"検定結果の説明
    "TestData"検定統計と 値
    "TestDataTable""TestData"のフォーマットされたバージョン
    "TestStatistic"検定統計
    "TestStatisticTable"フォーマットされた"TestStatistic"
  • 次の特性はどの検定が行われているかに依存しない．
  • データ分布に関連する特性
  • "FittedDistribution"データのフィットした分布
    "FittedDistributionParameters"データの分布母数
  • 使用可能なオプション
  • Method Automatic 値を計算するメソッド
    SignificanceLevel 0.05診断とレポートのための切捨て
  • 適合度検定では， のときにのみ が棄却されるような切捨て が選択される．特性"TestConclusion"および"ShortTestConclusion"で使われる の値はSignificanceLevelオプションで制御される．デフォルトで， は0.05に設定されている． »
  • Method->"MonteCarlo"の設定では，入力 と同じ長さのデータ集合が，フィットされた分布を使って のもとで生成される．次に，BaringhausHenzeTest[si,"TestStatistic"]からのEmpiricalDistributionを使って 値が推定される． »
  • Method{method,"SmoothingParameter"β}と設定すると，カスタムの平滑化母数 β を使うことができる．デフォルトは である．この場合，検定はHenze-Zirkler検定としても知られるものになる． »

例題

すべて開く すべて閉じる

例  (3)

多変量正規性についての検定を行う：

Wolfram Language code: data = RandomVariate[BinormalDistribution[1 / 2], 1000];
Wolfram Language code: BaringhausHenzeTest[data]

Baringhaus–Henze検定から検定統計を抽出する：

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{1, 2, 3}, {{2, 1, 0}, {1, 3, -1}, {0, -1, 1}}], 1000];
Wolfram Language code: BaringhausHenzeTest[data, "TestStatistic"]

フォーマットされた検定表を得る：

Wolfram Language code: data = RandomVariate[ProductDistribution[BinormalDistribution[2 / 3], BinormalDistribution[-1 / 2]], 1000];
Wolfram Language code: BaringhausHenzeTest[data, "TestDataTable"]

スコープ  (6)

検定  (3)

一変量の正規性についてBaringhaus–Henze検定を行う：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 1000]; data2 = RandomVariate[StudentTDistribution[4], 1000];

正規データの 値は，非正規データの 値と比べて大きい：

Wolfram Language code: BaringhausHenzeTest[data1]
Wolfram Language code: BaringhausHenzeTest[data2]

多変量の正規性についてBaringhaus–Henze検定を行う：

Wolfram Language code: data1 = RandomVariate[MultinormalDistribution[{0, 0, 0}, {{3, 2, 1}, {2, 4, 0}, {1, 0, 2}}], 1000]; data2 = RandomVariate[MultivariateTDistribution[{{3, 2, 1}, {2, 4, 0}, {1, 0, 2}}, 6], 1000];

正規データの 値は，非正規データの 値と比べて大きい：

Wolfram Language code: BaringhausHenzeTest[data1]
Wolfram Language code: BaringhausHenzeTest[data2]

関連特性の抽出のためにHypothesisTestDataオブジェクトを作る：

Wolfram Language code: data = RandomVariate[BinormalDistribution[-0.5], 10^3];
Wolfram Language code: ℋ = BaringhausHenzeTest[data, "HypothesisTestData"]

抽出可能な特性：

Wolfram Language code: ℋ["Properties"]

レポート  (3)

Baringhaus–Henze検定の結果を表にする：

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 10^3];
Wolfram Language code: ℋ = BaringhausHenzeTest[data, "HypothesisTestData"];

完全な検定表：

Wolfram Language code: ℋ["TestDataTable"]

値の表：

Wolfram Language code: ℋ["PValueTable"]

検定統計：

Wolfram Language code: ℋ["TestStatisticTable"]

カスタマイズされたレポート用にBaringhaus–Henze検定の表から項目を取り出す：

Wolfram Language code: data1 = RandomVariate[BinormalDistribution[.5], 10^3]; data2 = RandomVariate[BinormalDistribution[.5], 10^3];
Wolfram Language code: ℋ1 = BaringhausHenzeTest[data1, "TestData"]
Wolfram Language code: ℋ2 = BaringhausHenzeTest[data2, "TestData"]
Wolfram Language code: BarChart[{Labeled[ℋ1, "Set 1"], Labeled[ℋ2, "Set 2"]}, ChartLabels -> {"Statistic", "p‐value"}]

"ShortTestConclusion"と"TestConclusion"を使って検定の結論をレポートする：

Wolfram Language code: data = BlockRandom[SeedRandom[1];RandomVariate[StudentTDistribution[4], {100, 2}]];
Wolfram Language code: ℋ = BaringhausHenzeTest[data, "HypothesisTestData"];
Wolfram Language code: ℋ["ShortTestConclusion"]
Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

有意水準が異なると，結論も異なることがある：

Wolfram Language code: ℋ = BaringhausHenzeTest[data, "HypothesisTestData", SignificanceLevel -> .001];
Wolfram Language code: ℋ["ShortTestConclusion"]
Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

オプション  (3)

Method  (2)

Baringhaus–Henze検定に使われる平滑化母数 β を設定する：

Wolfram Language code: BlockRandom[SeedRandom["fixed"];data = RandomVariate[BinormalDistribution[2 / 3], 1000];]
Wolfram Language code: pvls = Table[{beta, BaringhausHenzeTest[data, Method -> {Automatic, "SmoothingParameter" -> beta}]}, {beta, {0.05, 0.1, 0.25, 0.5, 1, 1.5, 2, 3, 5}}];

平滑化母数 β は結果の 値に影響する：

Wolfram Language code: ListLinePlot[pvls, FrameLabel -> {"β", "P-Value"}, Frame -> True, AxesOrigin -> {0, 0}, PlotRange -> All]

モンテカルロ法に基づくメソッドで使われるランダムなシードを設定する：

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 1000];
Wolfram Language code: pts = Table[{i, BaringhausHenzeTest[data, Method -> {"MonteCarlo", "RandomSeed" -> i, "MonteCarloSamples" -> 100}]}, {i, Range[1, 10]}];

シードは生成器の状態に影響を与え，結果の 値にもいくらか影響を与える：

Wolfram Language code: Show[ListLinePlot[pts, PlotRange -> {Min[pts[[All, 2]]], Max[pts[[All, 2]]]}, FrameLabel -> {"Seed", "P-Value"}, Frame -> True, AxesOrigin -> {0, 0}]]

モンテカルロ法と検定母数 β のカスタム設定を使って 値を求める：

Wolfram Language code: BaringhausHenzeTest[data, Method -> {"MonteCarlo", "MonteCarloSamples" -> 100, "SmoothingParameter" -> 0.25}]

デフォルトメソッドで得られた 値と比較する：

Wolfram Language code: BaringhausHenzeTest[data, Method -> {Automatic, "SmoothingParameter" -> 0.25}]

SignificanceLevel  (1)

"TestConclusion"と"ShortTestConclusion"で使う有意水準を設定する：

Wolfram Language code: data = BlockRandom[SeedRandom[2];RandomVariate[StudentTDistribution[5], {100, 2}]];
Wolfram Language code: BaringhausHenzeTest[data, "ShortTestConclusion", SignificanceLevel -> .1]
Wolfram Language code: BaringhausHenzeTest[data, "ShortTestConclusion", SignificanceLevel -> .25]

デフォルトで0.05が使われる：

Wolfram Language code: BaringhausHenzeTest[data, "TestConclusion"]//TraditionalForm

アプリケーション  (4)

Baringhaus–Henze検定の検出力曲線（が偽であるときにこれを拒絶する確率）：

Wolfram Language code: data = Table[RandomVariate[MultivariateTDistribution[IdentityMatrix[2], 3], {1000, i}], {i, n = Range[10, 50, 5]}];
Wolfram Language code: ℋ = Map[BaringhausHenzeTest, data, {2}];
Wolfram Language code: pC = Interpolation[Transpose[{n, Table[Probability[x ≤ 0.05, xi], {i, ℋ}]}], InterpolationOrder -> 1];

近似検出力曲線曲線を可視化する：

Wolfram Language code: Plot[pC[x], {x, 10, 50}, PlotRange -> {0, 1}, Ticks -> {n, Automatic}, AxesOrigin -> {7, 0}, AxesLabel -> {"Sample Size", "Power"}]

基礎となる分布がMultivariateTDistributionであり，検定サイズが0.05，サンプルサイズが43である場合の，Baringhaus–Henze検定の検出力を推定する：

Wolfram Language code: pC[43.]

連続時間ランダム過程がガウス過程であるかどうかを調べる．非整数ブラウン運動：

Wolfram Language code: proc1 = RandomFunction[FractionalBrownianMotionProcess[0.1, 1., 0.6], {10, 15, 0.1}, 300];
Wolfram Language code: BaringhausHenzeTest[proc1["ValueList"]]

幾何ブラウン運動の対数の差：

Wolfram Language code: proc2 = RandomFunction[GeometricBrownianMotionProcess[0.1, 0.6, 1.], {10, 15, 0.1}, 300];
Wolfram Language code: BaringhausHenzeTest[Differences /@ Log[proc2["ValueList"]]]

コックス・インガソール・ロス(Cox–Ingersoll–Ross)過程の対数の差：

Wolfram Language code: proc3 = RandomFunction[CoxIngersollRossProcess[0.1, 0.6, 0.1, 1.], {10, 15, 0.1}, 300];
Wolfram Language code: BaringhausHenzeTest[Differences /@ Log[proc3["ValueList"]]]

治療研究の前と後の患者の体重が記録されている．データが多変量正規分布に従っていれば，平均の多変量検定を使って対照群と実験群を識別することができる：

Wolfram Language code: data = ExampleData[{"Statistics", "AnorexiaTreatment"}];
Wolfram Language code: ExampleData[{"Statistics", "AnorexiaTreatment"}, "ColumnDescriptions"]
Wolfram Language code: groups = data[[All, 1]];

BaringhausHenzeTestを使って，データの3群が多変量正規分布に従っているかどうかを判定する：

Wolfram Language code: BaringhausHenzeTest[g1 = Pick[data[[All, 2 ;; ]], groups, "Cont"], "ShortTestConclusion"]
Wolfram Language code: BaringhausHenzeTest[g2 = Pick[data[[All, 2 ;; ]], groups, "CBT"], "ShortTestConclusion"]
Wolfram Language code: BaringhausHenzeTest[g3 = Pick[data[[All, 2 ;; ]], groups, "FT"], "ShortTestConclusion"]

Baringhaus–Henze検定はContおよびFTの群を棄却しなかった．TTestを使ってこの2群の平均が等しいかどうかを見る：

Wolfram Language code: TTest[{g1, g3}, 0, "TestDataTable"]

データが標準非相関二変量正規分布に従っているという仮説を検定する：

Wolfram Language code: bhep[rho_Real] := BlockRandom[SeedRandom["example"];BaringhausHenzeTest[RandomVariate[BinormalDistribution[rho], 250], ProductDistribution[{NormalDistribution[], 2}]]]
Wolfram Language code: LogPlot[bhep[rho], {rho, -0.5, 0.5}, PlotRange -> {0.001, 1}]

特性と関係  (5)

Baringhaus–Henze検定は，データに適用された線形変換が非特異であればアフィン不変である：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], {1000, 3}];
Wolfram Language code: data2 = AffineTransform[{ToeplitzMatrix[3], RandomReal[1, 3]}][data1];
Wolfram Language code: Grid[Join[{{"BaringhausHenze Test", "statistic", "p-value"}}, MapThread[Prepend, {{BaringhausHenzeTest[data1, "TestData"], BaringhausHenzeTest[data2, "TestData"]}, {"data1", "data2"}}]], Frame -> All]

正規性についてのMardiaの結合検定はもまた，同じ特性を有する：

Wolfram Language code: Grid[Join[{{"Mardia Combined Test", "statistic", "p-value"}}, MapThread[Prepend, {{MardiaKurtosisTest[data1, "TestData"], MardiaKurtosisTest[data2, "TestData"]}, {"data1", "data2"}}]], Frame -> All]

のもとでは，検定統計はLogNormalDistributionに漸近的に従う：

Wolfram Language code: SeedRandom[10]; n = 25; t = Table[BaringhausHenzeTest[RandomVariate[ MultinormalDistribution[{0, 1}, ToeplitzMatrix[{2, 1}]], n], "TestStatistic"], {10 ^ 3}];

検定統計がLogNormalDistribution族からの分布に従うかどうかの検定を行う：

Wolfram Language code: DistributionFitTest[t, LogNormalDistribution[mu, sig], "ShortTestConclusion"]

検定統計のヒストグラムを正規対数密度とともに示す：

Wolfram Language code: pdf = PDF[EstimatedDistribution[t, LogNormalDistribution[mu, sig]]]
Wolfram Language code: Show[Histogram[t, {0.05}, "PDF"], Plot[pdf[x], {x, 0, 2}]]

BaringhausHenzeTest統計は，帰無仮説のもとでサンプルの経験特性関数と特性関数の間の距離に基づいている：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {100, 2}];
Wolfram Language code: StandardizeAndDecorrelate[data_] := With[{c = Transpose[Subtract[Transpose[data], Mean[data]]]}, c.Inverse[CholeskyDecomposition[Mean[Outer[Times, #, #]& /@ c]]]]

経験特性関数を定義し，距離を比較する：

Wolfram Language code: cf[{t1_, t2_}] = CharacteristicFunction[EmpiricalDistribution[StandardizeAndDecorrelate[data]], {t1, t2}];
Wolfram Language code: d[{t1_Real, t2_Real}] := Length[data]Abs[cf[{t1, t2}] - Exp[-(t1 ^ 2 + t2 ^ 2) / 2]] ^ 2
Wolfram Language code: NExpectation[d[{t1, t2}], {t1NormalDistribution[0, 2], t2NormalDistribution[0, 2]}]

BaringhausHenzeTestでレポートされた検定特性の値と比較する：

Wolfram Language code: BaringhausHenzeTest[data, "TestStatistic", Method -> {Automatic, "SmoothingParameter" -> 2}]

退化したサンプル共分散関数のサンプルについては，検定統計その最大値である4 n を与える：

Wolfram Language code: htd = BaringhausHenzeTest[ConstantArray[0, {3, 2}], "HypothesisTestData"];
Wolfram Language code: htd["TestStatistic"]

対応する 値は0である：

Wolfram Language code: htd["PValue"]

小さい値の平滑化母数 β については，Baringhaus–Henze検定は裾部の動作により敏感である：

Wolfram Language code: data = RandomVariate[MultivariateTDistribution[IdentityMatrix[3], 4], {2000, 50}];
Wolfram Language code: bhepP[beta_Real] := BaringhausHenzeTest[#, Method -> {Automatic, "SmoothingParameter" -> beta}]& /@ data

平滑化母数の関数としての多変量正規仮説の棄却率：

Wolfram Language code: Table[{beta, NProbability[x < 0.05, xbhepP[beta]]}, {beta, {0.05, 0.1, 0.5, 1.0, 5.0}}]

Mardia検定と比較する：

Wolfram Language code: Table[NProbability[x < 0.05, xtest /@ data], {test, {MardiaCombinedTest, MardiaSkewnessTest, MardiaKurtosisTest}}]

おもしろい例題  (1)

標準の正規境界で二変量分布を定義する：

Wolfram Language code: bv𝒟 = TransformedDistribution[{X, (2Z - 1) X}, {XNormalDistribution[], ZBernoulliDistribution[2 / 3]}];

境界分布は標準ガウス分布である：

Wolfram Language code: CharacteristicFunction[MarginalDistribution[bv𝒟, 1], t] == CharacteristicFunction[MarginalDistribution[bv𝒟, 2], t] == CharacteristicFunction[NormalDistribution[], t]

二変量分布からのサンプル：

Wolfram Language code: data = RandomVariate[bv𝒟, 1000];

その成分のヒストグラムをプロットし，標準正規分布の密度関数と比較する：

Wolfram Language code: GraphicsRow[Show[Histogram[#, {0.2}, "PDF"], Plot[PDF[NormalDistribution[], x], {x, -3, 3}]]& /@ Transpose[data], ImageSize -> 400]

分布 は同時ガウス分布ではない：

Wolfram Language code: BaringhausHenzeTest[data]

サンプルされた確率ベクトルを平面上に示す：

Wolfram Language code: ListPlot[data, AspectRatio -> 1, AxesLabel -> {"SubscriptBox[X, 1]", "SubscriptBox[X, 2]"}]
Wolfram Research (2015), BaringhausHenzeTest, Wolfram言語関数， https://reference.wolfram.com/language/ref/BaringhausHenzeTest.html.

テキスト

Wolfram Research (2015), BaringhausHenzeTest, Wolfram言語関数， https://reference.wolfram.com/language/ref/BaringhausHenzeTest.html.

CMS

Wolfram Language. 2015. "BaringhausHenzeTest." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BaringhausHenzeTest.html.

APA

Wolfram Language. (2015). BaringhausHenzeTest. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BaringhausHenzeTest.html

BibTeX

@misc{reference.wolfram_2026_baringhaushenzetest, author="Wolfram Research", title="{BaringhausHenzeTest}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/BaringhausHenzeTest.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_baringhaushenzetest, organization={Wolfram Research}, title={BaringhausHenzeTest}, year={2015}, url={https://reference.wolfram.com/language/ref/BaringhausHenzeTest.html}, note=[Accessed: 15-August-2026]}