WOLFRAM

Wolfram 语言与系统参考资料中心

BaringhausHenzeTest[data]

用 Baringhaus–Henze 检验来检验数据是否遵循 MultinormalDistribution.

BaringhausHenzeTest[data,MultinormalDistribution[μ,Σ]]

检验数据是否遵循平均向量为 μ 、协方差矩阵为 Σ 的分布.

BaringhausHenzeTest[data,"property"]

返回 "property" 的值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
检验  
报告  
选项  
Method  
SignificanceLevel  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

BaringhausHenzeTest

BaringhausHenzeTest[data]

用 Baringhaus–Henze 检验来检验数据是否遵循 MultinormalDistribution.

BaringhausHenzeTest[data,MultinormalDistribution[μ,Σ]]

检验数据是否遵循平均向量为 μ 、协方差矩阵为 Σ 的分布.

BaringhausHenzeTest[data,"property"]

返回 "property" 的值.

更多信息和选项

  • BaringhausHenzeTest 执行一个拟合优度检验, 零假设 下从 MultinormalDistribution 中提取 data ，而备择假设 下则不是.
  • BaringhausHenzeTest 也叫做 Baringhaus–Henze–Epps–Pulley 多变量正态性检验或者 BHEP 检验.
  • 默认情况下，一个概率值或 -值被返回.
  • 一个小的 -值意味着 data 不大可能来自一个多变量正态分布.
  • data 可以是单变量 {x1,…,xn} 或多变量 {{x1,y1,…},…,{xn,yn,…}}.
  • Baringhaus–Henze 检验实际上使用基于去相关标准化 data 的经验特征函数和标准的多变量高斯特征函数 Tβ=Expectation[n Abs[Ψemp[t]-Ψst[t]]2,{t1,…,td}] 之间的 距离的检验统计量 Tβ ，其中 =ProductDistribution[{NormalDistribution[0,β],d}]. »
  • 参数 β 为正且决定了经验分布的平滑性. 它是自动确定的，但是可以使用 Method 设置来更改.
  • BaringhausHenzeTest[data,MultinormalDistribution[μ,Σ],"HypothesisTestData"] 返回一个可以通过 htd["property"] 形式提取额外检验结果及属性的 HypothesisTestData 对象 htd .
  • BaringhausHenzeTest[data,MultinormalDistribution[μ,Σ],"property"] 可用于直接给出 "property" 的值.
  • 与报告检验结果相关的属性包括：
  • "PValue"-值
    "PValueTable""PValue" 的格式化形式
    "ShortTestConclusion"检验结果的简短说明
    "TestConclusion"检验结果的说明
    "TestData"检验统计量和 -值
    "TestDataTable""TestData" 的格式化形式
    "TestStatistic"检验统计量
    "TestStatisticTable"格式化的"TestStatistic"
  • 下列属性与执行哪种检验无关.
  • 与数据分布相关的属性包括：
  • "FittedDistribution"数据的拟合分布
    "FittedDistributionParameters"数据的分布参数
  • 可以给出下列选项：
  • Method Automatic用于计算 -值的方法
    SignificanceLevel 0.05进行诊断并报告的临界值
  • 对于一个拟合优度检验，选择临界值 使得只在 的情况下拒绝 . 用于 "TestConclusion" 和 "ShortTestConclusion" 属性的 值由 SignificanceLevel 选项来控制. 默认情况下 被设为 0.05. »
  • 通过设置 Method->"MonteCarlo"，在 下使用拟合分布生成一些长度相同的数据集作为输入 . 然后用 BaringhausHenzeTest[si,"TestStatistic"] 中的 EmpiricalDistribution 来估计 -值. »
  • 设置 Method{method,"SmoothingParameter"β} 允许自定义平滑参数 β. 默认情况下，，这种情况下的检验亦被称作 Henze-Zirkler 检验. »

范例

打开所有单元 关闭所有单元

基本范例  (3)

执行一个多变量正态性检验：

