BatesDistribution

0から1までに一様分布した n 個の確率変数の平均の分布を表す．

BatesDistribution[n,{min,max}]

min から max までに一様分布した n 個の確率変数の平均の分布を表す．

詳細

一様確率変数の平均の分布における値の確率密度は，ではに比例し，その他では0である．
BatesDistribution[n,{min,max}]は各 x_iがUniformDistribution[{min,max}]に従うTransformedDistribution[(x₁+⋯+x_n)/n,…]に等しい．
BatesDistributionでは，n は任意の正の整数，min と max は min<max の任意の実数でよい．
BatesDistributionでは，min と max は単位次元が等しい任意の数量でよく，n は無次元量でよい． »
BatesDistributionは，Mean，CDF，RandomVariate等の関数とともに使うことができる．

予備知識

BatesDistribution[n,{min,max}]は，min から max までの区間で定義され，正の整数 n でパラメータ化された統計分布を表す．Bates分布の確率密度関数(PDF)の全体的な形は，n によって著しく変わり，では一様，では三角，では単峰となる．1引数の形のBatesDistribution[n]はBatesDistribution[n,{0,1}]に等しく，標準化されたBates分布と呼ばれることがある．
数学的には，Bates分布BatesDistribution[n]は，n 個の統計的に独立の一様分布に従う確率変数の平均として定義される．つまり，XBatesDistribution[n]はであると言うのに等しい．ただし，すべてのについて X_iUniformDistribution[]である．2引数の形のBatesDistribution[n,{min,max}]も，UniformDistribution[{min,max}]という例外を除いて同じ意味を持つ．Bates分布の重要な応用の1つは計算にある．歴史的に，の標準化されたBates分布が標準正規変数の生成に使われてきた．
RandomVariateを使ってBates分布から，1つあるいは複数の機械精度あるいは任意精度（後者はWorkingPrecisionオプションを介す）の擬似乱数変量を得ることができる．Distributed[x,BatesDistribution[n,{min,max}]]（より簡略すると xBatesDistribution[n,{min,max}]）を使って，確率変数 x がBates分布に従って分布していると宣言することができる．このような宣言は，Probability，NProbability，Expectation，NExpectation等の関数で使うことができる．
確率密度関数および累積分布関数は，PDF[BatesDistribution[n,{min,max}],x]およびCDF[BatesDistribution[n,{min,max}],x]を使って得られることがある．平均，中央値，分散，原点の周りのモーメント，中心モーメントは，それぞれMean，Median，Variance，Moment，CentralMomentを使って計算することができる．
DistributionFitTestを使って，与えられたデータ集合がBates分布と一致するかどうかを検定することが，EstimatedDistributionを使って与えられたデータからBatesパラメトリック分布を推定することが，FindDistributionParametersを使ってデータをBates分布にフィットすることができる．ProbabilityPlotを使って記号Bates分布のCDFに対する与えられたデータのCDFのプロットを生成することが，QuantilePlotを使って記号Bates分布の変位値に対する与えられたデータの変位値のプロットを生成することができる．
TransformedDistributionを使って変換されたBates分布を表すことが，CensoredDistributionを使って上限値と下限値の間で切り取られた値の分布を表すことが，TruncatedDistributionを使って上限値と下限値の間で切断された値の分布を表すことができる．CopulaDistributionを使ってBates分布を含む高次元分布を構築することが，ProductDistributionを使ってBates分布を含む独立成分分布の結合分布を計算することができる．
BatesDistributionは他の数多くの分布と関連している．例えばBates分布のPDFは，厳密に，のときはUniformDistribution，のときはTriangularDistributionであり，より大きいの値についてはNormalDistributionのPDFと視覚的に似ている．BatesDistributionは，統計的に独立な一様分布に従う確率変数の（平均ではなく）和を表すUniformSumDistributionとも密接な関係がある．

例題

すべて開くすべて閉じる

例 (4)

確率密度関数：