Wolfram Language code: data = RandomVariate[BinormalDistribution[1 / 2], 1000];
Wolfram Language code: BaringhausHenzeTest[data]

从 Baringhaus–Henze 检验中提取检验统计量：

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{1, 2, 3}, {{2, 1, 0}, {1, 3, -1}, {0, -1, 1}}], 1000];
Wolfram Language code: BaringhausHenzeTest[data, "TestStatistic"]

获取格式化检验表：

Wolfram Language code: data = RandomVariate[ProductDistribution[BinormalDistribution[2 / 3], BinormalDistribution[-1 / 2]], 1000];
Wolfram Language code: BaringhausHenzeTest[data, "TestDataTable"]

范围  (6)

检验  (3)

执行一个单变量正态性 Baringhaus–Henze 检验：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 1000]; data2 = RandomVariate[StudentTDistribution[4], 1000];

正常数据的 -值相对于非正常数据的 -值是很大的：

Wolfram Language code: BaringhausHenzeTest[data1]
Wolfram Language code: BaringhausHenzeTest[data2]

执行一个多变量正态性 Baringhaus–Henze 检验：

Wolfram Language code: data1 = RandomVariate[MultinormalDistribution[{0, 0, 0}, {{3, 2, 1}, {2, 4, 0}, {1, 0, 2}}], 1000]; data2 = RandomVariate[MultivariateTDistribution[{{3, 2, 1}, {2, 4, 0}, {1, 0, 2}}, 6], 1000];

正常数据的 -值相对于非正常数据的 -值是很大的：

Wolfram Language code: BaringhausHenzeTest[data1]
Wolfram Language code: BaringhausHenzeTest[data2]

为重复提取属性创建一个 HypothesisTestData 对象：

Wolfram Language code: data = RandomVariate[BinormalDistribution[-0.5], 10^3];
Wolfram Language code: ℋ = BaringhausHenzeTest[data, "HypothesisTestData"]

可供提取的属性：

Wolfram Language code: ℋ["Properties"]

报告  (3)

将 Baringhaus–Henze 检验结果制成表格：

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 10^3];
Wolfram Language code: ℋ = BaringhausHenzeTest[data, "HypothesisTestData"];

完整的检验表格：

Wolfram Language code: ℋ["TestDataTable"]

-值表：

Wolfram Language code: ℋ["PValueTable"]

检验统计量：

Wolfram Language code: ℋ["TestStatisticTable"]

为定制报告从 Baringhaus–Henze 检验表中找出相应条目：

Wolfram Language code: data1 = RandomVariate[BinormalDistribution[.5], 10^3]; data2 = RandomVariate[BinormalDistribution[.5], 10^3];
Wolfram Language code: ℋ1 = BaringhausHenzeTest[data1, "TestData"]
Wolfram Language code: ℋ2 = BaringhausHenzeTest[data2, "TestData"]
Wolfram Language code: BarChart[{Labeled[ℋ1, "Set 1"], Labeled[ℋ2, "Set 2"]}, ChartLabels -> {"Statistic", "p‐value"}]

使用 "ShortTestConclusion" 和 "TestConclusion" 报告检验结论：

Wolfram Language code: data = BlockRandom[SeedRandom[1];RandomVariate[StudentTDistribution[4], {100, 2}]];
Wolfram Language code: ℋ = BaringhausHenzeTest[data, "HypothesisTestData"];
Wolfram Language code: ℋ["ShortTestConclusion"]
Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

在不同的显著性水平上检验结论可能不同：

Wolfram Language code: ℋ = BaringhausHenzeTest[data, "HypothesisTestData", SignificanceLevel -> .001];
Wolfram Language code: ℋ["ShortTestConclusion"]
Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

选项  (3)

Method  (2)

设置用于 Baringhaus–Henze 检验的平滑参数 β：

Wolfram Language code: BlockRandom[SeedRandom["fixed"];data = RandomVariate[BinormalDistribution[2 / 3], 1000];]
Wolfram Language code: pvls = Table[{beta, BaringhausHenzeTest[data, Method -> {Automatic, "SmoothingParameter" -> beta}]}, {beta, {0.05, 0.1, 0.25, 0.5, 1, 1.5, 2, 3, 5}}];

平滑参数 β 会影响相应的 -值：

Wolfram Language code: ListLinePlot[pvls, FrameLabel -> {"β", "P-Value"}, Frame -> True, AxesOrigin -> {0, 0}, PlotRange -> All]

设置用于基于蒙特卡罗方法的随机种子：

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 1000];
Wolfram Language code: pts = Table[{i, BaringhausHenzeTest[data, Method -> {"MonteCarlo", "RandomSeed" -> i, "MonteCarloSamples" -> 100}]}, {i, Range[1, 10]}];

种子会影响生成器的状态，对相应的 -值也有一定的影响:

Wolfram Language code: Show[ListLinePlot[pts, PlotRange -> {Min[pts[[All, 2]]], Max[pts[[All, 2]]]}, FrameLabel -> {"Seed", "P-Value"}, Frame -> True, AxesOrigin -> {0, 0}]]

用蒙特卡洛方法和自定义检验参数 β 来找到 -值：

Wolfram Language code: BaringhausHenzeTest[data, Method -> {"MonteCarlo", "MonteCarloSamples" -> 100, "SmoothingParameter" -> 0.25}]

与用默认方法获得的 -值相比较：

Wolfram Language code: BaringhausHenzeTest[data, Method -> {Automatic, "SmoothingParameter" -> 0.25}]

SignificanceLevel  (1)

设置用于 "TestConclusion" 和 "ShortTestConclusion" 的显著性水平：

Wolfram Language code: data = BlockRandom[SeedRandom[2];RandomVariate[StudentTDistribution[5], {100, 2}]];
Wolfram Language code: BaringhausHenzeTest[data, "ShortTestConclusion", SignificanceLevel -> .1]
Wolfram Language code: BaringhausHenzeTest[data, "ShortTestConclusion", SignificanceLevel -> .25]

默认情况下使用 0.05 ：

Wolfram Language code: BaringhausHenzeTest[data, "TestConclusion"]//TraditionalForm

应用  (4)

Baringhaus–Henze 检验的功效曲线（当 为假是将其拒绝的机率）：

Wolfram Language code: data = Table[RandomVariate[MultivariateTDistribution[IdentityMatrix[2], 3], {1000, i}], {i, n = Range[10, 50, 5]}];
Wolfram Language code: ℋ = Map[BaringhausHenzeTest, data, {2}];
Wolfram Language code: pC = Interpolation[Transpose[{n, Table[Probability[x ≤ 0.05, xi], {i, ℋ}]}], InterpolationOrder -> 1];

显示近似的功效曲线：

Wolfram Language code: Plot[pC[x], {x, 10, 50}, PlotRange -> {0, 1}, Ticks -> {n, Automatic}, AxesOrigin -> {7, 0}, AxesLabel -> {"Sample Size", "Power"}]

当分布为MultivariateTDistribution、检验水平是 0.05 且样本量是43时估计 Baringhaus–Henze 检验的功效：

Wolfram Language code: pC[43.]

检查连续时间随机过程是否为高斯过程. 分数布朗运动：

Wolfram Language code: proc1 = RandomFunction[FractionalBrownianMotionProcess[0.1, 1., 0.6], {10, 15, 0.1}, 300];
Wolfram Language code: BaringhausHenzeTest[proc1["ValueList"]]

几何布朗运动的对数的差分：

Wolfram Language code: proc2 = RandomFunction[GeometricBrownianMotionProcess[0.1, 0.6, 1.], {10, 15, 0.1}, 300];
Wolfram Language code: BaringhausHenzeTest[Differences /@ Log[proc2["ValueList"]]]

Cox–Ingersoll–Ross 过程的对数的差分：

Wolfram Language code: proc3 = RandomFunction[CoxIngersollRossProcess[0.1, 0.6, 0.1, 1.], {10, 15, 0.1}, 300];
Wolfram Language code: BaringhausHenzeTest[Differences /@ Log[proc3["ValueList"]]]

病人在接受某种疗法前后的体重被记录下来. 如果数据遵循多变量正态分布，那么均值的多变量检验可用作区别对照组和实验组的检验：

Wolfram Language code: data = ExampleData[{"Statistics", "AnorexiaTreatment"}];
Wolfram Language code: ExampleData[{"Statistics", "AnorexiaTreatment"}, "ColumnDescriptions"]
Wolfram Language code: groups = data[[All, 1]];

用 BaringhausHenzeTest 确定这三组数据是否为多变量正态分布:

Wolfram Language code: BaringhausHenzeTest[g1 = Pick[data[[All, 2 ;; ]], groups, "Cont"], "ShortTestConclusion"]
Wolfram Language code: BaringhausHenzeTest[g2 = Pick[data[[All, 2 ;; ]], groups, "CBT"], "ShortTestConclusion"]
Wolfram Language code: BaringhausHenzeTest[g3 = Pick[data[[All, 2 ;; ]], groups, "FT"], "ShortTestConclusion"]

Cont 和 FT 组中的数据没有被 Baringhaus–Henze 检验拒绝. 使用 TTest 检验这两组的均值是否相同：

Wolfram Language code: TTest[{g1, g3}, 0, "TestDataTable"]

检验数据服从标准不相关双正态分布的假设：

Wolfram Language code: bhep[rho_Real] := BlockRandom[SeedRandom["example"];BaringhausHenzeTest[RandomVariate[BinormalDistribution[rho], 250], ProductDistribution[{NormalDistribution[], 2}]]]
Wolfram Language code: LogPlot[bhep[rho], {rho, -0.5, 0.5}, PlotRange -> {0.001, 1}]

属性和关系  (5)

如果应用于数据的线性变换是非奇异的，则 Baringhaus–Henze 检验是仿射不变的：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], {1000, 3}];
Wolfram Language code: data2 = AffineTransform[{ToeplitzMatrix[3], RandomReal[1, 3]}][data1];
Wolfram Language code: Grid[Join[{{"BaringhausHenze Test", "statistic", "p-value"}}, MapThread[Prepend, {{BaringhausHenzeTest[data1, "TestData"], BaringhausHenzeTest[data2, "TestData"]}, {"data1", "data2"}}]], Frame -> All]

检验正态性的 Mardia 组合检验也享有一样的性质：

Wolfram Language code: Grid[Join[{{"Mardia Combined Test", "statistic", "p-value"}}, MapThread[Prepend, {{MardiaKurtosisTest[data1, "TestData"], MardiaKurtosisTest[data2, "TestData"]}, {"data1", "data2"}}]], Frame -> All]

在 下检验统计量渐近地遵循 LogNormalDistribution：

Wolfram Language code: SeedRandom[10]; n = 25; t = Table[BaringhausHenzeTest[RandomVariate[ MultinormalDistribution[{0, 1}, ToeplitzMatrix[{2, 1}]], n], "TestStatistic"], {10 ^ 3}];

查看检验统计量是否遵循 LogNormalDistribution 族中的某个分布：

Wolfram Language code: DistributionFitTest[t, LogNormalDistribution[mu, sig], "ShortTestConclusion"]

显示具有对数正态密度的检验统计量的直方图：

Wolfram Language code: pdf = PDF[EstimatedDistribution[t, LogNormalDistribution[mu, sig]]]
Wolfram Language code: Show[Histogram[t, {0.05}, "PDF"], Plot[pdf[x], {x, 0, 2}]]

BaringhausHenzeTest 统计量是基于样本经验特征函数和零假设下的特征函数之间的距离的：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {100, 2}];
Wolfram Language code: StandardizeAndDecorrelate[data_] := With[{c = Transpose[Subtract[Transpose[data], Mean[data]]]}, c.Inverse[CholeskyDecomposition[Mean[Outer[Times, #, #]& /@ c]]]]

定义经验特征函数并计算距离：

Wolfram Language code: cf[{t1_, t2_}] = CharacteristicFunction[EmpiricalDistribution[StandardizeAndDecorrelate[data]], {t1, t2}];
Wolfram Language code: d[{t1_Real, t2_Real}] := Length[data]Abs[cf[{t1, t2}] - Exp[-(t1 ^ 2 + t2 ^ 2) / 2]] ^ 2
Wolfram Language code: NExpectation[d[{t1, t2}], {t1NormalDistribution[0, 2], t2NormalDistribution[0, 2]}]

与 BaringhausHenzeTest 报告的检验统计量相比：

Wolfram Language code: BaringhausHenzeTest[data, "TestStatistic", Method -> {Automatic, "SmoothingParameter" -> 2}]

对具有退化样本协方差函数的样本, 检验统计量给出其最大值 4 n:

Wolfram Language code: htd = BaringhausHenzeTest[ConstantArray[0, {3, 2}], "HypothesisTestData"];
Wolfram Language code: htd["TestStatistic"]

相应的 -值等于零：

Wolfram Language code: htd["PValue"]

当平滑参数 β 取较小的值时， Baringhaus–Henze 检验对尾的特性更敏感：

Wolfram Language code: data = RandomVariate[MultivariateTDistribution[IdentityMatrix[3], 4], {2000, 50}];
Wolfram Language code: bhepP[beta_Real] := BaringhausHenzeTest[#, Method -> {Automatic, "SmoothingParameter" -> beta}]& /@ data

拒绝多变量正态性假设的比例是平滑参数的函数：

Wolfram Language code: Table[{beta, NProbability[x < 0.05, xbhepP[beta]]}, {beta, {0.05, 0.1, 0.5, 1.0, 5.0}}]

与 Mardia 检验对比：

Wolfram Language code: Table[NProbability[x < 0.05, xtest /@ data], {test, {MardiaCombinedTest, MardiaSkewnessTest, MardiaKurtosisTest}}]

巧妙范例  (1)

定义一个有标准正态边缘的双变量分布：

Wolfram Language code: bv𝒟 = TransformedDistribution[{X, (2Z - 1) X}, {XNormalDistribution[], ZBernoulliDistribution[2 / 3]}];

边缘分布是标准高斯分布：

Wolfram Language code: CharacteristicFunction[MarginalDistribution[bv𝒟, 1], t] == CharacteristicFunction[MarginalDistribution[bv𝒟, 2], t] == CharacteristicFunction[NormalDistribution[], t]

双变量分布中的样本：

Wolfram Language code: data = RandomVariate[bv𝒟, 1000];

画出其分量的直方图并与标准正态分布的密度函数相比较：

Wolfram Language code: GraphicsRow[Show[Histogram[#, {0.2}, "PDF"], Plot[PDF[NormalDistribution[], x], {x, -3, 3}]]& /@ Transpose[data], ImageSize -> 400]

分布不是联合高斯分布：

Wolfram Language code: BaringhausHenzeTest[data]

在平面上显示随机向量的抽样：

Wolfram Language code: ListPlot[data, AspectRatio -> 1, AxesLabel -> {"SubscriptBox[X, 1]", "SubscriptBox[X, 2]"}]
Wolfram Research (2015)，BaringhausHenzeTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BaringhausHenzeTest.html.

文本

Wolfram Research (2015)，BaringhausHenzeTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BaringhausHenzeTest.html.

CMS

Wolfram 语言. 2015. "BaringhausHenzeTest." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BaringhausHenzeTest.html.

APA

Wolfram 语言. (2015). BaringhausHenzeTest. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BaringhausHenzeTest.html 年

BibTeX

@misc{reference.wolfram_2026_baringhaushenzetest, author="Wolfram Research", title="{BaringhausHenzeTest}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/BaringhausHenzeTest.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_baringhaushenzetest, organization={Wolfram Research}, title={BaringhausHenzeTest}, year={2015}, url={https://reference.wolfram.com/language/ref/BaringhausHenzeTest.html}, note=[Accessed: 14-August-2026]}