Wolfram Language code: Plot[Table[PDF[BatesDistribution[n], x], {n, {1, 2, 5}}]//Evaluate, {x, 0, 1}, Filling -> Axis, Exclusions -> None]

累積分布関数：

Wolfram Language code: Plot[Table[CDF[BatesDistribution[n], x], {n, {1, 2, 5}}]//Evaluate, {x, 0, 1}, Filling -> Axis, Exclusions -> None]

平均：

Wolfram Language code: Mean[BatesDistribution[n]]

Wolfram Language code: Mean[BatesDistribution[n, {min, max}]]

分散：

Wolfram Language code: Variance[BatesDistribution[n]]

Wolfram Language code: Variance[BatesDistribution[n, {min, max}]]

スコープ (8)

Bates分布から擬似乱数のサンプルを生成する：

Wolfram Language code: data = RandomVariate[BatesDistribution[4], 10 ^ 4];

そのヒストグラムを確率密度関数と比較する：

Wolfram Language code: Show[Histogram[data, 15, "PDF"], Plot[PDF[BatesDistribution[4], x], {x, 0, 1}, PlotStyle -> Thick]]

分布母数推定：

Wolfram Language code: sample = RandomVariate[BatesDistribution[3], 10 ^ 3];

サンプルデータから分布母数を推定する：

Wolfram Language code: edist = EstimatedDistribution[sample, BatesDistribution[n]]

データヒストグラムを推定分布の確率密度関数と比較する：

Wolfram Language code: Show[Histogram[sample, 20, "PDF"], Plot[PDF[edist, x], {x, 0, 1}, PlotStyle -> Thick]]

歪度：

Wolfram Language code: Skewness[BatesDistribution[n]]

Wolfram Language code: Skewness[BatesDistribution[n, {min, max}]]

尖度は領域には依存しない：

Wolfram Language code: DiscretePlot[Kurtosis[BatesDistribution[n, {min, max}]], {n, 1, 10}]

Wolfram Language code: Kurtosis[BatesDistribution[n]]//Simplify

Wolfram Language code: Kurtosis[BatesDistribution[n, {min, max}]]//Simplify

極限では，尖度はNormalDistributionの尖度に等しい：

Wolfram Language code: Limit[Kurtosis[BatesDistribution[n]], n -> ∞]

母数の関数としての閉じた形の種々のモーメント：

Wolfram Language code: FormulaGrid[list_, type_] := Grid[...]

Moment：

Wolfram Language code: FormulaGrid[Table[Moment[BatesDistribution[n], r]//Factor, {r, 5}], M]

記号次数の閉じた形：

Wolfram Language code: Moment[BatesDistribution[n], r]

CentralMoment：

Wolfram Language code: FormulaGrid[Table[CentralMoment[BatesDistribution[n], r], {r, 5}], CM]

記号次数の閉じた形：

Wolfram Language code: CentralMoment[BatesDistribution[n], r]

FactorialMoment：

Wolfram Language code: FormulaGrid[Table[FactorialMoment[BatesDistribution[n], r]//Factor, {r, 5}], FM]

Cumulant：

Wolfram Language code: FormulaGrid[Table[Cumulant[BatesDistribution[n], r], {r, 5}], C]

記号次数の閉じた形：

Wolfram Language code: Cumulant[BatesDistribution[n], r]

ハザード関数：

Wolfram Language code:

Plot[Table[HazardFunction[BatesDistribution[n], x], {n, {2, 3, 4}}]//Evaluate, {x, 0, 0.99}, Filling -> Axis, Exclusions -> None]

分位関数：

Wolfram Language code: Plot[Table[Quantile[BatesDistribution[n], q], {n, {2, 4, 8}}]//Evaluate, {q, 0, 1}, Filling -> Axis, Exclusions -> None]

母数でQuantityを一貫して使うとQuantityDistributionが与えられる：

Wolfram Language code: pressure𝒟 = BatesDistribution[3, {Quantity[100, "Newtons"/"Meters"^2], Quantity[120, "Newtons"/"Meters"^2]}]

平均圧力を計算する：

Wolfram Language code: Mean[pressure𝒟]

Wolfram Language code: UnitSimplify[%]

アプリケーション (2)

一様分布の平均はBates分布に従う：

Wolfram Language code: pdf2 = PDF[TransformedDistribution[(u + v) / 2, {u, v}ProductDistribution[{UniformDistribution[], 2}]], x];

Wolfram Language code: pdf3 = PDF[TransformedDistribution[(u + v + w) / 3, {u, v, w}ProductDistribution[{UniformDistribution[], 3}]], x];

Wolfram Language code:

pdf4 = PDF[TransformedDistribution[(u + v + w + z) / 4, {u, v, w, z}ProductDistribution[{UniformDistribution[], 4}]], x];

Wolfram Language code: Batespdf[n_] := PDF[BatesDistribution[n], x]

Wolfram Language code:

{Plot[{pdf2, pdf3, pdf4}, {x, 0, 1}, Exclusions -> None], Plot[{Batespdf[2], Batespdf[3], Batespdf[4]}, {x, 0, 1}, Exclusions -> None]}

あるデバイスの寿命には，A，B，Cの3つの段階がある．各段階における時間（単位：時間）は上の一様分布に従い，段階Cを過ぎると故障する．各段階に留まる平均時間の分布を求める：

Wolfram Language code: 𝒟 = BatesDistribution[3, {Quantity[0, "Hours"], Quantity[10, "Hours"]}];

Wolfram Language code: Plot[PDF[𝒟, Quantity[x, "Hours"]], {x, 0, 10}, Filling -> Axis, Exclusions -> None, AxesLabel -> {"h"}]

一つの段階に留まる平均時間を求める：

Wolfram Language code: Mean[𝒟]

このデバイスが一つの段階に平均で4時間以上留まる確率を求める：

Wolfram Language code: Probability[x > Quantity[4, "Hours"], x𝒟]

Wolfram Language code: N[%]

同種のデバイス30個で同一段階に留まる平均時間のシミュレーションを行う：

Wolfram Language code:

ListPlot[{RandomVariate[𝒟, 30], {{0, Mean[𝒟]}, {30, Mean[𝒟]}}}, Filling -> Axis, Joined -> {False, True}, AxesLabel -> Automatic]

特性と関係 (5)

Bates分布は平行移動とスケーリングの下では閉じている：

Wolfram Language code: TransformedDistribution[a * u + b, uBatesDistribution[n, {min, max}], Assumptions -> a > 0]

負の因子によるスケーリング：

Wolfram Language code: TransformedDistribution[a * u + b, uBatesDistribution[n, {min, max}], Assumptions -> a < 0]

デフォルト領域は区間である：

Wolfram Language code: CharacteristicFunction[BatesDistribution[n, {0, 1}], t]

Wolfram Language code: CharacteristicFunction[BatesDistribution[n], t]

Wolfram Language code: % - %%

他の分布との関係：

一様分布に従う n 個の変数の平均の分布はBates分布に従う：

Wolfram Language code: (CharacteristicFunction[UniformDistribution[{min, max}], t / n]) ^ n

Wolfram Language code: CharacteristicFunction[BatesDistribution[n, {min, max}], t]

Wolfram Language code: Simplify[% - %%]

三角分布はBates分布の特殊なケースである：

Wolfram Language code: CharacteristicFunction[TriangularDistribution[{0, 1}], t]

Wolfram Language code: CharacteristicFunction[BatesDistribution[2], t]

Wolfram Language code: % - %%//FullSimplify

おもしろい例題 (1)

累積分布関数の等高線を持つ n のさまざまな値についての確率密度関数：

Wolfram Language code:

dist = BatesDistribution[Floor[n]];cdf = Function[{x, n}, Evaluate[CDF[dist, x]]];
ql = {0.025, 0.10, 0.25, 0.5, 0.75, 0.90, 0.975};
cl = Table[ColorData["Rainbow"][q], {q, Join[{0.0}, ql]}];

Wolfram Language code:

Legended[Plot3D[PDF[dist, x], {x, 0, 1}, {n, 1, 20}, PlotTheme -> "Marketing", MeshFunctions -> {cdf}, Mesh -> {ql}, MeshStyle -> GrayLevel[0.8], PlotRange -> All, Exclusions -> Sin[Pi n] == 0, MeshShading -> cl, AxesLabel -> Automatic, PlotPoints -> 40, BaseStyle -> Opacity[0.9], ImageSize -> 400], BarLegend["Rainbow", ql, LegendLabel -> "prob"]]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

BatesDistribution

詳細

予備知識

例題

例 (4)

スコープ (8)

アプリケーション (2)

特性と関係 (5)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

BatesDistribution

詳細

予備知識

例題

例 (4)

スコープ (8)

アプリケーション (2)

特性と関係 (5)

おもしろい例題 (1)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX